1 dnl === configure.ac --------------------------------------------------------===
2 dnl The LLVM Compiler Infrastructure
4 dnl This file was developed by the LLVM research group and is distributed under
5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
7 dnl===-----------------------------------------------------------------------===
8 dnl This is the LLVM configuration script. It is processed by the autoconf
9 dnl program to produce a script named configure. This script contains the
10 dnl configuration checks that LLVM needs in order to support multiple platforms.
11 dnl This file is composed of 10 sections per the recommended organization of
12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
13 dnl please keep the various types of checks within their sections. The sections
16 dnl SECTION 1: Initialization & Setup
17 dnl SECTION 2: Architecture, target, and host checks
18 dnl SECTION 3: Command line arguments for the configure script.
19 dnl SECTION 4: Check for programs we need and that they are the right version
20 dnl SECTION 5: Check for libraries
21 dnl SECTION 6: Check for header files
22 dnl SECTION 7: Check for types and structures
23 dnl SECTION 8: Check for specific functions needed
24 dnl SECTION 9: Additional checks, variables, etc.
25 dnl SECTION 10: Specify the output files and generate it
27 dnl===-----------------------------------------------------------------------===
29 dnl=== SECTION 1: Initialization & Setup
31 dnl===-----------------------------------------------------------------------===
32 dnl Initialize autoconf and define the package name, version number and
33 dnl email address for reporting bugs.
34 AC_INIT([[llvm]],[[1.5cvs]],[llvmbugs@cs.uiuc.edu])
36 dnl Provide a copyright substitution and ensure the copyright notice is included
37 dnl in the output of --version option of the generated configure script.
38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
39 AC_COPYRIGHT($LLVM_COPYRIGHT)
41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
42 dnl use some autoconf macros only available in 2.59.
45 dnl Verify that the source directory is valid. This makes sure that we are
46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
50 dnl various tools where the m4 autoconf macros are.
51 AC_CONFIG_AUX_DIR([autoconf])
53 dnl Quit if the source directory has already been configured.
54 dnl NOTE: This relies upon undocumented autoconf behavior.
55 if test ${srcdir} != "." ; then
56 if test -f ${srcdir}/include/llvm/Config/config.h ; then
57 AC_MSG_ERROR([Already configured in ${srcdir}])
61 dnl Configure all of the projects present in our source tree. While we could
62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
64 dnl Instead we match on the known projects.
65 for i in `ls ${srcdir}/projects`
67 if test -d ${srcdir}/projects/${i} ; then
70 "sample") AC_CONFIG_SUBDIRS([projects/sample]) ;;
71 "Stacker") AC_CONFIG_SUBDIRS([projects/Stacker]) ;;
72 "llvm-test") AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
73 "llvm-reopt") AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
74 "llvm-gcc") AC_CONFIG_SUBDIRS([projects/llvm-gcc]) ;;
75 "llvm-java") AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
76 "llvm-tv") AC_CONFIG_SUBDIRS([projects/llvm-tv]) ;;
77 "llvm-fefw") AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
78 "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
80 AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
86 dnl===-----------------------------------------------------------------------===
88 dnl=== SECTION 2: Architecture, target, and host checks
90 dnl===-----------------------------------------------------------------------===
92 dnl Check the target for which we're compiling and the host that will do the
93 dnl compilations. This will tell us which LLVM compiler will be used for
94 dnl compiling SSA into object code. This needs to be done early because
95 dnl following tests depend on it.
98 dnl Determine the platform type and cache its value. This helps us configure
99 dnl the System library to the correct build platform.
100 AC_CACHE_CHECK([type of operating system we're on],
104 llvm_cv_os_type="AIX"
105 llvm_cv_platform_type="Unix" ;;
107 llvm_cv_os_type="Cygwin"
108 llvm_cv_platform_type="Unix" ;;
110 llvm_cv_os_type="Darwin"
111 llvm_cv_platform_type="Unix" ;;
113 llvm_cv_os_type="FreeBSD"
114 llvm_cv_platform_type="Unix" ;;
116 llvm_cv_os_type="Interix"
117 llvm_cv_platform_type="Unix" ;;
119 llvm_cv_os_type="Linux"
120 llvm_cv_platform_type="Unix" ;;
122 llvm_cv_os_type="SunOS"
123 llvm_cv_platform_type="Unix" ;;
125 llvm_cv_os_type="Win32"
126 llvm_cv_platform_type="Win32" ;;
128 llvm_cv_os_type="MingW"
129 llvm_cv_platform_type="Win32" ;;
131 llvm_cv_os_type="Unknown"
132 llvm_cv_platform_type="Unknown" ;;
135 dnl Make sure we aren't attempting to configure for an unknown system
136 if test "$llvm_cv_os_type" = "Unknown" ; then
137 AC_MSG_ERROR([Operating system is unknown, configure can't continue])
140 dnl Set the "OS" Makefile variable based on the platform type so the
141 dnl makefile can configure itself to specific build hosts
142 AC_SUBST(OS,$llvm_cv_os_type)
144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
145 dnl This is used by lib/System to determine the basic kind of implementation
147 case $llvm_cv_platform_type in
149 AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
150 AC_SUBST(LLVM_ON_UNIX,[1])
151 AC_SUBST(LLVM_ON_WIN32,[0])
154 AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
155 AC_SUBST(LLVM_ON_UNIX,[0])
156 AC_SUBST(LLVM_ON_WIN32,[1])
160 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
161 dnl V9, since that is all that we support at the moment, and autoconf will only
162 dnl tell us we're a sparc.
164 sparc*-*-solaris*) AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
168 dnl Determine what our target architecture is and configure accordingly.
169 dnl This will allow Makefiles to make a distinction between the hardware and
171 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
173 i?86-*) llvm_cv_target_arch="x86" ;;
174 amd64-* | x86_64-*) llvm_cv_target_arch="x86_64" ;;
175 sparc*-*) llvm_cv_target_arch="Sparc" ;;
176 powerpc*-*) llvm_cv_target_arch="PowerPC" ;;
177 alpha*-*) llvm_cv_target_arch="Alpha" ;;
178 ia64-*) llvm_cv_target_arch="IA64" ;;
179 *) llvm_cv_target_arch="Unknown" ;;
182 if test "$llvm_cv_target_arch" = "Unknown" ; then
183 AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
186 dnl Define a substitution, ARCH, for the target architecture
187 AC_SUBST(ARCH,$llvm_cv_target_arch)
189 dnl Check for the endianness of the target
190 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
192 dnl===-----------------------------------------------------------------------===
194 dnl=== SECTION 3: Command line arguments for the configure script.
196 dnl===-----------------------------------------------------------------------===
198 dnl --enable-optimized : check whether they want to do an optimized build:
199 AC_ARG_ENABLE(optimized,
200 AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
201 if test ${enableval} = "no" ; then
202 AC_SUBST(ENABLE_OPTIMIZED,[[]])
204 AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
207 dnl --enable-jit: check whether they want to enable the jit
209 AS_HELP_STRING(--enable-jit,
210 [Enable Just In Time Compiling (default is YES)]),,
212 if test ${enableval} = "no"
216 case "$llvm_cv_target_arch" in
217 x86) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
218 Sparc) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
219 PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
220 x86_64) AC_SUBST(JIT,[[]]) ;;
221 *) AC_SUBST(JIT,[[]]) ;;
225 dnl Allow enablement of doxygen generated documentation
226 AC_ARG_ENABLE(doxygen,
227 AS_HELP_STRING([--enable-doxygen],
228 [Build doxygen documentation (default is NO)]),,
231 yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
232 no) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
233 default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
234 *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
237 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
238 AC_ARG_WITH(llvmgccdir,
239 AS_HELP_STRING([--with-llvmgccdir],
240 [Specify location of llvm-gcc install dir (default searches PATH)]),,
243 default) WITH_LLVMGCCDIR=default ;;
244 /*) WITH_LLVMGCCDIR=$withval ;;
245 *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
248 dnl===-----------------------------------------------------------------------===
250 dnl=== SECTION 4: Check for programs we need and that they are the right version
252 dnl===-----------------------------------------------------------------------===
254 dnl Check for compilation tools
261 dnl Check for the tools that the makefiles require
264 AC_PATH_PROG(CMP, [cmp], [cmp])
265 AC_PATH_PROG(CP, [cp], [cp])
266 AC_PATH_PROG(DATE, [date], [date])
267 AC_PATH_PROG(FIND, [find], [find])
268 AC_PATH_PROG(GREP, [grep], [grep])
269 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
270 AC_PATH_PROG(MV, [mv], [mv])
272 AC_PATH_PROG(RM, [rm], [rm])
273 AC_PATH_PROG(SED, [sed], [sed])
274 AC_PATH_PROG(TAR, [tar], [gtar])
276 dnl Find the install program
279 dnl Checks for documentation and testing tools that we can do without. If these
280 dnl are not found then they are set to "true" which always succeeds but does
281 dnl nothing. This just lets the build output show that we could have done
282 dnl something if the tool was available.
283 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
284 AC_PATH_PROG(DOT,[dot],[true dot])
285 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
286 AC_PATH_PROG(ETAGS,[etags],[true etags])
287 AC_PATH_PROG(GROFF,[groff],[true groff])
288 AC_PATH_PROG(GZIP,[gzip],[true gzip])
289 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
290 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
291 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
293 AC_PATH_PROG(ZIP,[zip],[true zip])
295 dnl Determine if the linker supports the -R option.
298 dnl Check for libtool and the library that has dlopen function (which must come
299 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
305 if test "$lt_cv_dlopen_self" = "yes" ; then
306 AC_DEFINE([CAN_DLOPEN_SELF],[1],
307 [Define if dlopen(0) will open the symbols of the program])
310 dnl Check if we know how to tell etags we are using C++:
311 etags_version=`$ETAGS --version 2>&1`
312 case "$etags_version" in
313 *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
314 *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
317 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
319 if test "$WITH_LLVMGCCDIR" = "default" ; then
320 AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
321 AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
323 LLVMGCC=$WITH_LLVMGCCDIR/bin/llvm-gcc
324 LLVMGXX=$WITH_LLVMGCCDIR/bin/llvm-g++
325 AC_SUBST(LLVMGCC,$LLVMGCC)
326 AC_SUBST(LLVMGXX,$LLVMGXX)
329 AC_MSG_CHECKING([tool compatibility])
331 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
332 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
333 dnl to support those options.
334 dnl "icc" emits gcc signatures
335 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
347 if test "$GCC" != "yes" && test "$ICC" != "yes"
349 AC_MSG_ERROR([gcc|icc required but not found])
352 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
353 if test "$GXX" != "yes" && test "$IXX" != "yes"
355 AC_MSG_ERROR([g++|icc required but not found])
358 dnl Verify that GCC is version 3.0 or higher
359 if test "$GCC" = "yes"
361 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
362 if test "$gccmajor" -lt "3"
364 AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
368 dnl Check for GNU Make. We use its extensions, so don't build without it
369 if test -z "$llvm_cv_gnu_make_command"
371 AC_MSG_ERROR([GNU Make required but not found])
374 dnl Tool compatibility is okay if we make it here.
377 dnl===-----------------------------------------------------------------------===
379 dnl=== SECTION 5: Check for libraries
381 dnl===-----------------------------------------------------------------------===
383 dnl libelf is for sparc only; we can ignore it if we don't have it
384 AC_CHECK_LIB(elf, elf_begin)
386 dnl lt_dlopen may be required for plugin support.
387 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
388 [Define if lt_dlopen() is available on this platform]),
389 AC_MSG_WARN([lt_dlopen() not found - plugin support might
392 dnl dlopen() is required for plugin support.
393 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
394 [Define if dlopen() is available on this platform.]),
395 AC_MSG_WARN([dlopen() not found - disabling plugin support]))
397 dnl mallinfo is optional; the code can compile (minus features) without it
398 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
399 [Define if mallinfo() is available on this platform.]))
401 dnl pthread locking functions are optional - but llvm will not be thread-safe
403 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
404 AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
405 [Have pthread_mutex_lock]))
407 dnl===-----------------------------------------------------------------------===
409 dnl=== SECTION 6: Check for header files
411 dnl===-----------------------------------------------------------------------===
413 dnl First, use autoconf provided macros for specific headers that we need
414 dnl We don't check for ancient stuff or things that are guaranteed to be there
415 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
416 dnl Generally we're looking for POSIX headers.
418 AC_HEADER_MMAP_ANONYMOUS
424 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
425 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
426 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
427 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
429 dnl===-----------------------------------------------------------------------===
431 dnl=== SECTION 7: Check for types and structures
433 dnl===-----------------------------------------------------------------------===
439 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
440 AC_CHECK_TYPES([uint64_t],,
441 AC_CHECK_TYPES([u_int64_t],,
442 AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
444 dnl===-----------------------------------------------------------------------===
446 dnl=== SECTION 8: Check for specific functions needed
448 dnl===-----------------------------------------------------------------------===
450 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
451 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
452 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
453 AC_CHECK_FUNCS([strtoll strtoq sysconf])
458 dnl Check for variations in the Standard C++ library and STL. These macros are
459 dnl provided by LLVM in the autoconf/m4 directory.
462 AC_CXX_HAVE_STD_ITERATOR
463 AC_CXX_HAVE_BI_ITERATOR
464 AC_CXX_HAVE_FWD_ITERATOR
468 dnl Check for mmap and mprotect support. We need both to do the JIT and for
469 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
470 dnl be opened for allocating RWX memory.
473 AC_NEED_DEV_ZERO_FOR_MMAP
474 AC_CHECK_FUNC(mprotect,,
475 AC_MSG_ERROR([Function mprotect() required but not found]))
477 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
479 AC_MSG_WARN([mmap() of a fixed address required but not supported])
481 if test "$ac_cv_func_mmap_file" = "no"
483 AC_MSG_WARN([mmap() of files required but not found])
486 dnl===-----------------------------------------------------------------------===
488 dnl=== SECTION 9: Additional checks, variables, etc.
490 dnl===-----------------------------------------------------------------------===
492 dnl See if the llvm-gcc executable can compile to LLVM assembly
493 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
494 [llvm_cv_llvmgcc_sanity="no"
495 if test -x "$LLVMGCC" ; then
496 cp /dev/null conftest.c
497 "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
498 if test $? -eq 0 ; then
499 llvm_cv_llvmgcc_sanity="yes"
504 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
505 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
506 llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
507 AC_SUBST(LLVMCC1,$llvmcc1path)
508 llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
509 AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
510 llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
511 AC_SUBST(LLVMGCCDIR,$llvmgccdir)
514 dnl Propagate the shared library extension that the libltdl checks did to
515 dnl the Makefiles so we can use it there too
516 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
518 # Translate the various configuration directories and other basic
519 # information into substitutions that will end up in Makefile.config.in
520 # that these configured values can be used by the makefiles
521 eval LLVM_PREFIX="${prefix}";
522 eval LLVM_BINDIR="${prefix}/bin";
523 eval LLVM_LIBDIR="${prefix}/lib";
524 eval LLVM_DATADIR="${prefix}/share/llvm";
525 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
526 eval LLVM_ETCDIR="${prefix}/etc/llvm";
527 eval LLVM_INCLUDEDIR="${prefix}/include";
528 eval LLVM_INFODIR="${prefix}/info";
529 eval LLVM_MANDIR="${prefix}/man";
530 LLVM_CONFIGTIME=`date`
531 AC_SUBST(LLVM_PREFIX)
532 AC_SUBST(LLVM_BINDIR)
533 AC_SUBST(LLVM_LIBDIR)
534 AC_SUBST(LLVM_DATADIR)
535 AC_SUBST(LLVM_DOCSDIR)
536 AC_SUBST(LLVM_ETCDIR)
537 AC_SUBST(LLVM_INCLUDEDIR)
538 AC_SUBST(LLVM_INFODIR)
539 AC_SUBST(LLVM_MANDIR)
540 AC_SUBST(LLVM_CONFIGTIME)
542 # Place the various directores into the config.h file as #defines so that we
543 # can know about the installation paths within LLVM.
544 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
545 [Installation prefix directory])
546 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
547 [Installation directory for binary executables])
548 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
549 [Installation directory for libraries])
550 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
551 [Installation directory for data files])
552 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
553 [Installation directory for documentation])
554 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
555 [Installation directory for config files])
556 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
557 [Installation directory for include files])
558 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
559 [Installation directory for .info files])
560 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
561 [Installation directory for man pages])
562 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
563 [Time at which LLVM was configured])
565 dnl===-----------------------------------------------------------------------===
567 dnl=== SECTION 10: Specify the output files and generate it
569 dnl===-----------------------------------------------------------------------===
571 dnl Configure header files
572 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
574 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
575 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
576 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
577 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
578 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
580 dnl Configure the makefile's configuration data
581 AC_CONFIG_FILES([Makefile.config])
583 dnl Configure llvmc's configuration files
584 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
586 dnl Configure doxygen's configuration file
587 AC_CONFIG_FILES([docs/doxygen.cfg])
589 dnl Do special configuration of Makefiles
590 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
591 AC_CONFIG_MAKEFILE(Makefile)
592 AC_CONFIG_MAKEFILE(Makefile.common)
593 AC_CONFIG_MAKEFILE(examples/Makefile)
594 AC_CONFIG_MAKEFILE(lib/Makefile)
595 AC_CONFIG_MAKEFILE(runtime/Makefile)
596 AC_CONFIG_MAKEFILE(test/Makefile)
597 AC_CONFIG_MAKEFILE(test/Makefile.tests)
598 AC_CONFIG_MAKEFILE(tools/Makefile)
599 AC_CONFIG_MAKEFILE(utils/Makefile)
600 AC_CONFIG_MAKEFILE(projects/Makefile)
602 dnl Finally, crank out the output
605 dnl Warn loudly if llvm-gcc was not obviously working
606 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
607 AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
608 AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
609 AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
610 AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
611 AC_MSG_WARN([***** build the llvm tools.])