CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  64
  65 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  66
  67 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  68 if ( LLVM_USE_FOLDERS )
  69   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  70 endif()
  71
  72 include(VersionFromVCS)
  73
  74 option(LLVM_APPEND_VC_REV
  75   "Append the version control system revision id to LLVM version" OFF)
  76
  77 if( LLVM_APPEND_VC_REV )
  78   add_version_info_from_vcs(PACKAGE_VERSION)
  79 endif()
  80
  81 set(PACKAGE_NAME LLVM)
  82 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  83 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  84
  85 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  86   "Default URL where bug reports are to be submitted.")
  87
  88 # Configure CPack.
  89 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  90 set(CPACK_PACKAGE_VENDOR "LLVM")
  91 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  92 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  93 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  94 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  95 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  96 if(WIN32 AND NOT UNIX)
  97   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  98   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  99   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 100   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 101   set(CPACK_NSIS_MODIFY_PATH "ON")
 102   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 103   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 104     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 105   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 106     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 107   if( CMAKE_CL_64 )
 108     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 109   endif()
 110 endif()
 111 include(CPack)
 112
 113 # Sanity check our source directory to make sure that we are not trying to
 114 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 115 # sure that we don't have any stray generated files lying around in the tree
 116 # (which would end up getting picked up by header search, instead of the correct
 117 # versions).
 118 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 119   message(FATAL_ERROR "In-source builds are not allowed.
 120 CMake would overwrite the makefiles distributed with LLVM.
 121 Please create a directory and run cmake from there, passing the path
 122 to this source directory as the last argument.
 123 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 124 Please delete them.")
 125 endif()
 126 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 127   file(GLOB_RECURSE
 128     tablegenned_files_on_include_dir
 129     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 130   file(GLOB_RECURSE
 131     tablegenned_files_on_lib_dir
 132     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 133   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 134     message(FATAL_ERROR "Apparently there is a previous in-source build,
 135 probably as the result of running `configure' and `make' on
 136 ${CMAKE_CURRENT_SOURCE_DIR}.
 137 This may cause problems. The suspicious files are:
 138 ${tablegenned_files_on_lib_dir}
 139 ${tablegenned_files_on_include_dir}
 140 Please clean the source directory.")
 141   endif()
 142 endif()
 143
 144 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 145
 146 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 147
 148 # They are used as destination of target generators.
 149 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 150 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 151 if(WIN32 OR CYGWIN)
 152   # DLL platform -- put DLLs into bin.
 153   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 154 else()
 155   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 156 endif()
 157
 158 # Each of them corresponds to llvm-config's.
 159 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 160 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 161 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 162 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 163 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 164
 165 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 166 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 167
 168 set(LLVM_ALL_TARGETS
 169   AArch64
 170   ARM
 171   CppBackend
 172   Hexagon
 173   Mips
 174   MSP430
 175   NVPTX
 176   PowerPC
 177   R600
 178   Sparc
 179   SystemZ
 180   X86
 181   XCore
 182   )
 183
 184 # List of targets with JIT support:
 185 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 186
 187 set(LLVM_TARGETS_TO_BUILD "all"
 188     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 189
 190 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 191   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 192
 193 option(BUILD_SHARED_LIBS
 194   "Build all libraries as shared libraries instead of static" OFF)
 195
 196 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 197 if(LLVM_ENABLE_TIMESTAMPS)
 198   set(ENABLE_TIMESTAMPS 1)
 199 endif()
 200
 201 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 202 if(LLVM_ENABLE_BACKTRACES)
 203   set(ENABLE_BACKTRACES 1)
 204 endif()
 205
 206 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 207 if(LLVM_ENABLE_CRASH_OVERRIDES)
 208   set(ENABLE_CRASH_OVERRIDES 1)
 209 endif()
 210
 211 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 212 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 213 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 214
 215 set(LLVM_TARGET_ARCH "host"
 216   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 217
 218 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 219
 220 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 221
 222 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 223
 224 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 225   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 226 endif()
 227
 228 set(LLVM_TARGETS_TO_BUILD
 229    ${LLVM_TARGETS_TO_BUILD}
 230    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 231 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 232
 233 include(AddLLVMDefinitions)
 234
 235 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 236 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 237 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 238 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 239 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 240 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 241 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 242 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 243
 244 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 245   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 246 else()
 247   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 248 endif()
 249
 250 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 251   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 252
 253 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 254        "Set to ON to force using an old, unsupported host toolchain." OFF)
 255
 256 option(LLVM_USE_INTEL_JITEVENTS
 257   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 258   OFF)
 259
 260 if( LLVM_USE_INTEL_JITEVENTS )
 261   # Verify we are on a supported platform
 262   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 263     message(FATAL_ERROR
 264       "Intel JIT API support is available on Linux and Windows only.")
 265   endif()
 266 endif( LLVM_USE_INTEL_JITEVENTS )
 267
 268 option(LLVM_USE_OPROFILE
 269   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 270
 271 # If enabled, verify we are on a platform that supports oprofile.
 272 if( LLVM_USE_OPROFILE )
 273   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 274     message(FATAL_ERROR "OProfile support is available on Linux only.")
 275   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 276 endif( LLVM_USE_OPROFILE )
 277
 278 set(LLVM_USE_SANITIZER "" CACHE STRING
 279   "Define the sanitizer used to build binaries and tests.")
 280
 281 option(LLVM_USE_SPLIT_DWARF
 282   "Use -gsplit-dwarf when compiling llvm." OFF)
 283
 284 option(WITH_POLLY "Build LLVM with Polly" ON)
 285 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 286
 287 # Define an option controlling whether we should build for 32-bit on 64-bit
 288 # platforms, where supported.
 289 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 290   # TODO: support other platforms and toolchains.
 291   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 292 endif()
 293
 294 # Define the default arguments to use with 'lit', and an option for the user to
 295 # override.
 296 set(LIT_ARGS_DEFAULT "-sv")
 297 if (MSVC OR XCODE)
 298   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 299 endif()
 300 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 301
 302 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 303 if( WIN32 AND NOT CYGWIN )
 304   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 305 endif()
 306
 307 # Define options to control the inclusion and default build behavior for
 308 # components which may not strictly be necessary (tools, examples, and tests).
 309 #
 310 # This is primarily to support building smaller or faster project files.
 311 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 312 option(LLVM_BUILD_TOOLS
 313   "Build the LLVM tools. If OFF, just generate build targets." ON)
 314
 315 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 316
 317 option(LLVM_BUILD_RUNTIME
 318   "Build the LLVM runtime libraries." ON)
 319 option(LLVM_BUILD_EXAMPLES
 320   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 321 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 322
 323 option(LLVM_BUILD_TESTS
 324   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 325 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 326
 327 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 328 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 329 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 330 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 331
 332 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 333   "Build compiler-rt as an external project." OFF)
 334
 335 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 336 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" OFF)
 337 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 338 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 339   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 340 endif()
 341
 342 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 343 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 344   set(LLVM_USE_HOST_TOOLS ON)
 345 endif()
 346
 347 # All options referred to from HandleLLVMOptions have to be specified
 348 # BEFORE this include, otherwise options will not be correctly set on
 349 # first cmake run
 350 include(config-ix)
 351
 352 # By default, we target the host, but this can be overridden at CMake
 353 # invocation time.
 354 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 355   "Default target for which LLVM will generate code." )
 356 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 357
 358 include(HandleLLVMOptions)
 359
 360 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 361 # FIXME: We should support systems with only Python 3, but that requires work
 362 # on LLDB.
 363 set(Python_ADDITIONAL_VERSIONS 2.7)
 364 include(FindPythonInterp)
 365 if( NOT PYTHONINTERP_FOUND )
 366   message(FATAL_ERROR
 367 "Unable to find Python interpreter, required for builds and testing.
 368
 369 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 370 endif()
 371
 372 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 373   message(FATAL_ERROR "Python 2.7 or newer is required")
 374 endif()
 375
 376 ######
 377 # LLVMBuild Integration
 378 #
 379 # We use llvm-build to generate all the data required by the CMake based
 380 # build system in one swoop:
 381 #
 382 #  - We generate a file (a CMake fragment) in the object root which contains
 383 #    all the definitions that are required by CMake.
 384 #
 385 #  - We generate the library table used by llvm-config.
 386 #
 387 #  - We generate the dependencies for the CMake fragment, so that we will
 388 #    automatically reconfigure outselves.
 389
 390 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 391 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 392   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 393 set(LLVMBUILDCMAKEFRAG
 394   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 395
 396 # Create the list of optional components that are enabled
 397 if (LLVM_USE_INTEL_JITEVENTS)
 398   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 399 endif (LLVM_USE_INTEL_JITEVENTS)
 400 if (LLVM_USE_OPROFILE)
 401   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 402 endif (LLVM_USE_OPROFILE)
 403
 404 message(STATUS "Constructing LLVMBuild project information")
 405 execute_process(
 406   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 407             --native-target "${LLVM_NATIVE_ARCH}"
 408             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 409             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 410             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 411             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 412             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 413             ERROR_VARIABLE LLVMBUILDERRORS
 414             OUTPUT_STRIP_TRAILING_WHITESPACE
 415             ERROR_STRIP_TRAILING_WHITESPACE
 416   RESULT_VARIABLE LLVMBUILDRESULT)
 417
 418 # On Win32, CMake doesn't properly handle piping the default output/error
 419 # streams into the GUI console. So, we explicitly catch and report them.
 420 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 421   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 422 endif()
 423 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 424   message(FATAL_ERROR
 425     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 426 endif()
 427
 428 # Include the generated CMake fragment. This will define properties from the
 429 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 430 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 431 # files change.
 432 include(${LLVMBUILDCMAKEFRAG})
 433
 434 ######
 435
 436 # Configure all of the various header file fragments LLVM uses which depend on
 437 # configuration variables.
 438 set(LLVM_ENUM_TARGETS "")
 439 set(LLVM_ENUM_ASM_PRINTERS "")
 440 set(LLVM_ENUM_ASM_PARSERS "")
 441 set(LLVM_ENUM_DISASSEMBLERS "")
 442 foreach(t ${LLVM_TARGETS_TO_BUILD})
 443   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 444
 445   list(FIND LLVM_ALL_TARGETS ${t} idx)
 446   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 447   if( idx LESS 0 AND idy LESS 0 )
 448     message(FATAL_ERROR "The target `${t}' does not exist.
 449     It should be one of\n${LLVM_ALL_TARGETS}")
 450   else()
 451     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 452   endif()
 453
 454   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 455   if( asmp_file )
 456     set(LLVM_ENUM_ASM_PRINTERS
 457       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 458   endif()
 459   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 460     set(LLVM_ENUM_ASM_PARSERS
 461       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 462   endif()
 463   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 464     set(LLVM_ENUM_DISASSEMBLERS
 465       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 466   endif()
 467 endforeach(t)
 468
 469 # Produce the target definition files, which provide a way for clients to easily
 470 # include various classes of targets.
 471 configure_file(
 472   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 473   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 474   )
 475 configure_file(
 476   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 477   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 478   )
 479 configure_file(
 480   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 481   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 482   )
 483 configure_file(
 484   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 485   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 486   )
 487
 488 # Configure the three LLVM configuration header files.
 489 configure_file(
 490   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 491   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 492 configure_file(
 493   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 494   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 495 configure_file(
 496   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 497   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 498
 499 # They are not referenced. See set_output_directory().
 500 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 501 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 502 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 503
 504 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 505 if (APPLE)
 506   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 507   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 508 else(UNIX)
 509   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 510     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 511     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 512       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 513       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 514     endif()
 515   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 516 endif()
 517
 518 # Work around a broken bfd ld behavior. When linking a binary with a
 519 # foo.so library, it will try to find any library that foo.so uses and
 520 # check its symbols. This is wasteful (the check was done when foo.so
 521 # was created) and can fail since it is not the dynamic linker and
 522 # doesn't know how to handle search paths correctly.
 523 if (UNIX AND NOT APPLE)
 524   set(CMAKE_EXE_LINKER_FLAGS
 525       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 526 endif()
 527
 528 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 529
 530 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 531
 532 # when crosscompiling import the executable targets from a file
 533 if(LLVM_USE_HOST_TOOLS)
 534   include(CrossCompile)
 535 endif(LLVM_USE_HOST_TOOLS)
 536
 537 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 538   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 539   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 540   include_directories("/usr/local/include")
 541   link_directories("/usr/local/lib")
 542 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 543
 544 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 545    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 546 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 547
 548 # Make sure we don't get -rdynamic in every binary. For those that need it,
 549 # use export_executable_symbols(target).
 550 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 551
 552 include(AddLLVM)
 553 include(TableGen)
 554
 555 if( MINGW )
 556   # People report that -O3 is unreliable on MinGW. The traditional
 557   # build also uses -O2 for that reason:
 558   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 559 endif()
 560
 561 # Put this before tblgen. Else we have a circular dependence.
 562 add_subdirectory(lib/Support)
 563 add_subdirectory(lib/TableGen)
 564
 565 add_subdirectory(utils/TableGen)
 566
 567 add_subdirectory(include/llvm)
 568
 569 add_subdirectory(lib)
 570
 571 if( LLVM_INCLUDE_UTILS )
 572   add_subdirectory(utils/FileCheck)
 573   add_subdirectory(utils/PerfectShuffle)
 574   add_subdirectory(utils/count)
 575   add_subdirectory(utils/not)
 576   add_subdirectory(utils/llvm-lit)
 577   add_subdirectory(utils/yaml-bench)
 578 else()
 579   if ( LLVM_INCLUDE_TESTS )
 580     message(FATAL_ERROR "Including tests when not building utils will not work.
 581     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 582   endif()
 583 endif()
 584
 585 if(LLVM_INCLUDE_TESTS)
 586   add_subdirectory(utils/unittest)
 587 endif()
 588
 589 foreach( binding ${LLVM_BINDINGS_LIST} )
 590   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 591     add_subdirectory(bindings/${binding})
 592   endif()
 593 endforeach()
 594
 595 add_subdirectory(projects)
 596
 597 if(WITH_POLLY)
 598   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 599     set(WITH_POLLY OFF)
 600   endif()
 601 endif(WITH_POLLY)
 602
 603 if( LLVM_INCLUDE_TOOLS )
 604   add_subdirectory(tools)
 605 endif()
 606
 607 if( LLVM_INCLUDE_EXAMPLES )
 608   add_subdirectory(examples)
 609 endif()
 610
 611 if( LLVM_INCLUDE_TESTS )
 612   add_subdirectory(test)
 613   add_subdirectory(unittests)
 614   if (MSVC)
 615     # This utility is used to prevent crashing tests from calling Dr. Watson on
 616     # Windows.
 617     add_subdirectory(utils/KillTheDoctor)
 618   endif()
 619
 620   # Add a global check rule now that all subdirectories have been traversed
 621   # and we know the total set of lit testsuites.
 622   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 623   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 624   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 625   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 626   add_lit_target(check-all
 627     "Running all regression tests"
 628     ${LLVM_LIT_TESTSUITES}
 629     PARAMS ${LLVM_LIT_PARAMS}
 630     DEPENDS ${LLVM_LIT_DEPENDS}
 631     ARGS ${LLVM_LIT_EXTRA_ARGS}
 632     )
 633 endif()
 634
 635 if (LLVM_INCLUDE_DOCS)
 636   add_subdirectory(docs)
 637 endif()
 638
 639 add_subdirectory(cmake/modules)
 640
 641 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 642   install(DIRECTORY include/llvm include/llvm-c
 643     DESTINATION include
 644     COMPONENT llvm-headers
 645     FILES_MATCHING
 646     PATTERN "*.def"
 647     PATTERN "*.h"
 648     PATTERN "*.td"
 649     PATTERN "*.inc"
 650     PATTERN "LICENSE.TXT"
 651     PATTERN ".svn" EXCLUDE
 652     )
 653
 654   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 655     DESTINATION include
 656     COMPONENT llvm-headers
 657     FILES_MATCHING
 658     PATTERN "*.def"
 659     PATTERN "*.h"
 660     PATTERN "*.gen"
 661     PATTERN "*.inc"
 662     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 663     PATTERN "CMakeFiles" EXCLUDE
 664     PATTERN "config.h" EXCLUDE
 665     PATTERN ".svn" EXCLUDE
 666     )
 667
 668   if (NOT CMAKE_CONFIGURATION_TYPES)
 669     add_custom_target(installhdrs
 670                       DEPENDS ${name}
 671                       COMMAND "${CMAKE_COMMAND}"
 672                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 673                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 674   endif()
 675 endif()