autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 # Determine the LLVM native architecture for the target
 238 case "$llvm_cv_target_arch" in
 239     x86)     LLVM_NATIVE_ARCH="X86" ;;
 240     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 241     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 242 esac
 243
 244 dnl Define a substitution, ARCH, for the target architecture
 245 AC_SUBST(ARCH,$llvm_cv_target_arch)
 246
 247 dnl Check for the endianness of the target
 248 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 249
 250 dnl Check for build platform executable suffix if we're crosscompiling
 251 if test "$cross_compiling" = yes; then
 252   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 253   AC_BUILD_EXEEXT
 254   ac_build_prefix=${build_alias}-
 255   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 256   if test -z "$BUILD_CXX"; then
 257      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 258      if test -z "$BUILD_CXX"; then
 259        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 260      fi
 261   fi
 262 else
 263   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 264 fi
 265
 266 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 267 dnl that this build is being done from a checkout. This sets up several
 268 dnl defaults for the command line switches. When we build with a CVS directory,
 269 dnl we get a debug with assertions turned on. Without, we assume a source
 270 dnl release and we get an optimized build without assertions.
 271 dnl See --enable-optimized and --enable-assertions below
 272 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 273   cvsbuild="yes"
 274   optimize="no"
 275   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 276 else
 277   cvsbuild="no"
 278   optimize="yes"
 279 fi
 280
 281 dnl===-----------------------------------------------------------------------===
 282 dnl===
 283 dnl=== SECTION 3: Command line arguments for the configure script.
 284 dnl===
 285 dnl===-----------------------------------------------------------------------===
 286
 287 dnl --enable-optimized : check whether they want to do an optimized build:
 288 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 289  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 290 if test ${enableval} = "no" ; then
 291   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 292 else
 293   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 294 fi
 295
 296 dnl --enable-profiling : check whether they want to do a profile build:
 297 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 298  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 299 if test ${enableval} = "no" ; then
 300   AC_SUBST(ENABLE_PROFILING,[[]])
 301 else
 302   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 303 fi
 304
 305 dnl --enable-assertions : check whether they want to turn on assertions or not:
 306 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 307   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 308 if test ${enableval} = "yes" ; then
 309   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 310 else
 311   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 312 fi
 313
 314 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 315 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 316   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 317 if test ${enableval} = "yes" ; then
 318   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 319   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 320 else
 321   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 322   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 323 fi
 324
 325 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 326 AC_ARG_ENABLE(debug-runtime,
 327    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 328 if test ${enableval} = "no" ; then
 329   AC_SUBST(DEBUG_RUNTIME,[[]])
 330 else
 331   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 332 fi
 333
 334 dnl --enable-jit: check whether they want to enable the jit
 335 AC_ARG_ENABLE(jit,
 336   AS_HELP_STRING(--enable-jit,
 337                  [Enable Just In Time Compiling (default is YES)]),,
 338   enableval=default)
 339 if test ${enableval} = "no"
 340 then
 341   AC_SUBST(JIT,[[]])
 342 else
 343   case "$llvm_cv_target_arch" in
 344     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 345     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 347     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 348     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 349     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 350     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 351     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 352     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 353     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 354     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 355     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 356   esac
 357 fi
 358
 359 dnl Allow enablement of doxygen generated documentation
 360 AC_ARG_ENABLE(doxygen,
 361               AS_HELP_STRING([--enable-doxygen],
 362                              [Build doxygen documentation (default is NO)]),,
 363                              enableval=default)
 364 case "$enableval" in
 365   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 366   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 367   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 368   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 369 esac
 370
 371 dnl Allow disablement of threads
 372 AC_ARG_ENABLE(threads,
 373               AS_HELP_STRING([--enable-threads],
 374                              [Use threads if available (default is YES)]),,
 375                              enableval=default)
 376 case "$enableval" in
 377   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 378   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 379   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 380   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 381 esac
 382 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 383
 384 dnl Allow building without position independent code
 385 AC_ARG_ENABLE(pic,
 386   AS_HELP_STRING([--enable-pic],
 387                  [Build LLVM with Position Independent Code (default is YES)]),,
 388                  enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 391   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 392   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 394 esac
 395 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 396                    [Define if position independent code is enabled])
 397
 398 dnl Allow specific targets to be specified for building (or not)
 399 TARGETS_TO_BUILD=""
 400 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 401     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 402     enableval=all)
 403 case "$enableval" in
 404   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 405   host-only)
 406     case "$llvm_cv_target_arch" in
 407       x86)     TARGETS_TO_BUILD="X86" ;;
 408       x86_64)  TARGETS_TO_BUILD="X86" ;;
 409       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 410       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 411       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 412       IA64)    TARGETS_TO_BUILD="IA64" ;;
 413       ARM)     TARGETS_TO_BUILD="ARM" ;;
 414       Mips)    TARGETS_TO_BUILD="Mips" ;;
 415       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 416       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 417       XCore)   TARGETS_TO_BUILD="XCore" ;;
 418       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 419       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 420     esac
 421     ;;
 422   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 423       case "$a_target" in
 424         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 425         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 426         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 427         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 428         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 429         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 430         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 431         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 432         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 433         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 434         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 435         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 436         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 437         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 438         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 439         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 440       esac
 441   done
 442   ;;
 443 esac
 444 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 445
 446 # Determine whether we are building LLVM support for the native architecture.
 447 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 448 for a_target in $TARGETS_TO_BUILD; do
 449   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 450     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 451     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 452       [LLVM architecture name for the native architecture, if available])
 453   fi
 454 done
 455
 456 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 457 # Targets.def and AsmPrinters.def.
 458 LLVM_ENUM_TARGETS=""
 459 LLVM_ENUM_ASM_PRINTERS=""
 460 for target_to_build in $TARGETS_TO_BUILD; do
 461   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 462   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 463     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 464   fi
 465 done
 466 AC_SUBST(LLVM_ENUM_TARGETS)
 467 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 468
 469 dnl Prevent the CBackend from using printf("%a") for floating point so older
 470 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 471 dnl can still compile the CBE's output
 472 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 473   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 474   enableval=default)
 475 case "$enableval" in
 476   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 477   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 478   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 479   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 480 esac
 481 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 482                    [Define if CBE is enabled for printf %a output])
 483
 484 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 485 AC_ARG_WITH(llvmgccdir,
 486   AS_HELP_STRING([--with-llvmgccdir],
 487     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 488     withval=default)
 489 case "$withval" in
 490   default) WITH_LLVMGCCDIR=default ;;
 491   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 492   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 493 esac
 494
 495 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 496 AC_ARG_WITH(llvmgcc,
 497   AS_HELP_STRING([--with-llvmgcc],
 498     [Specify location of llvm-gcc driver (default searches PATH)]),
 499     LLVMGCC=$with_llvmgcc
 500       WITH_LLVMGCCDIR="",)
 501
 502 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 503 AC_ARG_WITH(llvmgxx,
 504   AS_HELP_STRING([--with-llvmgxx],
 505     [Specify location of llvm-g++ driver (default searches PATH)]),
 506     LLVMGXX=$with_llvmgxx
 507     WITH_LLVMGCCDIR="",)
 508
 509 if test -n "$LLVMGCC"; then
 510    LLVMGCCCOMMAND="$LLVMGCC"
 511 fi
 512
 513 if test -n "$LLVMGXX"; then
 514    LLVMGXXCOMMAND="$LLVMGXX"
 515 fi
 516
 517 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 518    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 519 fi
 520
 521 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 522    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 523 fi
 524
 525 dnl Specify extra build options
 526 AC_ARG_WITH(extra-options,
 527   AS_HELP_STRING([--with-extra-options],
 528                  [Specify additional options to compile LLVM with]),,
 529                  withval=default)
 530 case "$withval" in
 531   default) EXTRA_OPTIONS= ;;
 532   *) EXTRA_OPTIONS=$withval ;;
 533 esac
 534 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 535
 536 dnl Allow specific bindings to be specified for building (or not)
 537 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 538     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 539     enableval=default)
 540 BINDINGS_TO_BUILD=""
 541 case "$enableval" in
 542   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 543   all ) BINDINGS_TO_BUILD="ocaml" ;;
 544   none | no) BINDINGS_TO_BUILD="" ;;
 545   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 546       case "$a_binding" in
 547         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 548         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 549       esac
 550   done
 551   ;;
 552 esac
 553
 554 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 555 dnl script for bindings/ocaml/configure, except that its auto value depends on
 556 dnl OCAMLC, which is found here to support tests.
 557 AC_ARG_WITH([ocaml-libdir],
 558   [AS_HELP_STRING([--with-ocaml-libdir],
 559     [Specify install location for ocaml bindings (default is stdlib)])],
 560   [],
 561   [withval=auto])
 562 case "$withval" in
 563   auto) with_ocaml_libdir="$withval" ;;
 564   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 565   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 566 esac
 567
 568 dnl Allow linking of LLVM with GPLv3 binutils code.
 569 AC_ARG_WITH(binutils-include,
 570   AS_HELP_STRING([--with-binutils-include],
 571     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 572   withval=default)
 573 case "$withval" in
 574   default) WITH_BINUTILS_INCDIR=default ;;
 575   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 576   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 577 esac
 578 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 579   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 580   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 581      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 582      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 583   fi
 584 fi
 585
 586 dnl --enable-libffi : check whether the user wants to turn off libffi:
 587 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 588   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 589   enableval=yes)
 590 case "$enableval" in
 591   yes) llvm_cv_enable_libffi="yes" ;;
 592   no)  llvm_cv_enable_libffi="no"  ;;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 597 if test "$llvm_cv_os_type" = "Win32" ; then
 598    llvmc_dynamic="yes"
 599 else
 600    llvmc_dynamic="no"
 601 fi
 602
 603 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 604 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 605 --enable-llvmc-dynamic,
 606 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 607 enableval=$llvmc_dynamic)
 608 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1; then
 609    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 610 else
 611    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 612 fi
 613
 614 dnl===-----------------------------------------------------------------------===
 615 dnl===
 616 dnl=== SECTION 4: Check for programs we need and that they are the right version
 617 dnl===
 618 dnl===-----------------------------------------------------------------------===
 619
 620 dnl Check for compilation tools
 621 AC_PROG_CPP
 622 AC_PROG_CC(gcc)
 623 AC_PROG_CXX(g++)
 624
 625 AC_PROG_NM
 626 AC_SUBST(NM)
 627
 628 dnl Check for the tools that the makefiles require
 629 AC_CHECK_GNU_MAKE
 630 AC_PROG_LN_S
 631 AC_PATH_PROG(CMP, [cmp], [cmp])
 632 AC_PATH_PROG(CP, [cp], [cp])
 633 AC_PATH_PROG(DATE, [date], [date])
 634 AC_PATH_PROG(FIND, [find], [find])
 635 AC_PATH_PROG(GREP, [grep], [grep])
 636 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 637 AC_PATH_PROG(MV,   [mv],   [mv])
 638 AC_PROG_RANLIB
 639 AC_PATH_PROG(RM,   [rm],   [rm])
 640 AC_PATH_PROG(SED,  [sed],  [sed])
 641 AC_PATH_PROG(TAR,  [tar],  [gtar])
 642 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 643
 644 dnl Looking for misc. graph plotting software
 645 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 646 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 647   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 648   dnl If we're targeting for mingw we should emit windows paths, not msys
 649   if test "$llvm_cv_os_type" = "MingW" ; then
 650     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 651   fi
 652   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 653    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 654 fi
 655 AC_PATH_PROG(DOT, [dot], [echo dot])
 656 if test "$DOT" != "echo dot" ; then
 657   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 658   dnl If we're targeting for mingw we should emit windows paths, not msys
 659   if test "$llvm_cv_os_type" = "MingW" ; then
 660     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 661   fi
 662   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 663    [Define to path to dot program if found or 'echo dot' otherwise])
 664 fi
 665 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 666 if test "$GV" != "echo gv" ; then
 667   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 668   dnl If we're targeting for mingw we should emit windows paths, not msys
 669   if test "$llvm_cv_os_type" = "MingW" ; then
 670     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 671   fi
 672   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 673    [Define to path to gv program if found or 'echo gv' otherwise])
 674 fi
 675 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 676 if test "$DOTTY" != "echo dotty" ; then
 677   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 678   dnl If we're targeting for mingw we should emit windows paths, not msys
 679   if test "$llvm_cv_os_type" = "MingW" ; then
 680     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 681   fi
 682   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 683    [Define to path to dotty program if found or 'echo dotty' otherwise])
 684 fi
 685
 686 dnl Look for a sufficiently recent version of Perl.
 687 LLVM_PROG_PERL([5.006])
 688 AC_SUBST(PERL)
 689 if test x"$PERL" = xnone; then
 690    AC_SUBST(HAVE_PERL,0)
 691    AC_MSG_ERROR([perl is required but was not found, please install it])
 692 else
 693    AC_SUBST(HAVE_PERL,1)
 694 fi
 695
 696 dnl Find the install program
 697 AC_PROG_INSTALL
 698
 699 dnl Checks for documentation and testing tools that we can do without. If these
 700 dnl are not found then they are set to "true" which always succeeds but does
 701 dnl nothing. This just lets the build output show that we could have done
 702 dnl something if the tool was available.
 703 AC_PATH_PROG(BZIP2, [bzip2])
 704 AC_PATH_PROG(DOXYGEN, [doxygen])
 705 AC_PATH_PROG(GROFF, [groff])
 706 AC_PATH_PROG(GZIP, [gzip])
 707 AC_PATH_PROG(POD2HTML, [pod2html])
 708 AC_PATH_PROG(POD2MAN, [pod2man])
 709 AC_PATH_PROG(RUNTEST, [runtest])
 710 DJ_AC_PATH_TCLSH
 711 AC_PATH_PROG(ZIP, [zip])
 712 AC_PATH_PROGS(OCAMLC, [ocamlc])
 713 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 714 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 715 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 716 AC_PATH_PROGS(GAS, [gas as])
 717
 718 dnl Determine whether the linker supports the -R option.
 719 AC_LINK_USE_R
 720
 721 dnl Determine whether the linker supports the -export-dynamic option.
 722 AC_LINK_EXPORT_DYNAMIC
 723
 724 dnl Check for libtool and the library that has dlopen function (which must come
 725 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 726 dnl libtool).
 727 AC_LIBTOOL_DLOPEN
 728 AC_LIB_LTDL
 729 AC_PROG_LIBTOOL
 730
 731 if test "$lt_cv_dlopen_self" = "yes" ; then
 732   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 733               [Define if dlopen(0) will open the symbols of the program])
 734 fi
 735
 736
 737 if test "$WITH_LLVMGCCDIR" = "default" ; then
 738   LLVMGCC="llvm-gcc${EXEEXT}"
 739   LLVMGXX="llvm-g++${EXEEXT}"
 740   LLVMGCCCOMMAND="$LLVMGCC"
 741   LLVMGXXCOMMAND="$LLVMGXX"
 742   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 743   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 744   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 745   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 746 else
 747   if test -z "$LLVMGCC"; then
 748     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 749     LLVMGCCCOMMAND="$LLVMGCC"
 750   fi
 751   if test -z "$LLVMGXX"; then
 752     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 753     LLVMGXXCOMMAND="$LLVMGXX"
 754   fi
 755
 756   AC_SUBST(LLVMGCC,$LLVMGCC)
 757   AC_SUBST(LLVMGXX,$LLVMGXX)
 758   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 759   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 760 fi
 761
 762
 763 AC_MSG_CHECKING([tool compatibility])
 764
 765 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 766 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 767 dnl to support those options.
 768 dnl "icc" emits gcc signatures
 769 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 770 ICC=no
 771 IXX=no
 772 case $CC in
 773   icc*|icpc*)
 774     ICC=yes
 775     IXX=yes
 776     ;;
 777    *)
 778     ;;
 779 esac
 780
 781 if test "$GCC" != "yes" && test "$ICC" != "yes"
 782 then
 783   AC_MSG_ERROR([gcc|icc required but not found])
 784 fi
 785
 786 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 787 if test "$GXX" != "yes" && test "$IXX" != "yes"
 788 then
 789   AC_MSG_ERROR([g++|icc required but not found])
 790 fi
 791
 792 dnl Verify that GCC is version 3.0 or higher
 793 if test "$GCC" = "yes"
 794 then
 795   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 796 #error Unsupported GCC version
 797 #endif
 798 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 799 fi
 800
 801 dnl Check for GNU Make.  We use its extensions, so don't build without it
 802 if test -z "$llvm_cv_gnu_make_command"
 803 then
 804   AC_MSG_ERROR([GNU Make required but not found])
 805 fi
 806
 807 dnl Tool compatibility is okay if we make it here.
 808 AC_MSG_RESULT([ok])
 809
 810 dnl===-----------------------------------------------------------------------===
 811 dnl===
 812 dnl=== SECTION 5: Check for libraries
 813 dnl===
 814 dnl===-----------------------------------------------------------------------===
 815
 816 dnl libelf is for sparc only; we can ignore it if we don't have it
 817 AC_CHECK_LIB(elf, elf_begin)
 818 AC_CHECK_LIB(m,sin)
 819 if test "$llvm_cv_os_type" = "MingW" ; then
 820   AC_CHECK_LIB(imagehlp, main)
 821   AC_CHECK_LIB(psapi, main)
 822 fi
 823
 824 dnl dlopen() is required for plugin support.
 825 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 826                [Define if dlopen() is available on this platform.]),
 827                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 828
 829 dnl libffi is optional; used to call external functions from the interpreter
 830 if test "$llvm_cv_enable_libffi" = "yes" ; then
 831   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 832                  [Define if libffi is available on this platform.]),
 833                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 834 fi
 835
 836 dnl mallinfo is optional; the code can compile (minus features) without it
 837 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 838                [Define if mallinfo() is available on this platform.]))
 839
 840 dnl pthread locking functions are optional - but llvm will not be thread-safe
 841 dnl without locks.
 842 if test "$ENABLE_THREADS" -eq 1 ; then
 843   AC_CHECK_LIB(pthread,pthread_mutex_init)
 844   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 845                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 846                            [Have pthread_mutex_lock]))
 847   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 848                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 849                  [Have pthread_rwlock_init]))
 850   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 851                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 852                  [Have pthread_getspecific]))
 853 fi
 854
 855 dnl Allow extra x86-disassembler library
 856 AC_ARG_WITH(udis86,
 857   AS_HELP_STRING([--with-udis86=<path>],
 858     [Use udis86 external x86 disassembler library]),
 859     [
 860       AC_SUBST(USE_UDIS86, [1])
 861       case "$withval" in
 862         /usr/lib|yes) ;;
 863         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 864       esac
 865       AC_CHECK_LIB(udis86, ud_init, [], [
 866         echo "Error! You need to have libudis86 around."
 867         exit -1
 868       ])
 869     ],
 870     AC_SUBST(USE_UDIS86, [0]))
 871 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 872                    [Define if use udis86 library])
 873
 874 dnl===-----------------------------------------------------------------------===
 875 dnl===
 876 dnl=== SECTION 6: Check for header files
 877 dnl===
 878 dnl===-----------------------------------------------------------------------===
 879
 880 dnl First, use autoconf provided macros for specific headers that we need
 881 dnl We don't check for ancient stuff or things that are guaranteed to be there
 882 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 883 dnl Generally we're looking for POSIX headers.
 884 AC_HEADER_DIRENT
 885 AC_HEADER_MMAP_ANONYMOUS
 886 AC_HEADER_STAT
 887 AC_HEADER_STDC
 888 AC_HEADER_SYS_WAIT
 889 AC_HEADER_TIME
 890
 891 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 892 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 893 AC_CHECK_HEADERS([utime.h windows.h])
 894 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 895 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 896 if test "$ENABLE_THREADS" -eq 1 ; then
 897   AC_CHECK_HEADERS(pthread.h,
 898                    AC_SUBST(HAVE_PTHREAD, 1),
 899                    AC_SUBST(HAVE_PTHREAD, 0))
 900 else
 901   AC_SUBST(HAVE_PTHREAD, 0)
 902 fi
 903
 904 dnl Try to find ffi.h.
 905 if test "$llvm_cv_enable_libffi" = "yes" ; then
 906   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 907 fi
 908
 909 dnl===-----------------------------------------------------------------------===
 910 dnl===
 911 dnl=== SECTION 7: Check for types and structures
 912 dnl===
 913 dnl===-----------------------------------------------------------------------===
 914
 915 AC_HUGE_VAL_CHECK
 916 AC_TYPE_PID_T
 917 AC_TYPE_SIZE_T
 918 AC_TYPE_SIGNAL
 919 AC_STRUCT_TM
 920 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 921 AC_CHECK_TYPES([uint64_t],,
 922          AC_CHECK_TYPES([u_int64_t],,
 923          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 924
 925 dnl===-----------------------------------------------------------------------===
 926 dnl===
 927 dnl=== SECTION 8: Check for specific functions needed
 928 dnl===
 929 dnl===-----------------------------------------------------------------------===
 930
 931 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 932 AC_CHECK_FUNCS([powf fmodf strtof round ])
 933 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 934 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 935 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
 936 AC_CHECK_FUNCS([strerror strerror_r strerror_s ])
 937 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 938 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 939 AC_C_PRINTF_A
 940 AC_FUNC_ALLOCA
 941 AC_FUNC_RAND48
 942
 943 dnl Check for variations in the Standard C++ library and STL. These macros are
 944 dnl provided by LLVM in the autoconf/m4 directory.
 945 AC_CXX_HAVE_STD_ITERATOR
 946 AC_CXX_HAVE_BI_ITERATOR
 947 AC_CXX_HAVE_FWD_ITERATOR
 948 AC_FUNC_ISNAN
 949 AC_FUNC_ISINF
 950
 951 dnl Check for mmap support.We also need to know if /dev/zero is required to
 952 dnl be opened for allocating RWX memory.
 953 dnl Make sure we aren't attempting to configure for an unknown system
 954 if test "$llvm_cv_platform_type" = "Unix" ; then
 955   AC_FUNC_MMAP
 956   AC_FUNC_MMAP_FILE
 957   AC_NEED_DEV_ZERO_FOR_MMAP
 958
 959   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 960   then
 961     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 962   fi
 963   if test "$ac_cv_func_mmap_file" = "no"
 964   then
 965     AC_MSG_WARN([mmap() of files required but not found])
 966   fi
 967 fi
 968
 969 dnl atomic builtins are required for threading support.
 970 AC_MSG_CHECKING(for GCC atomic builtins)
 971 AC_LINK_IFELSE(
 972   AC_LANG_SOURCE(
 973     [[int main() {
 974         volatile unsigned long val = 1;
 975         __sync_synchronize();
 976         __sync_val_compare_and_swap(&val, 1, 0);
 977         __sync_add_and_fetch(&val, 1);
 978         __sync_sub_and_fetch(&val, 1);
 979         return 0;
 980       }
 981     ]]),
 982   AC_MSG_RESULT(yes)
 983   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
 984   AC_MSG_RESULT(no)
 985   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
 986   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
 987
 988
 989 dnl===-----------------------------------------------------------------------===
 990 dnl===
 991 dnl=== SECTION 9: Additional checks, variables, etc.
 992 dnl===
 993 dnl===-----------------------------------------------------------------------===
 994
 995 dnl Check, whether __dso_handle is present
 996 AC_CHECK_FUNCS([__dso_handle])
 997
 998 dnl See if the llvm-gcc executable can compile to LLVM assembly
 999 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1000 [llvm_cv_llvmgcc_sanity="no"
1001 if test -x "$LLVMGCC" ; then
1002   cp /dev/null conftest.c
1003   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1004       grep 'target datalayout =' > /dev/null 2>&1
1005   if test $? -eq 0 ; then
1006     llvm_cv_llvmgcc_sanity="yes"
1007   fi
1008   rm conftest.c
1009 fi])
1010
1011 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1012 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1013   AC_MSG_CHECKING([llvm-gcc component support])
1014   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1015   AC_SUBST(LLVMCC1,$llvmcc1path)
1016   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1017   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1018   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1019   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1020   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1021   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1022   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1023   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1024   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1025   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1026   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1027   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1028   AC_MSG_RESULT([ok])
1029 fi
1030
1031 dnl Propagate the shared library extension that the libltdl checks did to
1032 dnl the Makefiles so we can use it there too
1033 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1034
1035 # Translate the various configuration directories and other basic
1036 # information into substitutions that will end up in Makefile.config.in
1037 # that these configured values can be used by the makefiles
1038 if test "${prefix}" = "NONE" ; then
1039   prefix="/usr/local"
1040 fi
1041 eval LLVM_PREFIX="${prefix}";
1042 eval LLVM_BINDIR="${prefix}/bin";
1043 eval LLVM_LIBDIR="${prefix}/lib";
1044 eval LLVM_DATADIR="${prefix}/share/llvm";
1045 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1046 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1047 eval LLVM_INCLUDEDIR="${prefix}/include";
1048 eval LLVM_INFODIR="${prefix}/info";
1049 eval LLVM_MANDIR="${prefix}/man";
1050 LLVM_CONFIGTIME=`date`
1051 AC_SUBST(LLVM_PREFIX)
1052 AC_SUBST(LLVM_BINDIR)
1053 AC_SUBST(LLVM_LIBDIR)
1054 AC_SUBST(LLVM_DATADIR)
1055 AC_SUBST(LLVM_DOCSDIR)
1056 AC_SUBST(LLVM_ETCDIR)
1057 AC_SUBST(LLVM_INCLUDEDIR)
1058 AC_SUBST(LLVM_INFODIR)
1059 AC_SUBST(LLVM_MANDIR)
1060 AC_SUBST(LLVM_CONFIGTIME)
1061
1062 # Place the various directores into the config.h file as #defines so that we
1063 # can know about the installation paths within LLVM.
1064 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1065                    [Installation prefix directory])
1066 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1067                    [Installation directory for binary executables])
1068 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1069                    [Installation directory for libraries])
1070 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1071                    [Installation directory for data files])
1072 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1073                    [Installation directory for documentation])
1074 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1075                    [Installation directory for config files])
1076 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1077                    [Installation directory for include files])
1078 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1079                    [Installation directory for .info files])
1080 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1081                    [Installation directory for man pages])
1082 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1083                    [Time at which LLVM was configured])
1084 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1085                    [Host triple we were built on])
1086
1087 # Determine which bindings to build.
1088 if test "$BINDINGS_TO_BUILD" = auto ; then
1089   BINDINGS_TO_BUILD=""
1090   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1091     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1092   fi
1093 fi
1094 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1095
1096 # This isn't really configurey, but it avoids having to repeat the list in
1097 # other files.
1098 AC_SUBST(ALL_BINDINGS,ocaml)
1099
1100 # Do any work necessary to ensure that bindings have what they need.
1101 binding_prereqs_failed=0
1102 for a_binding in $BINDINGS_TO_BUILD ; do
1103   case "$a_binding" in
1104   ocaml)
1105     if test "x$OCAMLC" = x ; then
1106       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1107       binding_prereqs_failed=1
1108     fi
1109     if test "x$OCAMLDEP" = x ; then
1110       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1111       binding_prereqs_failed=1
1112     fi
1113     if test "x$OCAMLOPT" = x ; then
1114       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1115       dnl ocamlopt is optional!
1116     fi
1117     if test "x$with_ocaml_libdir" != xauto ; then
1118       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1119     else
1120       ocaml_stdlib="`"$OCAMLC" -where`"
1121       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1122       then
1123         # ocaml stdlib is beneath our prefix; use stdlib
1124         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1125       else
1126         # ocaml stdlib is outside our prefix; use libdir/ocaml
1127         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1128       fi
1129     fi
1130     ;;
1131   esac
1132 done
1133 if test "$binding_prereqs_failed" = 1 ; then
1134   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1135 fi
1136
1137 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1138 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1139
1140 dnl Determine linker rpath flag
1141 if test "$llvm_cv_link_use_r" = "yes" ; then
1142   RPATH="-Wl,-R"
1143 else
1144   RPATH="-Wl,-rpath"
1145 fi
1146 AC_SUBST(RPATH)
1147
1148 dnl Determine linker rdynamic flag
1149 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1150   RDYNAMIC="-Wl,-export-dynamic"
1151 else
1152   RDYNAMIC=""
1153 fi
1154 AC_SUBST(RDYNAMIC)
1155
1156 dnl===-----------------------------------------------------------------------===
1157 dnl===
1158 dnl=== SECTION 10: Specify the output files and generate it
1159 dnl===
1160 dnl===-----------------------------------------------------------------------===
1161
1162 dnl Configure header files
1163 dnl WARNING: dnl If you add or remove any of the following config headers, then
1164 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1165 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1166 dnl files can be updated automatically when their *.in sources change.
1167 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1168 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1169 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1170 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1171 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1172
1173 dnl Configure the makefile's configuration data
1174 AC_CONFIG_FILES([Makefile.config])
1175
1176 dnl Configure the RPM spec file for LLVM
1177 AC_CONFIG_FILES([llvm.spec])
1178
1179 dnl Configure doxygen's configuration file
1180 AC_CONFIG_FILES([docs/doxygen.cfg])
1181
1182 dnl Configure llvmc's Base plugin
1183 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1184
1185 dnl Do the first stage of configuration for llvm-config.in.
1186 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1187
1188 dnl Do special configuration of Makefiles
1189 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1190 AC_CONFIG_MAKEFILE(Makefile)
1191 AC_CONFIG_MAKEFILE(Makefile.common)
1192 AC_CONFIG_MAKEFILE(examples/Makefile)
1193 AC_CONFIG_MAKEFILE(lib/Makefile)
1194 AC_CONFIG_MAKEFILE(runtime/Makefile)
1195 AC_CONFIG_MAKEFILE(test/Makefile)
1196 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1197 AC_CONFIG_MAKEFILE(unittests/Makefile)
1198 AC_CONFIG_MAKEFILE(tools/Makefile)
1199 AC_CONFIG_MAKEFILE(utils/Makefile)
1200 AC_CONFIG_MAKEFILE(projects/Makefile)
1201 AC_CONFIG_MAKEFILE(bindings/Makefile)
1202 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1203
1204 dnl Finally, crank out the output
1205 AC_OUTPUT