CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.1svn")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME LLVM)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  29
  30 # Sanity check our source directory to make sure that we are not trying to
  31 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  32 # sure that we don't have any stray generated files lying around in the tree
  33 # (which would end up getting picked up by header search, instead of the correct
  34 # versions).
  35 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  36   message(FATAL_ERROR "In-source builds are not allowed.
  37 CMake would overwrite the makefiles distributed with LLVM.
  38 Please create a directory and run cmake from there, passing the path
  39 to this source directory as the last argument.
  40 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  41 Please delete them.")
  42 endif()
  43 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  44   file(GLOB_RECURSE
  45     tablegenned_files_on_include_dir
  46     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_lib_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  50   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  51     message(FATAL_ERROR "Apparently there is a previous in-source build,
  52 probably as the result of running `configure' and `make' on
  53 ${CMAKE_CURRENT_SOURCE_DIR}.
  54 This may cause problems. The suspicious files are:
  55 ${tablegenned_files_on_lib_dir}
  56 ${tablegenned_files_on_include_dir}
  57 Please clean the source directory.")
  58   endif()
  59 endif()
  60
  61 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  62
  63 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  64 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  65 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  66 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  67 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  68 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  69
  70 set(LLVM_ALL_TARGETS
  71   ARM
  72   CBackend
  73   CellSPU
  74   CppBackend
  75   Hexagon
  76   Mips
  77   MBlaze
  78   MSP430
  79   PowerPC
  80   PTX
  81   Sparc
  82   X86
  83   XCore
  84   )
  85
  86 # List of targets with JIT support:
  87 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  88
  89 if( MSVC )
  90   set(LLVM_TARGETS_TO_BUILD X86
  91     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  92 else( MSVC )
  93   set(LLVM_TARGETS_TO_BUILD "all"
  94     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  95 endif( MSVC )
  96
  97 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  98 if(LLVM_ENABLE_CBE_PRINTF_A)
  99   set(ENABLE_CBE_PRINTF_A 1)
 100 endif()
 101
 102 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 103 if(LLVM_ENABLE_TIMESTAMPS)
 104   set(ENABLE_TIMESTAMPS 1)
 105 endif()
 106
 107 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 108 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 109 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 110
 111 set(LLVM_TARGET_ARCH "host"
 112   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 113
 114 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 115
 116 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 117   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 118 endif()
 119
 120 set(LLVM_ENUM_TARGETS "")
 121 foreach(c ${LLVM_TARGETS_TO_BUILD})
 122   list(FIND LLVM_ALL_TARGETS ${c} idx)
 123   if( idx LESS 0 )
 124     message(FATAL_ERROR "The target `${c}' does not exist.
 125     It should be one of\n${LLVM_ALL_TARGETS}")
 126   else()
 127     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 128   endif()
 129 endforeach(c)
 130
 131 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 132
 133 include(AddLLVMDefinitions)
 134
 135 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 136
 137 # MSVC has a gazillion warnings with this.
 138 if( MSVC )
 139   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 140 else( MSVC )
 141   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 142 endif()
 143
 144 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 145 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 146
 147 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 148   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 149 else()
 150   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 151 endif()
 152
 153 # Define an option controlling whether we should build for 32-bit on 64-bit
 154 # platforms, where supported.
 155 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 156   # TODO: support other platforms and toolchains.
 157   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 158 endif()
 159
 160 # Define the default arguments to use with 'lit', and an option for the user to
 161 # override.
 162 set(LIT_ARGS_DEFAULT "-sv")
 163 if (MSVC OR XCODE)
 164   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 165 endif()
 166 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 167
 168 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 169 if( WIN32 AND NOT CYGWIN )
 170   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 171 endif()
 172
 173 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 174 # to use.
 175 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 176   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 177   # 2005 supports it but it is experimental.
 178   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 179     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 180 endif()
 181
 182 # Define options to control the inclusion and default build behavior for
 183 # components which may not strictly be necessary (tools, runtime, examples, and
 184 # tests).
 185 #
 186 # This is primarily to support building smaller or faster project files.
 187 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 188 option(LLVM_BUILD_TOOLS
 189   "Build the LLVM tools. If OFF, just generate build targets." ON)
 190
 191 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 192 option(LLVM_BUILD_RUNTIME
 193   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 194
 195 option(LLVM_BUILD_EXAMPLES
 196   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 197 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 198
 199 option(LLVM_BUILD_TESTS
 200   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 201 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 202
 203 # All options referred to from HandleLLVMOptions have to be specified
 204 # BEFORE this include, otherwise options will not be correctly set on
 205 # first cmake run
 206 include(config-ix)
 207 include(HandleLLVMOptions)
 208
 209 # Verify that we can find a Python interpreter,
 210 include(FindPythonInterp)
 211 if( NOT PYTHONINTERP_FOUND )
 212   message(FATAL_ERROR
 213 "Unable to find Python interpreter, required for builds and testing.
 214
 215 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 216 endif()
 217
 218 ######
 219 # LLVMBuild Integration
 220 #
 221 # We use llvm-build to generate all the data required by the CMake based
 222 # build system in one swoop:
 223 #
 224 #  - We generate a file (a CMake fragment) in the object root which contains
 225 #    all the definitions that are required by CMake.
 226 #
 227 #  - We generate the library table used by llvm-config.
 228 #
 229 #  - We generate the dependencies for the CMake fragment, so that we will
 230 #    automatically reconfigure outselves.
 231
 232 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 233 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 234   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 235 set(LLVMBUILDCMAKEFRAG
 236   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 237 message(STATUS "Constructing LLVMBuild project information")
 238 execute_process(
 239   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 240             --native-target "${LLVM_NATIVE_ARCH}"
 241             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 242             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 243             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 244             ERROR_VARIABLE LLVMBUILDOUTPUT
 245             ERROR_VARIABLE LLVMBUILDERRORS
 246             OUTPUT_STRIP_TRAILING_WHITESPACE
 247             ERROR_STRIP_TRAILING_WHITESPACE
 248   RESULT_VARIABLE LLVMBUILDRESULT)
 249
 250 # On Win32, CMake doesn't properly handle piping the default output/error
 251 # streams into the GUI console. So, we explicitly catch and report them.
 252 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 253   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 254 endif()
 255 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 256   message(FATAL_ERROR
 257     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 258 endif()
 259
 260 # Include the generated CMake fragment. This will define properties from the
 261 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 262 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 263 # files change.
 264 include(${LLVMBUILDCMAKEFRAG})
 265
 266 ######
 267
 268 # Configure all of the various header file fragments LLVM uses which depend on
 269 # configuration variables.
 270 set(LLVM_ENUM_ASM_PRINTERS "")
 271 set(LLVM_ENUM_ASM_PARSERS "")
 272 set(LLVM_ENUM_DISASSEMBLERS "")
 273 foreach(t ${LLVM_TARGETS_TO_BUILD})
 274   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 275   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 276   if( asmp_file )
 277     set(LLVM_ENUM_ASM_PRINTERS
 278       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 279   endif()
 280   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 281     set(LLVM_ENUM_ASM_PARSERS
 282       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 283   endif()
 284   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 285     set(LLVM_ENUM_DISASSEMBLERS
 286       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 287   endif()
 288 endforeach(t)
 289
 290 # Produce the target definition files, which provide a way for clients to easily
 291 # include various classes of targets.
 292 configure_file(
 293   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 294   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 295   )
 296 configure_file(
 297   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 298   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 299   )
 300 configure_file(
 301   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 302   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 303   )
 304 configure_file(
 305   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 306   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 307   )
 308
 309 # Configure the three LLVM configuration header files.
 310 configure_file(
 311   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 312   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 313 configure_file(
 314   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 315   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 316 configure_file(
 317   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 318   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 319
 320 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 321 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 322 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 323
 324 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 325
 326 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 327
 328 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 329    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 330 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 331
 332 include(AddLLVM)
 333 include(TableGen)
 334
 335 if( MINGW )
 336   # People report that -O3 is unreliable on MinGW. The traditional
 337   # build also uses -O2 for that reason:
 338   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 339 endif()
 340
 341 # Put this before tblgen. Else we have a circular dependence.
 342 add_subdirectory(lib/Support)
 343 add_subdirectory(lib/TableGen)
 344
 345 add_subdirectory(utils/TableGen)
 346
 347 add_subdirectory(include/llvm)
 348
 349 add_subdirectory(lib)
 350
 351 add_subdirectory(utils/FileCheck)
 352 add_subdirectory(utils/FileUpdate)
 353 add_subdirectory(utils/count)
 354 add_subdirectory(utils/not)
 355 add_subdirectory(utils/llvm-lit)
 356 add_subdirectory(utils/json-bench)
 357
 358 add_subdirectory(projects)
 359
 360 if( LLVM_INCLUDE_TOOLS )
 361   add_subdirectory(tools)
 362 endif()
 363
 364 if( LLVM_INCLUDE_RUNTIME )
 365   add_subdirectory(runtime)
 366 endif()
 367
 368 if( LLVM_INCLUDE_EXAMPLES )
 369   add_subdirectory(examples)
 370 endif()
 371
 372 if( LLVM_INCLUDE_TESTS )
 373   add_subdirectory(test)
 374   add_subdirectory(utils/unittest)
 375   add_subdirectory(unittests)
 376   if (MSVC)
 377     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 378     # Windows.
 379     add_subdirectory(utils/KillTheDoctor)
 380   endif()
 381 endif()
 382
 383 add_subdirectory(cmake/modules)
 384
 385 install(DIRECTORY include/
 386   DESTINATION include
 387   FILES_MATCHING
 388   PATTERN "*.def"
 389   PATTERN "*.h"
 390   PATTERN "*.td"
 391   PATTERN "*.inc"
 392   PATTERN "LICENSE.TXT"
 393   PATTERN ".svn" EXCLUDE
 394   )
 395
 396 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 397   DESTINATION include
 398   FILES_MATCHING
 399   PATTERN "*.def"
 400   PATTERN "*.h"
 401   PATTERN "*.gen"
 402   PATTERN "*.inc"
 403   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 404   PATTERN "CMakeFiles" EXCLUDE
 405   PATTERN ".svn" EXCLUDE
 406   )
 407
 408 # TODO: make and install documentation.
 409
 410 set(CPACK_PACKAGE_VENDOR "LLVM")
 411 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 412 set(CPACK_PACKAGE_VERSION_MINOR 9)
 413 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 414 include(CPack)
 415
 416 # Workaround for MSVS10 to avoid the Dialog Hell
 417 # FIXME: This could be removed with future version of CMake.
 418 if(MSVC_VERSION EQUAL 1600)
 419   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 420   if( EXISTS "${LLVM_SLN_FILENAME}" )
 421     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 422   endif()
 423 endif()