CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 2)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   ARM
  78   CellSPU
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   Sparc
  87   X86
  88   XCore
  89   )
  90
  91 # List of targets with JIT support:
  92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  93
  94 if( MSVC )
  95   set(LLVM_TARGETS_TO_BUILD X86
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97 else( MSVC )
  98   set(LLVM_TARGETS_TO_BUILD "all"
  99     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 100 endif( MSVC )
 101
 102 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 103   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 104
 105 option(BUILD_SHARED_LIBS
 106   "Build all libraries as shared libraries instead of static" OFF)
 107
 108 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 109 if(LLVM_ENABLE_CBE_PRINTF_A)
 110   set(ENABLE_CBE_PRINTF_A 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 114 if(LLVM_ENABLE_TIMESTAMPS)
 115   set(ENABLE_TIMESTAMPS 1)
 116 endif()
 117
 118 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 119 if(LLVM_ENABLE_BACKTRACES)
 120   set(ENABLE_BACKTRACES 1)
 121 endif()
 122
 123 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 124 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 125 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 126
 127 set(LLVM_TARGET_ARCH "host"
 128   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 129
 130 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 131
 132 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 133   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 134 endif()
 135
 136 set(LLVM_TARGETS_TO_BUILD
 137    ${LLVM_TARGETS_TO_BUILD}
 138    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 139
 140 set(LLVM_ENUM_TARGETS "")
 141 foreach(c ${LLVM_TARGETS_TO_BUILD})
 142   list(FIND LLVM_ALL_TARGETS ${c} idx)
 143   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 144   if( idx LESS 0 AND idy LESS 0 )
 145     message(FATAL_ERROR "The target `${c}' does not exist.
 146     It should be one of\n${LLVM_ALL_TARGETS}")
 147   else()
 148     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 149   endif()
 150 endforeach(c)
 151
 152 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 153
 154 include(AddLLVMDefinitions)
 155
 156 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 157
 158 # MSVC has a gazillion warnings with this.
 159 if( MSVC )
 160   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 161 else( MSVC )
 162   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 163 endif()
 164
 165 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 166 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 167
 168 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 169   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 170 else()
 171   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 172 endif()
 173
 174 option(LLVM_USE_INTEL_JITEVENTS
 175   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 176   OFF)
 177
 178 if( LLVM_USE_INTEL_JITEVENTS )
 179   # Verify we are on a supported platform
 180   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 181     message(FATAL_ERROR
 182       "Intel JIT API support is available on Linux and Windows only.")
 183   endif()
 184 endif( LLVM_USE_INTEL_JITEVENTS )
 185
 186 option(LLVM_USE_OPROFILE
 187   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 188
 189 # If enabled, ierify we are on a platform that supports oprofile.
 190 if( LLVM_USE_OPROFILE )
 191   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 192     message(FATAL_ERROR "OProfile support is available on Linux only.")
 193   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 194 endif( LLVM_USE_OPROFILE )
 195
 196 # Define an option controlling whether we should build for 32-bit on 64-bit
 197 # platforms, where supported.
 198 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 199   # TODO: support other platforms and toolchains.
 200   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 201 endif()
 202
 203 # Define the default arguments to use with 'lit', and an option for the user to
 204 # override.
 205 set(LIT_ARGS_DEFAULT "-sv")
 206 if (MSVC OR XCODE)
 207   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 208 endif()
 209 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 210
 211 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 212 if( WIN32 AND NOT CYGWIN )
 213   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 214 endif()
 215
 216 # Define options to control the inclusion and default build behavior for
 217 # components which may not strictly be necessary (tools, runtime, examples, and
 218 # tests).
 219 #
 220 # This is primarily to support building smaller or faster project files.
 221 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 222 option(LLVM_BUILD_TOOLS
 223   "Build the LLVM tools. If OFF, just generate build targets." ON)
 224
 225 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 226 option(LLVM_BUILD_RUNTIME
 227   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 228
 229 option(LLVM_BUILD_EXAMPLES
 230   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 231 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 232
 233 option(LLVM_BUILD_TESTS
 234   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 235 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 236
 237 # All options referred to from HandleLLVMOptions have to be specified
 238 # BEFORE this include, otherwise options will not be correctly set on
 239 # first cmake run
 240 include(config-ix)
 241
 242 # By default, we target the host, but this can be overridden at CMake
 243 # invocation time.
 244 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 245   "Default target for which LLVM will generate code." )
 246 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}" CACHE STRING
 247   "Default target for which LLVM will generate code." )
 248
 249 include(HandleLLVMOptions)
 250
 251 # Verify that we can find a Python interpreter,
 252 include(FindPythonInterp)
 253 if( NOT PYTHONINTERP_FOUND )
 254   message(FATAL_ERROR
 255 "Unable to find Python interpreter, required for builds and testing.
 256
 257 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 258 endif()
 259
 260 ######
 261 # LLVMBuild Integration
 262 #
 263 # We use llvm-build to generate all the data required by the CMake based
 264 # build system in one swoop:
 265 #
 266 #  - We generate a file (a CMake fragment) in the object root which contains
 267 #    all the definitions that are required by CMake.
 268 #
 269 #  - We generate the library table used by llvm-config.
 270 #
 271 #  - We generate the dependencies for the CMake fragment, so that we will
 272 #    automatically reconfigure outselves.
 273
 274 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 275 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 276   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 277 set(LLVMBUILDCMAKEFRAG
 278   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 279
 280 # Create the list of optional components that are enabled
 281 if (LLVM_USE_INTEL_JITEVENTS)
 282   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 283 endif (LLVM_USE_INTEL_JITEVENTS)
 284 if (LLVM_USE_OPROFILE)
 285   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 286 endif (LLVM_USE_OPROFILE)
 287
 288 message(STATUS "Constructing LLVMBuild project information")
 289 execute_process(
 290   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 291             --native-target "${LLVM_NATIVE_ARCH}"
 292             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 293             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 294             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 295             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 296             ERROR_VARIABLE LLVMBUILDOUTPUT
 297             ERROR_VARIABLE LLVMBUILDERRORS
 298             OUTPUT_STRIP_TRAILING_WHITESPACE
 299             ERROR_STRIP_TRAILING_WHITESPACE
 300   RESULT_VARIABLE LLVMBUILDRESULT)
 301
 302 # On Win32, CMake doesn't properly handle piping the default output/error
 303 # streams into the GUI console. So, we explicitly catch and report them.
 304 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 305   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 306 endif()
 307 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 308   message(FATAL_ERROR
 309     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 310 endif()
 311
 312 # Include the generated CMake fragment. This will define properties from the
 313 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 314 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 315 # files change.
 316 include(${LLVMBUILDCMAKEFRAG})
 317
 318 ######
 319
 320 # Configure all of the various header file fragments LLVM uses which depend on
 321 # configuration variables.
 322 set(LLVM_ENUM_ASM_PRINTERS "")
 323 set(LLVM_ENUM_ASM_PARSERS "")
 324 set(LLVM_ENUM_DISASSEMBLERS "")
 325 foreach(t ${LLVM_TARGETS_TO_BUILD})
 326   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 327   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 328   if( asmp_file )
 329     set(LLVM_ENUM_ASM_PRINTERS
 330       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 331   endif()
 332   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 333     set(LLVM_ENUM_ASM_PARSERS
 334       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 335   endif()
 336   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 337     set(LLVM_ENUM_DISASSEMBLERS
 338       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 339   endif()
 340 endforeach(t)
 341
 342 # Produce the target definition files, which provide a way for clients to easily
 343 # include various classes of targets.
 344 configure_file(
 345   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 346   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 347   )
 348 configure_file(
 349   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 350   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 351   )
 352 configure_file(
 353   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 354   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 355   )
 356 configure_file(
 357   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 358   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 359   )
 360
 361 # Configure the three LLVM configuration header files.
 362 configure_file(
 363   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 364   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 365 configure_file(
 366   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 367   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 368 configure_file(
 369   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 370   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 371
 372 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 373 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 374 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 375
 376 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 377
 378 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 379
 380 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 381    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 382 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 383
 384 include(AddLLVM)
 385 include(TableGen)
 386
 387 if( MINGW )
 388   # People report that -O3 is unreliable on MinGW. The traditional
 389   # build also uses -O2 for that reason:
 390   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 391 endif()
 392
 393 # Put this before tblgen. Else we have a circular dependence.
 394 add_subdirectory(lib/Support)
 395 add_subdirectory(lib/TableGen)
 396
 397 add_subdirectory(utils/TableGen)
 398
 399 add_subdirectory(include/llvm)
 400
 401 add_subdirectory(lib)
 402
 403 add_subdirectory(utils/FileCheck)
 404 add_subdirectory(utils/FileUpdate)
 405 add_subdirectory(utils/count)
 406 add_subdirectory(utils/not)
 407 add_subdirectory(utils/llvm-lit)
 408 add_subdirectory(utils/yaml-bench)
 409 add_subdirectory(utils/obj2yaml)
 410 add_subdirectory(utils/yaml2obj)
 411
 412 add_subdirectory(projects)
 413
 414 if( LLVM_INCLUDE_TOOLS )
 415   add_subdirectory(tools)
 416 endif()
 417
 418 if( LLVM_INCLUDE_RUNTIME )
 419   add_subdirectory(runtime)
 420 endif()
 421
 422 if( LLVM_INCLUDE_EXAMPLES )
 423   add_subdirectory(examples)
 424 endif()
 425
 426 if( LLVM_INCLUDE_TESTS )
 427   add_subdirectory(test)
 428   add_subdirectory(utils/unittest)
 429   add_subdirectory(unittests)
 430   if (MSVC)
 431     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 432     # Windows.
 433     add_subdirectory(utils/KillTheDoctor)
 434   endif()
 435
 436   # Add a global check rule now that all subdirectories have been traversed
 437   # and we know the total set of lit testsuites.
 438   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 439   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 440   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 441   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 442   add_lit_target(check-all
 443     "Running all regression tests"
 444     ${LLVM_LIT_TESTSUITES}
 445     PARAMS ${LLVM_LIT_PARAMS}
 446     DEPENDS ${LLVM_LIT_DEPENDS}
 447     ARGS ${LLVM_LIT_EXTRA_ARGS}
 448     )
 449 endif()
 450
 451 add_subdirectory(cmake/modules)
 452
 453 install(DIRECTORY include/
 454   DESTINATION include
 455   FILES_MATCHING
 456   PATTERN "*.def"
 457   PATTERN "*.h"
 458   PATTERN "*.td"
 459   PATTERN "*.inc"
 460   PATTERN "LICENSE.TXT"
 461   PATTERN ".svn" EXCLUDE
 462   )
 463
 464 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 465   DESTINATION include
 466   FILES_MATCHING
 467   PATTERN "*.def"
 468   PATTERN "*.h"
 469   PATTERN "*.gen"
 470   PATTERN "*.inc"
 471   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 472   PATTERN "CMakeFiles" EXCLUDE
 473   PATTERN ".svn" EXCLUDE
 474   )
 475
 476 # TODO: make and install documentation.
 477
 478 set(CPACK_PACKAGE_VENDOR "LLVM")
 479 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 480 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 481 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 482 include(CPack)
 483
 484 # Workaround for MSVS10 to avoid the Dialog Hell
 485 # FIXME: This could be removed with future version of CMake.
 486 if(MSVC_VERSION EQUAL 1600)
 487   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 488   if( EXISTS "${LLVM_SLN_FILENAME}" )
 489     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 490   endif()
 491 endif()