1 dnl === configure.ac --------------------------------------------------------===
2 dnl The LLVM Compiler Infrastructure
4 dnl This file was developed by the LLVM research group and is distributed under
5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
7 dnl===-----------------------------------------------------------------------===
8 dnl This is the LLVM configuration script. It is processed by the autoconf
9 dnl program to produce a script named configure. This script contains the
10 dnl configuration checks that LLVM needs in order to support multiple platforms.
11 dnl This file is composed of 10 sections per the recommended organization of
12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
13 dnl please keep the various types of checks within their sections. The sections
16 dnl SECTION 1: Initialization & Setup
17 dnl SECTION 2: Architecture, target, and host checks
18 dnl SECTION 3: Command line arguments for the configure script.
19 dnl SECTION 4: Check for programs we need and that they are the right version
20 dnl SECTION 5: Check for libraries
21 dnl SECTION 6: Check for header files
22 dnl SECTION 7: Check for types and structures
23 dnl SECTION 8: Check for specific functions needed
24 dnl SECTION 9: Additional checks, variables, etc.
25 dnl SECTION 10: Specify the output files and generate it
27 dnl===-----------------------------------------------------------------------===
29 dnl=== SECTION 1: Initialization & Setup
31 dnl===-----------------------------------------------------------------------===
32 dnl Initialize autoconf and define the package name, version number and
33 dnl email address for reporting bugs.
34 AC_INIT([[llvm]],[[1.8cvs]],[llvmbugs@cs.uiuc.edu])
36 dnl Provide a copyright substitution and ensure the copyright notice is included
37 dnl in the output of --version option of the generated configure script.
38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
42 dnl use some autoconf macros only available in 2.59.
45 dnl Verify that the source directory is valid. This makes sure that we are
46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
50 dnl various tools where the m4 autoconf macros are.
51 AC_CONFIG_AUX_DIR([autoconf])
53 dnl Quit if the source directory has already been configured.
54 dnl NOTE: This relies upon undocumented autoconf behavior.
55 if test ${srcdir} != "." ; then
56 if test -f ${srcdir}/include/llvm/Config/config.h ; then
57 AC_MSG_ERROR([Already configured in ${srcdir}])
61 dnl Configure all of the projects present in our source tree. While we could
62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
64 dnl Instead we match on the known projects.
65 for i in `ls ${srcdir}/projects`
67 if test -d ${srcdir}/projects/${i} ; then
70 "sample") AC_CONFIG_SUBDIRS([projects/sample]) ;;
71 "Stacker") AC_CONFIG_SUBDIRS([projects/Stacker]) ;;
72 "llvm-test") AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
73 "llvm-reopt") AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
74 "llvm-gcc") AC_CONFIG_SUBDIRS([projects/llvm-gcc]) ;;
75 "llvm-java") AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
76 "llvm-tv") AC_CONFIG_SUBDIRS([projects/llvm-tv]) ;;
77 "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
78 "llvm-kernel") AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
80 AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
86 dnl===-----------------------------------------------------------------------===
88 dnl=== SECTION 2: Architecture, target, and host checks
90 dnl===-----------------------------------------------------------------------===
92 dnl Check the target for which we're compiling and the host that will do the
93 dnl compilations. This will tell us which LLVM compiler will be used for
94 dnl compiling SSA into object code. This needs to be done early because
95 dnl following tests depend on it.
98 dnl Determine the platform type and cache its value. This helps us configure
99 dnl the System library to the correct build platform.
100 AC_CACHE_CHECK([type of operating system we're on],
104 llvm_cv_os_type="AIX"
105 llvm_cv_platform_type="Unix" ;;
107 llvm_cv_os_type="Cygwin"
108 llvm_cv_platform_type="Unix" ;;
110 llvm_cv_os_type="Darwin"
111 llvm_cv_platform_type="Unix" ;;
113 llvm_cv_os_type="FreeBSD"
114 llvm_cv_platform_type="Unix" ;;
116 llvm_cv_os_type="OpenBSD"
117 llvm_cv_platform_type="Unix" ;;
119 llvm_cv_os_type="HP-UX"
120 llvm_cv_platform_type="Unix" ;;
122 llvm_cv_os_type="Interix"
123 llvm_cv_platform_type="Unix" ;;
125 llvm_cv_os_type="Linux"
126 llvm_cv_platform_type="Unix" ;;
128 llvm_cv_os_type="SunOS"
129 llvm_cv_platform_type="Unix" ;;
131 llvm_cv_os_type="Win32"
132 llvm_cv_platform_type="Win32" ;;
134 llvm_cv_os_type="MingW"
135 llvm_cv_platform_type="Win32" ;;
137 llvm_cv_os_type="Unknown"
138 llvm_cv_platform_type="Unknown" ;;
141 dnl Make sure we aren't attempting to configure for an unknown system
142 if test "$llvm_cv_os_type" = "Unknown" ; then
143 AC_MSG_ERROR([Operating system is unknown, configure can't continue])
146 dnl Set the "OS" Makefile variable based on the platform type so the
147 dnl makefile can configure itself to specific build hosts
148 AC_SUBST(OS,$llvm_cv_os_type)
150 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
151 dnl This is used by lib/System to determine the basic kind of implementation
153 case $llvm_cv_platform_type in
155 AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
156 AC_SUBST(LLVM_ON_UNIX,[1])
157 AC_SUBST(LLVM_ON_WIN32,[0])
160 AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
161 AC_SUBST(LLVM_ON_UNIX,[0])
162 AC_SUBST(LLVM_ON_WIN32,[1])
166 dnl Determine what our target architecture is and configure accordingly.
167 dnl This will allow Makefiles to make a distinction between the hardware and
169 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
171 i?86-*) llvm_cv_target_arch="x86" ;;
172 amd64-* | x86_64-*) llvm_cv_target_arch="x86_64" ;;
173 sparc*-*) llvm_cv_target_arch="Sparc" ;;
174 powerpc*-*) llvm_cv_target_arch="PowerPC" ;;
175 alpha*-*) llvm_cv_target_arch="Alpha" ;;
176 ia64-*) llvm_cv_target_arch="IA64" ;;
177 *) llvm_cv_target_arch="Unknown" ;;
180 if test "$llvm_cv_target_arch" = "Unknown" ; then
181 AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
184 dnl Define a substitution, ARCH, for the target architecture
185 AC_SUBST(ARCH,$llvm_cv_target_arch)
187 dnl Check for the endianness of the target
188 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
190 dnl Check to see if there's a "CVS" directory indicating that this build is
191 dnl being done from a CVS checkout. This sets up several defaults for the
192 dnl command line switches. When we build with a CVS directory, we get a
193 dnl debug with assertions turned on. Without, we assume a source release and we
194 dnl get an optimized build without assertions. See --enable-optimized and
195 dnl --enable-assertions below
196 if test -d "CVS" -o -d "${srcdir}/CVS"; then
199 AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
205 dnl===-----------------------------------------------------------------------===
207 dnl=== SECTION 3: Command line arguments for the configure script.
209 dnl===-----------------------------------------------------------------------===
211 dnl --enable-optimized : check whether they want to do an optimized build:
212 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
213 [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
214 if test ${enableval} = "no" ; then
215 AC_SUBST(ENABLE_OPTIMIZED,[[]])
217 AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
220 dnl --enable-assertions : check whether they want to turn on assertions or not:
221 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
222 [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
223 if test ${enableval} = "yes" ; then
224 AC_SUBST(DISABLE_ASSERTIONS,[[]])
226 AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
229 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
230 AC_ARG_ENABLE(debug-runtime,
231 AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
232 if test ${enableval} = "no" ; then
233 AC_SUBST(DEBUG_RUNTIME,[[]])
235 AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
238 dnl --enable-jit: check whether they want to enable the jit
240 AS_HELP_STRING(--enable-jit,
241 [Enable Just In Time Compiling (default is YES)]),,
243 if test ${enableval} = "no"
247 case "$llvm_cv_target_arch" in
248 x86) AC_SUBST(TARGET_HAS_JIT,1) ;;
249 Sparc) AC_SUBST(TARGET_HAS_JIT,1) ;;
250 PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
251 x86_64) AC_SUBST(TARGET_HAS_JIT,0) ;;
252 Alpha) AC_SUBST(TARGET_HAS_JIT,1) ;;
253 IA64) AC_SUBST(TARGET_HAS_JIT,0) ;;
254 *) AC_SUBST(TARGET_HAS_JIT,0) ;;
258 dnl Allow enablement of doxygen generated documentation
259 AC_ARG_ENABLE(doxygen,
260 AS_HELP_STRING([--enable-doxygen],
261 [Build doxygen documentation (default is NO)]),,
264 yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
265 no) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
266 default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
267 *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
270 dnl Allow disablement of threads
271 AC_ARG_ENABLE(threads,
272 AS_HELP_STRING([--enable-threads],
273 [Use threads if available (default is YES)]),,
276 yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
277 no) AC_SUBST(ENABLE_THREADS,[0]) ;;
278 *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
280 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
282 dnl Allow specific targets to be specified for building (or not)
284 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
285 [Build specific host targets: all,host-only,{target-name} (default=all)]),,
288 all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
290 case "$llvm_cv_target_arch" in
291 x86) TARGETS_TO_BUILD="X86" ;;
292 x86_64) TARGETS_TO_BUILD="X86" ;;
293 Sparc) TARGETS_TO_BUILD="Sparc" ;;
294 PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
295 Alpha) TARGETS_TO_BUILD="Alpha" ;;
296 IA64) TARGETS_TO_BUILD="IA64" ;;
297 *) AC_MSG_ERROR([Can not set target to build]) ;;
300 *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
302 x86) TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
303 x86_64) TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
304 sparc) TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
305 powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
306 alpha) TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
307 ia64) TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
308 *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
313 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
314 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
316 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
317 AC_ARG_WITH(llvmgccdir,
318 AS_HELP_STRING([--with-llvmgccdir],
319 [Specify location of llvm-gcc install dir (default searches PATH)]),,
322 default) WITH_LLVMGCCDIR=default ;;
323 /* | [[A-Za-z]]:[[\\/]]*) WITH_LLVMGCCDIR=$withval ;;
324 *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
328 dnl===-----------------------------------------------------------------------===
330 dnl=== SECTION 4: Check for programs we need and that they are the right version
332 dnl===-----------------------------------------------------------------------===
334 dnl Check for compilation tools
341 dnl Check for the tools that the makefiles require
344 AC_PATH_PROG(CMP, [cmp], [cmp])
345 AC_PATH_PROG(CP, [cp], [cp])
346 AC_PATH_PROG(DATE, [date], [date])
347 AC_PATH_PROG(FIND, [find], [find])
348 AC_PATH_PROG(GREP, [grep], [grep])
349 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
350 AC_PATH_PROG(MV, [mv], [mv])
352 AC_PATH_PROG(RM, [rm], [rm])
353 AC_PATH_PROG(SED, [sed], [sed])
354 AC_PATH_PROG(TAR, [tar], [gtar])
355 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
356 if test "$GRAPHVIZ" != "echo Graphviz" ; then
357 AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
358 AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
359 [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
361 AC_PATH_PROG(GV, [gv], [echo gv])
362 if test "$GV" != "echo gv" ; then
363 AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
364 AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
365 [Define to path to gv program if found or 'echo gv' otherwise])
368 dnl Look for a sufficiently recent version of Perl.
369 LLVM_PROG_PERL([5.006])
371 if test x"$PERL" = xnone; then
372 AC_SUBST(HAVE_PERL,0)
374 AC_SUBST(HAVE_PERL,1)
377 dnl Find the install program
380 dnl Checks for documentation and testing tools that we can do without. If these
381 dnl are not found then they are set to "true" which always succeeds but does
382 dnl nothing. This just lets the build output show that we could have done
383 dnl something if the tool was available.
384 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
385 AC_PATH_PROG(DOT,[dot],[echo "Skipped: dot not found"])
386 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
387 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
388 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
389 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
390 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
391 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
392 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
394 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
396 dnl Determine if the linker supports the -R option.
399 dnl Check for libtool and the library that has dlopen function (which must come
400 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
406 if test "$lt_cv_dlopen_self" = "yes" ; then
407 AC_DEFINE([CAN_DLOPEN_SELF],[1],
408 [Define if dlopen(0) will open the symbols of the program])
411 dnl Check if we know how to tell etags we are using C++:
412 etags_version=`$ETAGS --version 2>&1`
413 case "$etags_version" in
414 *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
415 *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
418 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
420 if test "$WITH_LLVMGCCDIR" = "default" ; then
421 LLVMGCC="llvm-gcc${EXEEXT}"
422 LLVMGXX="llvm-g++${EXEEXT}"
423 AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
424 AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
426 LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
427 LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
428 AC_SUBST(LLVMGCC,$LLVMGCC)
429 AC_SUBST(LLVMGXX,$LLVMGXX)
432 AC_MSG_CHECKING([tool compatibility])
434 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
435 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
436 dnl to support those options.
437 dnl "icc" emits gcc signatures
438 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
450 if test "$GCC" != "yes" && test "$ICC" != "yes"
452 AC_MSG_ERROR([gcc|icc required but not found])
455 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
456 if test "$GXX" != "yes" && test "$IXX" != "yes"
458 AC_MSG_ERROR([g++|icc required but not found])
461 dnl Verify that GCC is version 3.0 or higher
462 if test "$GCC" = "yes"
464 gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
465 if test "$gccmajor" -lt "3"
467 AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
471 dnl Check for GNU Make. We use its extensions, so don't build without it
472 if test -z "$llvm_cv_gnu_make_command"
474 AC_MSG_ERROR([GNU Make required but not found])
477 dnl Tool compatibility is okay if we make it here.
480 dnl===-----------------------------------------------------------------------===
482 dnl=== SECTION 5: Check for libraries
484 dnl===-----------------------------------------------------------------------===
486 dnl libelf is for sparc only; we can ignore it if we don't have it
487 AC_CHECK_LIB(elf, elf_begin)
489 if test "$llvm_cv_os_type" == "MingW" ; then
490 AC_CHECK_HEADERS([windows.h imagehlp.h psapi.h])
491 AC_CHECK_LIB(imagehlp,[SymGetOptions])
492 AC_CHECK_LIB(psapi,[GetProcessMemoryInfo])
495 dnl lt_dlopen may be required for plugin support.
496 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
497 [Define if lt_dlopen() is available on this platform]),
498 AC_MSG_WARN([lt_dlopen() not found - plugin support might
501 dnl dlopen() is required for plugin support.
502 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
503 [Define if dlopen() is available on this platform.]),
504 AC_MSG_WARN([dlopen() not found - disabling plugin support]))
506 dnl mallinfo is optional; the code can compile (minus features) without it
507 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
508 [Define if mallinfo() is available on this platform.]))
510 dnl pthread locking functions are optional - but llvm will not be thread-safe
512 if test "$ENABLE_THREADS" -eq 1 ; then
513 AC_CHECK_LIB(pthread,pthread_mutex_init)
514 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
515 AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
516 [Have pthread_mutex_lock]))
519 dnl===-----------------------------------------------------------------------===
521 dnl=== SECTION 6: Check for header files
523 dnl===-----------------------------------------------------------------------===
525 dnl First, use autoconf provided macros for specific headers that we need
526 dnl We don't check for ancient stuff or things that are guaranteed to be there
527 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
528 dnl Generally we're looking for POSIX headers.
530 AC_HEADER_MMAP_ANONYMOUS
536 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
537 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
538 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
539 AC_CHECK_HEADERS([malloc/malloc.h])
540 if test "$ENABLE_THREADS" -eq 1 ; then
541 AC_CHECK_HEADERS(pthread.h)
544 dnl===-----------------------------------------------------------------------===
546 dnl=== SECTION 7: Check for types and structures
548 dnl===-----------------------------------------------------------------------===
554 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
555 AC_CHECK_TYPES([uint64_t],,
556 AC_CHECK_TYPES([u_int64_t],,
557 AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
559 dnl===-----------------------------------------------------------------------===
561 dnl=== SECTION 8: Check for specific functions needed
563 dnl===-----------------------------------------------------------------------===
565 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
566 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
567 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
568 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
573 dnl Check for variations in the Standard C++ library and STL. These macros are
574 dnl provided by LLVM in the autoconf/m4 directory.
577 AC_CXX_HAVE_STD_ITERATOR
578 AC_CXX_HAVE_BI_ITERATOR
579 AC_CXX_HAVE_FWD_ITERATOR
583 dnl Check for mmap and mprotect support. We need both to do the JIT and for
584 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
585 dnl be opened for allocating RWX memory.
588 AC_NEED_DEV_ZERO_FOR_MMAP
589 AC_CHECK_FUNC(mprotect,,
590 AC_MSG_ERROR([Function mprotect() required but not found]))
592 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
594 AC_MSG_WARN([mmap() of a fixed address required but not supported])
596 if test "$ac_cv_func_mmap_file" = "no"
598 AC_MSG_WARN([mmap() of files required but not found])
601 dnl===-----------------------------------------------------------------------===
603 dnl=== SECTION 9: Additional checks, variables, etc.
605 dnl===-----------------------------------------------------------------------===
607 dnl See if the llvm-gcc executable can compile to LLVM assembly
608 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
609 [llvm_cv_llvmgcc_sanity="no"
610 if test -x "$LLVMGCC" ; then
611 cp /dev/null conftest.c
612 "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
613 if test $? -eq 0 ; then
614 llvm_cv_llvmgcc_sanity="yes"
619 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
620 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
621 llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
622 AC_SUBST(LLVMCC1,$llvmcc1path)
623 llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
624 AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
625 llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
626 AC_SUBST(LLVMGCCDIR,$llvmgccdir)
627 llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
628 llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
629 AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
630 AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
633 dnl Propagate the shared library extension that the libltdl checks did to
634 dnl the Makefiles so we can use it there too
635 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
637 # Translate the various configuration directories and other basic
638 # information into substitutions that will end up in Makefile.config.in
639 # that these configured values can be used by the makefiles
640 if test "${prefix}" == "NONE" ; then
643 eval LLVM_PREFIX="${prefix}";
644 eval LLVM_BINDIR="${prefix}/bin";
645 eval LLVM_LIBDIR="${prefix}/lib";
646 eval LLVM_DATADIR="${prefix}/share/llvm";
647 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
648 eval LLVM_ETCDIR="${prefix}/etc/llvm";
649 eval LLVM_INCLUDEDIR="${prefix}/include";
650 eval LLVM_INFODIR="${prefix}/info";
651 eval LLVM_MANDIR="${prefix}/man";
652 LLVM_CONFIGTIME=`date`
653 AC_SUBST(LLVM_PREFIX)
654 AC_SUBST(LLVM_BINDIR)
655 AC_SUBST(LLVM_LIBDIR)
656 AC_SUBST(LLVM_DATADIR)
657 AC_SUBST(LLVM_DOCSDIR)
658 AC_SUBST(LLVM_ETCDIR)
659 AC_SUBST(LLVM_INCLUDEDIR)
660 AC_SUBST(LLVM_INFODIR)
661 AC_SUBST(LLVM_MANDIR)
662 AC_SUBST(LLVM_CONFIGTIME)
664 # Place the various directores into the config.h file as #defines so that we
665 # can know about the installation paths within LLVM.
666 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
667 [Installation prefix directory])
668 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
669 [Installation directory for binary executables])
670 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
671 [Installation directory for libraries])
672 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
673 [Installation directory for data files])
674 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
675 [Installation directory for documentation])
676 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
677 [Installation directory for config files])
678 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
679 [Installation directory for include files])
680 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
681 [Installation directory for .info files])
682 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
683 [Installation directory for man pages])
684 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
685 [Time at which LLVM was configured])
687 dnl===-----------------------------------------------------------------------===
689 dnl=== SECTION 10: Specify the output files and generate it
691 dnl===-----------------------------------------------------------------------===
693 dnl Configure header files
694 dnl WARNING: dnl If you add or remove any of the following config headers, then
695 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
696 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
697 dnl files can be updated automatically when their *.in sources change.
698 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
699 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
700 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
701 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
702 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
704 dnl Configure the makefile's configuration data
705 AC_CONFIG_FILES([Makefile.config])
707 dnl Configure doxygen's configuration file
708 AC_CONFIG_FILES([docs/doxygen.cfg])
710 dnl Do the first stage of configuration for llvm-config.in.
711 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
713 dnl Do special configuration of Makefiles
714 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
715 AC_CONFIG_MAKEFILE(Makefile)
716 AC_CONFIG_MAKEFILE(Makefile.common)
717 AC_CONFIG_MAKEFILE(examples/Makefile)
718 AC_CONFIG_MAKEFILE(lib/Makefile)
719 AC_CONFIG_MAKEFILE(runtime/Makefile)
720 AC_CONFIG_MAKEFILE(test/Makefile)
721 AC_CONFIG_MAKEFILE(test/Makefile.tests)
722 AC_CONFIG_MAKEFILE(tools/Makefile)
723 AC_CONFIG_MAKEFILE(utils/Makefile)
724 AC_CONFIG_MAKEFILE(projects/Makefile)
726 dnl Finally, crank out the output
729 dnl Warn loudly if llvm-gcc was not obviously working
730 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
731 AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
732 AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
733 AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
734 AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
735 AC_MSG_WARN([***** build the llvm tools.])