autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([support for generic build operating system],
 101                [llvm_cv_platform_type],
 102 [case $build in
 103   *-*-aix*) llvm_cv_platform_type="AIX" ;;
 104   *-*-cygwin*) llvm_cv_platform_type="Cygwin" ;;
 105   *-*-darwin*) llvm_cv_platform_type="Darwin" ;;
 106   *-*-freebsd*) llvm_cv_platform_type="FreeBSD" ;;
 107   *-*-interix*) llvm_cv_platform_type="Interix" ;;
 108   *-*-linux*) llvm_cv_platform_type="Linux" ;;
 109   *-*-solaris*) llvm_cv_platform_type="SunOS" ;;
 110   *-*-win32*) llvm_cv_platform_type="Win32" ;;
 111   *-*-mingw*) llvm_cv_platform_type="Win32" ;;
 112   *) llvm_cv_platform_type="Unknown" ;;
 113 esac])
 114
 115 dnl Make sure we aren't attempting to configure for an unknown system
 116 if test "$llvm_cv_platform_type" = "Unknown" ; then
 117   AC_MSG_ERROR([Operating system platform is unknown, configure can't continue])
 118 fi
 119
 120 dnl Set the "OS" Makefile variable based on the platform type so the
 121 dnl makefile can configure itself to specific build hosts
 122 AC_SUBST(OS,$llvm_cv_platform_type)
 123
 124 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_platform_type
 125 dnl This helps the #inclusion of the system specific include files
 126 dnl for the operating system abstraction library, lib/System.
 127 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_platform_type)
 128
 129 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 130 dnl V9, since that is all that we support at the moment, and autoconf will only
 131 dnl tell us we're a sparc.
 132 case $target in
 133   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 134   ;;
 135 esac
 136
 137 dnl Determine what our target architecture is and configure accordingly.
 138 dnl This will allow Makefiles to make a distinction between the hardware and
 139 dnl the OS.
 140 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 141 [case $target in
 142   i?86-*)                 llvm_cv_target_arch="x86" ;;
 143   amd64-* | x86_64-*)     llvm_cv_target_arch="AMD64" ;;
 144   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 145   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 146   *)                      llvm_cv_target_arch="Unknown" ;;
 147 esac])
 148
 149 if test "$llvm_cv_target_arch" = "Unknown" ; then
 150   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 151 fi
 152
 153 dnl Define a substitution, ARCH, for the target architecture
 154 AC_SUBST(ARCH,$llvm_cv_target_arch)
 155
 156 dnl Check for the endianness of the target
 157 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 158
 159 dnl===-----------------------------------------------------------------------===
 160 dnl===
 161 dnl=== SECTION 3: Command line arguments for the configure script.
 162 dnl===
 163 dnl===-----------------------------------------------------------------------===
 164
 165 dnl --enable-optimized : check whether they want to do an optimized build:
 166 AC_ARG_ENABLE(optimized,
 167               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 168 if test ${enableval} = "no" ; then
 169   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 170 else
 171   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 172 fi
 173
 174 dnl --enable-jit: check whether they want to enable the jit
 175 AC_ARG_ENABLE(jit,
 176   AS_HELP_STRING(--enable-jit,
 177                  [Enable Just In Time Compiling (default is YES)]),,
 178   enableval=default)
 179 if test ${enableval} = "no"
 180 then
 181   AC_SUBST(JIT,[[]])
 182 else
 183   case "$llvm_cv_target_arch" in
 184     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 185     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 186     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 187     AMD64)   AC_SUBST(JIT,[[]]) ;;
 188     *)       AC_SUBST(JIT,[[]]) ;;
 189   esac
 190 fi
 191
 192 dnl Allow enablement of doxygen generated documentation
 193 AC_ARG_ENABLE(doxygen,
 194               AS_HELP_STRING([--enable-doxygen],
 195                              [Build doxygen documentation (default is NO)]),,
 196                              enableval=default)
 197 case "$enableval" in
 198   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 199   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 200   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 201   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 202 esac
 203
 204 dnl===-----------------------------------------------------------------------===
 205 dnl===
 206 dnl=== SECTION 4: Check for programs we need and that they are the right version
 207 dnl===
 208 dnl===-----------------------------------------------------------------------===
 209
 210 dnl Check for compilation tools
 211 AC_PROG_CPP
 212 AC_PROG_CC(gcc)
 213 AC_PROG_CXX(g++)
 214 AC_PROG_FLEX
 215 AC_PROG_BISON
 216
 217 dnl Check for the tools that the makefiles require
 218 AC_CHECK_GNU_MAKE
 219 AC_PROG_LN_S
 220 AC_PATH_PROG(CMP, [cmp], [cmp])
 221 AC_PATH_PROG(CP, [cp], [cp])
 222 AC_PATH_PROG(DATE, [date], [date])
 223 AC_PATH_PROG(FIND, [find], [find])
 224 AC_PATH_PROG(GREP, [grep], [grep])
 225 AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 226 AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 227 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 228 AC_PATH_PROG(MV,   [mv],   [mv])
 229 AC_PATH_PROG(PAX,  [pax],  [pax])
 230 AC_PROG_RANLIB
 231 AC_PATH_PROG(RM,   [rm],   [rm])
 232 AC_PATH_PROG(SED,  [sed],  [sed])
 233 AC_PATH_PROG(TAR,  [tar],  [gtar])
 234
 235 dnl Find the install program
 236 AC_PROG_INSTALL
 237
 238 dnl Checks for documentation and testing tools that we can do without. If these
 239 dnl are not found then they are set to "true" which always succeeds but does
 240 dnl nothing. This just lets the build output show that we could have done
 241 dnl something if the tool was available.
 242 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 243 AC_PATH_PROG(DOT,[dot],[true dot])
 244 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 245 AC_PATH_PROG(ETAGS,[etags],[true etags])
 246 AC_PATH_PROG(GROFF,[groff],[true groff])
 247 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 248 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 249 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 250 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 251 DJ_AC_PATH_TCLSH
 252 AC_PATH_PROG(ZIP,[zip],[true zip])
 253
 254 dnl Determine if the linker supports the -R option.
 255 AC_LINK_USE_R
 256
 257 dnl Check for libtool and the library that has dlopen function (which must come
 258 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 259 dnl libtool).
 260 AC_LIBTOOL_DLOPEN
 261 AC_LIB_LTDL
 262 AC_PROG_LIBTOOL
 263
 264 dnl Check if we know how to tell etags we are using C++:
 265 etags_version=`$ETAGS --version 2>&1`
 266 case "$etags_version" in
 267         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 268         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 269         *) ETAGSFLAGS="" ;;
 270 esac
 271 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 272
 273 AC_MSG_CHECKING([tool compatibility])
 274
 275 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 276 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 277 dnl to support those options.
 278 dnl "icc" emits gcc signatures
 279 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 280 ICC=no
 281 IXX=no
 282 case $CC in
 283   icc*|icpc*)
 284     ICC=yes
 285     IXX=yes
 286     ;;
 287    *)
 288     ;;
 289 esac
 290
 291 if test "$GCC" != "yes" && test "$ICC" != "yes"
 292 then
 293   AC_MSG_ERROR([gcc|icc required but not found])
 294 fi
 295
 296 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 297 if test "$GXX" != "yes" && test "$IXX" != "yes"
 298 then
 299   AC_MSG_ERROR([g++|icc required but not found])
 300 fi
 301
 302 dnl Verify that GCC is version 3.0 or higher
 303 if test "$GCC" = "yes"
 304 then
 305   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 306   if test "$gccmajor" -lt "3"
 307   then
 308     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 309   fi
 310 fi
 311
 312 dnl Check for GNU Make.  We use its extensions, so don't build without it
 313 if test -z "$llvm_cv_gnu_make_command"
 314 then
 315   AC_MSG_ERROR([GNU Make required but not found])
 316 fi
 317
 318 dnl Tool compatibility is okay if we make it here.
 319 AC_MSG_RESULT([ok])
 320
 321 dnl===-----------------------------------------------------------------------===
 322 dnl===
 323 dnl=== SECTION 5: Check for libraries
 324 dnl===
 325 dnl===-----------------------------------------------------------------------===
 326
 327 dnl libelf is for sparc only; we can ignore it if we don't have it
 328 AC_CHECK_LIB(elf, elf_begin)
 329
 330 dnl lt_dlopen may be required for plugin support.
 331 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 332               [Define if lt_dlopen() is available on this platform]),
 333               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 334                            not be available]))
 335
 336 dnl dlopen() is required for plugin support.
 337 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 338                [Define if dlopen() is available on this platform.]),
 339                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 340
 341 dnl mallinfo is optional; the code can compile (minus features) without it
 342 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 343                [Define if mallinfo() is available on this platform.]))
 344
 345 dnl pthread locking functions are optional - but llvm will not be thread-safe
 346 dnl without locks.
 347 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 348                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 349                          [Have pthread_mutex_lock]))
 350
 351 dnl===-----------------------------------------------------------------------===
 352 dnl===
 353 dnl=== SECTION 6: Check for header files
 354 dnl===
 355 dnl===-----------------------------------------------------------------------===
 356
 357 dnl We don't check for ancient stuff or things that are guaranteed to be there
 358 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 359 AC_HEADER_STDC
 360
 361 dnl However, we do need some system specific header files. Generally we're
 362 dnl looking for POSIX headers.
 363 AC_HEADER_SYS_WAIT
 364 AC_CHECK_HEADERS([sys/time.h sys/mman.h sys/resource.h sys/time.h sys/types.h])
 365 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h limits.h link.h])
 366 AC_CHECK_HEADERS([malloc.h unistd.h windows.h])
 367 AC_HEADER_TIME
 368 AC_HEADER_MMAP_ANONYMOUS
 369
 370 dnl Check for things that need to be included in public headers, and so
 371 dnl for which we may not have access to a HAVE_* preprocessor #define.
 372 dnl (primarily used in DataTypes.h)
 373 AC_CHECK_HEADERS([inttypes.h stdint.h])
 374
 375 dnl===-----------------------------------------------------------------------===
 376 dnl===
 377 dnl=== SECTION 7: Check for types and structures
 378 dnl===
 379 dnl===-----------------------------------------------------------------------===
 380
 381 AC_TYPE_PID_T
 382 AC_TYPE_SIZE_T
 383 AC_TYPE_SIGNAL
 384 AC_STRUCT_TM
 385 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 386 AC_CHECK_TYPES([uint64_t],,
 387          AC_CHECK_TYPES([u_int64_t],,
 388          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 389
 390 dnl===-----------------------------------------------------------------------===
 391 dnl===
 392 dnl=== SECTION 8: Check for specific functions needed
 393 dnl===
 394 dnl===-----------------------------------------------------------------------===
 395
 396 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 397 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 398 AC_CHECK_FUNCS([realpath strdup strtoq strtoll sysconf ])
 399 AC_C_PRINTF_A
 400 AC_FUNC_ALLOCA
 401 AC_FUNC_RAND48
 402
 403 dnl Check for variations in the Standard C++ library and STL. These macros are
 404 dnl provided by LLVM in the autoconf/m4 directory.
 405 AC_CXX_HAVE_HASH_MAP
 406 AC_CXX_HAVE_HASH_SET
 407 AC_CXX_HAVE_STD_ITERATOR
 408 AC_CXX_HAVE_BI_ITERATOR
 409 AC_CXX_HAVE_FWD_ITERATOR
 410 AC_FUNC_ISNAN
 411 AC_FUNC_ISINF
 412
 413 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 414 dnl bytecode loading, etc.
 415 AC_FUNC_MMAP
 416 AC_FUNC_MMAP_FILE
 417 AC_CHECK_FUNC(mprotect,,
 418               AC_MSG_ERROR([Function mprotect() required but not found]))
 419
 420 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 421 then
 422   AC_MSG_WARN([mmap() required but not found])
 423 fi
 424 if test "$ac_cv_func_mmap_file" = "no"
 425 then
 426   AC_MSG_WARN([mmap() of files required but not found])
 427 fi
 428
 429 dnl===-----------------------------------------------------------------------===
 430 dnl===
 431 dnl=== SECTION 9: Additional checks, variables, etc.
 432 dnl===
 433 dnl===-----------------------------------------------------------------------===
 434
 435 dnl See if the llvmgcc executable can compile to LLVM assembly
 436 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 437 [llvm_cv_llvmgcc_sanity="no"
 438 if test -x "$LLVMGCC" ; then
 439   cp /dev/null conftest.c
 440   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 441   if test $? -eq 0 ; then
 442     llvm_cv_llvmgcc_sanity="yes"
 443   fi
 444   rm conftest.c
 445 fi])
 446
 447 dnl Since we have a sane llvmgcc, identify it and its sub-tools
 448 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 449   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 450   AC_SUBST(LLVMCC1,$llvmcc1path)
 451   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 452   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 453   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 454   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 455 fi
 456
 457 dnl Propagate the shared library extension that the libltdl checks did to
 458 dnl the Makefiles so we can use it there too
 459 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 460
 461 # Translate the various configuration directories and other basic
 462 # information into substitutions that will end up in Makefile.config.in
 463 # that these configured values can be used by the makefiles
 464 eval LLVM_PREFIX="${prefix}";
 465 eval LLVM_BINDIR="${prefix}/bin";
 466 eval LLVM_LIBDIR="${prefix}/lib";
 467 eval LLVM_DATADIR="${prefix}/share/llvm";
 468 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 469 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 470 eval LLVM_INCLUDEDIR="${prefix}/include";
 471 eval LLVM_INFODIR="${prefix}/info";
 472 eval LLVM_MANDIR="${prefix}/man";
 473 LLVM_CONFIGTIME=`date`
 474 AC_SUBST(LLVM_PREFIX)
 475 AC_SUBST(LLVM_BINDIR)
 476 AC_SUBST(LLVM_LIBDIR)
 477 AC_SUBST(LLVM_DATADIR)
 478 AC_SUBST(LLVM_DOCSDIR)
 479 AC_SUBST(LLVM_ETCDIR)
 480 AC_SUBST(LLVM_INCLUDEDIR)
 481 AC_SUBST(LLVM_INFODIR)
 482 AC_SUBST(LLVM_MANDIR)
 483 AC_SUBST(LLVM_CONFIGTIME)
 484
 485 # Place the various directores into the config.h file as #defines so that we
 486 # can know about the installation paths within LLVM.
 487 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 488                    [Installation prefix directory])
 489 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 490                    [Installation directory for binary executables])
 491 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 492                    [Installation directory for libraries])
 493 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 494                    [Installation directory for data files])
 495 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 496                    [Installation directory for documentation])
 497 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 498                    [Installation directory for config files])
 499 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 500                    [Installation directory for include files])
 501 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 502                    [Installation directory for .info files])
 503 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 504                    [Installation directory for man pages])
 505 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 506                    [Time at which LLVM was configured])
 507
 508 dnl===-----------------------------------------------------------------------===
 509 dnl===
 510 dnl=== SECTION 10: Specify the output files and generate it
 511 dnl===
 512 dnl===-----------------------------------------------------------------------===
 513
 514 dnl Configure header files
 515 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 516
 517 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 518 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 519 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 520 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 521 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 522
 523 dnl Configure the makefile's configuration data
 524 AC_CONFIG_FILES([Makefile.config])
 525
 526 dnl Configure llvmc's configuration files
 527 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 528
 529 dnl Configure doxygen's configuration file
 530 AC_CONFIG_FILES([docs/doxygen.cfg])
 531
 532 dnl Do special configuration of Makefiles
 533 AC_CONFIG_MAKEFILE(Makefile)
 534 AC_CONFIG_MAKEFILE(Makefile.common)
 535 AC_CONFIG_MAKEFILE(examples/Makefile)
 536 AC_CONFIG_MAKEFILE(lib/Makefile)
 537 AC_CONFIG_MAKEFILE(runtime/Makefile)
 538 AC_CONFIG_MAKEFILE(test/Makefile)
 539 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 540 AC_CONFIG_MAKEFILE(tools/Makefile)
 541 AC_CONFIG_MAKEFILE(utils/Makefile)
 542 AC_CONFIG_MAKEFILE(projects/Makefile)
 543
 544 dnl Finally, crank out the output
 545 AC_OUTPUT
 546
 547 dnl Warn loudly if llvm-gcc was not obviously working
 548 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 549  AC_MSG_WARN([***** llvmgcc/llvmg++ was not found, or does not appear to be ])
 550  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 551  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 552  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 553  AC_MSG_WARN([***** build the llvm tools.])
 554 fi