CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.0")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME llvm)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  29
  30 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  31   message(FATAL_ERROR "In-source builds are not allowed.
  32 CMake would overwrite the makefiles distributed with LLVM.
  33 Please create a directory and run cmake from there, passing the path
  34 to this source directory as the last argument.
  35 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  36 Please delete them.")
  37 endif()
  38
  39 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  40
  41 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  42 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  43 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  44 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  45 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  46 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  47
  48 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  49   file(GLOB_RECURSE
  50     tablegenned_files_on_include_dir
  51     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  52   file(GLOB_RECURSE
  53     tablegenned_files_on_lib_dir
  54     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  55   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  56     message(FATAL_ERROR "Apparently there is a previous in-source build,
  57 probably as the result of running `configure' and `make' on
  58 ${LLVM_MAIN_SRC_DIR}.
  59 This may cause problems. The suspicious files are:
  60 ${tablegenned_files_on_lib_dir}
  61 ${tablegenned_files_on_include_dir}
  62 Please clean the source directory.")
  63   endif()
  64 endif()
  65
  66 set(LLVM_ALL_TARGETS
  67   Alpha
  68   ARM
  69   CBackend
  70   CellSPU
  71   CppBackend
  72   Mips
  73   MBlaze
  74   MSP430
  75   PowerPC
  76   PTX
  77   Sparc
  78   X86
  79   XCore
  80   )
  81
  82 # List of targets with JIT support:
  83 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  84
  85 if( MSVC )
  86   set(LLVM_TARGETS_TO_BUILD X86
  87     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  88 else( MSVC )
  89   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  90     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  91 endif( MSVC )
  92
  93 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  94 if(LLVM_ENABLE_CBE_PRINTF_A)
  95   set(ENABLE_CBE_PRINTF_A 1)
  96 endif()
  97
  98 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
  99 if(LLVM_ENABLE_TIMESTAMPS)
 100   set(ENABLE_TIMESTAMPS 1)
 101 endif()
 102
 103 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 104 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 105 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 106
 107 set(LLVM_TARGET_ARCH "host"
 108   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 109
 110 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 111
 112 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 113   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 114 endif()
 115
 116 set(LLVM_ENUM_TARGETS "")
 117 foreach(c ${LLVM_TARGETS_TO_BUILD})
 118   list(FIND LLVM_ALL_TARGETS ${c} idx)
 119   if( idx LESS 0 )
 120     message(FATAL_ERROR "The target `${c}' does not exist.
 121     It should be one of\n${LLVM_ALL_TARGETS}")
 122   else()
 123     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 124   endif()
 125 endforeach(c)
 126
 127 # Produce llvm/Config/Targets.def
 128 configure_file(
 129   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 130   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 131   )
 132
 133 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 134
 135 include(AddLLVMDefinitions)
 136
 137 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 138
 139 # MSVC has a gazillion warnings with this.
 140 if( MSVC )
 141   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 142 else( MSVC )
 143   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 144 endif()
 145
 146 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 147 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 148
 149 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 150   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 151 else()
 152   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 153 endif()
 154
 155 # All options referred to from HandleLLVMOptions have to be specified
 156 # BEFORE this include, otherwise options will not be correctly set on
 157 # first cmake run
 158 include(config-ix)
 159 include(HandleLLVMOptions)
 160
 161 configure_file(
 162   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 163   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 164
 165 configure_file(
 166   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 167   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 168
 169 configure_file(
 170   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 171   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 172
 173 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 174 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 175 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 176
 177 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 178
 179 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 180
 181 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 182    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 183 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 184
 185 include(AddLLVM)
 186 include(TableGen)
 187
 188 macro(llvm_tablegen)
 189   tablegen(LLVM ${ARGN})
 190 endmacro()
 191
 192 if( MINGW )
 193   # People report that -O3 is unreliable on MinGW. The traditional
 194   # build also uses -O2 for that reason:
 195   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 196 endif()
 197
 198 # Put this before tblgen. Else we have a circular dependence.
 199 add_subdirectory(lib/Support)
 200 add_subdirectory(lib/TableGen)
 201
 202 add_subdirectory(utils/TableGen)
 203
 204 add_subdirectory(include/llvm)
 205
 206 add_subdirectory(lib)
 207
 208 add_subdirectory(utils/FileCheck)
 209 add_subdirectory(utils/FileUpdate)
 210 add_subdirectory(utils/count)
 211 add_subdirectory(utils/not)
 212 add_subdirectory(utils/llvm-lit)
 213
 214 add_subdirectory(projects)
 215
 216 option(LLVM_BUILD_TOOLS
 217   "Build the LLVM tools. If OFF, just generate build targets." ON)
 218 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 219 if( LLVM_INCLUDE_TOOLS )
 220   add_subdirectory(tools)
 221 endif()
 222
 223 option(LLVM_BUILD_RUNTIME
 224   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 225 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 226 if( LLVM_INCLUDE_RUNTIME )
 227   add_subdirectory(runtime)
 228 endif()
 229
 230 option(LLVM_BUILD_EXAMPLES
 231   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 232 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 233 if( LLVM_INCLUDE_EXAMPLES )
 234   add_subdirectory(examples)
 235 endif()
 236
 237 option(LLVM_BUILD_TESTS
 238   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 239 if( LLVM_INCLUDE_TESTS )
 240   add_subdirectory(test)
 241   add_subdirectory(utils/unittest)
 242   add_subdirectory(unittests)
 243   if (MSVC)
 244     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 245     # Windows.
 246     add_subdirectory(utils/KillTheDoctor)
 247   endif()
 248 endif()
 249
 250 add_subdirectory(cmake/modules)
 251
 252 install(DIRECTORY include/
 253   DESTINATION include
 254   FILES_MATCHING
 255   PATTERN "*.def"
 256   PATTERN "*.h"
 257   PATTERN "*.td"
 258   PATTERN "*.inc"
 259   PATTERN "LICENSE.TXT"
 260   PATTERN ".svn" EXCLUDE
 261   )
 262
 263 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 264   DESTINATION include
 265   FILES_MATCHING
 266   PATTERN "*.def"
 267   PATTERN "*.h"
 268   PATTERN "*.gen"
 269   PATTERN "*.inc"
 270   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 271   PATTERN "CMakeFiles" EXCLUDE
 272   PATTERN ".svn" EXCLUDE
 273   )
 274
 275 # TODO: make and install documentation.
 276
 277 set(CPACK_PACKAGE_VENDOR "LLVM")
 278 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 279 set(CPACK_PACKAGE_VERSION_MINOR 9)
 280 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 281 include(CPack)
 282
 283 # Workaround for MSVS10 to avoid the Dialog Hell
 284 # FIXME: This could be removed with future version of CMake.
 285 if(MSVC_VERSION EQUAL 1600)
 286   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 287   if( EXISTS "${LLVM_SLN_FILENAME}" )
 288     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 289   endif()
 290 endif()