CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  20   set(cmake_3_2_USES_TERMINAL)
  21 else()
  22   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  23 endif()
  24
  25 project(LLVM)
  26
  27 # The following only works with the Ninja generator in CMake >= 3.0.
  28 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  29   "Define the maximum number of concurrent compilation jobs.")
  30 if(LLVM_PARALLEL_COMPILE_JOBS)
  31   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33 endif()
  34
  35 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  36   "Define the maximum number of concurrent link jobs.")
  37 if(LLVM_PARALLEL_LINK_JOBS)
  38   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  39   set(CMAKE_JOB_POOL_LINK link_job_pool)
  40 endif()
  41
  42 # Add path for custom modules
  43 set(CMAKE_MODULE_PATH
  44   ${CMAKE_MODULE_PATH}
  45   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  46   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  47   )
  48
  49 set(LLVM_VERSION_MAJOR 3)
  50 set(LLVM_VERSION_MINOR 7)
  51 set(LLVM_VERSION_PATCH 0)
  52
  53 if (NOT PACKAGE_VERSION)
  54   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  55 endif()
  56
  57 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  58
  59 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  60 if ( LLVM_USE_FOLDERS )
  61   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  62 endif()
  63
  64 include(VersionFromVCS)
  65
  66 option(LLVM_APPEND_VC_REV
  67   "Append the version control system revision id to LLVM version" OFF)
  68
  69 if( LLVM_APPEND_VC_REV )
  70   add_version_info_from_vcs(PACKAGE_VERSION)
  71 endif()
  72
  73 set(PACKAGE_NAME LLVM)
  74 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  75 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  76
  77 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  78   "Default URL where bug reports are to be submitted.")
  79
  80 # Configure CPack.
  81 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  82 set(CPACK_PACKAGE_VENDOR "LLVM")
  83 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  84 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  85 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  86 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  87 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  88 if(WIN32 AND NOT UNIX)
  89   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  90   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  91   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  92   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  93   set(CPACK_NSIS_MODIFY_PATH "ON")
  94   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  95   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  96     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  97   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  98     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  99 endif()
 100 include(CPack)
 101
 102 # Sanity check our source directory to make sure that we are not trying to
 103 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 104 # sure that we don't have any stray generated files lying around in the tree
 105 # (which would end up getting picked up by header search, instead of the correct
 106 # versions).
 107 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 108   message(FATAL_ERROR "In-source builds are not allowed.
 109 CMake would overwrite the makefiles distributed with LLVM.
 110 Please create a directory and run cmake from there, passing the path
 111 to this source directory as the last argument.
 112 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 113 Please delete them.")
 114 endif()
 115 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 116   file(GLOB_RECURSE
 117     tablegenned_files_on_include_dir
 118     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 119   file(GLOB_RECURSE
 120     tablegenned_files_on_lib_dir
 121     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 122   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 123     message(FATAL_ERROR "Apparently there is a previous in-source build,
 124 probably as the result of running `configure' and `make' on
 125 ${CMAKE_CURRENT_SOURCE_DIR}.
 126 This may cause problems. The suspicious files are:
 127 ${tablegenned_files_on_lib_dir}
 128 ${tablegenned_files_on_include_dir}
 129 Please clean the source directory.")
 130   endif()
 131 endif()
 132
 133 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 134
 135 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 136
 137 # They are used as destination of target generators.
 138 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 139 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 140 if(WIN32 OR CYGWIN)
 141   # DLL platform -- put DLLs into bin.
 142   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 143 else()
 144   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 145 endif()
 146
 147 # Each of them corresponds to llvm-config's.
 148 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 149 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 150 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 151 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 152 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 153
 154 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 155 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 156
 157 set(LLVM_ALL_TARGETS
 158   AArch64
 159   ARM
 160   CppBackend
 161   Hexagon
 162   Mips
 163   MSP430
 164   NVPTX
 165   PowerPC
 166   R600
 167   Sparc
 168   SystemZ
 169   X86
 170   XCore
 171   )
 172
 173 # List of targets with JIT support:
 174 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 175
 176 set(LLVM_TARGETS_TO_BUILD "all"
 177     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 178
 179 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 180   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 181
 182 option(BUILD_SHARED_LIBS
 183   "Build all libraries as shared libraries instead of static" OFF)
 184
 185 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 186 if(LLVM_ENABLE_TIMESTAMPS)
 187   set(ENABLE_TIMESTAMPS 1)
 188 endif()
 189
 190 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 191 if(LLVM_ENABLE_BACKTRACES)
 192   set(ENABLE_BACKTRACES 1)
 193 endif()
 194
 195 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 196 if(LLVM_ENABLE_CRASH_OVERRIDES)
 197   set(ENABLE_CRASH_OVERRIDES 1)
 198 endif()
 199
 200 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 201 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 202 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 203
 204 set(LLVM_TARGET_ARCH "host"
 205   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 206
 207 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 208
 209 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 210
 211 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 212
 213 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 214   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 215 endif()
 216
 217 set(LLVM_TARGETS_TO_BUILD
 218    ${LLVM_TARGETS_TO_BUILD}
 219    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 220 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 221
 222 include(AddLLVMDefinitions)
 223
 224 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 225
 226 # MSVC has a gazillion warnings with this.
 227 if( MSVC )
 228   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 229 else()
 230   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 231 endif()
 232
 233 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 234 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 235 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 236 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 237 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 238
 239 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 240   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 241 else()
 242   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 243 endif()
 244
 245 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 246        "Set to ON to force using an old, unsupported host toolchain." OFF)
 247
 248 option(LLVM_USE_INTEL_JITEVENTS
 249   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 250   OFF)
 251
 252 if( LLVM_USE_INTEL_JITEVENTS )
 253   # Verify we are on a supported platform
 254   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 255     message(FATAL_ERROR
 256       "Intel JIT API support is available on Linux and Windows only.")
 257   endif()
 258 endif( LLVM_USE_INTEL_JITEVENTS )
 259
 260 option(LLVM_USE_OPROFILE
 261   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 262
 263 # If enabled, verify we are on a platform that supports oprofile.
 264 if( LLVM_USE_OPROFILE )
 265   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 266     message(FATAL_ERROR "OProfile support is available on Linux only.")
 267   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 268 endif( LLVM_USE_OPROFILE )
 269
 270 set(LLVM_USE_SANITIZER "" CACHE STRING
 271   "Define the sanitizer used to build binaries and tests.")
 272
 273 option(LLVM_USE_SPLIT_DWARF
 274   "Use -gsplit-dwarf when compiling llvm." OFF)
 275
 276 option(WITH_POLLY "Build LLVM with Polly" ON)
 277 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 278
 279 # Define an option controlling whether we should build for 32-bit on 64-bit
 280 # platforms, where supported.
 281 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 282   # TODO: support other platforms and toolchains.
 283   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 284 endif()
 285
 286 # Define the default arguments to use with 'lit', and an option for the user to
 287 # override.
 288 set(LIT_ARGS_DEFAULT "-sv")
 289 if (MSVC OR XCODE)
 290   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 291 endif()
 292 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 293
 294 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 295 if( WIN32 AND NOT CYGWIN )
 296   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 297 endif()
 298
 299 # Define options to control the inclusion and default build behavior for
 300 # components which may not strictly be necessary (tools, examples, and tests).
 301 #
 302 # This is primarily to support building smaller or faster project files.
 303 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 304 option(LLVM_BUILD_TOOLS
 305   "Build the LLVM tools. If OFF, just generate build targets." ON)
 306
 307 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 308
 309 option(LLVM_BUILD_RUNTIME
 310   "Build the LLVM runtime libraries." ON)
 311 option(LLVM_BUILD_EXAMPLES
 312   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 313 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 314
 315 option(LLVM_BUILD_TESTS
 316   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 317 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 318
 319 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 320 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 321 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 322 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 323
 324 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 325   "Build compiler-rt as an external project." OFF)
 326
 327 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 328 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 329 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 330   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 331 endif()
 332
 333 # All options referred to from HandleLLVMOptions have to be specified
 334 # BEFORE this include, otherwise options will not be correctly set on
 335 # first cmake run
 336 include(config-ix)
 337
 338 # By default, we target the host, but this can be overridden at CMake
 339 # invocation time.
 340 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 341   "Default target for which LLVM will generate code." )
 342 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 343
 344 include(HandleLLVMOptions)
 345
 346 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 347 # FIXME: We should support systems with only Python 3, but that requires work
 348 # on LLDB.
 349 set(Python_ADDITIONAL_VERSIONS 2.7)
 350 include(FindPythonInterp)
 351 if( NOT PYTHONINTERP_FOUND )
 352   message(FATAL_ERROR
 353 "Unable to find Python interpreter, required for builds and testing.
 354
 355 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 356 endif()
 357
 358 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 359   message(FATAL_ERROR "Python 2.7 or newer is required")
 360 endif()
 361
 362 ######
 363 # LLVMBuild Integration
 364 #
 365 # We use llvm-build to generate all the data required by the CMake based
 366 # build system in one swoop:
 367 #
 368 #  - We generate a file (a CMake fragment) in the object root which contains
 369 #    all the definitions that are required by CMake.
 370 #
 371 #  - We generate the library table used by llvm-config.
 372 #
 373 #  - We generate the dependencies for the CMake fragment, so that we will
 374 #    automatically reconfigure outselves.
 375
 376 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 377 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 378   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 379 set(LLVMBUILDCMAKEFRAG
 380   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 381
 382 # Create the list of optional components that are enabled
 383 if (LLVM_USE_INTEL_JITEVENTS)
 384   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 385 endif (LLVM_USE_INTEL_JITEVENTS)
 386 if (LLVM_USE_OPROFILE)
 387   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 388 endif (LLVM_USE_OPROFILE)
 389
 390 message(STATUS "Constructing LLVMBuild project information")
 391 execute_process(
 392   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 393             --native-target "${LLVM_NATIVE_ARCH}"
 394             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 395             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 396             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 397             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 398             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 399             ERROR_VARIABLE LLVMBUILDERRORS
 400             OUTPUT_STRIP_TRAILING_WHITESPACE
 401             ERROR_STRIP_TRAILING_WHITESPACE
 402   RESULT_VARIABLE LLVMBUILDRESULT)
 403
 404 # On Win32, CMake doesn't properly handle piping the default output/error
 405 # streams into the GUI console. So, we explicitly catch and report them.
 406 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 407   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 408 endif()
 409 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 410   message(FATAL_ERROR
 411     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 412 endif()
 413
 414 # Include the generated CMake fragment. This will define properties from the
 415 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 416 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 417 # files change.
 418 include(${LLVMBUILDCMAKEFRAG})
 419
 420 ######
 421
 422 # Configure all of the various header file fragments LLVM uses which depend on
 423 # configuration variables.
 424 set(LLVM_ENUM_TARGETS "")
 425 set(LLVM_ENUM_ASM_PRINTERS "")
 426 set(LLVM_ENUM_ASM_PARSERS "")
 427 set(LLVM_ENUM_DISASSEMBLERS "")
 428 foreach(t ${LLVM_TARGETS_TO_BUILD})
 429   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 430
 431   list(FIND LLVM_ALL_TARGETS ${t} idx)
 432   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 433   if( idx LESS 0 AND idy LESS 0 )
 434     message(FATAL_ERROR "The target `${t}' does not exist.
 435     It should be one of\n${LLVM_ALL_TARGETS}")
 436   else()
 437     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 438   endif()
 439
 440   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 441   if( asmp_file )
 442     set(LLVM_ENUM_ASM_PRINTERS
 443       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 444   endif()
 445   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 446     set(LLVM_ENUM_ASM_PARSERS
 447       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 448   endif()
 449   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 450     set(LLVM_ENUM_DISASSEMBLERS
 451       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 452   endif()
 453 endforeach(t)
 454
 455 # Produce the target definition files, which provide a way for clients to easily
 456 # include various classes of targets.
 457 configure_file(
 458   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 459   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 460   )
 461 configure_file(
 462   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 463   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 464   )
 465 configure_file(
 466   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 467   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 468   )
 469 configure_file(
 470   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 471   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 472   )
 473
 474 # Configure the three LLVM configuration header files.
 475 configure_file(
 476   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 477   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 478 configure_file(
 479   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 480   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 481 configure_file(
 482   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 483   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 484
 485 # They are not referenced. See set_output_directory().
 486 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 487 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 488 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 489
 490 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 491 if (APPLE)
 492   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 493   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 494 else(UNIX)
 495   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 496     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 497     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 498       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 499       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 500     endif()
 501   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 502 endif()
 503
 504 # Work around a broken bfd ld behavior. When linking a binary with a
 505 # foo.so library, it will try to find any library that foo.so uses and
 506 # check its symbols. This is wasteful (the check was done when foo.so
 507 # was created) and can fail since it is not the dynamic linker and
 508 # doesn't know how to handle search paths correctly.
 509 if (UNIX AND NOT APPLE)
 510   set(CMAKE_EXE_LINKER_FLAGS
 511       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 512 endif()
 513
 514 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 515
 516 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 517
 518 # when crosscompiling import the executable targets from a file
 519 if(CMAKE_CROSSCOMPILING)
 520   include(CrossCompile)
 521 endif(CMAKE_CROSSCOMPILING)
 522
 523 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 524   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 525   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 526   include_directories("/usr/local/include")
 527   link_directories("/usr/local/lib")
 528 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 529
 530 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 531    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 532 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 533
 534 # Make sure we don't get -rdynamic in every binary. For those that need it,
 535 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 536 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 537
 538 include(AddLLVM)
 539 include(TableGen)
 540
 541 if( MINGW )
 542   # People report that -O3 is unreliable on MinGW. The traditional
 543   # build also uses -O2 for that reason:
 544   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 545 endif()
 546
 547 # Put this before tblgen. Else we have a circular dependence.
 548 add_subdirectory(lib/Support)
 549 add_subdirectory(lib/TableGen)
 550
 551 add_subdirectory(utils/TableGen)
 552
 553 add_subdirectory(include/llvm)
 554
 555 add_subdirectory(lib)
 556
 557 if( LLVM_INCLUDE_UTILS )
 558   add_subdirectory(utils/FileCheck)
 559   add_subdirectory(utils/PerfectShuffle)
 560   add_subdirectory(utils/count)
 561   add_subdirectory(utils/not)
 562   add_subdirectory(utils/llvm-lit)
 563   add_subdirectory(utils/yaml-bench)
 564 else()
 565   if ( LLVM_INCLUDE_TESTS )
 566     message(FATAL_ERROR "Including tests when not building utils will not work.
 567     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 568   endif()
 569 endif()
 570
 571 if(LLVM_INCLUDE_TESTS)
 572   add_subdirectory(utils/unittest)
 573 endif()
 574
 575 foreach( binding ${LLVM_BINDINGS_LIST} )
 576   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 577     add_subdirectory(bindings/${binding})
 578   endif()
 579 endforeach()
 580
 581 add_subdirectory(projects)
 582
 583 if(WITH_POLLY)
 584   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 585     set(WITH_POLLY OFF)
 586   endif()
 587 endif(WITH_POLLY)
 588
 589 if( LLVM_INCLUDE_TOOLS )
 590   add_subdirectory(tools)
 591 endif()
 592
 593 if( LLVM_INCLUDE_EXAMPLES )
 594   add_subdirectory(examples)
 595 endif()
 596
 597 if( LLVM_INCLUDE_TESTS )
 598   add_subdirectory(test)
 599   add_subdirectory(unittests)
 600   if (MSVC)
 601     # This utility is used to prevent crashing tests from calling Dr. Watson on
 602     # Windows.
 603     add_subdirectory(utils/KillTheDoctor)
 604   endif()
 605
 606   # Add a global check rule now that all subdirectories have been traversed
 607   # and we know the total set of lit testsuites.
 608   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 609   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 610   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 611   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 612   add_lit_target(check-all
 613     "Running all regression tests"
 614     ${LLVM_LIT_TESTSUITES}
 615     PARAMS ${LLVM_LIT_PARAMS}
 616     DEPENDS ${LLVM_LIT_DEPENDS}
 617     ARGS ${LLVM_LIT_EXTRA_ARGS}
 618     )
 619 endif()
 620
 621 if (LLVM_INCLUDE_DOCS)
 622   add_subdirectory(docs)
 623 endif()
 624
 625 add_subdirectory(cmake/modules)
 626
 627 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 628   install(DIRECTORY include/llvm include/llvm-c
 629     DESTINATION include
 630     FILES_MATCHING
 631     PATTERN "*.def"
 632     PATTERN "*.h"
 633     PATTERN "*.td"
 634     PATTERN "*.inc"
 635     PATTERN "LICENSE.TXT"
 636     PATTERN ".svn" EXCLUDE
 637     )
 638
 639   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 640     DESTINATION include
 641     FILES_MATCHING
 642     PATTERN "*.def"
 643     PATTERN "*.h"
 644     PATTERN "*.gen"
 645     PATTERN "*.inc"
 646     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 647     PATTERN "CMakeFiles" EXCLUDE
 648     PATTERN "config.h" EXCLUDE
 649     PATTERN ".svn" EXCLUDE
 650     )
 651 endif()