1 dnl === configure.ac --------------------------------------------------------===
2 dnl The LLVM Compiler Infrastructure
4 dnl This file is distributed under the University of Illinois Open Source
5 dnl License. See LICENSE.TXT for details.
7 dnl===-----------------------------------------------------------------------===
8 dnl This is the LLVM configuration script. It is processed by the autoconf
9 dnl program to produce a script named configure. This script contains the
10 dnl configuration checks that LLVM needs in order to support multiple platforms.
11 dnl This file is composed of 10 sections per the recommended organization of
12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
13 dnl please keep the various types of checks within their sections. The sections
16 dnl SECTION 1: Initialization & Setup
17 dnl SECTION 2: Architecture, target, and host checks
18 dnl SECTION 3: Command line arguments for the configure script.
19 dnl SECTION 4: Check for programs we need and that they are the right version
20 dnl SECTION 5: Check for libraries
21 dnl SECTION 6: Check for header files
22 dnl SECTION 7: Check for types and structures
23 dnl SECTION 8: Check for specific functions needed
24 dnl SECTION 9: Additional checks, variables, etc.
25 dnl SECTION 10: Specify the output files and generate it
27 dnl===-----------------------------------------------------------------------===
29 dnl=== SECTION 1: Initialization & Setup
31 dnl===-----------------------------------------------------------------------===
32 dnl Initialize autoconf and define the package name, version number and
33 dnl email address for reporting bugs.
34 AC_INIT([[llvm]],[[2.3svn]],[llvmbugs@cs.uiuc.edu])
36 dnl Provide a copyright substitution and ensure the copyright notice is included
37 dnl in the output of --version option of the generated configure script.
38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
42 dnl use some autoconf macros only available in 2.59.
45 dnl Verify that the source directory is valid. This makes sure that we are
46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
50 dnl various tools where the m4 autoconf macros are.
51 AC_CONFIG_AUX_DIR([autoconf])
53 dnl Quit if the source directory has already been configured.
54 dnl NOTE: This relies upon undocumented autoconf behavior.
55 if test ${srcdir} != "." ; then
56 if test -f ${srcdir}/include/llvm/Config/config.h ; then
57 AC_MSG_ERROR([Already configured in ${srcdir}])
61 dnl Configure all of the projects present in our source tree. While we could
62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
64 dnl Instead we match on the known projects.
65 for i in `ls ${srcdir}/projects`
67 if test -d ${srcdir}/projects/${i} ; then
70 sample) AC_CONFIG_SUBDIRS([projects/sample]) ;;
71 privbracket) AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
72 llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
73 llvm-test) AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
74 llvm-reopt) AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
75 llvm-gcc) AC_CONFIG_SUBDIRS([projects/llvm-gcc]) ;;
76 llvm-java) AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
77 llvm-tv) AC_CONFIG_SUBDIRS([projects/llvm-tv]) ;;
78 llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
79 poolalloc) AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
80 llvm-kernel) AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
82 AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
88 dnl===-----------------------------------------------------------------------===
90 dnl=== SECTION 2: Architecture, target, and host checks
92 dnl===-----------------------------------------------------------------------===
94 dnl Check the target for which we're compiling and the host that will do the
95 dnl compilations. This will tell us which LLVM compiler will be used for
96 dnl compiling SSA into object code. This needs to be done early because
97 dnl following tests depend on it.
100 dnl Determine the platform type and cache its value. This helps us configure
101 dnl the System library to the correct build platform.
102 AC_CACHE_CHECK([type of operating system we're going to host on],
106 llvm_cv_link_all_option="-Wl,--whole-archive"
107 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
108 llvm_cv_os_type="AIX"
109 llvm_cv_platform_type="Unix" ;;
111 llvm_cv_link_all_option="-Wl,--whole-archive"
112 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
113 llvm_cv_os_type="IRIX"
114 llvm_cv_platform_type="Unix" ;;
116 llvm_cv_link_all_option="-Wl,--whole-archive"
117 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
118 llvm_cv_os_type="Cygwin"
119 llvm_cv_platform_type="Unix" ;;
121 llvm_cv_link_all_option="-Wl,-all_load"
122 llvm_cv_no_link_all_option="-Wl,-noall_load"
123 llvm_cv_os_type="Darwin"
124 llvm_cv_platform_type="Unix" ;;
126 llvm_cv_link_all_option="-Wl,--whole-archive"
127 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
128 llvm_cv_os_type="FreeBSD"
129 llvm_cv_platform_type="Unix" ;;
131 llvm_cv_link_all_option="-Wl,--whole-archive"
132 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
133 llvm_cv_os_type="OpenBSD"
134 llvm_cv_platform_type="Unix" ;;
136 llvm_cv_link_all_option="-Wl,--whole-archive"
137 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
138 llvm_cv_os_type="NetBSD"
139 llvm_cv_platform_type="Unix" ;;
141 llvm_cv_link_all_option="-Wl,--whole-archive"
142 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
143 llvm_cv_os_type="HP-UX"
144 llvm_cv_platform_type="Unix" ;;
146 llvm_cv_link_all_option="-Wl,--whole-archive"
147 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
148 llvm_cv_os_type="Interix"
149 llvm_cv_platform_type="Unix" ;;
151 llvm_cv_link_all_option="-Wl,--whole-archive"
152 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
153 llvm_cv_os_type="Linux"
154 llvm_cv_platform_type="Unix" ;;
156 llvm_cv_link_all_option="-Wl,-z,allextract"
157 llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
158 llvm_cv_os_type="SunOS"
159 llvm_cv_platform_type="Unix" ;;
161 llvm_cv_link_all_option="-Wl,--whole-archive"
162 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
163 llvm_cv_os_type="Win32"
164 llvm_cv_platform_type="Win32" ;;
166 llvm_cv_link_all_option="-Wl,--whole-archive"
167 llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
168 llvm_cv_os_type="MingW"
169 llvm_cv_platform_type="Win32" ;;
171 llvm_cv_link_all_option=""
172 llvm_cv_no_link_all_option=""
173 llvm_cv_os_type="Unknown"
174 llvm_cv_platform_type="Unknown" ;;
177 dnl Make sure we aren't attempting to configure for an unknown system
178 if test "$llvm_cv_os_type" = "Unknown" ; then
179 AC_MSG_ERROR([Operating system is unknown, configure can't continue])
182 dnl Set the "OS" Makefile variable based on the platform type so the
183 dnl makefile can configure itself to specific build hosts
184 AC_SUBST(OS,$llvm_cv_os_type)
186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
191 dnl This is used by lib/System to determine the basic kind of implementation
193 case $llvm_cv_platform_type in
195 AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
196 AC_SUBST(LLVM_ON_UNIX,[1])
197 AC_SUBST(LLVM_ON_WIN32,[0])
200 AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
201 AC_SUBST(LLVM_ON_UNIX,[0])
202 AC_SUBST(LLVM_ON_WIN32,[1])
206 dnl Determine what our target architecture is and configure accordingly.
207 dnl This will allow Makefiles to make a distinction between the hardware and
209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
211 i?86-*) llvm_cv_target_arch="x86" ;;
212 amd64-* | x86_64-*) llvm_cv_target_arch="x86_64" ;;
213 sparc*-*) llvm_cv_target_arch="Sparc" ;;
214 powerpc*-*) llvm_cv_target_arch="PowerPC" ;;
215 alpha*-*) llvm_cv_target_arch="Alpha" ;;
216 ia64-*) llvm_cv_target_arch="IA64" ;;
217 arm-*) llvm_cv_target_arch="ARM" ;;
218 mips-*) llvm_cv_target_arch="Mips" ;;
219 *) llvm_cv_target_arch="Unknown" ;;
222 if test "$llvm_cv_target_arch" = "Unknown" ; then
223 AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
226 dnl Define a substitution, ARCH, for the target architecture
227 AC_SUBST(ARCH,$llvm_cv_target_arch)
229 dnl Check for the endianness of the target
230 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
232 dnl Check for build platform executable suffix if we're crosscompiling
233 if test "$cross_compiling" = yes; then
234 AC_SUBST(LLVM_CROSS_COMPILING, [1])
237 AC_SUBST(LLVM_CROSS_COMPILING, [0])
240 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
241 dnl build is being done from a checkout. This sets up several defaults for the
242 dnl command line switches. When we build with a CVS directory, we get a
243 dnl debug with assertions turned on. Without, we assume a source release and we
244 dnl get an optimized build without assertions. See --enable-optimized and
245 dnl --enable-assertions below
246 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
249 AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
255 dnl===-----------------------------------------------------------------------===
257 dnl=== SECTION 3: Command line arguments for the configure script.
259 dnl===-----------------------------------------------------------------------===
261 dnl --enable-optimized : check whether they want to do an optimized build:
262 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
263 [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
264 if test ${enableval} = "no" ; then
265 AC_SUBST(ENABLE_OPTIMIZED,[[]])
267 AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
270 dnl --enable-assertions : check whether they want to turn on assertions or not:
271 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
272 [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
273 if test ${enableval} = "yes" ; then
274 AC_SUBST(DISABLE_ASSERTIONS,[[]])
276 AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
279 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
280 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
281 [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
282 if test ${enableval} = "yes" ; then
283 AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
284 AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
286 AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
287 AC_SUBST(EXPENSIVE_CHECKS,[[no]])
290 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
291 AC_ARG_ENABLE(debug-runtime,
292 AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
293 if test ${enableval} = "no" ; then
294 AC_SUBST(DEBUG_RUNTIME,[[]])
296 AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
299 dnl --enable-jit: check whether they want to enable the jit
301 AS_HELP_STRING(--enable-jit,
302 [Enable Just In Time Compiling (default is YES)]),,
304 if test ${enableval} = "no"
308 case "$llvm_cv_target_arch" in
309 x86) AC_SUBST(TARGET_HAS_JIT,1) ;;
310 Sparc) AC_SUBST(TARGET_HAS_JIT,0) ;;
311 PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
312 x86_64) AC_SUBST(TARGET_HAS_JIT,1) ;;
313 Alpha) AC_SUBST(TARGET_HAS_JIT,1) ;;
314 IA64) AC_SUBST(TARGET_HAS_JIT,0) ;;
315 ARM) AC_SUBST(TARGET_HAS_JIT,0) ;;
316 Mips) AC_SUBST(TARGET_HAS_JIT,0) ;;
317 *) AC_SUBST(TARGET_HAS_JIT,0) ;;
321 dnl Allow enablement of doxygen generated documentation
322 AC_ARG_ENABLE(doxygen,
323 AS_HELP_STRING([--enable-doxygen],
324 [Build doxygen documentation (default is NO)]),,
327 yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
328 no) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
329 default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
330 *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
333 dnl Allow disablement of threads
334 AC_ARG_ENABLE(threads,
335 AS_HELP_STRING([--enable-threads],
336 [Use threads if available (default is YES)]),,
339 yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
340 no) AC_SUBST(ENABLE_THREADS,[0]) ;;
341 default) AC_SUBST(ENABLE_THREADS,[1]) ;;
342 *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
344 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
346 dnl Allow building with position independent code
348 AS_HELP_STRING([--enable-pic],
349 [Build LLVM with Position Independent Code (default is NO)]),,
352 yes) AC_SUBST(ENABLE_PIC,[1]) ;;
353 no) AC_SUBST(ENABLE_PIC,[0]) ;;
354 default) AC_SUBST(ENABLE_PIC,[0]) ;;
355 *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
357 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
358 [Define if position independent code is enabled])
360 dnl Allow specific targets to be specified for building (or not)
362 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
363 [Build specific host targets: all,host-only,{target-name} (default=all)]),,
366 all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU CBackend MSIL" ;;
368 case "$llvm_cv_target_arch" in
369 x86) TARGETS_TO_BUILD="X86" ;;
370 x86_64) TARGETS_TO_BUILD="X86" ;;
371 Sparc) TARGETS_TO_BUILD="Sparc" ;;
372 PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
373 Alpha) TARGETS_TO_BUILD="Alpha" ;;
374 IA64) TARGETS_TO_BUILD="IA64" ;;
375 ARM) TARGETS_TO_BUILD="ARM" ;;
376 Mips) TARGETS_TO_BUILD="Mips" ;;
377 CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
378 *) AC_MSG_ERROR([Can not set target to build]) ;;
381 *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
383 x86) TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
384 x86_64) TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
385 sparc) TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
386 powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
387 alpha) TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
388 ia64) TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
389 arm) TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
390 mips) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
391 spu) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
392 cbe) TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
393 msil) TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
394 *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
399 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
401 dnl Prevent the CBackend from using printf("%a") for floating point so older
402 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
403 dnl can still compile the CBE's output
404 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
405 [Enable C Backend output with hex floating point via %a (default is YES)]),,
408 yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
409 no) AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
410 default) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
411 *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
413 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
414 [Define if CBE is enabled for printf %a output])
416 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
417 AC_ARG_WITH(llvmgccdir,
418 AS_HELP_STRING([--with-llvmgccdir],
419 [Specify location of llvm-gcc install dir (default searches PATH)]),,
422 default) WITH_LLVMGCCDIR=default ;;
423 /* | [[A-Za-z]]:[[\\/]]*) WITH_LLVMGCCDIR=$withval ;;
424 *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
427 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
429 AS_HELP_STRING([--with-llvmgcc],
430 [Specify location of llvm-gcc driver (default searches PATH)]),
431 LLVMGCC=$with_llvmgcc
434 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
436 AS_HELP_STRING([--with-llvmgxx],
437 [Specify location of llvm-g++ driver (default searches PATH)]),
438 LLVMGXX=$with_llvmgxx
441 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
442 AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
445 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
446 AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
449 dnl Specify extra build options
450 AC_ARG_WITH(extra-options,
451 AS_HELP_STRING([--with-extra-options],
452 [Specify addtional options to compile LLVM with]),,
455 default) EXTRA_OPTIONS= ;;
456 *) EXTRA_OPTIONS=$withval ;;
458 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
460 dnl Allow specific bindings to be specified for building (or not)
461 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
462 [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
466 yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
467 all ) BINDINGS_TO_BUILD="ocaml" ;;
468 none | no) BINDINGS_TO_BUILD="" ;;
469 *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
471 ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
472 *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
478 dnl Allow the ocaml libdir to be overridden. This could go in a configure
479 dnl script for bindings/ocaml/configure, except that its auto value depends on
480 dnl OCAMLC, which is found here to support tests.
481 AC_ARG_WITH([ocaml-libdir],
482 [AS_HELP_STRING([--with-ocaml-libdir],
483 [Specify install location for ocaml bindings (default is stdlib)])],
487 auto) with_ocaml_libdir="$withval" ;;
488 /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
489 *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
492 dnl===-----------------------------------------------------------------------===
494 dnl=== SECTION 4: Check for programs we need and that they are the right version
496 dnl===-----------------------------------------------------------------------===
498 dnl Check for compilation tools
508 dnl Check for the tools that the makefiles require
511 AC_PATH_PROG(CMP, [cmp], [cmp])
512 AC_PATH_PROG(CP, [cp], [cp])
513 AC_PATH_PROG(DATE, [date], [date])
514 AC_PATH_PROG(FIND, [find], [find])
515 AC_PATH_PROG(GREP, [grep], [grep])
516 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
517 AC_PATH_PROG(MV, [mv], [mv])
519 AC_PATH_PROG(RM, [rm], [rm])
520 AC_PATH_PROG(SED, [sed], [sed])
521 AC_PATH_PROG(TAR, [tar], [gtar])
522 AC_PATH_PROG(BINPWD,[pwd], [pwd])
524 dnl Looking for misc. graph plotting software
525 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
526 if test "$GRAPHVIZ" != "echo Graphviz" ; then
527 AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
528 dnl If we're targeting for mingw we should emit windows paths, not msys
529 if test "$llvm_cv_os_type" = "MingW" ; then
530 GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
532 AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
533 [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
535 AC_PATH_PROG(DOT, [dot], [echo dot])
536 if test "$DOT" != "echo dot" ; then
537 AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
538 dnl If we're targeting for mingw we should emit windows paths, not msys
539 if test "$llvm_cv_os_type" = "MingW" ; then
540 DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
542 AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
543 [Define to path to dot program if found or 'echo dot' otherwise])
545 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
546 if test "$GV" != "echo gv" ; then
547 AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
548 dnl If we're targeting for mingw we should emit windows paths, not msys
549 if test "$llvm_cv_os_type" = "MingW" ; then
550 GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
552 AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
553 [Define to path to gv program if found or 'echo gv' otherwise])
555 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
556 if test "$DOTTY" != "echo dotty" ; then
557 AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
558 dnl If we're targeting for mingw we should emit windows paths, not msys
559 if test "$llvm_cv_os_type" = "MingW" ; then
560 DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
562 AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
563 [Define to path to dotty program if found or 'echo dotty' otherwise])
566 dnl Look for a sufficiently recent version of Perl.
567 LLVM_PROG_PERL([5.006])
569 if test x"$PERL" = xnone; then
570 AC_SUBST(HAVE_PERL,0)
571 AC_MSG_ERROR([perl is required but was not found, please install it])
573 AC_SUBST(HAVE_PERL,1)
576 dnl Find the install program
579 dnl Checks for documentation and testing tools that we can do without. If these
580 dnl are not found then they are set to "true" which always succeeds but does
581 dnl nothing. This just lets the build output show that we could have done
582 dnl something if the tool was available.
583 AC_PATH_PROG(BZIP2, [bzip2])
584 AC_PATH_PROG(DOXYGEN, [doxygen])
585 AC_PATH_PROG(GROFF, [groff])
586 AC_PATH_PROG(GZIP, [gzip])
587 AC_PATH_PROG(POD2HTML, [pod2html])
588 AC_PATH_PROG(POD2MAN, [pod2man])
589 AC_PATH_PROG(RUNTEST, [runtest])
591 AC_PATH_PROG(ZIP, [zip])
592 AC_PATH_PROGS(OCAMLC, [ocamlc.opt ocamlc])
593 AC_PATH_PROGS(OCAMLOPT, [ocamlopt.opt ocamlopt])
594 AC_PATH_PROGS(OCAMLDEP, [ocamldep.opt ocamldep])
595 AC_PATH_PROGS(OCAMLDOC, [ocamldoc.opt ocamldoc])
597 dnl Determine if the linker supports the -R option.
600 dnl Check for libtool and the library that has dlopen function (which must come
601 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
607 if test "$lt_cv_dlopen_self" = "yes" ; then
608 AC_DEFINE([CAN_DLOPEN_SELF],[1],
609 [Define if dlopen(0) will open the symbols of the program])
612 if test "$WITH_LLVMGCCDIR" = "default" ; then
613 LLVMGCC="llvm-gcc${EXEEXT}"
614 LLVMGXX="llvm-g++${EXEEXT}"
615 AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
616 AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
618 if test -z "$LLVMGCC"; then
619 LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
621 if test -z "$LLVMGXX"; then
622 LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
624 AC_SUBST(LLVMGCC,$LLVMGCC)
625 AC_SUBST(LLVMGXX,$LLVMGXX)
628 AC_MSG_CHECKING([tool compatibility])
630 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
631 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
632 dnl to support those options.
633 dnl "icc" emits gcc signatures
634 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
646 if test "$GCC" != "yes" && test "$ICC" != "yes"
648 AC_MSG_ERROR([gcc|icc required but not found])
651 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
652 if test "$GXX" != "yes" && test "$IXX" != "yes"
654 AC_MSG_ERROR([g++|icc required but not found])
657 dnl Verify that GCC is version 3.0 or higher
658 if test "$GCC" = "yes"
660 AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
661 #error Unsupported GCC version
663 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
666 dnl Check for GNU Make. We use its extensions, so don't build without it
667 if test -z "$llvm_cv_gnu_make_command"
669 AC_MSG_ERROR([GNU Make required but not found])
672 dnl Tool compatibility is okay if we make it here.
675 dnl===-----------------------------------------------------------------------===
677 dnl=== SECTION 5: Check for libraries
679 dnl===-----------------------------------------------------------------------===
681 dnl libelf is for sparc only; we can ignore it if we don't have it
682 AC_CHECK_LIB(elf, elf_begin)
684 if test "$llvm_cv_os_type" = "MingW" ; then
685 AC_CHECK_LIB(imagehlp, main)
686 AC_CHECK_LIB(psapi, main)
689 dnl dlopen() is required for plugin support.
690 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
691 [Define if dlopen() is available on this platform.]),
692 AC_MSG_WARN([dlopen() not found - disabling plugin support]))
694 dnl mallinfo is optional; the code can compile (minus features) without it
695 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
696 [Define if mallinfo() is available on this platform.]))
698 dnl pthread locking functions are optional - but llvm will not be thread-safe
700 if test "$ENABLE_THREADS" -eq 1 ; then
701 AC_CHECK_LIB(pthread,pthread_mutex_init)
702 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
703 AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
704 [Have pthread_mutex_lock]))
707 dnl Allow extra x86-disassembler library
709 AS_HELP_STRING([--with-udis86=<path>],
710 [Use udis86 external x86 disassembler library]),
712 AC_SUBST(USE_UDIS86, [1])
715 *) LDFLAGS="$LDFLAGS -L${withval}" ;;
717 AC_CHECK_LIB(udis86, ud_init, [], [
718 echo "Error! You need to have libudis86 around."
722 AC_SUBST(USE_UDIS86, [0]))
723 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
724 [Define if use udis86 library])
726 dnl===-----------------------------------------------------------------------===
728 dnl=== SECTION 6: Check for header files
730 dnl===-----------------------------------------------------------------------===
732 dnl First, use autoconf provided macros for specific headers that we need
733 dnl We don't check for ancient stuff or things that are guaranteed to be there
734 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
735 dnl Generally we're looking for POSIX headers.
737 AC_HEADER_MMAP_ANONYMOUS
743 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
744 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
745 AC_CHECK_HEADERS([windows.h])
746 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
747 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
748 if test "$ENABLE_THREADS" -eq 1 ; then
749 AC_CHECK_HEADERS(pthread.h,
750 AC_SUBST(HAVE_PTHREAD, 1),
751 AC_SUBST(HAVE_PTHREAD, 0))
753 AC_SUBST(HAVE_PTHREAD, 0)
756 dnl===-----------------------------------------------------------------------===
758 dnl=== SECTION 7: Check for types and structures
760 dnl===-----------------------------------------------------------------------===
767 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
768 AC_CHECK_TYPES([uint64_t],,
769 AC_CHECK_TYPES([u_int64_t],,
770 AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
772 dnl===-----------------------------------------------------------------------===
774 dnl=== SECTION 8: Check for specific functions needed
776 dnl===-----------------------------------------------------------------------===
778 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
779 AC_CHECK_FUNCS([powf fmodf strtof round ])
780 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
781 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
782 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
783 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
784 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
789 dnl Check for variations in the Standard C++ library and STL. These macros are
790 dnl provided by LLVM in the autoconf/m4 directory.
793 AC_CXX_HAVE_STD_ITERATOR
794 AC_CXX_HAVE_BI_ITERATOR
795 AC_CXX_HAVE_FWD_ITERATOR
799 dnl Check for mmap support.We also need to know if /dev/zero is required to
800 dnl be opened for allocating RWX memory.
801 dnl Make sure we aren't attempting to configure for an unknown system
802 if test "$llvm_cv_platform_type" = "Unix" ; then
805 AC_NEED_DEV_ZERO_FOR_MMAP
807 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
809 AC_MSG_WARN([mmap() of a fixed address required but not supported])
811 if test "$ac_cv_func_mmap_file" = "no"
813 AC_MSG_WARN([mmap() of files required but not found])
817 dnl===-----------------------------------------------------------------------===
819 dnl=== SECTION 9: Additional checks, variables, etc.
821 dnl===-----------------------------------------------------------------------===
823 dnl Check, whether __dso_handle is present
824 AC_CHECK_FUNCS([__dso_handle])
826 dnl See if the llvm-gcc executable can compile to LLVM assembly
827 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
828 [llvm_cv_llvmgcc_sanity="no"
829 if test -x "$LLVMGCC" ; then
830 cp /dev/null conftest.c
831 "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
832 grep 'target datalayout =' > /dev/null 2>&1
833 if test $? -eq 0 ; then
834 llvm_cv_llvmgcc_sanity="yes"
839 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
840 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
841 AC_MSG_CHECKING([llvm-gcc component support])
842 llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
843 AC_SUBST(LLVMCC1,$llvmcc1path)
844 llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
845 AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
846 llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
847 AC_SUBST(LLVMGCCDIR,$llvmgccdir)
848 llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
849 AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
850 llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
851 llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
852 AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
853 AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
854 llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
855 AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
859 dnl Propagate the shared library extension that the libltdl checks did to
860 dnl the Makefiles so we can use it there too
861 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
863 # Translate the various configuration directories and other basic
864 # information into substitutions that will end up in Makefile.config.in
865 # that these configured values can be used by the makefiles
866 if test "${prefix}" = "NONE" ; then
869 eval LLVM_PREFIX="${prefix}";
870 eval LLVM_BINDIR="${prefix}/bin";
871 eval LLVM_LIBDIR="${prefix}/lib";
872 eval LLVM_DATADIR="${prefix}/share/llvm";
873 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
874 eval LLVM_ETCDIR="${prefix}/etc/llvm";
875 eval LLVM_INCLUDEDIR="${prefix}/include";
876 eval LLVM_INFODIR="${prefix}/info";
877 eval LLVM_MANDIR="${prefix}/man";
878 LLVM_CONFIGTIME=`date`
879 AC_SUBST(LLVM_PREFIX)
880 AC_SUBST(LLVM_BINDIR)
881 AC_SUBST(LLVM_LIBDIR)
882 AC_SUBST(LLVM_DATADIR)
883 AC_SUBST(LLVM_DOCSDIR)
884 AC_SUBST(LLVM_ETCDIR)
885 AC_SUBST(LLVM_INCLUDEDIR)
886 AC_SUBST(LLVM_INFODIR)
887 AC_SUBST(LLVM_MANDIR)
888 AC_SUBST(LLVM_CONFIGTIME)
890 # Place the various directores into the config.h file as #defines so that we
891 # can know about the installation paths within LLVM.
892 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
893 [Installation prefix directory])
894 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
895 [Installation directory for binary executables])
896 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
897 [Installation directory for libraries])
898 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
899 [Installation directory for data files])
900 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
901 [Installation directory for documentation])
902 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
903 [Installation directory for config files])
904 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
905 [Installation directory for include files])
906 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
907 [Installation directory for .info files])
908 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
909 [Installation directory for man pages])
910 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
911 [Time at which LLVM was configured])
912 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
913 [Host triple we were built on])
915 # Determine which bindings to build.
916 if test "$BINDINGS_TO_BUILD" = auto ; then
918 if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
919 BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
922 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
924 # This isn't really configurey, but it avoids having to repeat the list in
926 AC_SUBST(ALL_BINDINGS,ocaml)
928 # Do any work necessary to ensure that bindings have what they need.
929 binding_prereqs_failed=0
930 for a_binding in $BINDINGS_TO_BUILD ; do
933 if test "x$OCAMLC" = x ; then
934 AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
935 binding_prereqs_failed=1
937 if test "x$OCAMLDEP" = x ; then
938 AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
939 binding_prereqs_failed=1
941 if test "x$OCAMLOPT" = x ; then
942 AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
943 dnl ocamlopt is optional!
945 if test "x$with_ocaml_libdir" != xauto ; then
946 AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
948 ocaml_stdlib="`"$OCAMLC" -where`"
949 if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
951 # ocaml stdlib is beneath our prefix; use stdlib
952 AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
954 # ocaml stdlib is outside our prefix; use libdir/ocaml
955 AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
961 if test "$binding_prereqs_failed" = 1 ; then
962 AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
966 dnl===-----------------------------------------------------------------------===
968 dnl=== SECTION 10: Specify the output files and generate it
970 dnl===-----------------------------------------------------------------------===
972 dnl Configure header files
973 dnl WARNING: dnl If you add or remove any of the following config headers, then
974 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
975 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
976 dnl files can be updated automatically when their *.in sources change.
977 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
978 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
979 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
980 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
981 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
983 dnl Configure the makefile's configuration data
984 AC_CONFIG_FILES([Makefile.config])
986 dnl Configure the RPM spec file for LLVM
987 AC_CONFIG_FILES([llvm.spec])
989 dnl Configure doxygen's configuration file
990 AC_CONFIG_FILES([docs/doxygen.cfg])
992 dnl Do the first stage of configuration for llvm-config.in.
993 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
995 dnl Do special configuration of Makefiles
996 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
997 AC_CONFIG_MAKEFILE(Makefile)
998 AC_CONFIG_MAKEFILE(Makefile.common)
999 AC_CONFIG_MAKEFILE(examples/Makefile)
1000 AC_CONFIG_MAKEFILE(lib/Makefile)
1001 AC_CONFIG_MAKEFILE(runtime/Makefile)
1002 AC_CONFIG_MAKEFILE(test/Makefile)
1003 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1004 AC_CONFIG_MAKEFILE(tools/Makefile)
1005 AC_CONFIG_MAKEFILE(utils/Makefile)
1006 AC_CONFIG_MAKEFILE(projects/Makefile)
1007 AC_CONFIG_MAKEFILE(bindings/Makefile)
1008 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1010 dnl Finally, crank out the output