autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  80       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  81       *)
  82         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  83         ;;
  84     esac
  85   fi
  86 done
  87
  88 dnl===-----------------------------------------------------------------------===
  89 dnl===
  90 dnl=== SECTION 2: Architecture, target, and host checks
  91 dnl===
  92 dnl===-----------------------------------------------------------------------===
  93
  94 dnl Check the target for which we're compiling and the host that will do the
  95 dnl compilations. This will tell us which LLVM compiler will be used for
  96 dnl compiling SSA into object code. This needs to be done early because
  97 dnl following tests depend on it.
  98 AC_CANONICAL_TARGET
  99
 100 dnl Determine the platform type and cache its value. This helps us configure
 101 dnl the System library to the correct build platform.
 102 AC_CACHE_CHECK([type of operating system we're going to host on],
 103                [llvm_cv_os_type],
 104 [case $host in
 105   *-*-aix*)
 106     llvm_cv_link_all_option="-Wl,--whole-archive"
 107     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 108     llvm_cv_os_type="AIX"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-irix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="IRIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-cygwin*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="Cygwin"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-darwin*)
 121     llvm_cv_link_all_option="-Wl,-all_load"
 122     llvm_cv_link_all_option="-Wl,-noall_load"
 123     llvm_cv_os_type="Darwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-freebsd*)
 126     llvm_cv_link_all_option="-Wl,--whole-archive"
 127     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 128     llvm_cv_os_type="FreeBSD"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-openbsd*)
 131     llvm_cv_link_all_option="-Wl,--whole-archive"
 132     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 133     llvm_cv_os_type="OpenBSD"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-netbsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="NetBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-hpux*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="HP-UX"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-interix*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="Interix"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-linux*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="Linux"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-solaris*)
 156     llvm_cv_link_all_option="-Wl,-z,allextract"
 157     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 158     llvm_cv_os_type="SunOS"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-win32*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Win32"
 164     llvm_cv_platform_type="Win32" ;;
 165   *-*-mingw*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="MingW"
 169     llvm_cv_platform_type="Win32" ;;
 170   *)
 171     llvm_cv_link_all_option=""
 172     llvm_cv_no_link_all_option=""
 173     llvm_cv_os_type="Unknown"
 174     llvm_cv_platform_type="Unknown" ;;
 175 esac])
 176
 177 dnl Make sure we aren't attempting to configure for an unknown system
 178 if test "$llvm_cv_os_type" = "Unknown" ; then
 179   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 180 fi
 181
 182 dnl Set the "OS" Makefile variable based on the platform type so the
 183 dnl makefile can configure itself to specific build hosts
 184 AC_SUBST(OS,$llvm_cv_os_type)
 185
 186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 189
 190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 191 dnl This is used by lib/System to determine the basic kind of implementation
 192 dnl to use.
 193 case $llvm_cv_platform_type in
 194   Unix)
 195     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 196     AC_SUBST(LLVM_ON_UNIX,[1])
 197     AC_SUBST(LLVM_ON_WIN32,[0])
 198     ;;
 199   Win32)
 200     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 201     AC_SUBST(LLVM_ON_UNIX,[0])
 202     AC_SUBST(LLVM_ON_WIN32,[1])
 203     ;;
 204 esac
 205
 206 dnl Determine what our target architecture is and configure accordingly.
 207 dnl This will allow Makefiles to make a distinction between the hardware and
 208 dnl the OS.
 209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 210 [case $target in
 211   i?86-*)                 llvm_cv_target_arch="x86" ;;
 212   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 213   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 214   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 215   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 216   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 217   arm-*)                  llvm_cv_target_arch="ARM" ;;
 218   *)                      llvm_cv_target_arch="Unknown" ;;
 219 esac])
 220
 221 if test "$llvm_cv_target_arch" = "Unknown" ; then
 222   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 223 fi
 224
 225 dnl Define a substitution, ARCH, for the target architecture
 226 AC_SUBST(ARCH,$llvm_cv_target_arch)
 227
 228 dnl Check for the endianness of the target
 229 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 230
 231 dnl Check for build platform executable suffix if we're crosscompiling
 232 if test "$cross_compiling" = yes; then
 233   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 234   AC_BUILD_EXEEXT
 235 else
 236   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 237 fi
 238
 239 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 240 dnl build is being done from a checkout. This sets up several defaults for the
 241 dnl command line switches. When we build with a CVS directory, we get a
 242 dnl debug with assertions turned on. Without, we assume a source release and we
 243 dnl get an optimized build without assertions. See --enable-optimized and
 244 dnl --enable-assertions below
 245 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 246   cvsbuild="yes"
 247   optimize="no"
 248   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 249 else
 250   cvsbuild="no"
 251   optimize="yes"
 252 fi
 253
 254 dnl===-----------------------------------------------------------------------===
 255 dnl===
 256 dnl=== SECTION 3: Command line arguments for the configure script.
 257 dnl===
 258 dnl===-----------------------------------------------------------------------===
 259
 260 dnl --enable-optimized : check whether they want to do an optimized build:
 261 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 262  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 263 if test ${enableval} = "no" ; then
 264   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 265 else
 266   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 267 fi
 268
 269 dnl --enable-assertions : check whether they want to turn on assertions or not:
 270 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 271   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 272 if test ${enableval} = "yes" ; then
 273   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 274 else
 275   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 276 fi
 277
 278 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 279 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 280   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 281 if test ${enableval} = "yes" ; then
 282   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 283   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 284 else
 285   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 286   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 287 fi
 288
 289 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 290 AC_ARG_ENABLE(debug-runtime,
 291    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 292 if test ${enableval} = "no" ; then
 293   AC_SUBST(DEBUG_RUNTIME,[[]])
 294 else
 295   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 296 fi
 297
 298 dnl --enable-jit: check whether they want to enable the jit
 299 AC_ARG_ENABLE(jit,
 300   AS_HELP_STRING(--enable-jit,
 301                  [Enable Just In Time Compiling (default is YES)]),,
 302   enableval=default)
 303 if test ${enableval} = "no"
 304 then
 305   AC_SUBST(JIT,[[]])
 306 else
 307   case "$llvm_cv_target_arch" in
 308     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 309     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 310     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 311     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 312     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 313     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 314     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 315     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 316   esac
 317 fi
 318
 319 dnl Allow enablement of doxygen generated documentation
 320 AC_ARG_ENABLE(doxygen,
 321               AS_HELP_STRING([--enable-doxygen],
 322                              [Build doxygen documentation (default is NO)]),,
 323                              enableval=default)
 324 case "$enableval" in
 325   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 326   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 327   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 328   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 329 esac
 330
 331 dnl Allow disablement of threads
 332 AC_ARG_ENABLE(threads,
 333               AS_HELP_STRING([--enable-threads],
 334                              [Use threads if available (default is YES)]),,
 335                              enableval=default)
 336 case "$enableval" in
 337   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 338   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 339   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 340   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 341 esac
 342 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 343
 344 dnl Allow building with position independent code
 345 AC_ARG_ENABLE(pic,
 346   AS_HELP_STRING([--enable-pic],
 347                  [Build LLVM with Position Independent Code (default is NO)]),,
 348                  enableval=default)
 349 case "$enableval" in
 350   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 351   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 352   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 353   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 354 esac
 355 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 356                    [Define if position independent code is enabled])
 357
 358 dnl Allow specific targets to be specified for building (or not)
 359 TARGETS_TO_BUILD=""
 360 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 361     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 362     enableval=all)
 363 case "$enableval" in
 364   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 365   host-only)
 366     case "$llvm_cv_target_arch" in
 367       x86)     TARGETS_TO_BUILD="X86" ;;
 368       x86_64)  TARGETS_TO_BUILD="X86" ;;
 369       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 370       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 371       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 372       IA64)    TARGETS_TO_BUILD="IA64" ;;
 373       ARM)     TARGETS_TO_BUILD="ARM" ;;
 374       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 375     esac
 376     ;;
 377   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 378       case "$a_target" in
 379         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 380         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 381         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 382         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 383         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 384         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 385         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 386         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 387       esac
 388   done
 389   ;;
 390 esac
 391 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 392 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 393
 394 dnl Prevent the CBackend from using printf("%a") for floating point so older
 395 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 396 dnl can still compile the CBE's output
 397 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 398   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 399   enableval=default)
 400 case "$enableval" in
 401   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 402   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 403   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 404   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 405 esac
 406 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 407                    [Define if CBE is enabled for printf %a output])
 408
 409 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 410 AC_ARG_WITH(llvmgccdir,
 411   AS_HELP_STRING([--with-llvmgccdir],
 412     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 413     withval=default)
 414 case "$withval" in
 415   default) WITH_LLVMGCCDIR=default ;;
 416   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 417   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 418 esac
 419
 420 dnl Specify extra build options
 421 AC_ARG_WITH(extra-options,
 422   AS_HELP_STRING([--with-extra-options],
 423                  [Specify addtional options to compile LLVM with]),,
 424                  withval=default)
 425 case "$withval" in
 426   default) EXTRA_OPTIONS= ;;
 427   *) EXTRA_OPTIONS=$withval ;;
 428 esac
 429 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 430
 431 dnl===-----------------------------------------------------------------------===
 432 dnl===
 433 dnl=== SECTION 4: Check for programs we need and that they are the right version
 434 dnl===
 435 dnl===-----------------------------------------------------------------------===
 436
 437 dnl Check for compilation tools
 438 AC_PROG_CPP
 439 AC_PROG_CC(gcc)
 440 AC_PROG_CXX(g++)
 441 AC_PROG_FLEX
 442 AC_PROG_BISON
 443
 444 AC_PROG_NM
 445 AC_SUBST(NM)
 446
 447 dnl Check for the tools that the makefiles require
 448 AC_CHECK_GNU_MAKE
 449 AC_PROG_LN_S
 450 AC_PATH_PROG(CMP, [cmp], [cmp])
 451 AC_PATH_PROG(CP, [cp], [cp])
 452 AC_PATH_PROG(DATE, [date], [date])
 453 AC_PATH_PROG(FIND, [find], [find])
 454 AC_PATH_PROG(GREP, [grep], [grep])
 455 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 456 AC_PATH_PROG(MV,   [mv],   [mv])
 457 AC_PROG_RANLIB
 458 AC_PATH_PROG(RM,   [rm],   [rm])
 459 AC_PATH_PROG(SED,  [sed],  [sed])
 460 AC_PATH_PROG(TAR,  [tar],  [gtar])
 461 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 462
 463 dnl Looking for misc. graph plotting software
 464 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 465 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 466   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 467   dnl If we're targeting for mingw we should emit windows paths, not msys
 468   if test "$llvm_cv_os_type" = "MingW" ; then
 469     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 470   fi
 471   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 472    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 473 fi
 474 AC_PATH_PROG(DOT, [dot], [echo dot])
 475 if test "$DOT" != "echo dot" ; then
 476   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 477   dnl If we're targeting for mingw we should emit windows paths, not msys
 478   if test "$llvm_cv_os_type" = "MingW" ; then
 479     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 480   fi
 481   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 482    [Define to path to dot program if found or 'echo dot' otherwise])
 483 fi
 484 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 485 if test "$GV" != "echo gv" ; then
 486   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 487   dnl If we're targeting for mingw we should emit windows paths, not msys
 488   if test "$llvm_cv_os_type" = "MingW" ; then
 489     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 490   fi
 491   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 492    [Define to path to gv program if found or 'echo gv' otherwise])
 493 fi
 494 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 495 if test "$DOTTY" != "echo dotty" ; then
 496   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 497   dnl If we're targeting for mingw we should emit windows paths, not msys
 498   if test "$llvm_cv_os_type" = "MingW" ; then
 499     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 500   fi
 501   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 502    [Define to path to dotty program if found or 'echo dotty' otherwise])
 503 fi
 504
 505 dnl Look for a sufficiently recent version of Perl.
 506 LLVM_PROG_PERL([5.006])
 507 AC_SUBST(PERL)
 508 if test x"$PERL" = xnone; then
 509    AC_SUBST(HAVE_PERL,0)
 510    AC_MSG_ERROR([perl is required but was not found, please install it])
 511 else
 512    AC_SUBST(HAVE_PERL,1)
 513 fi
 514
 515 dnl Find the install program
 516 AC_PROG_INSTALL
 517
 518 dnl Checks for documentation and testing tools that we can do without. If these
 519 dnl are not found then they are set to "true" which always succeeds but does
 520 dnl nothing. This just lets the build output show that we could have done
 521 dnl something if the tool was available.
 522 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 523 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 524 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 525 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 526 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 527 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 528 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 529 DJ_AC_PATH_TCLSH
 530 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 531
 532 dnl Determine if the linker supports the -R option.
 533 AC_LINK_USE_R
 534
 535 dnl Check for libtool and the library that has dlopen function (which must come
 536 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 537 dnl libtool).
 538 AC_LIBTOOL_DLOPEN
 539 AC_LIB_LTDL
 540 AC_PROG_LIBTOOL
 541
 542 if test "$lt_cv_dlopen_self" = "yes" ; then
 543   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 544               [Define if dlopen(0) will open the symbols of the program])
 545 fi
 546
 547 dnl Check if we know how to tell etags we are using C++:
 548 etags_version=`$ETAGS --version 2>&1`
 549 case "$etags_version" in
 550         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 551         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 552         *) ETAGSFLAGS="" ;;
 553 esac
 554 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 555
 556 if test "$WITH_LLVMGCCDIR" = "default" ; then
 557   LLVMGCC="llvm-gcc${EXEEXT}"
 558   LLVMGXX="llvm-g++${EXEEXT}"
 559   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 560   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 561 else
 562   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 563   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 564   AC_SUBST(LLVMGCC,$LLVMGCC)
 565   AC_SUBST(LLVMGXX,$LLVMGXX)
 566 fi
 567
 568 AC_MSG_CHECKING([tool compatibility])
 569
 570 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 571 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 572 dnl to support those options.
 573 dnl "icc" emits gcc signatures
 574 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 575 ICC=no
 576 IXX=no
 577 case $CC in
 578   icc*|icpc*)
 579     ICC=yes
 580     IXX=yes
 581     ;;
 582    *)
 583     ;;
 584 esac
 585
 586 if test "$GCC" != "yes" && test "$ICC" != "yes"
 587 then
 588   AC_MSG_ERROR([gcc|icc required but not found])
 589 fi
 590
 591 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 592 if test "$GXX" != "yes" && test "$IXX" != "yes"
 593 then
 594   AC_MSG_ERROR([g++|icc required but not found])
 595 fi
 596
 597 dnl Verify that GCC is version 3.0 or higher
 598 if test "$GCC" = "yes"
 599 then
 600   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 601   if test "$gccmajor" -lt "3"
 602   then
 603     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 604   fi
 605 fi
 606
 607 dnl Check for GNU Make.  We use its extensions, so don't build without it
 608 if test -z "$llvm_cv_gnu_make_command"
 609 then
 610   AC_MSG_ERROR([GNU Make required but not found])
 611 fi
 612
 613 dnl Tool compatibility is okay if we make it here.
 614 AC_MSG_RESULT([ok])
 615
 616 dnl===-----------------------------------------------------------------------===
 617 dnl===
 618 dnl=== SECTION 5: Check for libraries
 619 dnl===
 620 dnl===-----------------------------------------------------------------------===
 621
 622 dnl libelf is for sparc only; we can ignore it if we don't have it
 623 AC_CHECK_LIB(elf, elf_begin)
 624 AC_CHECK_LIB(m,sin)
 625 if test "$llvm_cv_os_type" = "MingW" ; then
 626   AC_CHECK_LIB(imagehlp, main)
 627   AC_CHECK_LIB(psapi, main)
 628 fi
 629
 630 dnl lt_dlopen may be required for plugin support.
 631 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 632               [Define if lt_dlopen() is available on this platform]),
 633               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 634                            not be available]))
 635
 636 dnl dlopen() is required for plugin support.
 637 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 638                [Define if dlopen() is available on this platform.]),
 639                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 640
 641 dnl mallinfo is optional; the code can compile (minus features) without it
 642 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 643                [Define if mallinfo() is available on this platform.]))
 644
 645 dnl pthread locking functions are optional - but llvm will not be thread-safe
 646 dnl without locks.
 647 if test "$ENABLE_THREADS" -eq 1 ; then
 648   AC_CHECK_LIB(pthread,pthread_mutex_init)
 649   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 650                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 651                            [Have pthread_mutex_lock]))
 652 fi
 653
 654 dnl Allow extra x86-disassembler library
 655 AC_ARG_WITH(udis86,
 656   AS_HELP_STRING([--with-udis86=<path>],
 657     [Use udis86 external x86 disassembler library]),
 658     [
 659       AC_SUBST(USE_UDIS86, [1])
 660       case "$withval" in
 661         /usr/lib|yes) ;;
 662         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 663       esac
 664       AC_CHECK_LIB(udis86, ud_init, [], [
 665         echo "Error! You need to have libudis86 around."
 666         exit -1
 667       ])
 668     ],
 669     AC_SUBST(USE_UDIS86, [0]))
 670 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 671                    [Define if use udis86 library])
 672
 673 dnl===-----------------------------------------------------------------------===
 674 dnl===
 675 dnl=== SECTION 6: Check for header files
 676 dnl===
 677 dnl===-----------------------------------------------------------------------===
 678
 679 dnl First, use autoconf provided macros for specific headers that we need
 680 dnl We don't check for ancient stuff or things that are guaranteed to be there
 681 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 682 dnl Generally we're looking for POSIX headers.
 683 AC_HEADER_DIRENT
 684 AC_HEADER_MMAP_ANONYMOUS
 685 AC_HEADER_STAT
 686 AC_HEADER_STDC
 687 AC_HEADER_SYS_WAIT
 688 AC_HEADER_TIME
 689
 690 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 691 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 692 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 693 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 694 if test "$ENABLE_THREADS" -eq 1 ; then
 695   AC_CHECK_HEADER(pthread.h,
 696                   AC_SUBST(HAVE_PTHREAD, 1),
 697                    AC_SUBST(HAVE_PTHREAD, 0))
 698 else
 699   AC_SUBST(HAVE_PTHREAD, 0)
 700 fi
 701
 702 dnl===-----------------------------------------------------------------------===
 703 dnl===
 704 dnl=== SECTION 7: Check for types and structures
 705 dnl===
 706 dnl===-----------------------------------------------------------------------===
 707
 708 AC_HUGE_VAL_CHECK
 709 AC_TYPE_PID_T
 710 AC_TYPE_SIZE_T
 711 AC_TYPE_SIGNAL
 712 AC_STRUCT_TM
 713 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 714 AC_CHECK_TYPES([uint64_t],,
 715          AC_CHECK_TYPES([u_int64_t],,
 716          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 717
 718 dnl===-----------------------------------------------------------------------===
 719 dnl===
 720 dnl=== SECTION 8: Check for specific functions needed
 721 dnl===
 722 dnl===-----------------------------------------------------------------------===
 723
 724 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 725 AC_CHECK_FUNCS([powf fmodf strtof round ])
 726 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 727 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 728 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 729 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 730 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 731 AC_C_PRINTF_A
 732 AC_FUNC_ALLOCA
 733 AC_FUNC_RAND48
 734
 735 dnl Check for variations in the Standard C++ library and STL. These macros are
 736 dnl provided by LLVM in the autoconf/m4 directory.
 737 AC_CXX_HAVE_HASH_MAP
 738 AC_CXX_HAVE_HASH_SET
 739 AC_CXX_HAVE_STD_ITERATOR
 740 AC_CXX_HAVE_BI_ITERATOR
 741 AC_CXX_HAVE_FWD_ITERATOR
 742 AC_FUNC_ISNAN
 743 AC_FUNC_ISINF
 744
 745 dnl Check for mmap support.We also need to know if /dev/zero is required to
 746 dnl be opened for allocating RWX memory.
 747 dnl Make sure we aren't attempting to configure for an unknown system
 748 if test "$llvm_cv_platform_type" = "Unix" ; then
 749   AC_FUNC_MMAP
 750   AC_FUNC_MMAP_FILE
 751   AC_NEED_DEV_ZERO_FOR_MMAP
 752
 753   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 754   then
 755     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 756   fi
 757   if test "$ac_cv_func_mmap_file" = "no"
 758   then
 759     AC_MSG_WARN([mmap() of files required but not found])
 760   fi
 761 fi
 762
 763 dnl===-----------------------------------------------------------------------===
 764 dnl===
 765 dnl=== SECTION 9: Additional checks, variables, etc.
 766 dnl===
 767 dnl===-----------------------------------------------------------------------===
 768
 769 dnl Check, whether __dso_handle is present
 770 AC_CHECK_FUNCS([__dso_handle])
 771
 772 dnl See if the llvm-gcc executable can compile to LLVM assembly
 773 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 774 [llvm_cv_llvmgcc_sanity="no"
 775 if test -x "$LLVMGCC" ; then
 776   cp /dev/null conftest.c
 777   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 778       grep 'target datalayout =' > /dev/null 2>&1
 779   if test $? -eq 0 ; then
 780     llvm_cv_llvmgcc_sanity="yes"
 781   fi
 782   rm conftest.c
 783 fi])
 784
 785 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 786 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 787   AC_MSG_CHECKING([llvm-gcc component support])
 788   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 789   AC_SUBST(LLVMCC1,$llvmcc1path)
 790   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 791   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 792   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 793   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 794   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 795   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 796   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 797   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 798   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 799   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 800   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 801   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 802   AC_MSG_RESULT([ok])
 803 fi
 804
 805 dnl Propagate the shared library extension that the libltdl checks did to
 806 dnl the Makefiles so we can use it there too
 807 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 808
 809 # Translate the various configuration directories and other basic
 810 # information into substitutions that will end up in Makefile.config.in
 811 # that these configured values can be used by the makefiles
 812 if test "${prefix}" = "NONE" ; then
 813   prefix="/usr/local"
 814 fi
 815 eval LLVM_PREFIX="${prefix}";
 816 eval LLVM_BINDIR="${prefix}/bin";
 817 eval LLVM_LIBDIR="${prefix}/lib";
 818 eval LLVM_DATADIR="${prefix}/share/llvm";
 819 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 820 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 821 eval LLVM_INCLUDEDIR="${prefix}/include";
 822 eval LLVM_INFODIR="${prefix}/info";
 823 eval LLVM_MANDIR="${prefix}/man";
 824 LLVM_CONFIGTIME=`date`
 825 AC_SUBST(LLVM_PREFIX)
 826 AC_SUBST(LLVM_BINDIR)
 827 AC_SUBST(LLVM_LIBDIR)
 828 AC_SUBST(LLVM_DATADIR)
 829 AC_SUBST(LLVM_DOCSDIR)
 830 AC_SUBST(LLVM_ETCDIR)
 831 AC_SUBST(LLVM_INCLUDEDIR)
 832 AC_SUBST(LLVM_INFODIR)
 833 AC_SUBST(LLVM_MANDIR)
 834 AC_SUBST(LLVM_CONFIGTIME)
 835
 836 # Place the various directores into the config.h file as #defines so that we
 837 # can know about the installation paths within LLVM.
 838 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 839                    [Installation prefix directory])
 840 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 841                    [Installation directory for binary executables])
 842 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 843                    [Installation directory for libraries])
 844 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 845                    [Installation directory for data files])
 846 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 847                    [Installation directory for documentation])
 848 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 849                    [Installation directory for config files])
 850 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 851                    [Installation directory for include files])
 852 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 853                    [Installation directory for .info files])
 854 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 855                    [Installation directory for man pages])
 856 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 857                    [Time at which LLVM was configured])
 858
 859 dnl===-----------------------------------------------------------------------===
 860 dnl===
 861 dnl=== SECTION 10: Specify the output files and generate it
 862 dnl===
 863 dnl===-----------------------------------------------------------------------===
 864
 865 dnl Configure header files
 866 dnl WARNING: dnl If you add or remove any of the following config headers, then
 867 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 868 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 869 dnl files can be updated automatically when their *.in sources change.
 870 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 871 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 872 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 873 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 874 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 875
 876 dnl Configure the makefile's configuration data
 877 AC_CONFIG_FILES([Makefile.config])
 878
 879 dnl Configure the RPM spec file for LLVM
 880 AC_CONFIG_FILES([llvm.spec])
 881
 882 dnl Configure doxygen's configuration file
 883 AC_CONFIG_FILES([docs/doxygen.cfg])
 884
 885 dnl Do the first stage of configuration for llvm-config.in.
 886 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 887
 888 dnl Do special configuration of Makefiles
 889 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 890 AC_CONFIG_MAKEFILE(Makefile)
 891 AC_CONFIG_MAKEFILE(Makefile.common)
 892 AC_CONFIG_MAKEFILE(examples/Makefile)
 893 AC_CONFIG_MAKEFILE(lib/Makefile)
 894 AC_CONFIG_MAKEFILE(runtime/Makefile)
 895 AC_CONFIG_MAKEFILE(test/Makefile)
 896 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 897 AC_CONFIG_MAKEFILE(tools/Makefile)
 898 AC_CONFIG_MAKEFILE(utils/Makefile)
 899 AC_CONFIG_MAKEFILE(projects/Makefile)
 900
 901 dnl Finally, crank out the output
 902 AC_OUTPUT
 903