autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-unknown-eabi*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="Freestanding"
 182     llvm_cv_platform_type="Unix" ;;
 183   *-unknown-elf*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Freestanding"
 187     llvm_cv_platform_type="Unix" ;;
 188   *)
 189     llvm_cv_link_all_option=""
 190     llvm_cv_no_link_all_option=""
 191     llvm_cv_os_type="Unknown"
 192     llvm_cv_platform_type="Unknown" ;;
 193 esac])
 194
 195 AC_CACHE_CHECK([type of operating system we're going to target],
 196                [llvm_cv_target_os_type],
 197 [case $target in
 198   *-*-aix*)
 199     llvm_cv_target_os_type="AIX" ;;
 200   *-*-irix*)
 201     llvm_cv_target_os_type="IRIX" ;;
 202   *-*-cygwin*)
 203     llvm_cv_target_os_type="Cygwin" ;;
 204   *-*-darwin*)
 205     llvm_cv_target_os_type="Darwin" ;;
 206   *-*-freebsd*)
 207     llvm_cv_target_os_type="FreeBSD" ;;
 208   *-*-openbsd*)
 209     llvm_cv_target_os_type="OpenBSD" ;;
 210   *-*-netbsd*)
 211     llvm_cv_target_os_type="NetBSD" ;;
 212   *-*-dragonfly*)
 213     llvm_cv_target_os_type="DragonFly" ;;
 214   *-*-hpux*)
 215     llvm_cv_target_os_type="HP-UX" ;;
 216   *-*-interix*)
 217     llvm_cv_target_os_type="Interix" ;;
 218   *-*-linux*)
 219     llvm_cv_target_os_type="Linux" ;;
 220   *-*-solaris*)
 221     llvm_cv_target_os_type="SunOS" ;;
 222   *-*-win32*)
 223     llvm_cv_target_os_type="Win32" ;;
 224   *-*-mingw*)
 225     llvm_cv_target_os_type="MingW" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_target_os_type="Freestanding" ;;
 228   *)
 229     llvm_cv_target_os_type="Unknown" ;;
 230 esac])
 231
 232 dnl Make sure we aren't attempting to configure for an unknown system
 233 if test "$llvm_cv_os_type" = "Unknown" ; then
 234   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 235 fi
 236
 237 dnl Set the "OS" Makefile variable based on the platform type so the
 238 dnl makefile can configure itself to specific build hosts
 239 AC_SUBST(OS,$llvm_cv_os_type)
 240 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 241 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 242
 243 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 244 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 245 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 246
 247 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 248 dnl This is used by lib/System to determine the basic kind of implementation
 249 dnl to use.
 250 case $llvm_cv_platform_type in
 251   Unix)
 252     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 253     AC_SUBST(LLVM_ON_UNIX,[1])
 254     AC_SUBST(LLVM_ON_WIN32,[0])
 255     ;;
 256   Win32)
 257     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 258     AC_SUBST(LLVM_ON_UNIX,[0])
 259     AC_SUBST(LLVM_ON_WIN32,[1])
 260     ;;
 261 esac
 262
 263 dnl Determine what our target architecture is and configure accordingly.
 264 dnl This will allow Makefiles to make a distinction between the hardware and
 265 dnl the OS.
 266 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 267 [case $target in
 268   i?86-*)                 llvm_cv_target_arch="x86" ;;
 269   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 270   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 271   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 272   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 273   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 274   mips-*)                 llvm_cv_target_arch="Mips" ;;
 275   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 276   xcore-*)                llvm_cv_target_arch="XCore" ;;
 277   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 278   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 279   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 280   *)                      llvm_cv_target_arch="Unknown" ;;
 281 esac])
 282
 283 if test "$llvm_cv_target_arch" = "Unknown" ; then
 284   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 285 fi
 286
 287 # Determine the LLVM native architecture for the target
 288 case "$llvm_cv_target_arch" in
 289     x86)     LLVM_NATIVE_ARCH="X86" ;;
 290     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 291     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 292 esac
 293
 294 dnl Define a substitution, ARCH, for the target architecture
 295 AC_SUBST(ARCH,$llvm_cv_target_arch)
 296
 297 dnl Check for the endianness of the target
 298 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 299
 300 dnl Check for build platform executable suffix if we're crosscompiling
 301 if test "$cross_compiling" = yes; then
 302   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 303   AC_BUILD_EXEEXT
 304   ac_build_prefix=${build_alias}-
 305   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 306   if test -z "$BUILD_CXX"; then
 307      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 308      if test -z "$BUILD_CXX"; then
 309        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 310      fi
 311   fi
 312 else
 313   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 314 fi
 315
 316 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 317 dnl that this build is being done from a checkout. This sets up several
 318 dnl defaults for the command line switches. When we build with a CVS directory,
 319 dnl we get a debug with assertions turned on. Without, we assume a source
 320 dnl release and we get an optimized build without assertions.
 321 dnl See --enable-optimized and --enable-assertions below
 322 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 323   cvsbuild="yes"
 324   optimize="no"
 325   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 326 else
 327   cvsbuild="no"
 328   optimize="yes"
 329 fi
 330
 331 dnl===-----------------------------------------------------------------------===
 332 dnl===
 333 dnl=== SECTION 3: Command line arguments for the configure script.
 334 dnl===
 335 dnl===-----------------------------------------------------------------------===
 336
 337 dnl --enable-optimized : check whether they want to do an optimized build:
 338 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 339  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 340 if test ${enableval} = "no" ; then
 341   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 342 else
 343   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 344 fi
 345
 346 dnl --enable-profiling : check whether they want to do a profile build:
 347 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 348  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 349 if test ${enableval} = "no" ; then
 350   AC_SUBST(ENABLE_PROFILING,[[]])
 351 else
 352   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 353 fi
 354
 355 dnl --enable-assertions : check whether they want to turn on assertions or not:
 356 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 357   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 358 if test ${enableval} = "yes" ; then
 359   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 360 else
 361   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 362 fi
 363
 364 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 365 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 366   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 367 if test ${enableval} = "yes" ; then
 368   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 369   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 370 else
 371   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 372   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 373 fi
 374
 375 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 376 AC_ARG_ENABLE(debug-runtime,
 377    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 378 if test ${enableval} = "no" ; then
 379   AC_SUBST(DEBUG_RUNTIME,[[]])
 380 else
 381   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 382 fi
 383
 384 dnl --enable-jit: check whether they want to enable the jit
 385 AC_ARG_ENABLE(jit,
 386   AS_HELP_STRING(--enable-jit,
 387                  [Enable Just In Time Compiling (default is YES)]),,
 388   enableval=default)
 389 if test ${enableval} = "no"
 390 then
 391   AC_SUBST(JIT,[[]])
 392 else
 393   case "$llvm_cv_target_arch" in
 394     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 395     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 396     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 397     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 398     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 399     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 400     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 401     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 402     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 403     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 404     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 405     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 406     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 407   esac
 408 fi
 409
 410 dnl Allow enablement of doxygen generated documentation
 411 AC_ARG_ENABLE(doxygen,
 412               AS_HELP_STRING([--enable-doxygen],
 413                              [Build doxygen documentation (default is NO)]),,
 414                              enableval=default)
 415 case "$enableval" in
 416   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 417   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 418   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 419   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 420 esac
 421
 422 dnl Allow disablement of threads
 423 AC_ARG_ENABLE(threads,
 424               AS_HELP_STRING([--enable-threads],
 425                              [Use threads if available (default is YES)]),,
 426                              enableval=default)
 427 case "$enableval" in
 428   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 429   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 430   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 431   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 432 esac
 433 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 434
 435 dnl Allow building without position independent code
 436 AC_ARG_ENABLE(pic,
 437   AS_HELP_STRING([--enable-pic],
 438                  [Build LLVM with Position Independent Code (default is YES)]),,
 439                  enableval=default)
 440 case "$enableval" in
 441   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 442   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 443   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 444   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 445 esac
 446 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 447                    [Define if position independent code is enabled])
 448
 449 dnl Allow specific targets to be specified for building (or not)
 450 TARGETS_TO_BUILD=""
 451 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 452     [Build specific host targets: all or target1,target2,... Valid targets are:
 453      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 454      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 455     enableval=all)
 456 if test "$enableval" = host-only ; then
 457   enableval=host
 458 fi
 459 case "$enableval" in
 460   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 461   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 462       case "$a_target" in
 463         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 464         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 465         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 466         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 467         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 468         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 469         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 470         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 471         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 472         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 473         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 474         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 475         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 476         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 477         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 478         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 479         host) case "$llvm_cv_target_arch" in
 480             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 481             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 482             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 483             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 484             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 485             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 486             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 487             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 488             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 489             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 490             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 491             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 492             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 493             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 494           esac ;;
 495         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 496       esac
 497   done
 498   ;;
 499 esac
 500 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 501
 502 # Determine whether we are building LLVM support for the native architecture.
 503 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 504 for a_target in $TARGETS_TO_BUILD; do
 505   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 506     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 507     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 508       [LLVM architecture name for the native architecture, if available])
 509   fi
 510 done
 511
 512 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 513 # Targets.def, AsmPrinters.def, and AsmParsers.def.
 514 LLVM_ENUM_TARGETS=""
 515 LLVM_ENUM_ASM_PRINTERS=""
 516 LLVM_ENUM_ASM_PARSERS=""
 517 for target_to_build in $TARGETS_TO_BUILD; do
 518   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 519   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 520     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 521   fi
 522   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 523     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 524   fi
 525 done
 526 AC_SUBST(LLVM_ENUM_TARGETS)
 527 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 528 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 529
 530 dnl Prevent the CBackend from using printf("%a") for floating point so older
 531 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 532 dnl can still compile the CBE's output
 533 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 534   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 535   enableval=default)
 536 case "$enableval" in
 537   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 538   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 539   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 540   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 541 esac
 542 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 543                    [Define if CBE is enabled for printf %a output])
 544
 545 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 546 AC_ARG_WITH(llvmgccdir,
 547   AS_HELP_STRING([--with-llvmgccdir],
 548     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 549     withval=default)
 550 case "$withval" in
 551   default) WITH_LLVMGCCDIR=default ;;
 552   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 553   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 554 esac
 555
 556 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 557 AC_ARG_WITH(llvmgcc,
 558   AS_HELP_STRING([--with-llvmgcc],
 559     [Specify location of llvm-gcc driver (default searches PATH)]),
 560     LLVMGCC=$with_llvmgcc
 561       WITH_LLVMGCCDIR="",)
 562
 563 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 564 AC_ARG_WITH(llvmgxx,
 565   AS_HELP_STRING([--with-llvmgxx],
 566     [Specify location of llvm-g++ driver (default searches PATH)]),
 567     LLVMGXX=$with_llvmgxx
 568     WITH_LLVMGCCDIR="",)
 569
 570 if test -n "$LLVMGCC"; then
 571    LLVMGCCCOMMAND="$LLVMGCC"
 572 fi
 573
 574 if test -n "$LLVMGXX"; then
 575    LLVMGXXCOMMAND="$LLVMGXX"
 576 fi
 577
 578 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 579    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 580 fi
 581
 582 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 583    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 584 fi
 585
 586 dnl Specify extra build options
 587 AC_ARG_WITH(extra-options,
 588   AS_HELP_STRING([--with-extra-options],
 589                  [Specify additional options to compile LLVM with]),,
 590                  withval=default)
 591 case "$withval" in
 592   default) EXTRA_OPTIONS= ;;
 593   *) EXTRA_OPTIONS=$withval ;;
 594 esac
 595 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 596
 597 dnl Allow specific bindings to be specified for building (or not)
 598 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 599     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 600     enableval=default)
 601 BINDINGS_TO_BUILD=""
 602 case "$enableval" in
 603   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 604   all ) BINDINGS_TO_BUILD="ocaml" ;;
 605   none | no) BINDINGS_TO_BUILD="" ;;
 606   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 607       case "$a_binding" in
 608         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 609         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 610       esac
 611   done
 612   ;;
 613 esac
 614
 615 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 616 dnl script for bindings/ocaml/configure, except that its auto value depends on
 617 dnl OCAMLC, which is found here to support tests.
 618 AC_ARG_WITH([ocaml-libdir],
 619   [AS_HELP_STRING([--with-ocaml-libdir],
 620     [Specify install location for ocaml bindings (default is stdlib)])],
 621   [],
 622   [withval=auto])
 623 case "$withval" in
 624   auto) with_ocaml_libdir="$withval" ;;
 625   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 626   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 627 esac
 628
 629 dnl Allow linking of LLVM with GPLv3 binutils code.
 630 AC_ARG_WITH(binutils-include,
 631   AS_HELP_STRING([--with-binutils-include],
 632     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 633   withval=default)
 634 case "$withval" in
 635   default) WITH_BINUTILS_INCDIR=default ;;
 636   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 637   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 638 esac
 639 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 640   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 641   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 642      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 643      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 644   fi
 645 fi
 646
 647 dnl --enable-libffi : check whether the user wants to turn off libffi:
 648 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 649   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 650   enableval=yes)
 651 case "$enableval" in
 652   yes) llvm_cv_enable_libffi="yes" ;;
 653   no)  llvm_cv_enable_libffi="no"  ;;
 654   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 655 esac
 656
 657 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 658 if test "$llvm_cv_os_type" = "Win32" ; then
 659    llvmc_dynamic="yes"
 660 else
 661    llvmc_dynamic="no"
 662 fi
 663
 664 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 665 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 666 --enable-llvmc-dynamic,
 667 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 668 enableval=$llvmc_dynamic)
 669 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 670    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 671 else
 672    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 673 fi
 674
 675 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 676 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 677 --enable-llvmc-dynamic-plugins,
 678 [Enable dynamic LLVMC plugins (default is YES)]),,
 679 enableval=yes)
 680 if test ${enableval} = "yes" ; then
 681    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 682 else
 683    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 684 fi
 685
 686 dnl===-----------------------------------------------------------------------===
 687 dnl===
 688 dnl=== SECTION 4: Check for programs we need and that they are the right version
 689 dnl===
 690 dnl===-----------------------------------------------------------------------===
 691
 692 dnl Check for compilation tools
 693 AC_PROG_CPP
 694 AC_PROG_CC(gcc)
 695 AC_PROG_CXX(g++)
 696
 697 AC_PROG_NM
 698 AC_SUBST(NM)
 699
 700 dnl Check for the tools that the makefiles require
 701 AC_CHECK_GNU_MAKE
 702 AC_PROG_LN_S
 703 AC_PATH_PROG(CMP, [cmp], [cmp])
 704 AC_PATH_PROG(CP, [cp], [cp])
 705 AC_PATH_PROG(DATE, [date], [date])
 706 AC_PATH_PROG(FIND, [find], [find])
 707 AC_PATH_PROG(GREP, [grep], [grep])
 708 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 709 AC_PATH_PROG(MV,   [mv],   [mv])
 710 AC_PROG_RANLIB
 711 AC_PATH_PROG(RM,   [rm],   [rm])
 712 AC_PATH_PROG(SED,  [sed],  [sed])
 713 AC_PATH_PROG(TAR,  [tar],  [gtar])
 714 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 715
 716 dnl Looking for misc. graph plotting software
 717 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 718 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 719   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 720   dnl If we're targeting for mingw we should emit windows paths, not msys
 721   if test "$llvm_cv_os_type" = "MingW" ; then
 722     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 723   fi
 724   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 725    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 726 fi
 727 AC_PATH_PROG(DOT, [dot], [echo dot])
 728 if test "$DOT" != "echo dot" ; then
 729   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 730   dnl If we're targeting for mingw we should emit windows paths, not msys
 731   if test "$llvm_cv_os_type" = "MingW" ; then
 732     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 733   fi
 734   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 735    [Define to path to dot program if found or 'echo dot' otherwise])
 736 fi
 737 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 738 if test "$FDP" != "echo fdp" ; then
 739   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 740   dnl If we're targeting for mingw we should emit windows paths, not msys
 741   if test "$llvm_cv_os_type" = "MingW" ; then
 742     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 743   fi
 744   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 745    [Define to path to fdp program if found or 'echo fdp' otherwise])
 746 fi
 747 AC_PATH_PROG(NEATO, [neato], [echo neato])
 748 if test "$NEATO" != "echo neato" ; then
 749   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 750   dnl If we're targeting for mingw we should emit windows paths, not msys
 751   if test "$llvm_cv_os_type" = "MingW" ; then
 752     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 753   fi
 754   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 755    [Define to path to neato program if found or 'echo neato' otherwise])
 756 fi
 757 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 758 if test "$TWOPI" != "echo twopi" ; then
 759   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 760   dnl If we're targeting for mingw we should emit windows paths, not msys
 761   if test "$llvm_cv_os_type" = "MingW" ; then
 762     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 763   fi
 764   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 765    [Define to path to twopi program if found or 'echo twopi' otherwise])
 766 fi
 767 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 768 if test "$CIRCO" != "echo circo" ; then
 769   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 770   dnl If we're targeting for mingw we should emit windows paths, not msys
 771   if test "$llvm_cv_os_type" = "MingW" ; then
 772     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 773   fi
 774   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 775    [Define to path to circo program if found or 'echo circo' otherwise])
 776 fi
 777 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 778 if test "$GV" != "echo gv" ; then
 779   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 780   dnl If we're targeting for mingw we should emit windows paths, not msys
 781   if test "$llvm_cv_os_type" = "MingW" ; then
 782     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 783   fi
 784   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 785    [Define to path to gv program if found or 'echo gv' otherwise])
 786 fi
 787 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 788 if test "$DOTTY" != "echo dotty" ; then
 789   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 790   dnl If we're targeting for mingw we should emit windows paths, not msys
 791   if test "$llvm_cv_os_type" = "MingW" ; then
 792     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 793   fi
 794   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 795    [Define to path to dotty program if found or 'echo dotty' otherwise])
 796 fi
 797
 798 dnl Look for a sufficiently recent version of Perl.
 799 LLVM_PROG_PERL([5.006])
 800 AC_SUBST(PERL)
 801 if test x"$PERL" = xnone; then
 802    AC_SUBST(HAVE_PERL,0)
 803    AC_MSG_ERROR([perl is required but was not found, please install it])
 804 else
 805    AC_SUBST(HAVE_PERL,1)
 806 fi
 807
 808 dnl Find the install program
 809 AC_PROG_INSTALL
 810
 811 dnl Checks for documentation and testing tools that we can do without. If these
 812 dnl are not found then they are set to "true" which always succeeds but does
 813 dnl nothing. This just lets the build output show that we could have done
 814 dnl something if the tool was available.
 815 AC_PATH_PROG(BZIP2, [bzip2])
 816 AC_PATH_PROG(DOXYGEN, [doxygen])
 817 AC_PATH_PROG(GROFF, [groff])
 818 AC_PATH_PROG(GZIP, [gzip])
 819 AC_PATH_PROG(POD2HTML, [pod2html])
 820 AC_PATH_PROG(POD2MAN, [pod2man])
 821 AC_PATH_PROG(RUNTEST, [runtest])
 822 DJ_AC_PATH_TCLSH
 823 AC_PATH_PROG(ZIP, [zip])
 824 AC_PATH_PROGS(OCAMLC, [ocamlc])
 825 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 826 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 827 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 828 AC_PATH_PROGS(GAS, [gas as])
 829
 830 dnl Determine whether the linker supports the -R option.
 831 AC_LINK_USE_R
 832
 833 dnl Determine whether the linker supports the -export-dynamic option.
 834 AC_LINK_EXPORT_DYNAMIC
 835
 836 dnl Check for libtool and the library that has dlopen function (which must come
 837 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 838 dnl libtool).
 839 AC_LIBTOOL_DLOPEN
 840 AC_LIB_LTDL
 841 AC_PROG_LIBTOOL
 842
 843 if test "$lt_cv_dlopen_self" = "yes" ; then
 844   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 845               [Define if dlopen(0) will open the symbols of the program])
 846 fi
 847
 848
 849 if test "$WITH_LLVMGCCDIR" = "default" ; then
 850   LLVMGCC="llvm-gcc${EXEEXT}"
 851   LLVMGXX="llvm-g++${EXEEXT}"
 852   LLVMGCCCOMMAND="$LLVMGCC"
 853   LLVMGXXCOMMAND="$LLVMGXX"
 854   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 855   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 856   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 857   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 858 else
 859   if test -z "$LLVMGCC"; then
 860     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 861     LLVMGCCCOMMAND="$LLVMGCC"
 862   fi
 863   if test -z "$LLVMGXX"; then
 864     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 865     LLVMGXXCOMMAND="$LLVMGXX"
 866   fi
 867
 868   AC_SUBST(LLVMGCC,$LLVMGCC)
 869   AC_SUBST(LLVMGXX,$LLVMGXX)
 870   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 871   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 872 fi
 873
 874
 875 AC_MSG_CHECKING([tool compatibility])
 876
 877 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 878 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 879 dnl to support those options.
 880 dnl "icc" emits gcc signatures
 881 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 882 ICC=no
 883 IXX=no
 884 case $CC in
 885   icc*|icpc*)
 886     ICC=yes
 887     IXX=yes
 888     ;;
 889    *)
 890     ;;
 891 esac
 892
 893 if test "$GCC" != "yes" && test "$ICC" != "yes"
 894 then
 895   AC_MSG_ERROR([gcc|icc required but not found])
 896 fi
 897
 898 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 899 if test "$GXX" != "yes" && test "$IXX" != "yes"
 900 then
 901   AC_MSG_ERROR([g++|icc required but not found])
 902 fi
 903
 904 dnl Verify that GCC is version 3.0 or higher
 905 if test "$GCC" = "yes"
 906 then
 907   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 908 #error Unsupported GCC version
 909 #endif
 910 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 911 fi
 912
 913 dnl Check for GNU Make.  We use its extensions, so don't build without it
 914 if test -z "$llvm_cv_gnu_make_command"
 915 then
 916   AC_MSG_ERROR([GNU Make required but not found])
 917 fi
 918
 919 dnl Tool compatibility is okay if we make it here.
 920 AC_MSG_RESULT([ok])
 921
 922 dnl===-----------------------------------------------------------------------===
 923 dnl===
 924 dnl=== SECTION 5: Check for libraries
 925 dnl===
 926 dnl===-----------------------------------------------------------------------===
 927
 928 AC_CHECK_LIB(m,sin)
 929 if test "$llvm_cv_os_type" = "MingW" ; then
 930   AC_CHECK_LIB(imagehlp, main)
 931   AC_CHECK_LIB(psapi, main)
 932 fi
 933
 934 dnl dlopen() is required for plugin support.
 935 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 936                [Define if dlopen() is available on this platform.]),
 937                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 938
 939 dnl libffi is optional; used to call external functions from the interpreter
 940 if test "$llvm_cv_enable_libffi" = "yes" ; then
 941   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 942                  [Define if libffi is available on this platform.]),
 943                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 944 fi
 945
 946 dnl mallinfo is optional; the code can compile (minus features) without it
 947 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 948                [Define if mallinfo() is available on this platform.]))
 949
 950 dnl pthread locking functions are optional - but llvm will not be thread-safe
 951 dnl without locks.
 952 if test "$ENABLE_THREADS" -eq 1 ; then
 953   AC_CHECK_LIB(pthread,pthread_mutex_init)
 954   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 955                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 956                            [Have pthread_mutex_lock]))
 957   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 958                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 959                  [Have pthread_rwlock_init]))
 960   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 961                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 962                  [Have pthread_getspecific]))
 963 fi
 964
 965 dnl Allow extra x86-disassembler library
 966 AC_ARG_WITH(udis86,
 967   AS_HELP_STRING([--with-udis86=<path>],
 968     [Use udis86 external x86 disassembler library]),
 969     [
 970       AC_SUBST(USE_UDIS86, [1])
 971       case "$withval" in
 972         /usr/lib|yes) ;;
 973         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 974       esac
 975       AC_CHECK_LIB(udis86, ud_init, [], [
 976         echo "Error! You need to have libudis86 around."
 977         exit -1
 978       ])
 979     ],
 980     AC_SUBST(USE_UDIS86, [0]))
 981 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 982                    [Define if use udis86 library])
 983
 984 dnl Allow OProfile support for JIT output.
 985 AC_ARG_WITH(oprofile,
 986   AS_HELP_STRING([--with-oprofile=<prefix>],
 987     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
 988     [
 989       AC_SUBST(USE_OPROFILE, [1])
 990       case "$withval" in
 991         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
 992         *) llvm_cv_oppath="${withval}/lib/oprofile"
 993            CPPFLAGS="-I${withval}/include";;
 994       esac
 995       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
 996       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
 997         echo "Error! You need to have libopagent around."
 998         exit -1
 999       ])
