autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-auroraux*)
 169     llvm_cv_link_all_option="-Wl,-z,allextract"
 170     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 171     llvm_cv_os_type="AuroraUX"
 172     llvm_cv_platform_type="Unix" ;;
 173   *-*-win32*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="Win32"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-*-mingw*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="MingW"
 182     llvm_cv_platform_type="Win32" ;;
 183   *-*-haiku*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Haiku"
 187     llvm_cv_platform_type="Unix" ;;
 188   *-unknown-eabi*)
 189     llvm_cv_link_all_option="-Wl,--whole-archive"
 190     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 191     llvm_cv_os_type="Freestanding"
 192     llvm_cv_platform_type="Unix" ;;
 193   *-unknown-elf*)
 194     llvm_cv_link_all_option="-Wl,--whole-archive"
 195     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 196     llvm_cv_os_type="Freestanding"
 197     llvm_cv_platform_type="Unix" ;;
 198   *)
 199     llvm_cv_link_all_option=""
 200     llvm_cv_no_link_all_option=""
 201     llvm_cv_os_type="Unknown"
 202     llvm_cv_platform_type="Unknown" ;;
 203 esac])
 204
 205 AC_CACHE_CHECK([type of operating system we're going to target],
 206                [llvm_cv_target_os_type],
 207 [case $target in
 208   *-*-aix*)
 209     llvm_cv_target_os_type="AIX" ;;
 210   *-*-irix*)
 211     llvm_cv_target_os_type="IRIX" ;;
 212   *-*-cygwin*)
 213     llvm_cv_target_os_type="Cygwin" ;;
 214   *-*-darwin*)
 215     llvm_cv_target_os_type="Darwin" ;;
 216   *-*-freebsd*)
 217     llvm_cv_target_os_type="FreeBSD" ;;
 218   *-*-openbsd*)
 219     llvm_cv_target_os_type="OpenBSD" ;;
 220   *-*-netbsd*)
 221     llvm_cv_target_os_type="NetBSD" ;;
 222   *-*-dragonfly*)
 223     llvm_cv_target_os_type="DragonFly" ;;
 224   *-*-hpux*)
 225     llvm_cv_target_os_type="HP-UX" ;;
 226   *-*-interix*)
 227     llvm_cv_target_os_type="Interix" ;;
 228   *-*-linux*)
 229     llvm_cv_target_os_type="Linux" ;;
 230   *-*-solaris*)
 231     llvm_cv_target_os_type="SunOS" ;;
 232   *-*-auroraux*)
 233     llvm_cv_target_os_type="AuroraUX" ;;
 234   *-*-win32*)
 235     llvm_cv_target_os_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_target_os_type="MingW" ;;
 238   *-*-haiku*)
 239     llvm_cv_target_os_type="Haiku" ;;
 240   *-unknown-eabi*)
 241     llvm_cv_target_os_type="Freestanding" ;;
 242   *)
 243     llvm_cv_target_os_type="Unknown" ;;
 244 esac])
 245
 246 dnl Make sure we aren't attempting to configure for an unknown system
 247 if test "$llvm_cv_os_type" = "Unknown" ; then
 248   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 249 fi
 250
 251 dnl Set the "OS" Makefile variable based on the platform type so the
 252 dnl makefile can configure itself to specific build hosts
 253 AC_SUBST(OS,$llvm_cv_os_type)
 254 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 255 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 256
 257 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 258 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 259 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 260
 261 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 262 dnl This is used by lib/System to determine the basic kind of implementation
 263 dnl to use.
 264 case $llvm_cv_platform_type in
 265   Unix)
 266     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 267     AC_SUBST(LLVM_ON_UNIX,[1])
 268     AC_SUBST(LLVM_ON_WIN32,[0])
 269     ;;
 270   Win32)
 271     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 272     AC_SUBST(LLVM_ON_UNIX,[0])
 273     AC_SUBST(LLVM_ON_WIN32,[1])
 274     ;;
 275 esac
 276
 277 dnl Determine what our target architecture is and configure accordingly.
 278 dnl This will allow Makefiles to make a distinction between the hardware and
 279 dnl the OS.
 280 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 281 [case $target in
 282   i?86-*)                 llvm_cv_target_arch="x86" ;;
 283   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 284   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 285   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 286   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 287   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 288   mips-*)                 llvm_cv_target_arch="Mips" ;;
 289   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 290   xcore-*)                llvm_cv_target_arch="XCore" ;;
 291   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 292   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 293   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 294   *)                      llvm_cv_target_arch="Unknown" ;;
 295 esac])
 296
 297 if test "$llvm_cv_target_arch" = "Unknown" ; then
 298   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 299 fi
 300
 301 # Determine the LLVM native architecture for the target
 302 case "$llvm_cv_target_arch" in
 303     x86)     LLVM_NATIVE_ARCH="X86" ;;
 304     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 305     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 306 esac
 307
 308 dnl Define a substitution, ARCH, for the target architecture
 309 AC_SUBST(ARCH,$llvm_cv_target_arch)
 310
 311 dnl Check for the endianness of the target
 312 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 313
 314 dnl Check for build platform executable suffix if we're crosscompiling
 315 if test "$cross_compiling" = yes; then
 316   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 317   AC_BUILD_EXEEXT
 318   ac_build_prefix=${build_alias}-
 319   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 320   if test -z "$BUILD_CXX"; then
 321      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 322      if test -z "$BUILD_CXX"; then
 323        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 324      fi
 325   fi
 326 else
 327   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 328 fi
 329
 330 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 331 dnl that this build is being done from a checkout. This sets up several
 332 dnl defaults for the command line switches. When we build with a CVS directory,
 333 dnl we get a debug with assertions turned on. Without, we assume a source
 334 dnl release and we get an optimized build without assertions.
 335 dnl See --enable-optimized and --enable-assertions below
 336 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 337   cvsbuild="yes"
 338   optimize="no"
 339   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 340 else
 341   cvsbuild="no"
 342   optimize="yes"
 343 fi
 344
 345 dnl===-----------------------------------------------------------------------===
 346 dnl===
 347 dnl=== SECTION 3: Command line arguments for the configure script.
 348 dnl===
 349 dnl===-----------------------------------------------------------------------===
 350
 351 dnl --enable-optimized : check whether they want to do an optimized build:
 352 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 353  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 354 if test ${enableval} = "no" ; then
 355   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 356 else
 357   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 358 fi
 359
 360 dnl --enable-profiling : check whether they want to do a profile build:
 361 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 362  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 363 if test ${enableval} = "no" ; then
 364   AC_SUBST(ENABLE_PROFILING,[[]])
 365 else
 366   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 367 fi
 368
 369 dnl --enable-assertions : check whether they want to turn on assertions or not:
 370 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 371   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 372 if test ${enableval} = "yes" ; then
 373   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 374 else
 375   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 376 fi
 377
 378 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 379 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 380   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 381 if test ${enableval} = "yes" ; then
 382   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 383   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 384 else
 385   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 386   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 387 fi
 388
 389 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 390 AC_ARG_ENABLE(debug-runtime,
 391    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 392 if test ${enableval} = "no" ; then
 393   AC_SUBST(DEBUG_RUNTIME,[[]])
 394 else
 395   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 396 fi
 397
 398 dnl --enable-debug-symbols : should even optimized compiler libraries
 399 dnl have debug symbols?
 400 AC_ARG_ENABLE(debug-symbols,
 401    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 402 if test ${enableval} = "no" ; then
 403   AC_SUBST(DEBUG_SYMBOLS,[[]])
 404 else
 405   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 406 fi
 407
 408 dnl --enable-jit: check whether they want to enable the jit
 409 AC_ARG_ENABLE(jit,
 410   AS_HELP_STRING(--enable-jit,
 411                  [Enable Just In Time Compiling (default is YES)]),,
 412   enableval=default)
 413 if test ${enableval} = "no"
 414 then
 415   AC_SUBST(JIT,[[]])
 416 else
 417   case "$llvm_cv_target_arch" in
 418     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 419     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 420     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 421     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 422     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 423     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 424     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 425     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 426     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 427     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 428     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 429     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 430     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 431   esac
 432 fi
 433
 434 dnl Allow enablement of doxygen generated documentation
 435 AC_ARG_ENABLE(doxygen,
 436               AS_HELP_STRING([--enable-doxygen],
 437                              [Build doxygen documentation (default is NO)]),,
 438                              enableval=default)
 439 case "$enableval" in
 440   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 441   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 442   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 443   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 444 esac
 445
 446 dnl Allow disablement of threads
 447 AC_ARG_ENABLE(threads,
 448               AS_HELP_STRING([--enable-threads],
 449                              [Use threads if available (default is YES)]),,
 450                              enableval=default)
 451 case "$enableval" in
 452   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 453   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 454   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 455   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 456 esac
 457 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 458
 459 dnl Allow building without position independent code
 460 AC_ARG_ENABLE(pic,
 461   AS_HELP_STRING([--enable-pic],
 462                  [Build LLVM with Position Independent Code (default is YES)]),,
 463                  enableval=default)
 464 case "$enableval" in
 465   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 466   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 467   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 468   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 469 esac
 470 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 471                    [Define if position independent code is enabled])
 472
 473 dnl Allow linking tools against the shared library.
 474 AC_ARG_ENABLE(shared,
 475   AS_HELP_STRING([--enable-shared],
 476                  [Link LLVM tools shared (default is NO)]),,
 477                  enableval=default)
 478 case "$enableval" in
 479   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 480   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 481   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 482   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 483 esac
 484
 485 dnl Allow specific targets to be specified for building (or not)
 486 TARGETS_TO_BUILD=""
 487 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 488     [Build specific host targets: all or target1,target2,... Valid targets are:
 489      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 490      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 491     enableval=all)
 492 if test "$enableval" = host-only ; then
 493   enableval=host
 494 fi
 495 case "$enableval" in
 496   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 497   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 498       case "$a_target" in
 499         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 500         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 501         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 502         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 503         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 504         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 505         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 506         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 507         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 508         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 509         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 510         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 511         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 512         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 513         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 514         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 515         host) case "$llvm_cv_target_arch" in
 516             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 517             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 518             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 519             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 520             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 521             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 522             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 523             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 524             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 525             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 526             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 527             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 528             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 529             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 530           esac ;;
 531         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 532       esac
 533   done
 534   ;;
 535 esac
 536 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 537
 538 # Determine whether we are building LLVM support for the native architecture.
 539 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 540 for a_target in $TARGETS_TO_BUILD; do
 541   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 542     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 543     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 544       [LLVM architecture name for the native architecture, if available])
 545   fi
 546 done
 547
 548 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 549 # target feature def files.
 550 LLVM_ENUM_TARGETS=""
 551 LLVM_ENUM_ASM_PRINTERS=""
 552 LLVM_ENUM_ASM_PARSERS=""
 553 LLVM_ENUM_DISASSEMBLERS=""
 554 for target_to_build in $TARGETS_TO_BUILD; do
 555   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 556   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 557     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 558   fi
 559   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 560     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 561   fi
 562   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 563     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 564   fi
 565 done
 566 AC_SUBST(LLVM_ENUM_TARGETS)
 567 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 568 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 569 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 570
 571 dnl Prevent the CBackend from using printf("%a") for floating point so older
 572 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 573 dnl can still compile the CBE's output
 574 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 575   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 576   enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 579   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 580   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 582 esac
 583 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 584                    [Define if CBE is enabled for printf %a output])
 585
 586 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 587 AC_ARG_WITH(llvmgccdir,
 588   AS_HELP_STRING([--with-llvmgccdir],
 589     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 590     withval=default)
 591 case "$withval" in
 592   default) WITH_LLVMGCCDIR=default ;;
 593   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 594   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 595 esac
 596
 597 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 598 AC_ARG_WITH(llvmgcc,
 599   AS_HELP_STRING([--with-llvmgcc],
 600     [Specify location of llvm-gcc driver (default searches PATH)]),
 601     LLVMGCC=$with_llvmgcc
 602       WITH_LLVMGCCDIR="",)
 603
 604 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 605 AC_ARG_WITH(llvmgxx,
 606   AS_HELP_STRING([--with-llvmgxx],
 607     [Specify location of llvm-g++ driver (default searches PATH)]),
 608     LLVMGXX=$with_llvmgxx
 609     WITH_LLVMGCCDIR="",)
 610
 611 if test -n "$LLVMGCC"; then
 612    LLVMGCCCOMMAND="$LLVMGCC"
 613 fi
 614
 615 if test -n "$LLVMGXX"; then
 616    LLVMGXXCOMMAND="$LLVMGXX"
 617 fi
 618
 619 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 620    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 621 fi
 622
 623 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 624    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 625 fi
 626
 627 dnl Allow a specific Clang compiler to be used with this LLVM config.
 628 AC_ARG_WITH(clang,
 629   AS_HELP_STRING([--with-clang],
 630     [Specify location of clang compiler (default is --with-built-clang)]),
 631     [],[with_clang=default])
 632
 633 dnl Enable use of the built Clang.
 634 AC_ARG_WITH(built-clang,
 635   AS_HELP_STRING([--with-built-clang],
 636     [Use the compiled Clang as the LLVM compiler (default=check)]),
 637     [],[with_built_clang=check])
 638
 639 dnl Select the Clang compiler option.
 640 dnl
 641 dnl If --with-clang is given, always honor that; otherwise honor
 642 dnl --with-built-clang, or check if we have the clang sources.
 643 AC_MSG_CHECKING([clang compiler])
 644 WITH_CLANGPATH=""
 645 WITH_BUILT_CLANG=0
 646 if test "$with_clang" != "default"; then
 647    WITH_CLANGPATH="$with_clang"
 648    if ! test -x "$WITH_CLANGPATH"; then
 649      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 650    fi
 651 elif test "$with_built_clang" = "yes"; then
 652    WITH_BUILT_CLANG=1
 653 elif test "$with_built_clang" = "no"; then
 654    WITH_BUILT_CLANG=0
 655 else
 656    if test "$with_built_clang" != "check"; then
 657       AC_MSG_ERROR([invalid value for --with-built-clang.])
 658    fi
 659
 660    if test -f ${srcdir}/tools/clang/README.txt; then
 661      WITH_BUILT_CLANG=1
 662    fi
 663 fi
 664
 665 if ! test -z "$WITH_CLANGPATH"; then
 666    AC_MSG_RESULT([$WITH_CLANGPATH])
 667    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 668 elif test "$WITH_BUILT_CLANG" = "1"; then
 669    AC_MSG_RESULT([built])
 670 else
 671    AC_MSG_RESULT([none])
 672 fi
 673 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 674 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 675 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 676
 677 dnl Override the option to use for optimized builds.
 678 AC_ARG_WITH(optimize-option,
 679   AS_HELP_STRING([--with-optimize-option],
 680                  [Select the compiler options to use for optimized builds]),,
 681                  withval=default)
 682 AC_MSG_CHECKING([optimization flags])
 683 case "$withval" in
 684   default)
 685     case "$llvm_cv_os_type" in
 686     MingW) optimize_option=-O3 ;;
 687     *)     optimize_option=-O2 ;;
 688     esac ;;
 689   *) optimize_option="$withval" ;;
 690 esac
 691 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 692 AC_MSG_RESULT([$optimize_option])
 693
 694 dnl Specify extra build options
 695 AC_ARG_WITH(extra-options,
 696   AS_HELP_STRING([--with-extra-options],
 697                  [Specify additional options to compile LLVM with]),,
 698                  withval=default)
 699 case "$withval" in
 700   default) EXTRA_OPTIONS= ;;
 701   *) EXTRA_OPTIONS=$withval ;;
 702 esac
 703 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 704
 705 dnl Allow specific bindings to be specified for building (or not)
 706 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 707     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 708     enableval=default)
 709 BINDINGS_TO_BUILD=""
 710 case "$enableval" in
 711   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 712   all ) BINDINGS_TO_BUILD="ocaml" ;;
 713   none | no) BINDINGS_TO_BUILD="" ;;
 714   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 715       case "$a_binding" in
 716         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 717         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 718       esac
 719   done
 720   ;;
 721 esac
 722
 723 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 724 dnl script for bindings/ocaml/configure, except that its auto value depends on
 725 dnl OCAMLC, which is found here to support tests.
 726 AC_ARG_WITH([ocaml-libdir],
 727   [AS_HELP_STRING([--with-ocaml-libdir],
 728     [Specify install location for ocaml bindings (default is stdlib)])],
 729   [],
 730   [withval=auto])
 731 case "$withval" in
 732   auto) with_ocaml_libdir="$withval" ;;
 733   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 734   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 735 esac
 736
 737 AC_ARG_WITH(c-include-dirs,
 738   AS_HELP_STRING([--with-c-include-dirs],
 739     [Colon separated list of directories clang will search for headers]),,
 740     withval="")
 741 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 742                    [Directories clang will search for headers])
 743
 744 AC_ARG_WITH(cxx-include-root,
 745   AS_HELP_STRING([--with-cxx-include-root],
 746     [Directory with the libstdc++ headers.]),,
 747     withval="")
 748 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 749                    [Directory with the libstdc++ headers.])
 750
 751 AC_ARG_WITH(cxx-include-arch,
 752   AS_HELP_STRING([--with-cxx-include-arch],
 753     [Architecture of the libstdc++ headers.]),,
 754     withval="")
 755 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 756                    [Arch the libstdc++ headers.])
 757
 758 AC_ARG_WITH(cxx-include-32bit-dir,
 759   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 760     [32 bit multilib dir.]),,
 761     withval="")
 762 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 763                    [32 bit multilib directory.])
 764
 765 AC_ARG_WITH(cxx-include-64bit-dir,
 766   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 767     [64 bit multilib directory.]),,
 768     withval="")
 769 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 770                    [64 bit multilib directory.])
 771
 772 dnl Allow linking of LLVM with GPLv3 binutils code.
 773 AC_ARG_WITH(binutils-include,
 774   AS_HELP_STRING([--with-binutils-include],
 775     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 776   withval=default)
 777 case "$withval" in
 778   default) WITH_BINUTILS_INCDIR=default ;;
 779   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 780   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 781 esac
 782 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 783   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 784   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 785      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 786      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 787   fi
 788 fi
 789
 790 dnl --enable-libffi : check whether the user wants to turn off libffi:
 791 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 792   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 793   [case "$enableval" in
 794     yes) llvm_cv_enable_libffi="yes" ;;
 795     no)  llvm_cv_enable_libffi="no"  ;;
 796     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 797   esac],
 798   llvm_cv_enable_libffi=no)
 799
 800 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 801 if test "$llvm_cv_os_type" = "Win32" ; then
 802    llvmc_dynamic="yes"
 803 else
 804    llvmc_dynamic="no"
 805 fi
 806
 807 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 808 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 809 --enable-llvmc-dynamic,
 810 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 811 enableval=$llvmc_dynamic)
 812 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 813    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 814 else
 815    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 816 fi
 817
 818 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 819 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 820 --enable-llvmc-dynamic-plugins,
 821 [Enable dynamic LLVMC plugins (default is YES)]),,
 822 enableval=yes)
 823 if test ${enableval} = "yes" ; then
 824    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 825 else
 826    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 827 fi
 828
 829 dnl===-----------------------------------------------------------------------===
 830 dnl===
 831 dnl=== SECTION 4: Check for programs we need and that they are the right version
 832 dnl===
 833 dnl===-----------------------------------------------------------------------===
 834
 835 dnl Check for compilation tools
 836 AC_PROG_CPP
 837 AC_PROG_CC(gcc)
 838 AC_PROG_CXX(g++)
 839
 840 AC_PROG_NM
 841 AC_SUBST(NM)
 842
 843 dnl Check for the tools that the makefiles require
 844 AC_CHECK_GNU_MAKE
 845 AC_PROG_LN_S
 846 AC_PATH_PROG(CMP, [cmp], [cmp])
 847 AC_PATH_PROG(CP, [cp], [cp])
 848 AC_PATH_PROG(DATE, [date], [date])
 849 AC_PATH_PROG(FIND, [find], [find])
 850 AC_PATH_PROG(GREP, [grep], [grep])
 851 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 852 AC_PATH_PROG(MV,   [mv],   [mv])
 853 AC_PROG_RANLIB
 854 AC_CHECK_TOOL(AR, ar, false)
 855 AC_PATH_PROG(RM,   [rm],   [rm])
 856 AC_PATH_PROG(SED,  [sed],  [sed])
 857 AC_PATH_PROG(TAR,  [tar],  [gtar])
 858 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 859
 860 dnl Looking for misc. graph plotting software
 861 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 862 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 863   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 864   dnl If we're targeting for mingw we should emit windows paths, not msys
 865   if test "$llvm_cv_os_type" = "MingW" ; then
 866     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 867   fi
 868   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 869    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 870 fi
 871 AC_PATH_PROG(DOT, [dot], [echo dot])
 872 if test "$DOT" != "echo dot" ; then
 873   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 874   dnl If we're targeting for mingw we should emit windows paths, not msys
 875   if test "$llvm_cv_os_type" = "MingW" ; then
 876     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 877   fi
 878   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 879    [Define to path to dot program if found or 'echo dot' otherwise])
 880 fi
 881 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 882 if test "$FDP" != "echo fdp" ; then
 883   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 884   dnl If we're targeting for mingw we should emit windows paths, not msys
 885   if test "$llvm_cv_os_type" = "MingW" ; then
 886     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 887   fi
 888   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 889    [Define to path to fdp program if found or 'echo fdp' otherwise])
 890 fi
 891 AC_PATH_PROG(NEATO, [neato], [echo neato])
 892 if test "$NEATO" != "echo neato" ; then
 893   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 894   dnl If we're targeting for mingw we should emit windows paths, not msys
 895   if test "$llvm_cv_os_type" = "MingW" ; then
 896     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 897   fi
 898   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 899    [Define to path to neato program if found or 'echo neato' otherwise])
 900 fi
 901 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 902 if test "$TWOPI" != "echo twopi" ; then
 903   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 904   dnl If we're targeting for mingw we should emit windows paths, not msys
 905   if test "$llvm_cv_os_type" = "MingW" ; then
 906     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 907   fi
 908   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 909    [Define to path to twopi program if found or 'echo twopi' otherwise])
 910 fi
 911 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 912 if test "$CIRCO" != "echo circo" ; then
 913   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 914   dnl If we're targeting for mingw we should emit windows paths, not msys
 915   if test "$llvm_cv_os_type" = "MingW" ; then
 916     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 917   fi
 918   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 919    [Define to path to circo program if found or 'echo circo' otherwise])
 920 fi
 921 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 922 if test "$GV" != "echo gv" ; then
 923   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 924   dnl If we're targeting for mingw we should emit windows paths, not msys
 925   if test "$llvm_cv_os_type" = "MingW" ; then
 926     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 927   fi
 928   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 929    [Define to path to gv program if found or 'echo gv' otherwise])
 930 fi
 931 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 932 if test "$DOTTY" != "echo dotty" ; then
 933   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 934   dnl If we're targeting for mingw we should emit windows paths, not msys
 935   if test "$llvm_cv_os_type" = "MingW" ; then
 936     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 937   fi
 938   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 939    [Define to path to dotty program if found or 'echo dotty' otherwise])
 940 fi
 941
 942 dnl Look for a sufficiently recent version of Perl.
 943 LLVM_PROG_PERL([5.006])
 944 AC_SUBST(PERL)
 945 if test x"$PERL" = xnone; then
 946    AC_SUBST(HAVE_PERL,0)
 947    AC_MSG_ERROR([perl is required but was not found, please install it])
 948 else
 949    AC_SUBST(HAVE_PERL,1)
 950 fi
 951
 952 dnl Find the install program
 953 AC_PROG_INSTALL
 954
 955 dnl Checks for documentation and testing tools that we can do without. If these
 956 dnl are not found then they are set to "true" which always succeeds but does
 957 dnl nothing. This just lets the build output show that we could have done
 958 dnl something if the tool was available.
 959 AC_PATH_PROG(BZIP2, [bzip2])
 960 AC_PATH_PROG(DOXYGEN, [doxygen])
 961 AC_PATH_PROG(GROFF, [groff])
 962 AC_PATH_PROG(GZIP, [gzip])
 963 AC_PATH_PROG(POD2HTML, [pod2html])
 964 AC_PATH_PROG(POD2MAN, [pod2man])
 965 AC_PATH_PROG(RUNTEST, [runtest])
 966 DJ_AC_PATH_TCLSH
 967 AC_PATH_PROG(ZIP, [zip])
 968 AC_PATH_PROGS(OCAMLC, [ocamlc])
 969 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 970 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 971 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 972 AC_PATH_PROGS(GAS, [gas as])
 973
 974 dnl Determine whether the linker supports the -R option.
 975 AC_LINK_USE_R
 976
 977 dnl Determine whether the linker supports the -export-dynamic option.
 978 AC_LINK_EXPORT_DYNAMIC
 979
 980 dnl Check for libtool and the library that has dlopen function (which must come
 981 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 982 dnl libtool).
 983 AC_LIBTOOL_DLOPEN
 984 AC_LIB_LTDL
 985
 986 if test "$WITH_LLVMGCCDIR" = "default" ; then
 987   LLVMGCC="llvm-gcc${EXEEXT}"
 988   LLVMGXX="llvm-g++${EXEEXT}"
 989   LLVMGCCCOMMAND="$LLVMGCC"
 990   LLVMGXXCOMMAND="$LLVMGXX"
 991   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 992   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 993   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 994   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 995 else
 996   if test -z "$LLVMGCC"; then
 997     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 998     LLVMGCCCOMMAND="$LLVMGCC"
 999   fi
