CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  64
  65 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  66
  67 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  68 if ( LLVM_USE_FOLDERS )
  69   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  70 endif()
  71
  72 include(VersionFromVCS)
  73
  74 option(LLVM_APPEND_VC_REV
  75   "Append the version control system revision id to LLVM version" OFF)
  76
  77 if( LLVM_APPEND_VC_REV )
  78   add_version_info_from_vcs(PACKAGE_VERSION)
  79 endif()
  80
  81 set(PACKAGE_NAME LLVM)
  82 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  83 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  84
  85 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  86   "Default URL where bug reports are to be submitted.")
  87
  88 # Configure CPack.
  89 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  90 set(CPACK_PACKAGE_VENDOR "LLVM")
  91 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  92 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  93 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  94 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  95 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  96 if(WIN32 AND NOT UNIX)
  97   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  98   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  99   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 100   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 101   set(CPACK_NSIS_MODIFY_PATH "ON")
 102   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 103   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 104     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 105   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 106     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 107   if( CMAKE_CL_64 )
 108     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 109   endif()
 110 endif()
 111 include(CPack)
 112
 113 # Sanity check our source directory to make sure that we are not trying to
 114 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 115 # sure that we don't have any stray generated files lying around in the tree
 116 # (which would end up getting picked up by header search, instead of the correct
 117 # versions).
 118 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 119   message(FATAL_ERROR "In-source builds are not allowed.
 120 CMake would overwrite the makefiles distributed with LLVM.
 121 Please create a directory and run cmake from there, passing the path
 122 to this source directory as the last argument.
 123 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 124 Please delete them.")
 125 endif()
 126 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 127   file(GLOB_RECURSE
 128     tablegenned_files_on_include_dir
 129     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 130   file(GLOB_RECURSE
 131     tablegenned_files_on_lib_dir
 132     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 133   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 134     message(FATAL_ERROR "Apparently there is a previous in-source build,
 135 probably as the result of running `configure' and `make' on
 136 ${CMAKE_CURRENT_SOURCE_DIR}.
 137 This may cause problems. The suspicious files are:
 138 ${tablegenned_files_on_lib_dir}
 139 ${tablegenned_files_on_include_dir}
 140 Please clean the source directory.")
 141   endif()
 142 endif()
 143
 144 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 145
 146 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 147
 148 # They are used as destination of target generators.
 149 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 150 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 151 if(WIN32 OR CYGWIN)
 152   # DLL platform -- put DLLs into bin.
 153   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 154 else()
 155   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 156 endif()
 157
 158 # Each of them corresponds to llvm-config's.
 159 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 160 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 161 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 162 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 163 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 164
 165 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 166 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 167
 168 set(LLVM_ALL_TARGETS
 169   AArch64
 170   ARM
 171   CppBackend
 172   Hexagon
 173   Mips
 174   MSP430
 175   NVPTX
 176   PowerPC
 177   R600
 178   Sparc
 179   SystemZ
 180   X86
 181   XCore
 182   )
 183
 184 # List of targets with JIT support:
 185 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 186
 187 set(LLVM_TARGETS_TO_BUILD "all"
 188     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 189
 190 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 191   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 192
 193 option(BUILD_SHARED_LIBS
 194   "Build all libraries as shared libraries instead of static" OFF)
 195
 196 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 197 if(LLVM_ENABLE_TIMESTAMPS)
 198   set(ENABLE_TIMESTAMPS 1)
 199 endif()
 200
 201 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 202 if(LLVM_ENABLE_BACKTRACES)
 203   set(ENABLE_BACKTRACES 1)
 204 endif()
 205
 206 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 207 if(LLVM_ENABLE_CRASH_OVERRIDES)
 208   set(ENABLE_CRASH_OVERRIDES 1)
 209 endif()
 210
 211 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 212 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 213 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 214
 215 set(LLVM_TARGET_ARCH "host"
 216   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 217
 218 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 219
 220 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 221
 222 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 223
 224 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 225   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 226 endif()
 227
 228 set(LLVM_TARGETS_TO_BUILD
 229    ${LLVM_TARGETS_TO_BUILD}
 230    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 231 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 232
 233 include(AddLLVMDefinitions)
 234
 235 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 236 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 237 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 238 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 239 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 240 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 241 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 242 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 243
 244 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 245   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 246 else()
 247   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 248 endif()
 249
 250 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 251   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 252
 253 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 254        "Set to ON to force using an old, unsupported host toolchain." OFF)
 255
 256 option(LLVM_USE_INTEL_JITEVENTS
 257   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 258   OFF)
 259
 260 if( LLVM_USE_INTEL_JITEVENTS )
 261   # Verify we are on a supported platform
 262   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 263     message(FATAL_ERROR
 264       "Intel JIT API support is available on Linux and Windows only.")
 265   endif()
 266 endif( LLVM_USE_INTEL_JITEVENTS )
 267
 268 option(LLVM_USE_OPROFILE
 269   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 270
 271 # If enabled, verify we are on a platform that supports oprofile.
 272 if( LLVM_USE_OPROFILE )
 273   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 274     message(FATAL_ERROR "OProfile support is available on Linux only.")
 275   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 276 endif( LLVM_USE_OPROFILE )
 277
 278 set(LLVM_USE_SANITIZER "" CACHE STRING
 279   "Define the sanitizer used to build binaries and tests.")
 280
 281 option(LLVM_USE_SPLIT_DWARF
 282   "Use -gsplit-dwarf when compiling llvm." OFF)
 283
 284 option(WITH_POLLY "Build LLVM with Polly" ON)
 285 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 286
 287 # Define an option controlling whether we should build for 32-bit on 64-bit
 288 # platforms, where supported.
 289 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 290   # TODO: support other platforms and toolchains.
 291   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 292 endif()
 293
 294 # Define the default arguments to use with 'lit', and an option for the user to
 295 # override.
 296 set(LIT_ARGS_DEFAULT "-sv")
 297 if (MSVC OR XCODE)
 298   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 299 endif()
 300 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 301
 302 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 303 if( WIN32 AND NOT CYGWIN )
 304   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 305 endif()
 306
 307 # Define options to control the inclusion and default build behavior for
 308 # components which may not strictly be necessary (tools, examples, and tests).
 309 #
 310 # This is primarily to support building smaller or faster project files.
 311 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 312 option(LLVM_BUILD_TOOLS
 313   "Build the LLVM tools. If OFF, just generate build targets." ON)
 314
 315 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 316
 317 option(LLVM_BUILD_RUNTIME
 318   "Build the LLVM runtime libraries." ON)
 319 option(LLVM_BUILD_EXAMPLES
 320   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 321 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 322
 323 option(LLVM_BUILD_TESTS
 324   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 325 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 326
 327 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 328 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 329 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 330 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 331
 332 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 333   "Build compiler-rt as an external project." OFF)
 334
 335 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 336 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 337 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 338   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 339 endif()
 340
 341 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 342 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 343   set(LLVM_USE_HOST_TOOLS ON)
 344 endif()
 345
 346 # All options referred to from HandleLLVMOptions have to be specified
 347 # BEFORE this include, otherwise options will not be correctly set on
 348 # first cmake run
 349 include(config-ix)
 350
 351 # By default, we target the host, but this can be overridden at CMake
 352 # invocation time.
 353 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 354   "Default target for which LLVM will generate code." )
 355 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 356
 357 include(HandleLLVMOptions)
 358
 359 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 360 # FIXME: We should support systems with only Python 3, but that requires work
 361 # on LLDB.
 362 set(Python_ADDITIONAL_VERSIONS 2.7)
 363 include(FindPythonInterp)
 364 if( NOT PYTHONINTERP_FOUND )
 365   message(FATAL_ERROR
 366 "Unable to find Python interpreter, required for builds and testing.
 367
 368 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 369 endif()
 370
 371 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 372   message(FATAL_ERROR "Python 2.7 or newer is required")
 373 endif()
 374
 375 ######
 376 # LLVMBuild Integration
 377 #
 378 # We use llvm-build to generate all the data required by the CMake based
 379 # build system in one swoop:
 380 #
 381 #  - We generate a file (a CMake fragment) in the object root which contains
 382 #    all the definitions that are required by CMake.
 383 #
 384 #  - We generate the library table used by llvm-config.
 385 #
 386 #  - We generate the dependencies for the CMake fragment, so that we will
 387 #    automatically reconfigure outselves.
 388
 389 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 390 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 391   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 392 set(LLVMBUILDCMAKEFRAG
 393   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 394
 395 # Create the list of optional components that are enabled
 396 if (LLVM_USE_INTEL_JITEVENTS)
 397   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 398 endif (LLVM_USE_INTEL_JITEVENTS)
 399 if (LLVM_USE_OPROFILE)
 400   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 401 endif (LLVM_USE_OPROFILE)
 402
 403 message(STATUS "Constructing LLVMBuild project information")
 404 execute_process(
 405   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 406             --native-target "${LLVM_NATIVE_ARCH}"
 407             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 408             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 409             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 410             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 411             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 412             ERROR_VARIABLE LLVMBUILDERRORS
 413             OUTPUT_STRIP_TRAILING_WHITESPACE
 414             ERROR_STRIP_TRAILING_WHITESPACE
 415   RESULT_VARIABLE LLVMBUILDRESULT)
 416
 417 # On Win32, CMake doesn't properly handle piping the default output/error
 418 # streams into the GUI console. So, we explicitly catch and report them.
 419 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 420   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 421 endif()
 422 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 423   message(FATAL_ERROR
 424     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 425 endif()
 426
 427 # Include the generated CMake fragment. This will define properties from the
 428 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 429 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 430 # files change.
 431 include(${LLVMBUILDCMAKEFRAG})
 432
 433 ######
 434
 435 # Configure all of the various header file fragments LLVM uses which depend on
 436 # configuration variables.
 437 set(LLVM_ENUM_TARGETS "")
 438 set(LLVM_ENUM_ASM_PRINTERS "")
 439 set(LLVM_ENUM_ASM_PARSERS "")
 440 set(LLVM_ENUM_DISASSEMBLERS "")
 441 foreach(t ${LLVM_TARGETS_TO_BUILD})
 442   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 443
 444   list(FIND LLVM_ALL_TARGETS ${t} idx)
 445   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 446   if( idx LESS 0 AND idy LESS 0 )
 447     message(FATAL_ERROR "The target `${t}' does not exist.
 448     It should be one of\n${LLVM_ALL_TARGETS}")
 449   else()
 450     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 451   endif()
 452
 453   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 454   if( asmp_file )
 455     set(LLVM_ENUM_ASM_PRINTERS
 456       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 457   endif()
 458   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 459     set(LLVM_ENUM_ASM_PARSERS
 460       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 461   endif()
 462   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 463     set(LLVM_ENUM_DISASSEMBLERS
 464       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 465   endif()
 466 endforeach(t)
 467
 468 # Produce the target definition files, which provide a way for clients to easily
 469 # include various classes of targets.
 470 configure_file(
 471   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 472   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 473   )
 474 configure_file(
 475   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 476   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 477   )
 478 configure_file(
 479   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 480   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 481   )
 482 configure_file(
 483   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 484   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 485   )
 486
 487 # Configure the three LLVM configuration header files.
 488 configure_file(
 489   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 490   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 491 configure_file(
 492   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 493   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 494 configure_file(
 495   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 496   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 497
 498 # They are not referenced. See set_output_directory().
 499 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 500 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 501 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 502
 503 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 504 if (APPLE)
 505   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 506   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 507 else(UNIX)
 508   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 509     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 510     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 511       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 512       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 513     endif()
 514   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 515 endif()
 516
 517 # Work around a broken bfd ld behavior. When linking a binary with a
 518 # foo.so library, it will try to find any library that foo.so uses and
 519 # check its symbols. This is wasteful (the check was done when foo.so
 520 # was created) and can fail since it is not the dynamic linker and
 521 # doesn't know how to handle search paths correctly.
 522 if (UNIX AND NOT APPLE)
 523   set(CMAKE_EXE_LINKER_FLAGS
 524       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 525 endif()
 526
 527 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 528
 529 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 530
 531 # when crosscompiling import the executable targets from a file
 532 if(LLVM_USE_HOST_TOOLS)
 533   include(CrossCompile)
 534 endif(LLVM_USE_HOST_TOOLS)
 535
 536 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 537   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 538   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 539   include_directories("/usr/local/include")
 540   link_directories("/usr/local/lib")
 541 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 542
 543 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 544    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 545 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 546
 547 # Make sure we don't get -rdynamic in every binary. For those that need it,
 548 # use export_executable_symbols(target).
 549 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 550
 551 include(AddLLVM)
 552 include(TableGen)
 553
 554 if( MINGW )
 555   # People report that -O3 is unreliable on MinGW. The traditional
 556   # build also uses -O2 for that reason:
 557   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 558 endif()
 559
 560 # Put this before tblgen. Else we have a circular dependence.
 561 add_subdirectory(lib/Support)
 562 add_subdirectory(lib/TableGen)
 563
 564 add_subdirectory(utils/TableGen)
 565
 566 add_subdirectory(include/llvm)
 567
 568 add_subdirectory(lib)
 569
 570 if( LLVM_INCLUDE_UTILS )
 571   add_subdirectory(utils/FileCheck)
 572   add_subdirectory(utils/PerfectShuffle)
 573   add_subdirectory(utils/count)
 574   add_subdirectory(utils/not)
 575   add_subdirectory(utils/llvm-lit)
 576   add_subdirectory(utils/yaml-bench)
 577 else()
 578   if ( LLVM_INCLUDE_TESTS )
 579     message(FATAL_ERROR "Including tests when not building utils will not work.
 580     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 581   endif()
 582 endif()
 583
 584 if(LLVM_INCLUDE_TESTS)
 585   add_subdirectory(utils/unittest)
 586 endif()
 587
 588 foreach( binding ${LLVM_BINDINGS_LIST} )
 589   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 590     add_subdirectory(bindings/${binding})
 591   endif()
 592 endforeach()
 593
 594 add_subdirectory(projects)
 595
 596 if(WITH_POLLY)
 597   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 598     set(WITH_POLLY OFF)
 599   endif()
 600 endif(WITH_POLLY)
 601
 602 if( LLVM_INCLUDE_TOOLS )
 603   add_subdirectory(tools)
 604 endif()
 605
 606 if( LLVM_INCLUDE_EXAMPLES )
 607   add_subdirectory(examples)
 608 endif()
 609
 610 if( LLVM_INCLUDE_TESTS )
 611   add_subdirectory(test)
 612   add_subdirectory(unittests)
 613   if (MSVC)
 614     # This utility is used to prevent crashing tests from calling Dr. Watson on
 615     # Windows.
 616     add_subdirectory(utils/KillTheDoctor)
 617   endif()
 618
 619   # Add a global check rule now that all subdirectories have been traversed
 620   # and we know the total set of lit testsuites.
 621   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 622   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 623   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 624   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 625   add_lit_target(check-all
 626     "Running all regression tests"
 627     ${LLVM_LIT_TESTSUITES}
 628     PARAMS ${LLVM_LIT_PARAMS}
 629     DEPENDS ${LLVM_LIT_DEPENDS}
 630     ARGS ${LLVM_LIT_EXTRA_ARGS}
 631     )
 632 endif()
 633
 634 if (LLVM_INCLUDE_DOCS)
 635   add_subdirectory(docs)
 636 endif()
 637
 638 add_subdirectory(cmake/modules)
 639
 640 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 641   install(DIRECTORY include/llvm include/llvm-c
 642     DESTINATION include
 643     COMPONENT llvm-headers
 644     FILES_MATCHING
 645     PATTERN "*.def"
 646     PATTERN "*.h"
 647     PATTERN "*.td"
 648     PATTERN "*.inc"
 649     PATTERN "LICENSE.TXT"
 650     PATTERN ".svn" EXCLUDE
 651     )
 652
 653   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 654     DESTINATION include
 655     COMPONENT llvm-headers
 656     FILES_MATCHING
 657     PATTERN "*.def"
 658     PATTERN "*.h"
 659     PATTERN "*.gen"
 660     PATTERN "*.inc"
 661     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 662     PATTERN "CMakeFiles" EXCLUDE
 663     PATTERN "config.h" EXCLUDE
 664     PATTERN ".svn" EXCLUDE
 665     )
 666
 667   if (NOT CMAKE_CONFIGURATION_TYPES)
 668     add_custom_target(installhdrs
 669                       DEPENDS ${name}
 670                       COMMAND "${CMAKE_COMMAND}"
 671                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 672                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 673   endif()
 674 endif()