CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  19
  20 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  21 if ( LLVM_USE_FOLDERS )
  22   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  23 endif()
  24
  25 include(VersionFromVCS)
  26
  27 option(LLVM_APPEND_VC_REV
  28   "Append the version control system revision id to LLVM version" OFF)
  29
  30 if( LLVM_APPEND_VC_REV )
  31   add_version_info_from_vcs(PACKAGE_VERSION)
  32 endif()
  33
  34 set(PACKAGE_NAME LLVM)
  35 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  36 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  37
  38 # Configure CPack.
  39 set(CPACK_PACKAGE_VENDOR "LLVM")
  40 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  41 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  42 if( LLVM_APPEND_VC_REV )
  43   add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
  44 else()
  45   set(CPACK_PACKAGE_VERSION_PATCH "svn")
  46 endif()
  47 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  48 if(WIN32 AND NOT UNIX)
  49   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  50   set(CPACK_NSIS_MODIFY_PATH "ON")
  51   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  52   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  53     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  54   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  55     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  56 endif()
  57 include(CPack)
  58
  59 # Sanity check our source directory to make sure that we are not trying to
  60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  61 # sure that we don't have any stray generated files lying around in the tree
  62 # (which would end up getting picked up by header search, instead of the correct
  63 # versions).
  64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  65   message(FATAL_ERROR "In-source builds are not allowed.
  66 CMake would overwrite the makefiles distributed with LLVM.
  67 Please create a directory and run cmake from there, passing the path
  68 to this source directory as the last argument.
  69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  70 Please delete them.")
  71 endif()
  72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  73   file(GLOB_RECURSE
  74     tablegenned_files_on_include_dir
  75     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_lib_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  79   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  80     message(FATAL_ERROR "Apparently there is a previous in-source build,
  81 probably as the result of running `configure' and `make' on
  82 ${CMAKE_CURRENT_SOURCE_DIR}.
  83 This may cause problems. The suspicious files are:
  84 ${tablegenned_files_on_lib_dir}
  85 ${tablegenned_files_on_include_dir}
  86 Please clean the source directory.")
  87   endif()
  88 endif()
  89
  90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  91
  92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  97 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  98
  99 set(LLVM_ALL_TARGETS
 100   AArch64
 101   ARM
 102   CppBackend
 103   Hexagon
 104   Mips
 105   MSP430
 106   NVPTX
 107   PowerPC
 108   R600
 109   Sparc
 110   SystemZ
 111   X86
 112   XCore
 113   )
 114
 115 # List of targets with JIT support:
 116 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 117
 118 set(LLVM_TARGETS_TO_BUILD "all"
 119     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 120
 121 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 122   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 123
 124 option(BUILD_SHARED_LIBS
 125   "Build all libraries as shared libraries instead of static" OFF)
 126
 127 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 128 if(LLVM_ENABLE_CBE_PRINTF_A)
 129   set(ENABLE_CBE_PRINTF_A 1)
 130 endif()
 131
 132 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 133 if(LLVM_ENABLE_TIMESTAMPS)
 134   set(ENABLE_TIMESTAMPS 1)
 135 endif()
 136
 137 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 138 if(LLVM_ENABLE_BACKTRACES)
 139   set(ENABLE_BACKTRACES 1)
 140 endif()
 141
 142 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 143 if(LLVM_ENABLE_CRASH_OVERRIDES)
 144   set(ENABLE_CRASH_OVERRIDES 1)
 145 endif()
 146
 147 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 148 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 149 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 150
 151 set(LLVM_TARGET_ARCH "host"
 152   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 153
 154 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 155
 156 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 157
 158 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 159
 160 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 161   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 162 endif()
 163
 164 set(LLVM_TARGETS_TO_BUILD
 165    ${LLVM_TARGETS_TO_BUILD}
 166    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 167 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 168
 169 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 170
 171 include(AddLLVMDefinitions)
 172
 173 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 174
 175 # MSVC has a gazillion warnings with this.
 176 if( MSVC )
 177   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 178 else( MSVC )
 179   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 180 endif()
 181
 182 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 183 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 184
 185 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 186   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 187 else()
 188   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 189 endif()
 190
 191 option(LLVM_USE_INTEL_JITEVENTS
 192   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 193   OFF)
 194
 195 if( LLVM_USE_INTEL_JITEVENTS )
 196   # Verify we are on a supported platform
 197   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 198     message(FATAL_ERROR
 199       "Intel JIT API support is available on Linux and Windows only.")
 200   endif()
 201 endif( LLVM_USE_INTEL_JITEVENTS )
 202
 203 option(LLVM_USE_OPROFILE
 204   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 205
 206 # If enabled, verify we are on a platform that supports oprofile.
 207 if( LLVM_USE_OPROFILE )
 208   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 209     message(FATAL_ERROR "OProfile support is available on Linux only.")
 210   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 211 endif( LLVM_USE_OPROFILE )
 212
 213 set(LLVM_USE_SANITIZER "" CACHE STRING
 214   "Define the sanitizer used to build binaries and tests.")
 215
 216 option(LLVM_USE_SPLIT_DWARF
 217   "Use -gsplit-dwarf when compiling llvm." OFF)
 218
 219 # Define an option controlling whether we should build for 32-bit on 64-bit
 220 # platforms, where supported.
 221 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 222   # TODO: support other platforms and toolchains.
 223   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 224 endif()
 225
 226 # Define the default arguments to use with 'lit', and an option for the user to
 227 # override.
 228 set(LIT_ARGS_DEFAULT "-sv")
 229 if (MSVC OR XCODE)
 230   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 231 endif()
 232 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 233
 234 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 235 if( WIN32 AND NOT CYGWIN )
 236   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 237 endif()
 238
 239 # Define options to control the inclusion and default build behavior for
 240 # components which may not strictly be necessary (tools, runtime, examples, and
 241 # tests).
 242 #
 243 # This is primarily to support building smaller or faster project files.
 244 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 245 option(LLVM_BUILD_TOOLS
 246   "Build the LLVM tools. If OFF, just generate build targets." ON)
 247
 248 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 249 option(LLVM_BUILD_RUNTIME
 250   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 251
 252 option(LLVM_BUILD_EXAMPLES
 253   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 254 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 255
 256 option(LLVM_BUILD_TESTS
 257   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 258 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 259
 260 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 261 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 262 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 263
 264 # All options referred to from HandleLLVMOptions have to be specified
 265 # BEFORE this include, otherwise options will not be correctly set on
 266 # first cmake run
 267 include(config-ix)
 268
 269 # By default, we target the host, but this can be overridden at CMake
 270 # invocation time.
 271 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 272   "Default target for which LLVM will generate code." )
 273 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 274
 275 include(HandleLLVMOptions)
 276
 277 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 278 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 279 include(FindPythonInterp)
 280 if( NOT PYTHONINTERP_FOUND )
 281   message(FATAL_ERROR
 282 "Unable to find Python interpreter, required for builds and testing.
 283
 284 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 285 endif()
 286
 287 ######
 288 # LLVMBuild Integration
 289 #
 290 # We use llvm-build to generate all the data required by the CMake based
 291 # build system in one swoop:
 292 #
 293 #  - We generate a file (a CMake fragment) in the object root which contains
 294 #    all the definitions that are required by CMake.
 295 #
 296 #  - We generate the library table used by llvm-config.
 297 #
 298 #  - We generate the dependencies for the CMake fragment, so that we will
 299 #    automatically reconfigure outselves.
 300
 301 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 302 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 303   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 304 set(LLVMBUILDCMAKEFRAG
 305   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 306
 307 # Create the list of optional components that are enabled
 308 if (LLVM_USE_INTEL_JITEVENTS)
 309   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 310 endif (LLVM_USE_INTEL_JITEVENTS)
 311 if (LLVM_USE_OPROFILE)
 312   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 313 endif (LLVM_USE_OPROFILE)
 314
 315 message(STATUS "Constructing LLVMBuild project information")
 316 execute_process(
 317   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 318             --native-target "${LLVM_NATIVE_ARCH}"
 319             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 320             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 321             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 322             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 323             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 324             ERROR_VARIABLE LLVMBUILDERRORS
 325             OUTPUT_STRIP_TRAILING_WHITESPACE
 326             ERROR_STRIP_TRAILING_WHITESPACE
 327   RESULT_VARIABLE LLVMBUILDRESULT)
 328
 329 # On Win32, CMake doesn't properly handle piping the default output/error
 330 # streams into the GUI console. So, we explicitly catch and report them.
 331 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 332   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 333 endif()
 334 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 335   message(FATAL_ERROR
 336     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 337 endif()
 338
 339 # Include the generated CMake fragment. This will define properties from the
 340 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 341 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 342 # files change.
 343 include(${LLVMBUILDCMAKEFRAG})
 344
 345 ######
 346
 347 # Configure all of the various header file fragments LLVM uses which depend on
 348 # configuration variables.
 349 set(LLVM_ENUM_TARGETS "")
 350 set(LLVM_ENUM_ASM_PRINTERS "")
 351 set(LLVM_ENUM_ASM_PARSERS "")
 352 set(LLVM_ENUM_DISASSEMBLERS "")
 353 foreach(t ${LLVM_TARGETS_TO_BUILD})
 354   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 355
 356   list(FIND LLVM_ALL_TARGETS ${t} idx)
 357   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 358   if( idx LESS 0 AND idy LESS 0 )
 359     message(FATAL_ERROR "The target `${t}' does not exist.
 360     It should be one of\n${LLVM_ALL_TARGETS}")
 361   else()
 362     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 363   endif()
 364
 365   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 366   if( asmp_file )
 367     set(LLVM_ENUM_ASM_PRINTERS
 368       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 369   endif()
 370   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 371     set(LLVM_ENUM_ASM_PARSERS
 372       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 373   endif()
 374   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 375     set(LLVM_ENUM_DISASSEMBLERS
 376       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 377   endif()
 378 endforeach(t)
 379
 380 # Produce the target definition files, which provide a way for clients to easily
 381 # include various classes of targets.
 382 configure_file(
 383   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 384   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 385   )
 386 configure_file(
 387   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 388   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 389   )
 390 configure_file(
 391   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 392   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 393   )
 394 configure_file(
 395   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 396   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 397   )
 398
 399 # Configure the three LLVM configuration header files.
 400 configure_file(
 401   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 402   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 403 configure_file(
 404   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 405   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 406 configure_file(
 407   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 408   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 409
 410 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 411 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 412 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 413
 414 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 415
 416 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 417
 418 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 419   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 420   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 421   include_directories("/usr/local/include")
 422   link_directories("/usr/local/lib")
 423 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 424
 425 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 426    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 427 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 428
 429 # Make sure we don't get -rdynamic in every binary. For those that need it,
 430 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 431 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 432
 433 include(AddLLVM)
 434 include(TableGen)
 435
 436 if( MINGW )
 437   # People report that -O3 is unreliable on MinGW. The traditional
 438   # build also uses -O2 for that reason:
 439   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 440 endif()
 441
 442 # Put this before tblgen. Else we have a circular dependence.
 443 add_subdirectory(lib/Support)
 444 add_subdirectory(lib/TableGen)
 445
 446 add_subdirectory(utils/TableGen)
 447
 448 add_subdirectory(include/llvm)
 449
 450 add_subdirectory(lib)
 451
 452 add_subdirectory(utils/FileCheck)
 453 add_subdirectory(utils/FileUpdate)
 454 add_subdirectory(utils/count)
 455 add_subdirectory(utils/not)
 456 add_subdirectory(utils/llvm-lit)
 457 add_subdirectory(utils/yaml-bench)
 458
 459 add_subdirectory(projects)
 460
 461 if( LLVM_INCLUDE_TOOLS )
 462   add_subdirectory(tools)
 463 endif()
 464
 465 if( LLVM_INCLUDE_RUNTIME )
 466   add_subdirectory(runtime)
 467 endif()
 468
 469 if( LLVM_INCLUDE_EXAMPLES )
 470   add_subdirectory(examples)
 471 endif()
 472
 473 if( LLVM_INCLUDE_TESTS )
 474   add_subdirectory(test)
 475   add_subdirectory(utils/unittest)
 476   add_subdirectory(unittests)
 477   if (MSVC)
 478     # This utility is used to prevent crashing tests from calling Dr. Watson on
 479     # Windows.
 480     add_subdirectory(utils/KillTheDoctor)
 481   endif()
 482
 483   # Add a global check rule now that all subdirectories have been traversed
 484   # and we know the total set of lit testsuites.
 485   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 486   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 487   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 488   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 489   add_lit_target(check-all
 490     "Running all regression tests"
 491     ${LLVM_LIT_TESTSUITES}
 492     PARAMS ${LLVM_LIT_PARAMS}
 493     DEPENDS ${LLVM_LIT_DEPENDS}
 494     ARGS ${LLVM_LIT_EXTRA_ARGS}
 495     )
 496 endif()
 497
 498 if (LLVM_INCLUDE_DOCS)
 499   add_subdirectory(docs)
 500 endif()
 501
 502 add_subdirectory(cmake/modules)
 503
 504 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 505   install(DIRECTORY include/
 506     DESTINATION include
 507     FILES_MATCHING
 508     PATTERN "*.def"
 509     PATTERN "*.h"
 510     PATTERN "*.td"
 511     PATTERN "*.inc"
 512     PATTERN "LICENSE.TXT"
 513     PATTERN ".svn" EXCLUDE
 514     )
 515
 516   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 517     DESTINATION include
 518     FILES_MATCHING
 519     PATTERN "*.def"
 520     PATTERN "*.h"
 521     PATTERN "*.gen"
 522     PATTERN "*.inc"
 523     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 524     PATTERN "CMakeFiles" EXCLUDE
 525     PATTERN ".svn" EXCLUDE
 526     )
 527 endif()
 528
 529 # Workaround for MSVS10 to avoid the Dialog Hell
 530 # FIXME: This could be removed with future version of CMake.
 531 if(MSVC_VERSION EQUAL 1600)
 532   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 533   if( EXISTS "${LLVM_SLN_FILENAME}" )
 534     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 535   endif()
 536 endif()