arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 /*
  50  * The size of the PE/COFF section that covers the kernel image, which
  51  * runs from stext to _edata, must be a round multiple of the PE/COFF
  52  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  53  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  54  * boundary should be sufficient.
  55  */
  56 PECOFF_FILE_ALIGNMENT = 0x200;
  57
  58 #ifdef CONFIG_EFI
  59 #define PECOFF_EDATA_PADDING    \
  60         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  61 #else
  62 #define PECOFF_EDATA_PADDING
  63 #endif
  64
  65 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  66 /*
  67  *  4 KB granule:   1 level 2 entry
  68  * 16 KB granule: 128 level 3 entries, with contiguous bit
  69  * 64 KB granule:  32 level 3 entries, with contiguous bit
  70  */
  71 #define SEGMENT_ALIGN                   SZ_2M
  72 #else
  73 /*
  74  *  4 KB granule:  16 level 3 entries, with contiguous bit
  75  * 16 KB granule:   4 level 3 entries, without contiguous bit
  76  * 64 KB granule:   1 level 3 entry
  77  */
  78 #define SEGMENT_ALIGN                   SZ_64K
  79 #endif
  80
  81 SECTIONS
  82 {
  83         /*
  84          * XXX: The linker does not define how output sections are
  85          * assigned to input sections when there are multiple statements
  86          * matching the same input section name.  There is no documented
  87          * order of matching.
  88          */
  89         /DISCARD/ : {
  90                 ARM_EXIT_DISCARD(EXIT_TEXT)
  91                 ARM_EXIT_DISCARD(EXIT_DATA)
  92                 EXIT_CALL
  93                 *(.discard)
  94                 *(.discard.*)
  95                 *(.interp .dynamic)
  96                 *(.dynsym .dynstr .hash)
  97         }
  98
  99         . = KIMAGE_VADDR + TEXT_OFFSET;
 100
 101         .head.text : {
 102                 _text = .;
 103                 HEAD_TEXT
 104         }
 105         .text : {                       /* Real text segment            */
 106                 _stext = .;             /* Text and read-only data      */
 107                         __exception_text_start = .;
 108                         *(.exception.text)
 109                         __exception_text_end = .;
 110                         IRQENTRY_TEXT
 111                         TEXT_TEXT
 112                         SCHED_TEXT
 113                         LOCK_TEXT
 114                         HYPERVISOR_TEXT
 115                         IDMAP_TEXT
 116                         *(.fixup)
 117                         *(.gnu.warning)
 118                 . = ALIGN(16);
 119                 *(.got)                 /* Global offset table          */
 120         }
 121
 122         . = ALIGN(SEGMENT_ALIGN);
 123         _etext = .;                     /* End of text section */
 124
 125         RO_DATA(PAGE_SIZE)              /* everything from this point to     */
 126         EXCEPTION_TABLE(8)              /* __init_begin will be marked RO NX */
 127         NOTES
 128
 129         . = ALIGN(SEGMENT_ALIGN);
 130         __init_begin = .;
 131
 132         INIT_TEXT_SECTION(8)
 133         .exit.text : {
 134                 ARM_EXIT_KEEP(EXIT_TEXT)
 135         }
 136
 137         .init.data : {
 138                 INIT_DATA
 139                 INIT_SETUP(16)
 140                 INIT_CALLS
 141                 CON_INITCALL
 142                 SECURITY_INITCALL
 143                 INIT_RAM_FS
 144         }
 145         .exit.data : {
 146                 ARM_EXIT_KEEP(EXIT_DATA)
 147         }
 148
 149         PERCPU_SECTION(L1_CACHE_BYTES)
 150
 151         . = ALIGN(4);
 152         .altinstructions : {
 153                 __alt_instructions = .;
 154                 *(.altinstructions)
 155                 __alt_instructions_end = .;
 156         }
 157         .altinstr_replacement : {
 158                 *(.altinstr_replacement)
 159         }
 160         .rela : ALIGN(8) {
 161                 *(.rela .rela*)
 162         }
 163
 164         __rela_offset   = ABSOLUTE(ADDR(.rela) - KIMAGE_VADDR);
 165         __rela_size     = SIZEOF(.rela);
 166
 167         . = ALIGN(SEGMENT_ALIGN);
 168         __init_end = .;
 169
 170         _data = .;
 171         _sdata = .;
 172         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 173         PECOFF_EDATA_PADDING
 174         _edata = .;
 175
 176         BSS_SECTION(0, 0, 0)
 177
 178         . = ALIGN(PAGE_SIZE);
 179         idmap_pg_dir = .;
 180         . += IDMAP_DIR_SIZE;
 181         swapper_pg_dir = .;
 182         . += SWAPPER_DIR_SIZE;
 183
 184         _end = .;
 185
 186         STABS_DEBUG
 187
 188         HEAD_SYMBOLS
 189 }
 190
 191 /*
 192  * The HYP init code and ID map text can't be longer than a page each,
 193  * and should not cross a page boundary.
 194  */
 195 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 196         "HYP init code too big or misaligned")
 197 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 198         "ID map text too big or misaligned")
 199
 200 /*
 201  * If padding is applied before .head.text, virt<->phys conversions will fail.
 202  */
 203 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")