CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  19
  20 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  21 if ( LLVM_USE_FOLDERS )
  22   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  23 endif()
  24
  25 if(MSVC AND NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11))
  26   # set stack reserved size to ~10MB
  27   # CMake previously automatically set this value for MSVC builds, but the
  28   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
  29   # value (1 MB) which is not enough for us in tasks such as parsing recursive
  30   # C++ templates in Clang.
  31   set(CMAKE_CXX_STACK_SIZE "10000000")
  32 endif()
  33
  34 include(VersionFromVCS)
  35
  36 option(LLVM_APPEND_VC_REV
  37   "Append the version control system revision id to LLVM version" OFF)
  38
  39 if( LLVM_APPEND_VC_REV )
  40   add_version_info_from_vcs(PACKAGE_VERSION)
  41 endif()
  42
  43 set(PACKAGE_NAME LLVM)
  44 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  45 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  46
  47 # Configure CPack.
  48 set(CPACK_PACKAGE_VENDOR "LLVM")
  49 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  50 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  51 if( LLVM_APPEND_VC_REV )
  52   add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
  53 else()
  54   set(CPACK_PACKAGE_VERSION_PATCH "svn")
  55 endif()
  56 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  57 if(WIN32 AND NOT UNIX)
  58   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  59   set(CPACK_NSIS_MODIFY_PATH "ON")
  60   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  61   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  62     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  63   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  64     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  65 endif()
  66 include(CPack)
  67
  68 # Sanity check our source directory to make sure that we are not trying to
  69 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  70 # sure that we don't have any stray generated files lying around in the tree
  71 # (which would end up getting picked up by header search, instead of the correct
  72 # versions).
  73 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  74   message(FATAL_ERROR "In-source builds are not allowed.
  75 CMake would overwrite the makefiles distributed with LLVM.
  76 Please create a directory and run cmake from there, passing the path
  77 to this source directory as the last argument.
  78 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  79 Please delete them.")
  80 endif()
  81 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  82   file(GLOB_RECURSE
  83     tablegenned_files_on_include_dir
  84     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  85   file(GLOB_RECURSE
  86     tablegenned_files_on_lib_dir
  87     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  88   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  89     message(FATAL_ERROR "Apparently there is a previous in-source build,
  90 probably as the result of running `configure' and `make' on
  91 ${CMAKE_CURRENT_SOURCE_DIR}.
  92 This may cause problems. The suspicious files are:
  93 ${tablegenned_files_on_lib_dir}
  94 ${tablegenned_files_on_include_dir}
  95 Please clean the source directory.")
  96   endif()
  97 endif()
  98
  99 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 100
 101 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 102 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
 103 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 104 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
 105 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 106 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 107
 108 set(LLVM_ALL_TARGETS
 109   AArch64
 110   ARM
 111   CppBackend
 112   Hexagon
 113   Mips
 114   MSP430
 115   NVPTX
 116   PowerPC
 117   R600
 118   Sparc
 119   SystemZ
 120   X86
 121   XCore
 122   )
 123
 124 # List of targets with JIT support:
 125 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 126
 127 set(LLVM_TARGETS_TO_BUILD "all"
 128     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 129
 130 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 131   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 132
 133 option(BUILD_SHARED_LIBS
 134   "Build all libraries as shared libraries instead of static" OFF)
 135
 136 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 137 if(LLVM_ENABLE_CBE_PRINTF_A)
 138   set(ENABLE_CBE_PRINTF_A 1)
 139 endif()
 140
 141 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 142 if(LLVM_ENABLE_TIMESTAMPS)
 143   set(ENABLE_TIMESTAMPS 1)
 144 endif()
 145
 146 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 147 if(LLVM_ENABLE_BACKTRACES)
 148   set(ENABLE_BACKTRACES 1)
 149 endif()
 150
 151 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 152 if(LLVM_ENABLE_CRASH_OVERRIDES)
 153   set(ENABLE_CRASH_OVERRIDES 1)
 154 endif()
 155
 156 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 157 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 158 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 159
 160 set(LLVM_TARGET_ARCH "host"
 161   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 162
 163 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 164
 165 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 166
 167 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 168
 169 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 170   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 171 endif()
 172
 173 set(LLVM_TARGETS_TO_BUILD
 174    ${LLVM_TARGETS_TO_BUILD}
 175    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 176 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 177
 178 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 179
 180 include(AddLLVMDefinitions)
 181
 182 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 183
 184 # MSVC has a gazillion warnings with this.
 185 if( MSVC )
 186   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 187 else( MSVC )
 188   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 189 endif()
 190
 191 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 192 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 193
 194 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 195   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 196 else()
 197   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 198 endif()
 199
 200 option(LLVM_USE_INTEL_JITEVENTS
 201   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 202   OFF)
 203
 204 if( LLVM_USE_INTEL_JITEVENTS )
 205   # Verify we are on a supported platform
 206   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 207     message(FATAL_ERROR
 208       "Intel JIT API support is available on Linux and Windows only.")
 209   endif()
 210 endif( LLVM_USE_INTEL_JITEVENTS )
 211
 212 option(LLVM_USE_OPROFILE
 213   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 214
 215 # If enabled, verify we are on a platform that supports oprofile.
 216 if( LLVM_USE_OPROFILE )
 217   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 218     message(FATAL_ERROR "OProfile support is available on Linux only.")
 219   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 220 endif( LLVM_USE_OPROFILE )
 221
 222 set(LLVM_USE_SANITIZER "" CACHE STRING
 223   "Define the sanitizer used to build binaries and tests.")
 224
 225 option(LLVM_USE_SPLIT_DWARF
 226   "Use -gsplit-dwarf when compiling llvm." OFF)
 227
 228 # Define an option controlling whether we should build for 32-bit on 64-bit
 229 # platforms, where supported.
 230 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 231   # TODO: support other platforms and toolchains.
 232   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 233 endif()
 234
 235 # Define the default arguments to use with 'lit', and an option for the user to
 236 # override.
 237 set(LIT_ARGS_DEFAULT "-sv")
 238 if (MSVC OR XCODE)
 239   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 240 endif()
 241 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 242
 243 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 244 if( WIN32 AND NOT CYGWIN )
 245   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 246 endif()
 247
 248 # Define options to control the inclusion and default build behavior for
 249 # components which may not strictly be necessary (tools, examples, and tests).
 250 #
 251 # This is primarily to support building smaller or faster project files.
 252 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 253 option(LLVM_BUILD_TOOLS
 254   "Build the LLVM tools. If OFF, just generate build targets." ON)
 255
 256 option(LLVM_BUILD_RUNTIME
 257   "Build the LLVM runtime libraries." ON)
 258 option(LLVM_BUILD_EXAMPLES
 259   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 260 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 261
 262 option(LLVM_BUILD_TESTS
 263   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 264 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 265
 266 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 267 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 268 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 269
 270 # All options referred to from HandleLLVMOptions have to be specified
 271 # BEFORE this include, otherwise options will not be correctly set on
 272 # first cmake run
 273 include(config-ix)
 274
 275 # By default, we target the host, but this can be overridden at CMake
 276 # invocation time.
 277 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 278   "Default target for which LLVM will generate code." )
 279 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 280
 281 include(HandleLLVMOptions)
 282
 283 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 284 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 285 include(FindPythonInterp)
 286 if( NOT PYTHONINTERP_FOUND )
 287   message(FATAL_ERROR
 288 "Unable to find Python interpreter, required for builds and testing.
 289
 290 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 291 endif()
 292
 293 ######
 294 # LLVMBuild Integration
 295 #
 296 # We use llvm-build to generate all the data required by the CMake based
 297 # build system in one swoop:
 298 #
 299 #  - We generate a file (a CMake fragment) in the object root which contains
 300 #    all the definitions that are required by CMake.
 301 #
 302 #  - We generate the library table used by llvm-config.
 303 #
 304 #  - We generate the dependencies for the CMake fragment, so that we will
 305 #    automatically reconfigure outselves.
 306
 307 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 308 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 309   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 310 set(LLVMBUILDCMAKEFRAG
 311   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 312
 313 # Create the list of optional components that are enabled
 314 if (LLVM_USE_INTEL_JITEVENTS)
 315   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 316 endif (LLVM_USE_INTEL_JITEVENTS)
 317 if (LLVM_USE_OPROFILE)
 318   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 319 endif (LLVM_USE_OPROFILE)
 320
 321 message(STATUS "Constructing LLVMBuild project information")
 322 execute_process(
 323   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 324             --native-target "${LLVM_NATIVE_ARCH}"
 325             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 326             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 327             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 328             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 329             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 330             ERROR_VARIABLE LLVMBUILDERRORS
 331             OUTPUT_STRIP_TRAILING_WHITESPACE
 332             ERROR_STRIP_TRAILING_WHITESPACE
 333   RESULT_VARIABLE LLVMBUILDRESULT)
 334
 335 # On Win32, CMake doesn't properly handle piping the default output/error
 336 # streams into the GUI console. So, we explicitly catch and report them.
 337 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 338   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 339 endif()
 340 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 341   message(FATAL_ERROR
 342     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 343 endif()
 344
 345 # Include the generated CMake fragment. This will define properties from the
 346 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 347 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 348 # files change.
 349 include(${LLVMBUILDCMAKEFRAG})
 350
 351 ######
 352
 353 # Configure all of the various header file fragments LLVM uses which depend on
 354 # configuration variables.
 355 set(LLVM_ENUM_TARGETS "")
 356 set(LLVM_ENUM_ASM_PRINTERS "")
 357 set(LLVM_ENUM_ASM_PARSERS "")
 358 set(LLVM_ENUM_DISASSEMBLERS "")
 359 foreach(t ${LLVM_TARGETS_TO_BUILD})
 360   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 361
 362   list(FIND LLVM_ALL_TARGETS ${t} idx)
 363   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 364   if( idx LESS 0 AND idy LESS 0 )
 365     message(FATAL_ERROR "The target `${t}' does not exist.
 366     It should be one of\n${LLVM_ALL_TARGETS}")
 367   else()
 368     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 369   endif()
 370
 371   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 372   if( asmp_file )
 373     set(LLVM_ENUM_ASM_PRINTERS
 374       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 375   endif()
 376   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 377     set(LLVM_ENUM_ASM_PARSERS
 378       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 379   endif()
 380   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 381     set(LLVM_ENUM_DISASSEMBLERS
 382       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 383   endif()
 384 endforeach(t)
 385
 386 # Produce the target definition files, which provide a way for clients to easily
 387 # include various classes of targets.
 388 configure_file(
 389   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 390   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 391   )
 392 configure_file(
 393   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 394   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 395   )
 396 configure_file(
 397   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 398   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 399   )
 400 configure_file(
 401   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 402   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 403   )
 404
 405 # Configure the three LLVM configuration header files.
 406 configure_file(
 407   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 408   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 409 configure_file(
 410   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 411   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 412 configure_file(
 413   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 414   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 415
 416 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 417 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 418 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 419
 420 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 421
 422 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 423
 424 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 425   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 426   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 427   include_directories("/usr/local/include")
 428   link_directories("/usr/local/lib")
 429 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 430
 431 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 432    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 433 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 434
 435 # Make sure we don't get -rdynamic in every binary. For those that need it,
 436 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 437 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 438
 439 include(AddLLVM)
 440 include(TableGen)
 441
 442 if( MINGW )
 443   # People report that -O3 is unreliable on MinGW. The traditional
 444   # build also uses -O2 for that reason:
 445   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 446 endif()
 447
 448 # Put this before tblgen. Else we have a circular dependence.
 449 add_subdirectory(lib/Support)
 450 add_subdirectory(lib/TableGen)
 451
 452 add_subdirectory(utils/TableGen)
 453
 454 add_subdirectory(include/llvm)
 455
 456 add_subdirectory(lib)
 457
 458 add_subdirectory(utils/FileCheck)
 459 add_subdirectory(utils/FileUpdate)
 460 add_subdirectory(utils/count)
 461 add_subdirectory(utils/not)
 462 add_subdirectory(utils/llvm-lit)
 463 add_subdirectory(utils/yaml-bench)
 464
 465 add_subdirectory(projects)
 466
 467 if( LLVM_INCLUDE_TOOLS )
 468   add_subdirectory(tools)
 469 endif()
 470
 471 if( LLVM_INCLUDE_EXAMPLES )
 472   add_subdirectory(examples)
 473 endif()
 474
 475 if( LLVM_INCLUDE_TESTS )
 476   add_subdirectory(test)
 477   add_subdirectory(utils/unittest)
 478   add_subdirectory(unittests)
 479   if (MSVC)
 480     # This utility is used to prevent crashing tests from calling Dr. Watson on
 481     # Windows.
 482     add_subdirectory(utils/KillTheDoctor)
 483   endif()
 484
 485   # Add a global check rule now that all subdirectories have been traversed
 486   # and we know the total set of lit testsuites.
 487   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 488   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 489   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 490   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 491   add_lit_target(check-all
 492     "Running all regression tests"
 493     ${LLVM_LIT_TESTSUITES}
 494     PARAMS ${LLVM_LIT_PARAMS}
 495     DEPENDS ${LLVM_LIT_DEPENDS}
 496     ARGS ${LLVM_LIT_EXTRA_ARGS}
 497     )
 498 endif()
 499
 500 if (LLVM_INCLUDE_DOCS)
 501   add_subdirectory(docs)
 502 endif()
 503
 504 add_subdirectory(cmake/modules)
 505
 506 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 507   install(DIRECTORY include/
 508     DESTINATION include
 509     FILES_MATCHING
 510     PATTERN "*.def"
 511     PATTERN "*.h"
 512     PATTERN "*.td"
 513     PATTERN "*.inc"
 514     PATTERN "LICENSE.TXT"
 515     PATTERN ".svn" EXCLUDE
 516     )
 517
 518   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 519     DESTINATION include
 520     FILES_MATCHING
 521     PATTERN "*.def"
 522     PATTERN "*.h"
 523     PATTERN "*.gen"
 524     PATTERN "*.inc"
 525     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 526     PATTERN "CMakeFiles" EXCLUDE
 527     PATTERN ".svn" EXCLUDE
 528     )
 529 endif()
 530
 531 # Workaround for MSVS10 to avoid the Dialog Hell
 532 # FIXME: This could be removed with future version of CMake.
 533 if(MSVC_VERSION EQUAL 1600)
 534   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 535   if( EXISTS "${LLVM_SLN_FILENAME}" )
 536     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 537   endif()
 538 endif()