1000   if test -z "$LLVMGXX"; then
1001     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1002     LLVMGXXCOMMAND="$LLVMGXX"
1003   fi
1004
1005   AC_SUBST(LLVMGCC,$LLVMGCC)
1006   AC_SUBST(LLVMGXX,$LLVMGXX)
1007   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1008   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1009 fi
1010
1011 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1012 dnl found, otherwise clang if available.
1013 AC_ARG_WITH(llvmcc,
1014   AS_HELP_STRING([--with-llvmcc=<name>],
1015     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1016     [],[with_llvmcc=check])
1017 AC_MSG_CHECKING([LLVM capable compiler])
1018 if test "$with_llvmcc" != "check"; then
1019    if (test "$with_llvmcc" != "llvm-gcc" &&
1020        test "$with_llvmcc" != "clang" &&
1021        test "$with_llvmcc" != "none"); then
1022       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1023    fi
1024    WITH_LLVMCC="$with_llvmcc"
1025 elif test -n "$LLVMGCC"; then
1026    WITH_LLVMCC=llvm-gcc
1027 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1028    WITH_LLVMCC=clang
1029 else
1030    WITH_LLVMCC=none
1031 fi
1032 AC_MSG_RESULT([$WITH_LLVMCC])
1033 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1034
1035 AC_MSG_CHECKING([tool compatibility])
1036
1037 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1038 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1039 dnl to support those options.
1040 dnl "icc" emits gcc signatures
1041 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1042 ICC=no
1043 IXX=no
1044 case $CC in
1045   icc*|icpc*)
1046     ICC=yes
1047     IXX=yes
1048     ;;
1049    *)
1050     ;;
1051 esac
1052
1053 if test "$GCC" != "yes" && test "$ICC" != "yes"
1054 then
1055   AC_MSG_ERROR([gcc|icc required but not found])
1056 fi
1057
1058 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1059 if test "$GXX" != "yes" && test "$IXX" != "yes"
1060 then
1061   AC_MSG_ERROR([g++|icc required but not found])
1062 fi
1063
1064 dnl Verify that GCC is version 3.0 or higher
1065 if test "$GCC" = "yes"
1066 then
1067   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1068 #error Unsupported GCC version
1069 #endif
1070 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1071 fi
1072
1073 dnl Check for GNU Make.  We use its extensions, so don't build without it
1074 if test -z "$llvm_cv_gnu_make_command"
1075 then
1076   AC_MSG_ERROR([GNU Make required but not found])
1077 fi
1078
1079 dnl Tool compatibility is okay if we make it here.
1080 AC_MSG_RESULT([ok])
1081
1082 dnl Check optional compiler flags.
1083 AC_MSG_CHECKING([optional compiler flags])
1084 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1085 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1086 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1087
1088 dnl===-----------------------------------------------------------------------===
1089 dnl===
1090 dnl=== SECTION 5: Check for libraries
1091 dnl===
1092 dnl===-----------------------------------------------------------------------===
1093
1094 AC_CHECK_LIB(m,sin)
1095 if test "$llvm_cv_os_type" = "MingW" ; then
1096   AC_CHECK_LIB(imagehlp, main)
1097   AC_CHECK_LIB(psapi, main)
1098 fi
1099
1100 dnl dlopen() is required for plugin support.
1101 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1102                [Define if dlopen() is available on this platform.]),
1103                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1104
1105 dnl libffi is optional; used to call external functions from the interpreter
1106 if test "$llvm_cv_enable_libffi" = "yes" ; then
1107   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1108                  [Define if libffi is available on this platform.]),
1109                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1110 fi
1111
1112 dnl mallinfo is optional; the code can compile (minus features) without it
1113 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1114                [Define if mallinfo() is available on this platform.]))
1115
1116 dnl pthread locking functions are optional - but llvm will not be thread-safe
1117 dnl without locks.
1118 if test "$ENABLE_THREADS" -eq 1 ; then
1119   AC_CHECK_LIB(pthread, pthread_mutex_init)
1120   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1121                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1122                            [Have pthread_mutex_lock]))
1123   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1124                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1125                  [Have pthread_rwlock_init]))
1126   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1127                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1128                  [Have pthread_getspecific]))
1129 fi
1130
1131 dnl Allow extra x86-disassembler library
1132 AC_ARG_WITH(udis86,
1133   AS_HELP_STRING([--with-udis86=<path>],
1134     [Use udis86 external x86 disassembler library]),
1135     [
1136       AC_SUBST(USE_UDIS86, [1])
1137       case "$withval" in
1138         /usr/lib|yes) ;;
1139         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1140       esac
1141       AC_CHECK_LIB(udis86, ud_init, [], [
1142         echo "Error! You need to have libudis86 around."
1143         exit -1
1144       ])
1145     ],
1146     AC_SUBST(USE_UDIS86, [0]))
1147 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1148                    [Define if use udis86 library])
1149
1150 dnl Allow OProfile support for JIT output.
1151 AC_ARG_WITH(oprofile,
1152   AS_HELP_STRING([--with-oprofile=<prefix>],
1153     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1154     [
1155       AC_SUBST(USE_OPROFILE, [1])
1156       case "$withval" in
1157         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1158         no) llvm_cv_oppath=
1159             AC_SUBST(USE_OPROFILE, [0]) ;;
1160         *) llvm_cv_oppath="${withval}/lib/oprofile"
1161            CPPFLAGS="-I${withval}/include";;
1162       esac
1163       if test -n "$llvm_cv_oppath" ; then
1164         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1165         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1166         dnl libbfd is not included properly in libopagent in some Debian
1167         dnl versions.  If libbfd isn't found at all, we assume opagent works
1168         dnl anyway.
1169         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1170         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1171           echo "Error! You need to have libopagent around."
1172           exit -1
1173         ])
1174         AC_CHECK_HEADER([opagent.h], [], [
1175           echo "Error! You need to have opagent.h around."
1176           exit -1
1177           ])
1178       fi
1179     ],
1180     [
1181       AC_SUBST(USE_OPROFILE, [0])
1182     ])
1183 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1184                    [Define if we have the oprofile JIT-support library])
1185
1186 dnl===-----------------------------------------------------------------------===
1187 dnl===
1188 dnl=== SECTION 6: Check for header files
1189 dnl===
1190 dnl===-----------------------------------------------------------------------===
1191
1192 dnl First, use autoconf provided macros for specific headers that we need
1193 dnl We don't check for ancient stuff or things that are guaranteed to be there
1194 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1195 dnl Generally we're looking for POSIX headers.
1196 AC_HEADER_DIRENT
1197 AC_HEADER_MMAP_ANONYMOUS
1198 AC_HEADER_STAT
1199 AC_HEADER_STDC
1200 AC_HEADER_SYS_WAIT
1201 AC_HEADER_TIME
1202
1203 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1204 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1205 AC_CHECK_HEADERS([utime.h windows.h])
1206 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1207 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1208 if test "$ENABLE_THREADS" -eq 1 ; then
1209   AC_CHECK_HEADERS(pthread.h,
1210                    AC_SUBST(HAVE_PTHREAD, 1),
1211                    AC_SUBST(HAVE_PTHREAD, 0))
1212 else
1213   AC_SUBST(HAVE_PTHREAD, 0)
1214 fi
1215
1216 dnl Try to find ffi.h.
1217 if test "$llvm_cv_enable_libffi" = "yes" ; then
1218   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1219 fi
1220
1221 dnl===-----------------------------------------------------------------------===
1222 dnl===
1223 dnl=== SECTION 7: Check for types and structures
1224 dnl===
1225 dnl===-----------------------------------------------------------------------===
1226
1227 AC_HUGE_VAL_CHECK
1228 AC_TYPE_PID_T
1229 AC_TYPE_SIZE_T
1230 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1231 AC_STRUCT_TM
1232 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1233 AC_CHECK_TYPES([uint64_t],,
1234          AC_CHECK_TYPES([u_int64_t],,
1235          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1236
1237 dnl===-----------------------------------------------------------------------===
1238 dnl===
1239 dnl=== SECTION 8: Check for specific functions needed
1240 dnl===
1241 dnl===-----------------------------------------------------------------------===
1242
1243 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1244 AC_CHECK_FUNCS([powf fmodf strtof round ])
1245 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1246 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1247 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1248 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1249 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1250 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1251 AC_C_PRINTF_A
1252 AC_FUNC_RAND48
1253
1254 dnl Check for variations in the Standard C++ library and STL. These macros are
1255 dnl provided by LLVM in the autoconf/m4 directory.
1256 AC_FUNC_ISNAN
1257 AC_FUNC_ISINF
1258
1259 dnl Check for mmap support.We also need to know if /dev/zero is required to
1260 dnl be opened for allocating RWX memory.
1261 dnl Make sure we aren't attempting to configure for an unknown system
1262 if test "$llvm_cv_platform_type" = "Unix" ; then
1263   AC_FUNC_MMAP
1264   AC_FUNC_MMAP_FILE
1265   AC_NEED_DEV_ZERO_FOR_MMAP
1266
1267   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1268   then
1269     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1270   fi
1271   if test "$ac_cv_func_mmap_file" = "no"
1272   then
1273     AC_MSG_WARN([mmap() of files required but not found])
1274   fi
1275 fi
1276
1277 dnl atomic builtins are required for threading support.
1278 AC_MSG_CHECKING(for GCC atomic builtins)
1279 AC_LINK_IFELSE(
1280   AC_LANG_SOURCE(
1281     [[int main() {
1282         volatile unsigned long val = 1;
1283         __sync_synchronize();
1284         __sync_val_compare_and_swap(&val, 1, 0);
1285         __sync_add_and_fetch(&val, 1);
1286         __sync_sub_and_fetch(&val, 1);
1287         return 0;
1288       }
1289     ]]),
1290   AC_MSG_RESULT(yes)
1291   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1292   AC_MSG_RESULT(no)
1293   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1294   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1295
1296
1297 dnl===-----------------------------------------------------------------------===
1298 dnl===
1299 dnl=== SECTION 9: Additional checks, variables, etc.
1300 dnl===
1301 dnl===-----------------------------------------------------------------------===
1302
1303 dnl Handle 32-bit linux systems running a 64-bit kernel.
1304 dnl This has to come after section 4 because it invokes the compiler.
1305 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1306   AC_IS_LINUX_MIXED
1307   if test "$llvm_cv_linux_mixed" = "yes"; then
1308     llvm_cv_target_arch="x86"
1309     ARCH="x86"
1310   fi
1311 fi
1312
1313 dnl Check, whether __dso_handle is present
1314 AC_CHECK_FUNCS([__dso_handle])
1315
1316 dnl See if the llvm-gcc executable can compile to LLVM assembly
1317 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1318 [llvm_cv_llvmgcc_sanity="no"
1319 if test -x "$LLVMGCC" ; then
1320   cp /dev/null conftest.c
1321   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1322       grep 'target datalayout =' > /dev/null 2>&1
1323   if test $? -eq 0 ; then
1324     llvm_cv_llvmgcc_sanity="yes"
1325   fi
1326   rm conftest.c
1327 fi])
1328
1329 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1330 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1331   AC_MSG_CHECKING([llvm-gcc component support])
1332   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1333   AC_SUBST(LLVMCC1,$llvmcc1path)
1334   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1335   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1336   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1337   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1338   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1339   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1340   AC_MSG_RESULT([ok])
1341 fi
1342
1343 dnl Propagate the shared library extension that the libltdl checks did to
1344 dnl the Makefiles so we can use it there too
1345 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1346
1347 dnl Propagate the run-time library path variable that the libltdl
1348 dnl checks found to the Makefiles so we can use it there too
1349 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1350
1351 # Translate the various configuration directories and other basic
1352 # information into substitutions that will end up in Makefile.config.in
1353 # that these configured values can be used by the makefiles
1354 if test "${prefix}" = "NONE" ; then
1355   prefix="/usr/local"
1356 fi
1357 eval LLVM_PREFIX="${prefix}";
1358 eval LLVM_BINDIR="${prefix}/bin";
1359 eval LLVM_LIBDIR="${prefix}/lib";
1360 eval LLVM_DATADIR="${prefix}/share/llvm";
1361 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1362 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1363 eval LLVM_INCLUDEDIR="${prefix}/include";
1364 eval LLVM_INFODIR="${prefix}/info";
1365 eval LLVM_MANDIR="${prefix}/man";
1366 LLVM_CONFIGTIME=`date`
1367 AC_SUBST(LLVM_PREFIX)
1368 AC_SUBST(LLVM_BINDIR)
1369 AC_SUBST(LLVM_LIBDIR)
1370 AC_SUBST(LLVM_DATADIR)
1371 AC_SUBST(LLVM_DOCSDIR)
1372 AC_SUBST(LLVM_ETCDIR)
1373 AC_SUBST(LLVM_INCLUDEDIR)
1374 AC_SUBST(LLVM_INFODIR)
1375 AC_SUBST(LLVM_MANDIR)
1376 AC_SUBST(LLVM_CONFIGTIME)
1377
1378 # Place the various directores into the config.h file as #defines so that we
1379 # can know about the installation paths within LLVM.
1380 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1381                    [Installation prefix directory])
1382 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1383                    [Installation directory for binary executables])
1384 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1385                    [Installation directory for libraries])
1386 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1387                    [Installation directory for data files])
1388 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1389                    [Installation directory for documentation])
1390 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1391                    [Installation directory for config files])
1392 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1393                    [Installation directory for include files])
1394 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1395                    [Installation directory for .info files])
1396 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1397                    [Installation directory for man pages])
1398 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1399                    [Time at which LLVM was configured])
1400 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1401                    [Host triple we were built on])
1402
1403 # Determine which bindings to build.
1404 if test "$BINDINGS_TO_BUILD" = auto ; then
1405   BINDINGS_TO_BUILD=""
1406   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1407     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1408   fi
1409 fi
1410 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1411
1412 # This isn't really configurey, but it avoids having to repeat the list in
1413 # other files.
1414 AC_SUBST(ALL_BINDINGS,ocaml)
1415
1416 # Do any work necessary to ensure that bindings have what they need.
1417 binding_prereqs_failed=0
1418 for a_binding in $BINDINGS_TO_BUILD ; do
1419   case "$a_binding" in
1420   ocaml)
1421     if test "x$OCAMLC" = x ; then
1422       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1423       binding_prereqs_failed=1
1424     fi
1425     if test "x$OCAMLDEP" = x ; then
1426       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1427       binding_prereqs_failed=1
1428     fi
1429     if test "x$OCAMLOPT" = x ; then
1430       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1431       dnl ocamlopt is optional!
1432     fi
1433     if test "x$with_ocaml_libdir" != xauto ; then
1434       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1435     else
1436       ocaml_stdlib="`"$OCAMLC" -where`"
1437       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1438       then
1439         # ocaml stdlib is beneath our prefix; use stdlib
1440         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1441       else
1442         # ocaml stdlib is outside our prefix; use libdir/ocaml
1443         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1444       fi
1445     fi
1446     ;;
1447   esac
1448 done
1449 if test "$binding_prereqs_failed" = 1 ; then
1450   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1451 fi
1452
1453 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1454 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1455
1456 dnl Determine linker rpath flag
1457 if test "$llvm_cv_link_use_r" = "yes" ; then
1458   RPATH="-Wl,-R"
1459 else
1460   RPATH="-Wl,-rpath"
1461 fi
1462 AC_SUBST(RPATH)
1463
1464 dnl Determine linker rdynamic flag
1465 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1466   RDYNAMIC="-Wl,-export-dynamic"
1467 else
1468   RDYNAMIC=""
1469 fi
1470 AC_SUBST(RDYNAMIC)
1471
1472 dnl===-----------------------------------------------------------------------===
1473 dnl===
1474 dnl=== SECTION 10: Specify the output files and generate it
1475 dnl===
1476 dnl===-----------------------------------------------------------------------===
1477
1478 dnl Configure header files
1479 dnl WARNING: dnl If you add or remove any of the following config headers, then
1480 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1481 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1482 dnl files can be updated automatically when their *.in sources change.
1483 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1484 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1485 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1486 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1487 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1488 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1489
1490 dnl Configure the makefile's configuration data
1491 AC_CONFIG_FILES([Makefile.config])
1492
1493 dnl Configure the RPM spec file for LLVM
1494 AC_CONFIG_FILES([llvm.spec])
1495
1496 dnl Configure doxygen's configuration file
1497 AC_CONFIG_FILES([docs/doxygen.cfg])
1498
1499 dnl Configure llvmc's Base plugin
1500 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1501
1502 dnl Do the first stage of configuration for llvm-config.in.
1503 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1504
1505 dnl Do special configuration of Makefiles
1506 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1507 AC_CONFIG_MAKEFILE(Makefile)
1508 AC_CONFIG_MAKEFILE(Makefile.common)
1509 AC_CONFIG_MAKEFILE(examples/Makefile)
1510 AC_CONFIG_MAKEFILE(lib/Makefile)
1511 AC_CONFIG_MAKEFILE(runtime/Makefile)
1512 AC_CONFIG_MAKEFILE(test/Makefile)
1513 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1514 AC_CONFIG_MAKEFILE(unittests/Makefile)
1515 AC_CONFIG_MAKEFILE(tools/Makefile)
1516 AC_CONFIG_MAKEFILE(utils/Makefile)
1517 AC_CONFIG_MAKEFILE(projects/Makefile)
1518 AC_CONFIG_MAKEFILE(bindings/Makefile)
1519 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1520
1521 dnl Finally, crank out the output
1522 AC_OUTPUT