autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-interix*)
 116     llvm_cv_os_type="Interix"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-linux*)
 119     llvm_cv_os_type="Linux"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-solaris*)
 122     llvm_cv_os_type="SunOS"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-win32*)
 125     llvm_cv_os_type="Win32"
 126     llvm_cv_platform_type="Win32" ;;
 127   *-*-mingw*)
 128     llvm_cv_os_type="MingW"
 129     llvm_cv_platform_type="Win32" ;;
 130   *)
 131     llvm_cv_os_type="Unknown"
 132     llvm_cv_platform_type="Unknown" ;;
 133 esac])
 134
 135 dnl Make sure we aren't attempting to configure for an unknown system
 136 if test "$llvm_cv_os_type" = "Unknown" ; then
 137   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 138 fi
 139
 140 dnl Set the "OS" Makefile variable based on the platform type so the
 141 dnl makefile can configure itself to specific build hosts
 142 AC_SUBST(OS,$llvm_cv_os_type)
 143
 144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 145 dnl This is used by lib/System to determine the basic kind of implementation
 146 dnl to use.
 147 case $llvm_cv_platform_type in
 148   Unix)
 149     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 150     ;;
 151   Win32)
 152     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 153     ;;
 154 esac
 155
 156 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 157 dnl V9, since that is all that we support at the moment, and autoconf will only
 158 dnl tell us we're a sparc.
 159 case $target in
 160   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 161   ;;
 162 esac
 163
 164 dnl Determine what our target architecture is and configure accordingly.
 165 dnl This will allow Makefiles to make a distinction between the hardware and
 166 dnl the OS.
 167 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 168 [case $target in
 169   i?86-*)                 llvm_cv_target_arch="x86" ;;
 170   amd64-* | x86_64-*)     llvm_cv_target_arch="AMD64" ;;
 171   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 172   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 173   *)                      llvm_cv_target_arch="Unknown" ;;
 174 esac])
 175
 176 if test "$llvm_cv_target_arch" = "Unknown" ; then
 177   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 178 fi
 179
 180 dnl Define a substitution, ARCH, for the target architecture
 181 AC_SUBST(ARCH,$llvm_cv_target_arch)
 182
 183 dnl Check for the endianness of the target
 184 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 185
 186 dnl===-----------------------------------------------------------------------===
 187 dnl===
 188 dnl=== SECTION 3: Command line arguments for the configure script.
 189 dnl===
 190 dnl===-----------------------------------------------------------------------===
 191
 192 dnl --enable-optimized : check whether they want to do an optimized build:
 193 AC_ARG_ENABLE(optimized,
 194               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 195 if test ${enableval} = "no" ; then
 196   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 197 else
 198   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 199 fi
 200
 201 dnl --enable-jit: check whether they want to enable the jit
 202 AC_ARG_ENABLE(jit,
 203   AS_HELP_STRING(--enable-jit,
 204                  [Enable Just In Time Compiling (default is YES)]),,
 205   enableval=default)
 206 if test ${enableval} = "no"
 207 then
 208   AC_SUBST(JIT,[[]])
 209 else
 210   case "$llvm_cv_target_arch" in
 211     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 212     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 213     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 214     AMD64)   AC_SUBST(JIT,[[]]) ;;
 215     *)       AC_SUBST(JIT,[[]]) ;;
 216   esac
 217 fi
 218
 219 dnl Allow enablement of doxygen generated documentation
 220 AC_ARG_ENABLE(doxygen,
 221               AS_HELP_STRING([--enable-doxygen],
 222                              [Build doxygen documentation (default is NO)]),,
 223                              enableval=default)
 224 case "$enableval" in
 225   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 226   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 227   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 228   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 229 esac
 230
 231 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 232 AC_ARG_WITH(llvmgccdir,
 233   AS_HELP_STRING([--with-llvmgccdir],
 234     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 235     withval=default)
 236 case "$withval" in
 237   default) WITH_LLVMGCCDIR=default ;;
 238   /*)      WITH_LLVMGCCDIR=$withval ;;
 239   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 240 esac
 241
 242 dnl===-----------------------------------------------------------------------===
 243 dnl===
 244 dnl=== SECTION 4: Check for programs we need and that they are the right version
 245 dnl===
 246 dnl===-----------------------------------------------------------------------===
 247
 248 dnl Check for compilation tools
 249 AC_PROG_CPP
 250 AC_PROG_CC(gcc)
 251 AC_PROG_CXX(g++)
 252 AC_PROG_FLEX
 253 AC_PROG_BISON
 254
 255 dnl Check for the tools that the makefiles require
 256 AC_CHECK_GNU_MAKE
 257 AC_PROG_LN_S
 258 AC_PATH_PROG(CMP, [cmp], [cmp])
 259 AC_PATH_PROG(CP, [cp], [cp])
 260 AC_PATH_PROG(DATE, [date], [date])
 261 AC_PATH_PROG(FIND, [find], [find])
 262 AC_PATH_PROG(GREP, [grep], [grep])
 263 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 264 AC_PATH_PROG(MV,   [mv],   [mv])
 265 AC_PATH_PROG(PAX,  [pax],  [pax])
 266 AC_PROG_RANLIB
 267 AC_PATH_PROG(RM,   [rm],   [rm])
 268 AC_PATH_PROG(SED,  [sed],  [sed])
 269 AC_PATH_PROG(TAR,  [tar],  [gtar])
 270
 271 dnl Find the install program
 272 AC_PROG_INSTALL
 273
 274 dnl Checks for documentation and testing tools that we can do without. If these
 275 dnl are not found then they are set to "true" which always succeeds but does
 276 dnl nothing. This just lets the build output show that we could have done
 277 dnl something if the tool was available.
 278 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 279 AC_PATH_PROG(DOT,[dot],[true dot])
 280 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 281 AC_PATH_PROG(ETAGS,[etags],[true etags])
 282 AC_PATH_PROG(GROFF,[groff],[true groff])
 283 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 284 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 285 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 286 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 287 DJ_AC_PATH_TCLSH
 288 AC_PATH_PROG(ZIP,[zip],[true zip])
 289
 290 dnl Determine if the linker supports the -R option.
 291 AC_LINK_USE_R
 292
 293 dnl Check for libtool and the library that has dlopen function (which must come
 294 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 295 dnl libtool).
 296 AC_LIBTOOL_DLOPEN
 297 AC_LIB_LTDL
 298 AC_PROG_LIBTOOL
 299
 300 dnl Check if we know how to tell etags we are using C++:
 301 etags_version=`$ETAGS --version 2>&1`
 302 case "$etags_version" in
 303         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 304         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 305         *) ETAGSFLAGS="" ;;
 306 esac
 307 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 308
 309 if test "$WITH_LLVMGCCDIR" = "default" ; then
 310   AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 311   AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 312 else
 313   LLVMGCC=$WITH_LLVMGCCDIR/bin/llvm-gcc
 314   LLVMGXX=$WITH_LLVMGCCDIR/bin/llvm-g++
 315   AC_SUBST(LLVMGCC,$LLVMGCC)
 316   AC_SUBST(LLVMGXX,$LLVMGXX)
 317 fi
 318
 319 AC_MSG_CHECKING([tool compatibility])
 320
 321 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 322 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 323 dnl to support those options.
 324 dnl "icc" emits gcc signatures
 325 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 326 ICC=no
 327 IXX=no
 328 case $CC in
 329   icc*|icpc*)
 330     ICC=yes
 331     IXX=yes
 332     ;;
 333    *)
 334     ;;
 335 esac
 336
 337 if test "$GCC" != "yes" && test "$ICC" != "yes"
 338 then
 339   AC_MSG_ERROR([gcc|icc required but not found])
 340 fi
 341
 342 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 343 if test "$GXX" != "yes" && test "$IXX" != "yes"
 344 then
 345   AC_MSG_ERROR([g++|icc required but not found])
 346 fi
 347
 348 dnl Verify that GCC is version 3.0 or higher
 349 if test "$GCC" = "yes"
 350 then
 351   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 352   if test "$gccmajor" -lt "3"
 353   then
 354     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 355   fi
 356 fi
 357
 358 dnl Check for GNU Make.  We use its extensions, so don't build without it
 359 if test -z "$llvm_cv_gnu_make_command"
 360 then
 361   AC_MSG_ERROR([GNU Make required but not found])
 362 fi
 363
 364 dnl Tool compatibility is okay if we make it here.
 365 AC_MSG_RESULT([ok])
 366
 367 dnl===-----------------------------------------------------------------------===
 368 dnl===
 369 dnl=== SECTION 5: Check for libraries
 370 dnl===
 371 dnl===-----------------------------------------------------------------------===
 372
 373 dnl libelf is for sparc only; we can ignore it if we don't have it
 374 AC_CHECK_LIB(elf, elf_begin)
 375
 376 dnl lt_dlopen may be required for plugin support.
 377 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 378               [Define if lt_dlopen() is available on this platform]),
 379               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 380                            not be available]))
 381
 382 dnl dlopen() is required for plugin support.
 383 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 384                [Define if dlopen() is available on this platform.]),
 385                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 386
 387 dnl mallinfo is optional; the code can compile (minus features) without it
 388 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 389                [Define if mallinfo() is available on this platform.]))
 390
 391 dnl pthread locking functions are optional - but llvm will not be thread-safe
 392 dnl without locks.
 393 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 394                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 395                          [Have pthread_mutex_lock]))
 396
 397 dnl===-----------------------------------------------------------------------===
 398 dnl===
 399 dnl=== SECTION 6: Check for header files
 400 dnl===
 401 dnl===-----------------------------------------------------------------------===
 402
 403 dnl First, use autoconf provided macros for specific headers that we need
 404 dnl We don't check for ancient stuff or things that are guaranteed to be there
 405 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 406 dnl Generally we're looking for POSIX headers.
 407 AC_HEADER_DIRENT
 408 AC_HEADER_MMAP_ANONYMOUS
 409 AC_HEADER_STAT
 410 AC_HEADER_STDC
 411 AC_HEADER_SYS_WAIT
 412 AC_HEADER_TIME
 413
 414 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 415 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 416 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 417
 418 dnl===-----------------------------------------------------------------------===
 419 dnl===
 420 dnl=== SECTION 7: Check for types and structures
 421 dnl===
 422 dnl===-----------------------------------------------------------------------===
 423
 424 AC_TYPE_PID_T
 425 AC_TYPE_SIZE_T
 426 AC_TYPE_SIGNAL
 427 AC_STRUCT_TM
 428 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 429 AC_CHECK_TYPES([uint64_t],,
 430          AC_CHECK_TYPES([u_int64_t],,
 431          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 432
 433 dnl===-----------------------------------------------------------------------===
 434 dnl===
 435 dnl=== SECTION 8: Check for specific functions needed
 436 dnl===
 437 dnl===-----------------------------------------------------------------------===
 438
 439 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 440 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 441 AC_CHECK_FUNCS([realpath setrlimit strdup strerror strerror_r strtoll strtoq ])
 442 AC_CHECK_FUNCS([sysconf])
 443 AC_C_PRINTF_A
 444 AC_FUNC_ALLOCA
 445 AC_FUNC_RAND48
 446
 447 dnl Check for variations in the Standard C++ library and STL. These macros are
 448 dnl provided by LLVM in the autoconf/m4 directory.
 449 AC_CXX_HAVE_HASH_MAP
 450 AC_CXX_HAVE_HASH_SET
 451 AC_CXX_HAVE_STD_ITERATOR
 452 AC_CXX_HAVE_BI_ITERATOR
 453 AC_CXX_HAVE_FWD_ITERATOR
 454 AC_FUNC_ISNAN
 455 AC_FUNC_ISINF
 456
 457 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 458 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 459 dnl be opened for allocating RWX memory.
 460 AC_FUNC_MMAP
 461 AC_FUNC_MMAP_FILE
 462 AC_NEED_DEV_ZERO_FOR_MMAP
 463 AC_CHECK_FUNC(mprotect,,
 464               AC_MSG_ERROR([Function mprotect() required but not found]))
 465
 466 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 467 then
 468   AC_MSG_WARN([mmap() required but not found])
 469 fi
 470 if test "$ac_cv_func_mmap_file" = "no"
 471 then
 472   AC_MSG_WARN([mmap() of files required but not found])
 473 fi
 474
 475 dnl===-----------------------------------------------------------------------===
 476 dnl===
 477 dnl=== SECTION 9: Additional checks, variables, etc.
 478 dnl===
 479 dnl===-----------------------------------------------------------------------===
 480
 481 dnl See if the llvm-gcc executable can compile to LLVM assembly
 482 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 483 [llvm_cv_llvmgcc_sanity="no"
 484 if test -x "$LLVMGCC" ; then
 485   cp /dev/null conftest.c
 486   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 487   if test $? -eq 0 ; then
 488     llvm_cv_llvmgcc_sanity="yes"
 489   fi
 490   rm conftest.c
 491 fi])
 492
 493 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 494 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 495   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 496   AC_SUBST(LLVMCC1,$llvmcc1path)
 497   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 498   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 499   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 500   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 501 fi
 502
 503 dnl Propagate the shared library extension that the libltdl checks did to
 504 dnl the Makefiles so we can use it there too
 505 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 506
 507 # Translate the various configuration directories and other basic
 508 # information into substitutions that will end up in Makefile.config.in
 509 # that these configured values can be used by the makefiles
 510 eval LLVM_PREFIX="${prefix}";
 511 eval LLVM_BINDIR="${prefix}/bin";
 512 eval LLVM_LIBDIR="${prefix}/lib";
 513 eval LLVM_DATADIR="${prefix}/share/llvm";
 514 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 515 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 516 eval LLVM_INCLUDEDIR="${prefix}/include";
 517 eval LLVM_INFODIR="${prefix}/info";
 518 eval LLVM_MANDIR="${prefix}/man";
 519 LLVM_CONFIGTIME=`date`
 520 AC_SUBST(LLVM_PREFIX)
 521 AC_SUBST(LLVM_BINDIR)
 522 AC_SUBST(LLVM_LIBDIR)
 523 AC_SUBST(LLVM_DATADIR)
 524 AC_SUBST(LLVM_DOCSDIR)
 525 AC_SUBST(LLVM_ETCDIR)
 526 AC_SUBST(LLVM_INCLUDEDIR)
 527 AC_SUBST(LLVM_INFODIR)
 528 AC_SUBST(LLVM_MANDIR)
 529 AC_SUBST(LLVM_CONFIGTIME)
 530
 531 # Place the various directores into the config.h file as #defines so that we
 532 # can know about the installation paths within LLVM.
 533 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 534                    [Installation prefix directory])
 535 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 536                    [Installation directory for binary executables])
 537 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 538                    [Installation directory for libraries])
 539 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 540                    [Installation directory for data files])
 541 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 542                    [Installation directory for documentation])
 543 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 544                    [Installation directory for config files])
 545 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 546                    [Installation directory for include files])
 547 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 548                    [Installation directory for .info files])
 549 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 550                    [Installation directory for man pages])
 551 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 552                    [Time at which LLVM was configured])
 553
 554 dnl===-----------------------------------------------------------------------===
 555 dnl===
 556 dnl=== SECTION 10: Specify the output files and generate it
 557 dnl===
 558 dnl===-----------------------------------------------------------------------===
 559
 560 dnl Configure header files
 561 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 562
 563 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 564 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 565 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 566 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 567 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 568
 569 dnl Configure the makefile's configuration data
 570 AC_CONFIG_FILES([Makefile.config])
 571
 572 dnl Configure llvmc's configuration files
 573 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 574
 575 dnl Configure doxygen's configuration file
 576 AC_CONFIG_FILES([docs/doxygen.cfg])
 577
 578 dnl Do special configuration of Makefiles
 579 AC_CONFIG_MAKEFILE(Makefile)
 580 AC_CONFIG_MAKEFILE(Makefile.common)
 581 AC_CONFIG_MAKEFILE(examples/Makefile)
 582 AC_CONFIG_MAKEFILE(lib/Makefile)
 583 AC_CONFIG_MAKEFILE(runtime/Makefile)
 584 AC_CONFIG_MAKEFILE(test/Makefile)
 585 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 586 AC_CONFIG_MAKEFILE(tools/Makefile)
 587 AC_CONFIG_MAKEFILE(utils/Makefile)
 588 AC_CONFIG_MAKEFILE(projects/Makefile)
 589
 590 dnl Finally, crank out the output
 591 AC_OUTPUT
 592
 593 dnl Warn loudly if llvm-gcc was not obviously working
 594 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 595  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 596  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 597  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 598  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 599  AC_MSG_WARN([***** build the llvm tools.])
 600 fi