CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  41   "Default URL where bug reports are to be submitted.")
  42
  43 # Configure CPack.
  44 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  45 set(CPACK_PACKAGE_VENDOR "LLVM")
  46 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  47 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  48 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  50 if(WIN32 AND NOT UNIX)
  51   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  52   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  53   set(CPACK_NSIS_MODIFY_PATH "ON")
  54   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  55   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  56     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  57   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  58     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  59 endif()
  60 include(CPack)
  61
  62 # Sanity check our source directory to make sure that we are not trying to
  63 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  64 # sure that we don't have any stray generated files lying around in the tree
  65 # (which would end up getting picked up by header search, instead of the correct
  66 # versions).
  67 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  68   message(FATAL_ERROR "In-source builds are not allowed.
  69 CMake would overwrite the makefiles distributed with LLVM.
  70 Please create a directory and run cmake from there, passing the path
  71 to this source directory as the last argument.
  72 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  73 Please delete them.")
  74 endif()
  75 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_include_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  79   file(GLOB_RECURSE
  80     tablegenned_files_on_lib_dir
  81     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  82   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  83     message(FATAL_ERROR "Apparently there is a previous in-source build,
  84 probably as the result of running `configure' and `make' on
  85 ${CMAKE_CURRENT_SOURCE_DIR}.
  86 This may cause problems. The suspicious files are:
  87 ${tablegenned_files_on_lib_dir}
  88 ${tablegenned_files_on_include_dir}
  89 Please clean the source directory.")
  90   endif()
  91 endif()
  92
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  94
  95 # They are used as destination of target generators.
  96 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  97 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
  98
  99 # Each of them corresponds to llvm-config's.
 100 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 101 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 102 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 103
 104 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 105 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 106 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 107
 108 set(LLVM_ALL_TARGETS
 109   AArch64
 110   ARM
 111   CppBackend
 112   Hexagon
 113   Mips
 114   MSP430
 115   NVPTX
 116   PowerPC
 117   R600
 118   Sparc
 119   SystemZ
 120   X86
 121   XCore
 122   )
 123
 124 # List of targets with JIT support:
 125 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 126
 127 set(LLVM_TARGETS_TO_BUILD "all"
 128     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 129
 130 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 131   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 132
 133 option(BUILD_SHARED_LIBS
 134   "Build all libraries as shared libraries instead of static" OFF)
 135
 136 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 137 if(LLVM_ENABLE_CBE_PRINTF_A)
 138   set(ENABLE_CBE_PRINTF_A 1)
 139 endif()
 140
 141 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 142 if(LLVM_ENABLE_TIMESTAMPS)
 143   set(ENABLE_TIMESTAMPS 1)
 144 endif()
 145
 146 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 147 if(LLVM_ENABLE_BACKTRACES)
 148   set(ENABLE_BACKTRACES 1)
 149 endif()
 150
 151 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 152 if(LLVM_ENABLE_CRASH_OVERRIDES)
 153   set(ENABLE_CRASH_OVERRIDES 1)
 154 endif()
 155
 156 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 157 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 158 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 159
 160 set(LLVM_TARGET_ARCH "host"
 161   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 162
 163 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 164
 165 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 166
 167 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 168
 169 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 170   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 171 endif()
 172
 173 set(LLVM_TARGETS_TO_BUILD
 174    ${LLVM_TARGETS_TO_BUILD}
 175    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 176 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 177
 178 include(AddLLVMDefinitions)
 179
 180 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 181
 182 # MSVC has a gazillion warnings with this.
 183 if( MSVC )
 184   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 185 else( MSVC )
 186   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 187 endif()
 188
 189 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 190 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 191 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 192 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 193
 194 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 195   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 196 else()
 197   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 198 endif()
 199
 200 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 201        "Set to ON to force using an old, unsupported host toolchain." OFF)
 202
 203 option(LLVM_USE_INTEL_JITEVENTS
 204   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 205   OFF)
 206
 207 if( LLVM_USE_INTEL_JITEVENTS )
 208   # Verify we are on a supported platform
 209   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 210     message(FATAL_ERROR
 211       "Intel JIT API support is available on Linux and Windows only.")
 212   endif()
 213 endif( LLVM_USE_INTEL_JITEVENTS )
 214
 215 option(LLVM_USE_OPROFILE
 216   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 217
 218 # If enabled, verify we are on a platform that supports oprofile.
 219 if( LLVM_USE_OPROFILE )
 220   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 221     message(FATAL_ERROR "OProfile support is available on Linux only.")
 222   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 223 endif( LLVM_USE_OPROFILE )
 224
 225 set(LLVM_USE_SANITIZER "" CACHE STRING
 226   "Define the sanitizer used to build binaries and tests.")
 227
 228 option(LLVM_USE_SPLIT_DWARF
 229   "Use -gsplit-dwarf when compiling llvm." OFF)
 230
 231 # Define an option controlling whether we should build for 32-bit on 64-bit
 232 # platforms, where supported.
 233 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 234   # TODO: support other platforms and toolchains.
 235   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 236 endif()
 237
 238 # Define the default arguments to use with 'lit', and an option for the user to
 239 # override.
 240 set(LIT_ARGS_DEFAULT "-sv")
 241 if (MSVC OR XCODE)
 242   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 243 endif()
 244 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 245
 246 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 247 if( WIN32 AND NOT CYGWIN )
 248   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 249 endif()
 250
 251 # Define options to control the inclusion and default build behavior for
 252 # components which may not strictly be necessary (tools, examples, and tests).
 253 #
 254 # This is primarily to support building smaller or faster project files.
 255 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 256 option(LLVM_BUILD_TOOLS
 257   "Build the LLVM tools. If OFF, just generate build targets." ON)
 258
 259 option(LLVM_BUILD_RUNTIME
 260   "Build the LLVM runtime libraries." ON)
 261 option(LLVM_BUILD_EXAMPLES
 262   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 263 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 264
 265 option(LLVM_BUILD_TESTS
 266   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 267 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 268
 269 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 270 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 271 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 272
 273 # All options referred to from HandleLLVMOptions have to be specified
 274 # BEFORE this include, otherwise options will not be correctly set on
 275 # first cmake run
 276 include(config-ix)
 277
 278 # By default, we target the host, but this can be overridden at CMake
 279 # invocation time.
 280 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 281   "Default target for which LLVM will generate code." )
 282 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 283
 284 include(HandleLLVMOptions)
 285
 286 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 287 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 288 include(FindPythonInterp)
 289 if( NOT PYTHONINTERP_FOUND )
 290   message(FATAL_ERROR
 291 "Unable to find Python interpreter, required for builds and testing.
 292
 293 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 294 endif()
 295
 296 ######
 297 # LLVMBuild Integration
 298 #
 299 # We use llvm-build to generate all the data required by the CMake based
 300 # build system in one swoop:
 301 #
 302 #  - We generate a file (a CMake fragment) in the object root which contains
 303 #    all the definitions that are required by CMake.
 304 #
 305 #  - We generate the library table used by llvm-config.
 306 #
 307 #  - We generate the dependencies for the CMake fragment, so that we will
 308 #    automatically reconfigure outselves.
 309
 310 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 311 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 312   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 313 set(LLVMBUILDCMAKEFRAG
 314   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 315
 316 # Create the list of optional components that are enabled
 317 if (LLVM_USE_INTEL_JITEVENTS)
 318   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 319 endif (LLVM_USE_INTEL_JITEVENTS)
 320 if (LLVM_USE_OPROFILE)
 321   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 322 endif (LLVM_USE_OPROFILE)
 323
 324 message(STATUS "Constructing LLVMBuild project information")
 325 execute_process(
 326   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 327             --native-target "${LLVM_NATIVE_ARCH}"
 328             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 329             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 330             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 331             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 332             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 333             ERROR_VARIABLE LLVMBUILDERRORS
 334             OUTPUT_STRIP_TRAILING_WHITESPACE
 335             ERROR_STRIP_TRAILING_WHITESPACE
 336   RESULT_VARIABLE LLVMBUILDRESULT)
 337
 338 # On Win32, CMake doesn't properly handle piping the default output/error
 339 # streams into the GUI console. So, we explicitly catch and report them.
 340 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 341   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 342 endif()
 343 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 344   message(FATAL_ERROR
 345     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 346 endif()
 347
 348 # Include the generated CMake fragment. This will define properties from the
 349 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 350 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 351 # files change.
 352 include(${LLVMBUILDCMAKEFRAG})
 353
 354 ######
 355
 356 # Configure all of the various header file fragments LLVM uses which depend on
 357 # configuration variables.
 358 set(LLVM_ENUM_TARGETS "")
 359 set(LLVM_ENUM_ASM_PRINTERS "")
 360 set(LLVM_ENUM_ASM_PARSERS "")
 361 set(LLVM_ENUM_DISASSEMBLERS "")
 362 foreach(t ${LLVM_TARGETS_TO_BUILD})
 363   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 364
 365   list(FIND LLVM_ALL_TARGETS ${t} idx)
 366   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 367   if( idx LESS 0 AND idy LESS 0 )
 368     message(FATAL_ERROR "The target `${t}' does not exist.
 369     It should be one of\n${LLVM_ALL_TARGETS}")
 370   else()
 371     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 372   endif()
 373
 374   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 375   if( asmp_file )
 376     set(LLVM_ENUM_ASM_PRINTERS
 377       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 378   endif()
 379   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 380     set(LLVM_ENUM_ASM_PARSERS
 381       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 382   endif()
 383   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 384     set(LLVM_ENUM_DISASSEMBLERS
 385       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 386   endif()
 387 endforeach(t)
 388
 389 # Produce the target definition files, which provide a way for clients to easily
 390 # include various classes of targets.
 391 configure_file(
 392   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 393   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 394   )
 395 configure_file(
 396   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 397   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 398   )
 399 configure_file(
 400   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 401   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 402   )
 403 configure_file(
 404   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 405   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 406   )
 407
 408 # Configure the three LLVM configuration header files.
 409 configure_file(
 410   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 411   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 412 configure_file(
 413   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 414   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 415 configure_file(
 416   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 417   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 418
 419 # They are not referenced. See set_output_directory().
 420 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 421 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 422 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 423
 424 if( NOT DEFINED CMAKE_INSTALL_RPATH )
 425   set( CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 426 endif( NOT DEFINED CMAKE_INSTALL_RPATH )
 427
 428 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 429
 430 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 431
 432 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 433   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 434   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 435   include_directories("/usr/local/include")
 436   link_directories("/usr/local/lib")
 437 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 438
 439 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 440    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 441 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 442
 443 # Make sure we don't get -rdynamic in every binary. For those that need it,
 444 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 445 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 446
 447 include(AddLLVM)
 448 include(TableGen)
 449
 450 if( MINGW )
 451   # People report that -O3 is unreliable on MinGW. The traditional
 452   # build also uses -O2 for that reason:
 453   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 454 endif()
 455
 456 # Put this before tblgen. Else we have a circular dependence.
 457 add_subdirectory(lib/Support)
 458 add_subdirectory(lib/TableGen)
 459
 460 add_subdirectory(utils/TableGen)
 461
 462 add_subdirectory(include/llvm)
 463
 464 add_subdirectory(lib)
 465
 466 add_subdirectory(utils/FileCheck)
 467 add_subdirectory(utils/FileUpdate)
 468 add_subdirectory(utils/count)
 469 add_subdirectory(utils/not)
 470 add_subdirectory(utils/llvm-lit)
 471 add_subdirectory(utils/yaml-bench)
 472
 473 add_subdirectory(projects)
 474
 475 if( LLVM_INCLUDE_TOOLS )
 476   add_subdirectory(tools)
 477 endif()
 478
 479 if( LLVM_INCLUDE_EXAMPLES )
 480   add_subdirectory(examples)
 481 endif()
 482
 483 if( LLVM_INCLUDE_TESTS )
 484   add_subdirectory(test)
 485   add_subdirectory(utils/unittest)
 486   add_subdirectory(unittests)
 487   if (MSVC)
 488     # This utility is used to prevent crashing tests from calling Dr. Watson on
 489     # Windows.
 490     add_subdirectory(utils/KillTheDoctor)
 491   endif()
 492
 493   # Add a global check rule now that all subdirectories have been traversed
 494   # and we know the total set of lit testsuites.
 495   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 496   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 497   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 498   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 499   add_lit_target(check-all
 500     "Running all regression tests"
 501     ${LLVM_LIT_TESTSUITES}
 502     PARAMS ${LLVM_LIT_PARAMS}
 503     DEPENDS ${LLVM_LIT_DEPENDS}
 504     ARGS ${LLVM_LIT_EXTRA_ARGS}
 505     )
 506 endif()
 507
 508 if (LLVM_INCLUDE_DOCS)
 509   add_subdirectory(docs)
 510 endif()
 511
 512 add_subdirectory(cmake/modules)
 513
 514 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 515   install(DIRECTORY include/
 516     DESTINATION include
 517     FILES_MATCHING
 518     PATTERN "*.def"
 519     PATTERN "*.h"
 520     PATTERN "*.td"
 521     PATTERN "*.inc"
 522     PATTERN "LICENSE.TXT"
 523     PATTERN ".svn" EXCLUDE
 524     )
 525
 526   install(DIRECTORY ${LLVM_INCLUDE_DIR}/
 527     DESTINATION include
 528     FILES_MATCHING
 529     PATTERN "*.def"
 530     PATTERN "*.h"
 531     PATTERN "*.gen"
 532     PATTERN "*.inc"
 533     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 534     PATTERN "CMakeFiles" EXCLUDE
 535     PATTERN ".svn" EXCLUDE
 536     )
 537 endif()
 538
 539 # Workaround for MSVS10 to avoid the Dialog Hell
 540 # FIXME: This could be removed with future version of CMake.
 541 if(MSVC_VERSION EQUAL 1600)
 542   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 543   if( EXISTS "${LLVM_SLN_FILENAME}" )
 544     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 545   endif()
 546 endif()
 547