1000       AC_CHECK_HEADER([opagent.h], [], [
1001         echo "Error! You need to have opagent.h around."
1002         exit -1
1003       ])
1004     ],
1005     [
1006       llvm_cv_old_LIBS="$LIBS"
1007       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
1008       dnl If either the library or header aren't present, omit oprofile support.
1009       AC_SEARCH_LIBS(op_open_agent, opagent,
1010                      [AC_SUBST(USE_OPROFILE, [1])],
1011                      [LIBS="$llvm_cv_old_LIBS"
1012                       AC_SUBST(USE_OPROFILE, [0])])
1013       AC_CHECK_HEADER([opagent.h], [], [
1014         LIBS="$llvm_cv_old_LIBS"
1015         AC_SUBST(USE_OPROFILE, [0])
1016       ])
1017     ])
1018 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1019                    [Define if we have the oprofile JIT-support library])
1020
1021 dnl===-----------------------------------------------------------------------===
1022 dnl===
1023 dnl=== SECTION 6: Check for header files
1024 dnl===
1025 dnl===-----------------------------------------------------------------------===
1026
1027 dnl First, use autoconf provided macros for specific headers that we need
1028 dnl We don't check for ancient stuff or things that are guaranteed to be there
1029 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1030 dnl Generally we're looking for POSIX headers.
1031 AC_HEADER_DIRENT
1032 AC_HEADER_MMAP_ANONYMOUS
1033 AC_HEADER_STAT
1034 AC_HEADER_STDC
1035 AC_HEADER_SYS_WAIT
1036 AC_HEADER_TIME
1037
1038 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1039 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1040 AC_CHECK_HEADERS([utime.h windows.h])
1041 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1042 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1043 if test "$ENABLE_THREADS" -eq 1 ; then
1044   AC_CHECK_HEADERS(pthread.h,
1045                    AC_SUBST(HAVE_PTHREAD, 1),
1046                    AC_SUBST(HAVE_PTHREAD, 0))
1047 else
1048   AC_SUBST(HAVE_PTHREAD, 0)
1049 fi
1050
1051 dnl Try to find ffi.h.
1052 if test "$llvm_cv_enable_libffi" = "yes" ; then
1053   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1054 fi
1055
1056 dnl===-----------------------------------------------------------------------===
1057 dnl===
1058 dnl=== SECTION 7: Check for types and structures
1059 dnl===
1060 dnl===-----------------------------------------------------------------------===
1061
1062 AC_HUGE_VAL_CHECK
1063 AC_TYPE_PID_T
1064 AC_TYPE_SIZE_T
1065 AC_TYPE_SIGNAL
1066 AC_STRUCT_TM
1067 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1068 AC_CHECK_TYPES([uint64_t],,
1069          AC_CHECK_TYPES([u_int64_t],,
1070          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1071
1072 dnl===-----------------------------------------------------------------------===
1073 dnl===
1074 dnl=== SECTION 8: Check for specific functions needed
1075 dnl===
1076 dnl===-----------------------------------------------------------------------===
1077
1078 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1079 AC_CHECK_FUNCS([powf fmodf strtof round ])
1080 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1081 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1082 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1083 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1084 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1085 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1086 AC_C_PRINTF_A
1087 dnl FIXME: This is no longer used, please remove (but test)!!!
1088 AC_FUNC_ALLOCA
1089 AC_FUNC_RAND48
1090
1091 dnl Check for variations in the Standard C++ library and STL. These macros are
1092 dnl provided by LLVM in the autoconf/m4 directory.
1093 AC_CXX_HAVE_STD_ITERATOR
1094 AC_CXX_HAVE_BI_ITERATOR
1095 AC_CXX_HAVE_FWD_ITERATOR
1096 AC_FUNC_ISNAN
1097 AC_FUNC_ISINF
1098
1099 dnl Check for mmap support.We also need to know if /dev/zero is required to
1100 dnl be opened for allocating RWX memory.
1101 dnl Make sure we aren't attempting to configure for an unknown system
1102 if test "$llvm_cv_platform_type" = "Unix" ; then
1103   AC_FUNC_MMAP
1104   AC_FUNC_MMAP_FILE
1105   AC_NEED_DEV_ZERO_FOR_MMAP
1106
1107   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1108   then
1109     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1110   fi
1111   if test "$ac_cv_func_mmap_file" = "no"
1112   then
1113     AC_MSG_WARN([mmap() of files required but not found])
1114   fi
1115 fi
1116
1117 dnl atomic builtins are required for threading support.
1118 AC_MSG_CHECKING(for GCC atomic builtins)
1119 AC_LINK_IFELSE(
1120   AC_LANG_SOURCE(
1121     [[int main() {
1122         volatile unsigned long val = 1;
1123         __sync_synchronize();
1124         __sync_val_compare_and_swap(&val, 1, 0);
1125         __sync_add_and_fetch(&val, 1);
1126         __sync_sub_and_fetch(&val, 1);
1127         return 0;
1128       }
1129     ]]),
1130   AC_MSG_RESULT(yes)
1131   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1132   AC_MSG_RESULT(no)
1133   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1134   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1135
1136
1137 dnl===-----------------------------------------------------------------------===
1138 dnl===
1139 dnl=== SECTION 9: Additional checks, variables, etc.
1140 dnl===
1141 dnl===-----------------------------------------------------------------------===
1142
1143 dnl Check, whether __dso_handle is present
1144 AC_CHECK_FUNCS([__dso_handle])
1145
1146 dnl See if the llvm-gcc executable can compile to LLVM assembly
1147 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1148 [llvm_cv_llvmgcc_sanity="no"
1149 if test -x "$LLVMGCC" ; then
1150   cp /dev/null conftest.c
1151   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1152       grep 'target datalayout =' > /dev/null 2>&1
1153   if test $? -eq 0 ; then
1154     llvm_cv_llvmgcc_sanity="yes"
1155   fi
1156   rm conftest.c
1157 fi])
1158
1159 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1160 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1161   AC_MSG_CHECKING([llvm-gcc component support])
1162   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1163   AC_SUBST(LLVMCC1,$llvmcc1path)
1164   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1165   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1166   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1167   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1168   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1169   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1170   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1171   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1172   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1173   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1174   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1175   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1176   AC_MSG_RESULT([ok])
1177 fi
1178
1179 dnl Propagate the shared library extension that the libltdl checks did to
1180 dnl the Makefiles so we can use it there too
1181 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1182
1183 # Translate the various configuration directories and other basic
1184 # information into substitutions that will end up in Makefile.config.in
1185 # that these configured values can be used by the makefiles
1186 if test "${prefix}" = "NONE" ; then
1187   prefix="/usr/local"
1188 fi
1189 eval LLVM_PREFIX="${prefix}";
1190 eval LLVM_BINDIR="${prefix}/bin";
1191 eval LLVM_LIBDIR="${prefix}/lib";
1192 eval LLVM_DATADIR="${prefix}/share/llvm";
1193 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1194 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1195 eval LLVM_INCLUDEDIR="${prefix}/include";
1196 eval LLVM_INFODIR="${prefix}/info";
1197 eval LLVM_MANDIR="${prefix}/man";
1198 LLVM_CONFIGTIME=`date`
1199 AC_SUBST(LLVM_PREFIX)
1200 AC_SUBST(LLVM_BINDIR)
1201 AC_SUBST(LLVM_LIBDIR)
1202 AC_SUBST(LLVM_DATADIR)
1203 AC_SUBST(LLVM_DOCSDIR)
1204 AC_SUBST(LLVM_ETCDIR)
1205 AC_SUBST(LLVM_INCLUDEDIR)
1206 AC_SUBST(LLVM_INFODIR)
1207 AC_SUBST(LLVM_MANDIR)
1208 AC_SUBST(LLVM_CONFIGTIME)
1209
1210 # Place the various directores into the config.h file as #defines so that we
1211 # can know about the installation paths within LLVM.
1212 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1213                    [Installation prefix directory])
1214 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1215                    [Installation directory for binary executables])
1216 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1217                    [Installation directory for libraries])
1218 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1219                    [Installation directory for data files])
1220 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1221                    [Installation directory for documentation])
1222 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1223                    [Installation directory for config files])
1224 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1225                    [Installation directory for include files])
1226 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1227                    [Installation directory for .info files])
1228 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1229                    [Installation directory for man pages])
1230 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1231                    [Time at which LLVM was configured])
1232 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1233                    [Host triple we were built on])
1234
1235 # Determine which bindings to build.
1236 if test "$BINDINGS_TO_BUILD" = auto ; then
1237   BINDINGS_TO_BUILD=""
1238   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1239     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1240   fi
1241 fi
1242 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1243
1244 # This isn't really configurey, but it avoids having to repeat the list in
1245 # other files.
1246 AC_SUBST(ALL_BINDINGS,ocaml)
1247
1248 # Do any work necessary to ensure that bindings have what they need.
1249 binding_prereqs_failed=0
1250 for a_binding in $BINDINGS_TO_BUILD ; do
1251   case "$a_binding" in
1252   ocaml)
1253     if test "x$OCAMLC" = x ; then
1254       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1255       binding_prereqs_failed=1
1256     fi
1257     if test "x$OCAMLDEP" = x ; then
1258       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1259       binding_prereqs_failed=1
1260     fi
1261     if test "x$OCAMLOPT" = x ; then
1262       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1263       dnl ocamlopt is optional!
1264     fi
1265     if test "x$with_ocaml_libdir" != xauto ; then
1266       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1267     else
1268       ocaml_stdlib="`"$OCAMLC" -where`"
1269       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1270       then
1271         # ocaml stdlib is beneath our prefix; use stdlib
1272         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1273       else
1274         # ocaml stdlib is outside our prefix; use libdir/ocaml
1275         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1276       fi
1277     fi
1278     ;;
1279   esac
1280 done
1281 if test "$binding_prereqs_failed" = 1 ; then
1282   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1283 fi
1284
1285 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1286 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1287
1288 dnl Determine linker rpath flag
1289 if test "$llvm_cv_link_use_r" = "yes" ; then
1290   RPATH="-Wl,-R"
1291 else
1292   RPATH="-Wl,-rpath"
1293 fi
1294 AC_SUBST(RPATH)
1295
1296 dnl Determine linker rdynamic flag
1297 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1298   RDYNAMIC="-Wl,-export-dynamic"
1299 else
1300   RDYNAMIC=""
1301 fi
1302 AC_SUBST(RDYNAMIC)
1303
1304 dnl===-----------------------------------------------------------------------===
1305 dnl===
1306 dnl=== SECTION 10: Specify the output files and generate it
1307 dnl===
1308 dnl===-----------------------------------------------------------------------===
1309
1310 dnl Configure header files
1311 dnl WARNING: dnl If you add or remove any of the following config headers, then
1312 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1313 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1314 dnl files can be updated automatically when their *.in sources change.
1315 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1316 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1317 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1318 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1319 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1320
1321 dnl Configure the makefile's configuration data
1322 AC_CONFIG_FILES([Makefile.config])
1323
1324 dnl Configure the RPM spec file for LLVM
1325 AC_CONFIG_FILES([llvm.spec])
1326
1327 dnl Configure doxygen's configuration file
1328 AC_CONFIG_FILES([docs/doxygen.cfg])
1329
1330 dnl Configure llvmc's Base plugin
1331 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1332
1333 dnl Do the first stage of configuration for llvm-config.in.
1334 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1335
1336 dnl Do special configuration of Makefiles
1337 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1338 AC_CONFIG_MAKEFILE(Makefile)
1339 AC_CONFIG_MAKEFILE(Makefile.common)
1340 AC_CONFIG_MAKEFILE(examples/Makefile)
1341 AC_CONFIG_MAKEFILE(lib/Makefile)
1342 AC_CONFIG_MAKEFILE(runtime/Makefile)
1343 AC_CONFIG_MAKEFILE(test/Makefile)
1344 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1345 AC_CONFIG_MAKEFILE(unittests/Makefile)
1346 AC_CONFIG_MAKEFILE(tools/Makefile)
1347 AC_CONFIG_MAKEFILE(utils/Makefile)
1348 AC_CONFIG_MAKEFILE(projects/Makefile)
1349 AC_CONFIG_MAKEFILE(bindings/Makefile)
1350 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1351
1352 dnl Finally, crank out the output
1353 AC_OUTPUT