arch/tile/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3 #include <asm/cache.h>
   4 #include <asm/thread_info.h>
   5 #include <hv/hypervisor.h>
   6
   7 /* Text loads starting from the supervisor interrupt vector address. */
   8 #define TEXT_OFFSET MEM_SV_INTRPT
   9
  10 OUTPUT_ARCH(tile)
  11 ENTRY(_start)
  12 jiffies = jiffies_64;
  13
  14 PHDRS
  15 {
  16   intrpt1 PT_LOAD ;
  17   text PT_LOAD ;
  18   data PT_LOAD ;
  19 }
  20 SECTIONS
  21 {
  22   /* Text is loaded with a different VA than data; start with text. */
  23   #undef LOAD_OFFSET
  24   #define LOAD_OFFSET TEXT_OFFSET
  25
  26   /* Interrupt vectors */
  27   .intrpt1 (LOAD_OFFSET) : AT ( 0 )   /* put at the start of physical memory */
  28   {
  29     _text = .;
  30     *(.intrpt1)
  31   } :intrpt1 =0
  32
  33   /* Hypervisor call vectors */
  34   . = ALIGN(0x10000);
  35   .hvglue : AT (ADDR(.hvglue) - LOAD_OFFSET) {
  36     *(.hvglue)
  37   } :NONE
  38
  39   /* Now the real code */
  40   . = ALIGN(0x20000);
  41   _stext = .;
  42   .text : AT (ADDR(.text) - LOAD_OFFSET) {
  43     HEAD_TEXT
  44     SCHED_TEXT
  45     LOCK_TEXT
  46     IRQENTRY_TEXT
  47     __fix_text_end = .;   /* tile-cpack won't rearrange before this */
  48     TEXT_TEXT
  49     *(.text.*)
  50     *(.coldtext*)
  51     *(.fixup)
  52     *(.gnu.warning)
  53   } :text =0
  54   _etext = .;
  55
  56   /* "Init" is divided into two areas with very different virtual addresses. */
  57   INIT_TEXT_SECTION(PAGE_SIZE)
  58
  59   /* Now we skip back to PAGE_OFFSET for the data. */
  60   . = (. - TEXT_OFFSET + PAGE_OFFSET);
  61   #undef LOAD_OFFSET
  62   #define LOAD_OFFSET PAGE_OFFSET
  63
  64   . = ALIGN(PAGE_SIZE);
  65   __init_begin = .;
  66   VMLINUX_SYMBOL(_sinitdata) = .;
  67   INIT_DATA_SECTION(16) :data =0
  68   PERCPU_SECTION(L2_CACHE_BYTES)
  69   . = ALIGN(PAGE_SIZE);
  70   VMLINUX_SYMBOL(_einitdata) = .;
  71   __init_end = .;
  72
  73   _sdata = .;                   /* Start of data section */
  74
  75   RO_DATA_SECTION(PAGE_SIZE)
  76
  77   /* initially writeable, then read-only */
  78   . = ALIGN(PAGE_SIZE);
  79   __w1data_begin = .;
  80   .w1data : AT(ADDR(.w1data) - LOAD_OFFSET) {
  81     VMLINUX_SYMBOL(__w1data_begin) = .;
  82     *(.w1data)
  83     VMLINUX_SYMBOL(__w1data_end) = .;
  84   }
  85
  86   RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  87
  88   _edata = .;
  89
  90   EXCEPTION_TABLE(L2_CACHE_BYTES)
  91   NOTES
  92
  93
  94   BSS_SECTION(8, PAGE_SIZE, 1)
  95   _end = . ;
  96
  97   STABS_DEBUG
  98   DWARF_DEBUG
  99
 100   DISCARDS
 101 }