autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 # Determine the LLVM native architecture for the target
 238 case "$llvm_cv_target_arch" in
 239     x86)     LLVM_NATIVE_ARCH="X86" ;;
 240     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 241     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 242 esac
 243
 244 dnl Define a substitution, ARCH, for the target architecture
 245 AC_SUBST(ARCH,$llvm_cv_target_arch)
 246
 247 dnl Check for the endianness of the target
 248 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 249
 250 dnl Check for build platform executable suffix if we're crosscompiling
 251 if test "$cross_compiling" = yes; then
 252   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 253   AC_BUILD_EXEEXT
 254   ac_build_prefix=${build_alias}-
 255   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 256   if test -z "$BUILD_CXX"; then
 257      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 258      if test -z "$BUILD_CXX"; then
 259        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 260      fi
 261   fi
 262 else
 263   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 264 fi
 265
 266 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 267 dnl that this build is being done from a checkout. This sets up several
 268 dnl defaults for the command line switches. When we build with a CVS directory,
 269 dnl we get a debug with assertions turned on. Without, we assume a source
 270 dnl release and we get an optimized build without assertions.
 271 dnl See --enable-optimized and --enable-assertions below
 272 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 273   cvsbuild="yes"
 274   optimize="no"
 275   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 276 else
 277   cvsbuild="no"
 278   optimize="yes"
 279 fi
 280
 281 dnl===-----------------------------------------------------------------------===
 282 dnl===
 283 dnl=== SECTION 3: Command line arguments for the configure script.
 284 dnl===
 285 dnl===-----------------------------------------------------------------------===
 286
 287 dnl --enable-optimized : check whether they want to do an optimized build:
 288 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 289  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 290 if test ${enableval} = "no" ; then
 291   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 292 else
 293   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 294 fi
 295
 296 dnl --enable-profiling : check whether they want to do a profile build:
 297 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 298  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 299 if test ${enableval} = "no" ; then
 300   AC_SUBST(ENABLE_PROFILING,[[]])
 301 else
 302   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 303 fi
 304
 305 dnl --enable-assertions : check whether they want to turn on assertions or not:
 306 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 307   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 308 if test ${enableval} = "yes" ; then
 309   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 310 else
 311   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 312 fi
 313
 314 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 315 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 316   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 317 if test ${enableval} = "yes" ; then
 318   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 319   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 320 else
 321   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 322   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 323 fi
 324
 325 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 326 AC_ARG_ENABLE(debug-runtime,
 327    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 328 if test ${enableval} = "no" ; then
 329   AC_SUBST(DEBUG_RUNTIME,[[]])
 330 else
 331   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 332 fi
 333
 334 dnl --enable-jit: check whether they want to enable the jit
 335 AC_ARG_ENABLE(jit,
 336   AS_HELP_STRING(--enable-jit,
 337                  [Enable Just In Time Compiling (default is YES)]),,
 338   enableval=default)
 339 if test ${enableval} = "no"
 340 then
 341   AC_SUBST(JIT,[[]])
 342 else
 343   case "$llvm_cv_target_arch" in
 344     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 345     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 347     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 348     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 349     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 350     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 351     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 352     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 353     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 354     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 355     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 356   esac
 357 fi
 358
 359 dnl Allow enablement of doxygen generated documentation
 360 AC_ARG_ENABLE(doxygen,
 361               AS_HELP_STRING([--enable-doxygen],
 362                              [Build doxygen documentation (default is NO)]),,
 363                              enableval=default)
 364 case "$enableval" in
 365   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 366   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 367   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 368   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 369 esac
 370
 371 dnl Allow disablement of threads
 372 AC_ARG_ENABLE(threads,
 373               AS_HELP_STRING([--enable-threads],
 374                              [Use threads if available (default is YES)]),,
 375                              enableval=default)
 376 case "$enableval" in
 377   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 378   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 379   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 380   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 381 esac
 382 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 383
 384 dnl Allow building without position independent code
 385 AC_ARG_ENABLE(pic,
 386   AS_HELP_STRING([--enable-pic],
 387                  [Build LLVM with Position Independent Code (default is YES)]),,
 388                  enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 391   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 392   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 394 esac
 395 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 396                    [Define if position independent code is enabled])
 397
 398 dnl Allow specific targets to be specified for building (or not)
 399 TARGETS_TO_BUILD=""
 400 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 401     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 402     enableval=all)
 403 case "$enableval" in
 404   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 405   host-only)
 406     case "$llvm_cv_target_arch" in
 407       x86)     TARGETS_TO_BUILD="X86" ;;
 408       x86_64)  TARGETS_TO_BUILD="X86" ;;
 409       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 410       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 411       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 412       IA64)    TARGETS_TO_BUILD="IA64" ;;
 413       ARM)     TARGETS_TO_BUILD="ARM" ;;
 414       Mips)    TARGETS_TO_BUILD="Mips" ;;
 415       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 416       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 417       XCore)   TARGETS_TO_BUILD="XCore" ;;
 418       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 419       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 420     esac
 421     ;;
 422   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 423       case "$a_target" in
 424         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 425         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 426         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 427         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 428         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 429         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 430         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 431         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 432         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 433         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 434         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 435         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 436         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 437         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 438         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 439         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 440       esac
 441   done
 442   ;;
 443 esac
 444 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 445
 446 # Determine whether we are building LLVM support for the native architecture.
 447 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 448 for a_target in $TARGETS_TO_BUILD; do
 449   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 450     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 451     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 452       [LLVM architecture name for the native architecture, if available])
 453   fi
 454 done
 455
 456 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 457 # Targets.def and AsmPrinters.def.
 458 LLVM_ENUM_TARGETS=""
 459 LLVM_ENUM_ASM_PRINTERS=""
 460 for target_to_build in $TARGETS_TO_BUILD; do
 461   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 462   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 463     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 464   fi
 465 done
 466 AC_SUBST(LLVM_ENUM_TARGETS)
 467 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 468
 469 dnl Prevent the CBackend from using printf("%a") for floating point so older
 470 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 471 dnl can still compile the CBE's output
 472 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 473   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 474   enableval=default)
 475 case "$enableval" in
 476   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 477   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 478   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 479   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 480 esac
 481 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 482                    [Define if CBE is enabled for printf %a output])
 483
 484 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 485 AC_ARG_WITH(llvmgccdir,
 486   AS_HELP_STRING([--with-llvmgccdir],
 487     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 488     withval=default)
 489 case "$withval" in
 490   default) WITH_LLVMGCCDIR=default ;;
 491   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 492   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 493 esac
 494
 495 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 496 AC_ARG_WITH(llvmgcc,
 497   AS_HELP_STRING([--with-llvmgcc],
 498     [Specify location of llvm-gcc driver (default searches PATH)]),
 499     LLVMGCC=$with_llvmgcc
 500       WITH_LLVMGCCDIR="",)
 501
 502 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 503 AC_ARG_WITH(llvmgxx,
 504   AS_HELP_STRING([--with-llvmgxx],
 505     [Specify location of llvm-g++ driver (default searches PATH)]),
 506     LLVMGXX=$with_llvmgxx
 507     WITH_LLVMGCCDIR="",)
 508
 509 if test -n "$LLVMGCC"; then
 510    LLVMGCCCOMMAND="$LLVMGCC"
 511 fi
 512
 513 if test -n "$LLVMGXX"; then
 514    LLVMGXXCOMMAND="$LLVMGXX"
 515 fi
 516
 517 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 518    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 519 fi
 520
 521 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 522    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 523 fi
 524
 525 dnl Specify extra build options
 526 AC_ARG_WITH(extra-options,
 527   AS_HELP_STRING([--with-extra-options],
 528                  [Specify additional options to compile LLVM with]),,
 529                  withval=default)
 530 case "$withval" in
 531   default) EXTRA_OPTIONS= ;;
 532   *) EXTRA_OPTIONS=$withval ;;
 533 esac
 534 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 535
 536 dnl Allow specific bindings to be specified for building (or not)
 537 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 538     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 539     enableval=default)
 540 BINDINGS_TO_BUILD=""
 541 case "$enableval" in
 542   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 543   all ) BINDINGS_TO_BUILD="ocaml" ;;
 544   none | no) BINDINGS_TO_BUILD="" ;;
 545   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 546       case "$a_binding" in
 547         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 548         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 549       esac
 550   done
 551   ;;
 552 esac
 553
 554 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 555 dnl script for bindings/ocaml/configure, except that its auto value depends on
 556 dnl OCAMLC, which is found here to support tests.
 557 AC_ARG_WITH([ocaml-libdir],
 558   [AS_HELP_STRING([--with-ocaml-libdir],
 559     [Specify install location for ocaml bindings (default is stdlib)])],
 560   [],
 561   [withval=auto])
 562 case "$withval" in
 563   auto) with_ocaml_libdir="$withval" ;;
 564   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 565   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 566 esac
 567
 568 dnl Allow linking of LLVM with GPLv3 binutils code.
 569 AC_ARG_WITH(binutils-include,
 570   AS_HELP_STRING([--with-binutils-include],
 571     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 572   withval=default)
 573 case "$withval" in
 574   default) WITH_BINUTILS_INCDIR=default ;;
 575   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 576   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 577 esac
 578 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 579   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 580   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 581      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 582      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 583   fi
 584 fi
 585
 586 dnl --enable-libffi : check whether the user wants to turn off libffi:
 587 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 588   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 589   enableval=yes)
 590 case "$enableval" in
 591   yes) llvm_cv_enable_libffi="yes" ;;
 592   no)  llvm_cv_enable_libffi="no"  ;;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl===-----------------------------------------------------------------------===
 597 dnl===
 598 dnl=== SECTION 4: Check for programs we need and that they are the right version
 599 dnl===
 600 dnl===-----------------------------------------------------------------------===
 601
 602 dnl Check for compilation tools
 603 AC_PROG_CPP
 604 AC_PROG_CC(gcc)
 605 AC_PROG_CXX(g++)
 606
 607 AC_PROG_NM
 608 AC_SUBST(NM)
 609
 610 dnl Check for the tools that the makefiles require
 611 AC_CHECK_GNU_MAKE
 612 AC_PROG_LN_S
 613 AC_PATH_PROG(CMP, [cmp], [cmp])
 614 AC_PATH_PROG(CP, [cp], [cp])
 615 AC_PATH_PROG(DATE, [date], [date])
 616 AC_PATH_PROG(FIND, [find], [find])
 617 AC_PATH_PROG(GREP, [grep], [grep])
 618 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 619 AC_PATH_PROG(MV,   [mv],   [mv])
 620 AC_PROG_RANLIB
 621 AC_PATH_PROG(RM,   [rm],   [rm])
 622 AC_PATH_PROG(SED,  [sed],  [sed])
 623 AC_PATH_PROG(TAR,  [tar],  [gtar])
 624 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 625
 626 dnl Looking for misc. graph plotting software
 627 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 628 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 629   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 630   dnl If we're targeting for mingw we should emit windows paths, not msys
 631   if test "$llvm_cv_os_type" = "MingW" ; then
 632     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 633   fi
 634   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 635    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 636 fi
 637 AC_PATH_PROG(DOT, [dot], [echo dot])
 638 if test "$DOT" != "echo dot" ; then
 639   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 640   dnl If we're targeting for mingw we should emit windows paths, not msys
 641   if test "$llvm_cv_os_type" = "MingW" ; then
 642     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 643   fi
 644   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 645    [Define to path to dot program if found or 'echo dot' otherwise])
 646 fi
 647 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 648 if test "$GV" != "echo gv" ; then
 649   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 650   dnl If we're targeting for mingw we should emit windows paths, not msys
 651   if test "$llvm_cv_os_type" = "MingW" ; then
 652     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 653   fi
 654   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 655    [Define to path to gv program if found or 'echo gv' otherwise])
 656 fi
 657 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 658 if test "$DOTTY" != "echo dotty" ; then
 659   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 660   dnl If we're targeting for mingw we should emit windows paths, not msys
 661   if test "$llvm_cv_os_type" = "MingW" ; then
 662     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 663   fi
 664   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 665    [Define to path to dotty program if found or 'echo dotty' otherwise])
 666 fi
 667
 668 dnl Look for a sufficiently recent version of Perl.
 669 LLVM_PROG_PERL([5.006])
 670 AC_SUBST(PERL)
 671 if test x"$PERL" = xnone; then
 672    AC_SUBST(HAVE_PERL,0)
 673    AC_MSG_ERROR([perl is required but was not found, please install it])
 674 else
 675    AC_SUBST(HAVE_PERL,1)
 676 fi
 677
 678 dnl Find the install program
 679 AC_PROG_INSTALL
 680
 681 dnl Checks for documentation and testing tools that we can do without. If these
 682 dnl are not found then they are set to "true" which always succeeds but does
 683 dnl nothing. This just lets the build output show that we could have done
 684 dnl something if the tool was available.
 685 AC_PATH_PROG(BZIP2, [bzip2])
 686 AC_PATH_PROG(DOXYGEN, [doxygen])
 687 AC_PATH_PROG(GROFF, [groff])
 688 AC_PATH_PROG(GZIP, [gzip])
 689 AC_PATH_PROG(POD2HTML, [pod2html])
 690 AC_PATH_PROG(POD2MAN, [pod2man])
 691 AC_PATH_PROG(RUNTEST, [runtest])
 692 DJ_AC_PATH_TCLSH
 693 AC_PATH_PROG(ZIP, [zip])
 694 AC_PATH_PROGS(OCAMLC, [ocamlc])
 695 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 696 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 697 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 698 AC_PATH_PROGS(GAS, [gas as])
 699
 700 dnl Determine whether the linker supports the -R option.
 701 AC_LINK_USE_R
 702
 703 dnl Determine whether the linker supports the -export-dynamic option.
 704 AC_LINK_EXPORT_DYNAMIC
 705
 706 dnl Check for libtool and the library that has dlopen function (which must come
 707 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 708 dnl libtool).
 709 AC_LIBTOOL_DLOPEN
 710 AC_LIB_LTDL
 711 AC_PROG_LIBTOOL
 712
 713 if test "$lt_cv_dlopen_self" = "yes" ; then
 714   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 715               [Define if dlopen(0) will open the symbols of the program])
 716 fi
 717
 718
 719 if test "$WITH_LLVMGCCDIR" = "default" ; then
 720   LLVMGCC="llvm-gcc${EXEEXT}"
 721   LLVMGXX="llvm-g++${EXEEXT}"
 722   LLVMGCCCOMMAND="$LLVMGCC"
 723   LLVMGXXCOMMAND="$LLVMGXX"
 724   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 725   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 726   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 727   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 728 else
 729   if test -z "$LLVMGCC"; then
 730     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 731     LLVMGCCCOMMAND="$LLVMGCC"
 732   fi
 733   if test -z "$LLVMGXX"; then
 734     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 735     LLVMGXXCOMMAND="$LLVMGXX"
 736   fi
 737
 738   AC_SUBST(LLVMGCC,$LLVMGCC)
 739   AC_SUBST(LLVMGXX,$LLVMGXX)
 740   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 741   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 742 fi
 743
 744
 745 AC_MSG_CHECKING([tool compatibility])
 746
 747 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 748 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 749 dnl to support those options.
 750 dnl "icc" emits gcc signatures
 751 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 752 ICC=no
 753 IXX=no
 754 case $CC in
 755   icc*|icpc*)
 756     ICC=yes
 757     IXX=yes
 758     ;;
 759    *)
 760     ;;
 761 esac
 762
 763 if test "$GCC" != "yes" && test "$ICC" != "yes"
 764 then
 765   AC_MSG_ERROR([gcc|icc required but not found])
 766 fi
 767
 768 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 769 if test "$GXX" != "yes" && test "$IXX" != "yes"
 770 then
 771   AC_MSG_ERROR([g++|icc required but not found])
 772 fi
 773
 774 dnl Verify that GCC is version 3.0 or higher
 775 if test "$GCC" = "yes"
 776 then
 777   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 778 #error Unsupported GCC version
 779 #endif
 780 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 781 fi
 782
 783 dnl Check for GNU Make.  We use its extensions, so don't build without it
 784 if test -z "$llvm_cv_gnu_make_command"
 785 then
 786   AC_MSG_ERROR([GNU Make required but not found])
 787 fi
 788
 789 dnl Tool compatibility is okay if we make it here.
 790 AC_MSG_RESULT([ok])
 791
 792 dnl===-----------------------------------------------------------------------===
 793 dnl===
 794 dnl=== SECTION 5: Check for libraries
 795 dnl===
 796 dnl===-----------------------------------------------------------------------===
 797
 798 dnl libelf is for sparc only; we can ignore it if we don't have it
 799 AC_CHECK_LIB(elf, elf_begin)
 800 AC_CHECK_LIB(m,sin)
 801 if test "$llvm_cv_os_type" = "MingW" ; then
 802   AC_CHECK_LIB(imagehlp, main)
 803   AC_CHECK_LIB(psapi, main)
 804 fi
 805
 806 dnl dlopen() is required for plugin support.
 807 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 808                [Define if dlopen() is available on this platform.]),
 809                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 810
 811 dnl libffi is optional; used to call external functions from the interpreter
 812 if test "$llvm_cv_enable_libffi" = "yes" ; then
 813   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 814                  [Define if libffi is available on this platform.]),
 815                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 816 fi
 817
 818 dnl mallinfo is optional; the code can compile (minus features) without it
 819 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 820                [Define if mallinfo() is available on this platform.]))
 821
 822 dnl pthread locking functions are optional - but llvm will not be thread-safe
 823 dnl without locks.
 824 if test "$ENABLE_THREADS" -eq 1 ; then
 825   AC_CHECK_LIB(pthread,pthread_mutex_init)
 826   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 827                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 828                            [Have pthread_mutex_lock]))
 829   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 830                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 831                  [Have pthread_rwlock_init]))
 832   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 833                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 834                  [Have pthread_getspecific]))
 835 fi
 836
 837 dnl Allow extra x86-disassembler library
 838 AC_ARG_WITH(udis86,
 839   AS_HELP_STRING([--with-udis86=<path>],
 840     [Use udis86 external x86 disassembler library]),
 841     [
 842       AC_SUBST(USE_UDIS86, [1])
 843       case "$withval" in
 844         /usr/lib|yes) ;;
 845         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 846       esac
 847       AC_CHECK_LIB(udis86, ud_init, [], [
 848         echo "Error! You need to have libudis86 around."
 849         exit -1
 850       ])
 851     ],
 852     AC_SUBST(USE_UDIS86, [0]))
 853 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 854                    [Define if use udis86 library])
 855
 856 dnl===-----------------------------------------------------------------------===
 857 dnl===
 858 dnl=== SECTION 6: Check for header files
 859 dnl===
 860 dnl===-----------------------------------------------------------------------===
 861
 862 dnl First, use autoconf provided macros for specific headers that we need
 863 dnl We don't check for ancient stuff or things that are guaranteed to be there
 864 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 865 dnl Generally we're looking for POSIX headers.
 866 AC_HEADER_DIRENT
 867 AC_HEADER_MMAP_ANONYMOUS
 868 AC_HEADER_STAT
 869 AC_HEADER_STDC
 870 AC_HEADER_SYS_WAIT
 871 AC_HEADER_TIME
 872
 873 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 874 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 875 AC_CHECK_HEADERS([utime.h windows.h])
 876 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 877 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 878 if test "$ENABLE_THREADS" -eq 1 ; then
 879   AC_CHECK_HEADERS(pthread.h,
 880                    AC_SUBST(HAVE_PTHREAD, 1),
 881                    AC_SUBST(HAVE_PTHREAD, 0))
 882 else
 883   AC_SUBST(HAVE_PTHREAD, 0)
 884 fi
 885
 886 dnl Try to find ffi.h.
 887 if test "$llvm_cv_enable_libffi" = "yes" ; then
 888   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 889 fi
 890
 891 dnl===-----------------------------------------------------------------------===
 892 dnl===
 893 dnl=== SECTION 7: Check for types and structures
 894 dnl===
 895 dnl===-----------------------------------------------------------------------===
 896
 897 AC_HUGE_VAL_CHECK
 898 AC_TYPE_PID_T
 899 AC_TYPE_SIZE_T
 900 AC_TYPE_SIGNAL
 901 AC_STRUCT_TM
 902 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 903 AC_CHECK_TYPES([uint64_t],,
 904          AC_CHECK_TYPES([u_int64_t],,
 905          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 906
 907 dnl===-----------------------------------------------------------------------===
 908 dnl===
 909 dnl=== SECTION 8: Check for specific functions needed
 910 dnl===
 911 dnl===-----------------------------------------------------------------------===
 912
 913 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 914 AC_CHECK_FUNCS([powf fmodf strtof round ])
 915 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 916 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 917 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
 918 AC_CHECK_FUNCS([strerror strerror_r strerror_s ])
 919 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 920 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 921 AC_C_PRINTF_A
 922 AC_FUNC_ALLOCA
 923 AC_FUNC_RAND48
 924
 925 dnl Check for variations in the Standard C++ library and STL. These macros are
 926 dnl provided by LLVM in the autoconf/m4 directory.
 927 AC_CXX_HAVE_STD_ITERATOR
 928 AC_CXX_HAVE_BI_ITERATOR
 929 AC_CXX_HAVE_FWD_ITERATOR
 930 AC_FUNC_ISNAN
 931 AC_FUNC_ISINF
 932
 933 dnl Check for mmap support.We also need to know if /dev/zero is required to
 934 dnl be opened for allocating RWX memory.
 935 dnl Make sure we aren't attempting to configure for an unknown system
 936 if test "$llvm_cv_platform_type" = "Unix" ; then
 937   AC_FUNC_MMAP
 938   AC_FUNC_MMAP_FILE
 939   AC_NEED_DEV_ZERO_FOR_MMAP
 940
 941   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 942   then
 943     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 944   fi
 945   if test "$ac_cv_func_mmap_file" = "no"
 946   then
 947     AC_MSG_WARN([mmap() of files required but not found])
 948   fi
 949 fi
 950
 951 dnl atomic builtins are required for threading support.
 952 AC_MSG_CHECKING(for GCC atomic builtins)
 953 AC_LINK_IFELSE(
 954   AC_LANG_SOURCE(
 955     [[int main() {
 956         volatile unsigned long val = 1;
 957         __sync_synchronize();
 958         __sync_val_compare_and_swap(&val, 1, 0);
 959         __sync_add_and_fetch(&val, 1);
 960         __sync_sub_and_fetch(&val, 1);
 961         return 0;
 962       }
 963     ]]),
 964   AC_MSG_RESULT(yes)
 965   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
 966   AC_MSG_RESULT(no)
 967   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
 968   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
 969
 970
 971 dnl===-----------------------------------------------------------------------===
 972 dnl===
 973 dnl=== SECTION 9: Additional checks, variables, etc.
 974 dnl===
 975 dnl===-----------------------------------------------------------------------===
 976
 977 dnl Check, whether __dso_handle is present
 978 AC_CHECK_FUNCS([__dso_handle])
 979
 980 dnl See if the llvm-gcc executable can compile to LLVM assembly
 981 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 982 [llvm_cv_llvmgcc_sanity="no"
 983 if test -x "$LLVMGCC" ; then
 984   cp /dev/null conftest.c
 985   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 986       grep 'target datalayout =' > /dev/null 2>&1
 987   if test $? -eq 0 ; then
 988     llvm_cv_llvmgcc_sanity="yes"
 989   fi
 990   rm conftest.c
 991 fi])
 992
 993 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 994 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 995   AC_MSG_CHECKING([llvm-gcc component support])
 996   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 997   AC_SUBST(LLVMCC1,$llvmcc1path)
 998   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 999   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1000   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1001   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1002   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1003   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1004   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1005   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1006   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1007   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1008   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1009   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1010   AC_MSG_RESULT([ok])
1011 fi
1012
1013 dnl Propagate the shared library extension that the libltdl checks did to
1014 dnl the Makefiles so we can use it there too
1015 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1016
1017 # Translate the various configuration directories and other basic
1018 # information into substitutions that will end up in Makefile.config.in
1019 # that these configured values can be used by the makefiles
1020 if test "${prefix}" = "NONE" ; then
1021   prefix="/usr/local"
1022 fi
1023 eval LLVM_PREFIX="${prefix}";
1024 eval LLVM_BINDIR="${prefix}/bin";
1025 eval LLVM_LIBDIR="${prefix}/lib";
1026 eval LLVM_DATADIR="${prefix}/share/llvm";
1027 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1028 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1029 eval LLVM_INCLUDEDIR="${prefix}/include";
1030 eval LLVM_INFODIR="${prefix}/info";
1031 eval LLVM_MANDIR="${prefix}/man";
1032 LLVM_CONFIGTIME=`date`
1033 AC_SUBST(LLVM_PREFIX)
1034 AC_SUBST(LLVM_BINDIR)
1035 AC_SUBST(LLVM_LIBDIR)
1036 AC_SUBST(LLVM_DATADIR)
1037 AC_SUBST(LLVM_DOCSDIR)
1038 AC_SUBST(LLVM_ETCDIR)
1039 AC_SUBST(LLVM_INCLUDEDIR)
1040 AC_SUBST(LLVM_INFODIR)
1041 AC_SUBST(LLVM_MANDIR)
1042 AC_SUBST(LLVM_CONFIGTIME)
1043
1044 # Place the various directores into the config.h file as #defines so that we
1045 # can know about the installation paths within LLVM.
1046 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1047                    [Installation prefix directory])
1048 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1049                    [Installation directory for binary executables])
1050 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1051                    [Installation directory for libraries])
1052 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1053                    [Installation directory for data files])
1054 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1055                    [Installation directory for documentation])
1056 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1057                    [Installation directory for config files])
1058 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1059                    [Installation directory for include files])
1060 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1061                    [Installation directory for .info files])
1062 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1063                    [Installation directory for man pages])
1064 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1065                    [Time at which LLVM was configured])
1066 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1067                    [Host triple we were built on])
1068
1069 # Determine which bindings to build.
1070 if test "$BINDINGS_TO_BUILD" = auto ; then
1071   BINDINGS_TO_BUILD=""
1072   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1073     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1074   fi
1075 fi
1076 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1077
1078 # This isn't really configurey, but it avoids having to repeat the list in
1079 # other files.
1080 AC_SUBST(ALL_BINDINGS,ocaml)
1081
1082 # Do any work necessary to ensure that bindings have what they need.
1083 binding_prereqs_failed=0
1084 for a_binding in $BINDINGS_TO_BUILD ; do
1085   case "$a_binding" in
1086   ocaml)
1087     if test "x$OCAMLC" = x ; then
1088       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1089       binding_prereqs_failed=1
1090     fi
1091     if test "x$OCAMLDEP" = x ; then
1092       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1093       binding_prereqs_failed=1
1094     fi
1095     if test "x$OCAMLOPT" = x ; then
1096       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1097       dnl ocamlopt is optional!
1098     fi
1099     if test "x$with_ocaml_libdir" != xauto ; then
1100       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1101     else
1102       ocaml_stdlib="`"$OCAMLC" -where`"
1103       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1104       then
1105         # ocaml stdlib is beneath our prefix; use stdlib
1106         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1107       else
1108         # ocaml stdlib is outside our prefix; use libdir/ocaml
1109         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1110       fi
1111     fi
1112     ;;
1113   esac
1114 done
1115 if test "$binding_prereqs_failed" = 1 ; then
1116   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1117 fi
1118
1119 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1120 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1121
1122 dnl Determine linker rpath flag
1123 if test "$llvm_cv_link_use_r" = "yes" ; then
1124   RPATH="-Wl,-R"
1125 else
1126   RPATH="-Wl,-rpath"
1127 fi
1128 AC_SUBST(RPATH)
1129
1130 dnl Determine linker rdynamic flag
1131 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1132   RDYNAMIC="-Wl,-export-dynamic"
1133 else
1134   RDYNAMIC=""
1135 fi
1136 AC_SUBST(RDYNAMIC)
1137
1138 dnl===-----------------------------------------------------------------------===
1139 dnl===
1140 dnl=== SECTION 10: Specify the output files and generate it
1141 dnl===
1142 dnl===-----------------------------------------------------------------------===
1143
1144 dnl Configure header files
1145 dnl WARNING: dnl If you add or remove any of the following config headers, then
1146 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1147 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1148 dnl files can be updated automatically when their *.in sources change.
1149 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1150 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1151 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1152 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1153 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1154
1155 dnl Configure the makefile's configuration data
1156 AC_CONFIG_FILES([Makefile.config])
1157
1158 dnl Configure the RPM spec file for LLVM
1159 AC_CONFIG_FILES([llvm.spec])
1160
1161 dnl Configure doxygen's configuration file
1162 AC_CONFIG_FILES([docs/doxygen.cfg])
1163
1164 dnl Configure llvmc's Base plugin
1165 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1166
1167 dnl Do the first stage of configuration for llvm-config.in.
1168 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1169
1170 dnl Do special configuration of Makefiles
1171 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1172 AC_CONFIG_MAKEFILE(Makefile)
1173 AC_CONFIG_MAKEFILE(Makefile.common)
1174 AC_CONFIG_MAKEFILE(examples/Makefile)
1175 AC_CONFIG_MAKEFILE(lib/Makefile)
1176 AC_CONFIG_MAKEFILE(runtime/Makefile)
1177 AC_CONFIG_MAKEFILE(test/Makefile)
1178 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1179 AC_CONFIG_MAKEFILE(unittests/Makefile)
1180 AC_CONFIG_MAKEFILE(tools/Makefile)
1181 AC_CONFIG_MAKEFILE(utils/Makefile)
1182 AC_CONFIG_MAKEFILE(projects/Makefile)
1183 AC_CONFIG_MAKEFILE(bindings/Makefile)
1184 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1185
1186 dnl Finally, crank out the output
1187 AC_OUTPUT