autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.2svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  80       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  81       *)
  82         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  83         ;;
  84     esac
  85   fi
  86 done
  87
  88 dnl===-----------------------------------------------------------------------===
  89 dnl===
  90 dnl=== SECTION 2: Architecture, target, and host checks
  91 dnl===
  92 dnl===-----------------------------------------------------------------------===
  93
  94 dnl Check the target for which we're compiling and the host that will do the
  95 dnl compilations. This will tell us which LLVM compiler will be used for
  96 dnl compiling SSA into object code. This needs to be done early because
  97 dnl following tests depend on it.
  98 AC_CANONICAL_TARGET
  99
 100 dnl Determine the platform type and cache its value. This helps us configure
 101 dnl the System library to the correct build platform.
 102 AC_CACHE_CHECK([type of operating system we're going to host on],
 103                [llvm_cv_os_type],
 104 [case $host in
 105   *-*-aix*)
 106     llvm_cv_link_all_option="-Wl,--whole-archive"
 107     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 108     llvm_cv_os_type="AIX"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-irix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="IRIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-cygwin*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="Cygwin"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-darwin*)
 121     llvm_cv_link_all_option="-Wl,-all_load"
 122     llvm_cv_link_all_option="-Wl,-noall_load"
 123     llvm_cv_os_type="Darwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-freebsd*)
 126     llvm_cv_link_all_option="-Wl,--whole-archive"
 127     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 128     llvm_cv_os_type="FreeBSD"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-openbsd*)
 131     llvm_cv_link_all_option="-Wl,--whole-archive"
 132     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 133     llvm_cv_os_type="OpenBSD"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-netbsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="NetBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-hpux*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="HP-UX"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-interix*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="Interix"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-linux*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="Linux"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-solaris*)
 156     llvm_cv_link_all_option="-Wl,-z,allextract"
 157     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 158     llvm_cv_os_type="SunOS"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-win32*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Win32"
 164     llvm_cv_platform_type="Win32" ;;
 165   *-*-mingw*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="MingW"
 169     llvm_cv_platform_type="Win32" ;;
 170   *)
 171     llvm_cv_link_all_option=""
 172     llvm_cv_no_link_all_option=""
 173     llvm_cv_os_type="Unknown"
 174     llvm_cv_platform_type="Unknown" ;;
 175 esac])
 176
 177 dnl Make sure we aren't attempting to configure for an unknown system
 178 if test "$llvm_cv_os_type" = "Unknown" ; then
 179   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 180 fi
 181
 182 dnl Set the "OS" Makefile variable based on the platform type so the
 183 dnl makefile can configure itself to specific build hosts
 184 AC_SUBST(OS,$llvm_cv_os_type)
 185
 186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 189
 190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 191 dnl This is used by lib/System to determine the basic kind of implementation
 192 dnl to use.
 193 case $llvm_cv_platform_type in
 194   Unix)
 195     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 196     AC_SUBST(LLVM_ON_UNIX,[1])
 197     AC_SUBST(LLVM_ON_WIN32,[0])
 198     ;;
 199   Win32)
 200     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 201     AC_SUBST(LLVM_ON_UNIX,[0])
 202     AC_SUBST(LLVM_ON_WIN32,[1])
 203     ;;
 204 esac
 205
 206 dnl Determine what our target architecture is and configure accordingly.
 207 dnl This will allow Makefiles to make a distinction between the hardware and
 208 dnl the OS.
 209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 210 [case $target in
 211   i?86-*)                 llvm_cv_target_arch="x86" ;;
 212   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 213   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 214   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 215   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 216   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 217   arm-*)                  llvm_cv_target_arch="ARM" ;;
 218   mips-*)                 llvm_cv_target_arch="Mips" ;;
 219   *)                      llvm_cv_target_arch="Unknown" ;;
 220 esac])
 221
 222 if test "$llvm_cv_target_arch" = "Unknown" ; then
 223   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 224 fi
 225
 226 dnl Define a substitution, ARCH, for the target architecture
 227 AC_SUBST(ARCH,$llvm_cv_target_arch)
 228
 229 dnl Check for the endianness of the target
 230 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 231
 232 dnl Check for build platform executable suffix if we're crosscompiling
 233 if test "$cross_compiling" = yes; then
 234   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 235   AC_BUILD_EXEEXT
 236 else
 237   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 238 fi
 239
 240 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 241 dnl build is being done from a checkout. This sets up several defaults for the
 242 dnl command line switches. When we build with a CVS directory, we get a
 243 dnl debug with assertions turned on. Without, we assume a source release and we
 244 dnl get an optimized build without assertions. See --enable-optimized and
 245 dnl --enable-assertions below
 246 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 247   cvsbuild="yes"
 248   optimize="no"
 249   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 250 else
 251   cvsbuild="no"
 252   optimize="yes"
 253 fi
 254
 255 dnl===-----------------------------------------------------------------------===
 256 dnl===
 257 dnl=== SECTION 3: Command line arguments for the configure script.
 258 dnl===
 259 dnl===-----------------------------------------------------------------------===
 260
 261 dnl --enable-optimized : check whether they want to do an optimized build:
 262 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 263  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 264 if test ${enableval} = "no" ; then
 265   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 266 else
 267   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 268 fi
 269
 270 dnl --enable-assertions : check whether they want to turn on assertions or not:
 271 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 272   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 273 if test ${enableval} = "yes" ; then
 274   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 275 else
 276   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 277 fi
 278
 279 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 280 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 281   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 282 if test ${enableval} = "yes" ; then
 283   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 284   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 285 else
 286   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 287   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 288 fi
 289
 290 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 291 AC_ARG_ENABLE(debug-runtime,
 292    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 293 if test ${enableval} = "no" ; then
 294   AC_SUBST(DEBUG_RUNTIME,[[]])
 295 else
 296   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 297 fi
 298
 299 dnl --enable-jit: check whether they want to enable the jit
 300 AC_ARG_ENABLE(jit,
 301   AS_HELP_STRING(--enable-jit,
 302                  [Enable Just In Time Compiling (default is YES)]),,
 303   enableval=default)
 304 if test ${enableval} = "no"
 305 then
 306   AC_SUBST(JIT,[[]])
 307 else
 308   case "$llvm_cv_target_arch" in
 309     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 310     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 311     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 312     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 313     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 314     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 315     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 316     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 317     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 318   esac
 319 fi
 320
 321 dnl Allow enablement of doxygen generated documentation
 322 AC_ARG_ENABLE(doxygen,
 323               AS_HELP_STRING([--enable-doxygen],
 324                              [Build doxygen documentation (default is NO)]),,
 325                              enableval=default)
 326 case "$enableval" in
 327   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 328   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 329   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 330   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 331 esac
 332
 333 dnl Allow disablement of threads
 334 AC_ARG_ENABLE(threads,
 335               AS_HELP_STRING([--enable-threads],
 336                              [Use threads if available (default is YES)]),,
 337                              enableval=default)
 338 case "$enableval" in
 339   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 340   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 341   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 342   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 343 esac
 344 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 345
 346 dnl Allow building with position independent code
 347 AC_ARG_ENABLE(pic,
 348   AS_HELP_STRING([--enable-pic],
 349                  [Build LLVM with Position Independent Code (default is NO)]),,
 350                  enableval=default)
 351 case "$enableval" in
 352   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 353   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 354   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 355   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 356 esac
 357 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 358                    [Define if position independent code is enabled])
 359
 360 dnl Allow specific targets to be specified for building (or not)
 361 TARGETS_TO_BUILD=""
 362 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 363     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 364     enableval=all)
 365 case "$enableval" in
 366   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips" ;;
 367   host-only)
 368     case "$llvm_cv_target_arch" in
 369       x86)     TARGETS_TO_BUILD="X86" ;;
 370       x86_64)  TARGETS_TO_BUILD="X86" ;;
 371       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 372       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 373       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 374       IA64)    TARGETS_TO_BUILD="IA64" ;;
 375       ARM)     TARGETS_TO_BUILD="ARM" ;;
 376       Mips)    TARGETS_TO_BUILD="Mips" ;;
 377       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 378     esac
 379     ;;
 380   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 381       case "$a_target" in
 382         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 383         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 384         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 385         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 386         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 387         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 388         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 389         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 390         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 391       esac
 392   done
 393   ;;
 394 esac
 395 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 396 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 397
 398 dnl Prevent the CBackend from using printf("%a") for floating point so older
 399 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 400 dnl can still compile the CBE's output
 401 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 402   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 403   enableval=default)
 404 case "$enableval" in
 405   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 406   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 407   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 408   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 409 esac
 410 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 411                    [Define if CBE is enabled for printf %a output])
 412
 413 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 414 AC_ARG_WITH(llvmgccdir,
 415   AS_HELP_STRING([--with-llvmgccdir],
 416     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 417     withval=default)
 418 case "$withval" in
 419   default) WITH_LLVMGCCDIR=default ;;
 420   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 421   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 422 esac
 423
 424 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 425 AC_ARG_WITH(llvmgcc,
 426   AS_HELP_STRING([--with-llvmgcc],
 427     [Specify location of llvm-gcc driver (default searches PATH)]),
 428     LLVMGCC=$with_llvmgcc
 429       WITH_LLVMGCCDIR="",)
 430
 431 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 432 AC_ARG_WITH(llvmgxx,
 433   AS_HELP_STRING([--with-llvmgxx],
 434     [Specify location of llvm-g++ driver (default searches PATH)]),
 435     LLVMGXX=$with_llvmgxx
 436     WITH_LLVMGCCDIR="",)
 437
 438 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 439    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 440 fi
 441
 442 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 443    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 444 fi
 445
 446 dnl Specify extra build options
 447 AC_ARG_WITH(extra-options,
 448   AS_HELP_STRING([--with-extra-options],
 449                  [Specify addtional options to compile LLVM with]),,
 450                  withval=default)
 451 case "$withval" in
 452   default) EXTRA_OPTIONS= ;;
 453   *) EXTRA_OPTIONS=$withval ;;
 454 esac
 455 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 456
 457 dnl Allow specific bindings to be specified for building (or not)
 458 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 459     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 460     enableval=default)
 461 BINDINGS_TO_BUILD=""
 462 case "$enableval" in
 463   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 464   all ) BINDINGS_TO_BUILD="ocaml" ;;
 465   none | no) BINDINGS_TO_BUILD="" ;;
 466   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 467       case "$a_binding" in
 468         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 469         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 470       esac
 471   done
 472   ;;
 473 esac
 474
 475 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 476 dnl script for bindings/ocaml/configure, except that its auto value depends on
 477 dnl OCAMLC, which is found here to support tests.
 478 AC_ARG_WITH([ocaml-libdir],
 479   [AS_HELP_STRING([--with-ocaml-libdir],
 480     [Specify install location for ocaml bindings (default is stdlib)])],
 481   [],
 482   [withval=auto])
 483 case "$withval" in
 484   auto) with_ocaml_libdir="$withval" ;;
 485   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 486   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 487 esac
 488
 489 dnl===-----------------------------------------------------------------------===
 490 dnl===
 491 dnl=== SECTION 4: Check for programs we need and that they are the right version
 492 dnl===
 493 dnl===-----------------------------------------------------------------------===
 494
 495 dnl Check for compilation tools
 496 AC_PROG_CPP
 497 AC_PROG_CC(gcc)
 498 AC_PROG_CXX(g++)
 499 AC_PROG_FLEX
 500 AC_PROG_BISON
 501
 502 AC_PROG_NM
 503 AC_SUBST(NM)
 504
 505 dnl Check for the tools that the makefiles require
 506 AC_CHECK_GNU_MAKE
 507 AC_PROG_LN_S
 508 AC_PATH_PROG(CMP, [cmp], [cmp])
 509 AC_PATH_PROG(CP, [cp], [cp])
 510 AC_PATH_PROG(DATE, [date], [date])
 511 AC_PATH_PROG(FIND, [find], [find])
 512 AC_PATH_PROG(GREP, [grep], [grep])
 513 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 514 AC_PATH_PROG(MV,   [mv],   [mv])
 515 AC_PROG_RANLIB
 516 AC_PATH_PROG(RM,   [rm],   [rm])
 517 AC_PATH_PROG(SED,  [sed],  [sed])
 518 AC_PATH_PROG(TAR,  [tar],  [gtar])
 519 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 520
 521 dnl Looking for misc. graph plotting software
 522 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 523 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 524   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 525   dnl If we're targeting for mingw we should emit windows paths, not msys
 526   if test "$llvm_cv_os_type" = "MingW" ; then
 527     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 528   fi
 529   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 530    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 531 fi
 532 AC_PATH_PROG(DOT, [dot], [echo dot])
 533 if test "$DOT" != "echo dot" ; then
 534   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 535   dnl If we're targeting for mingw we should emit windows paths, not msys
 536   if test "$llvm_cv_os_type" = "MingW" ; then
 537     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 538   fi
 539   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 540    [Define to path to dot program if found or 'echo dot' otherwise])
 541 fi
 542 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 543 if test "$GV" != "echo gv" ; then
 544   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 545   dnl If we're targeting for mingw we should emit windows paths, not msys
 546   if test "$llvm_cv_os_type" = "MingW" ; then
 547     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 548   fi
 549   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 550    [Define to path to gv program if found or 'echo gv' otherwise])
 551 fi
 552 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 553 if test "$DOTTY" != "echo dotty" ; then
 554   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 555   dnl If we're targeting for mingw we should emit windows paths, not msys
 556   if test "$llvm_cv_os_type" = "MingW" ; then
 557     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 558   fi
 559   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 560    [Define to path to dotty program if found or 'echo dotty' otherwise])
 561 fi
 562
 563 dnl Look for a sufficiently recent version of Perl.
 564 LLVM_PROG_PERL([5.006])
 565 AC_SUBST(PERL)
 566 if test x"$PERL" = xnone; then
 567    AC_SUBST(HAVE_PERL,0)
 568    AC_MSG_ERROR([perl is required but was not found, please install it])
 569 else
 570    AC_SUBST(HAVE_PERL,1)
 571 fi
 572
 573 dnl Find the install program
 574 AC_PROG_INSTALL
 575
 576 dnl Checks for documentation and testing tools that we can do without. If these
 577 dnl are not found then they are set to "true" which always succeeds but does
 578 dnl nothing. This just lets the build output show that we could have done
 579 dnl something if the tool was available.
 580 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 581 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 582 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 583 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 584 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 585 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 586 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 587 DJ_AC_PATH_TCLSH
 588 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 589 AC_PATH_PROG(OCAMLC,[ocamlc],[echo "Skipped: ocamlc not found"])
 590 AC_PATH_PROG(OCAMLOPT,[ocamlopt],[echo "Skipped: ocamlopt not found"])
 591 AC_PATH_PROG(OCAMLDEP,[ocamldep],[echo "Skipped: ocamldep not found"])
 592
 593 dnl Determine if the linker supports the -R option.
 594 AC_LINK_USE_R
 595
 596 dnl Check for libtool and the library that has dlopen function (which must come
 597 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 598 dnl libtool).
 599 AC_LIBTOOL_DLOPEN
 600 AC_LIB_LTDL
 601 AC_PROG_LIBTOOL
 602
 603 if test "$lt_cv_dlopen_self" = "yes" ; then
 604   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 605               [Define if dlopen(0) will open the symbols of the program])
 606 fi
 607
 608 if test "$WITH_LLVMGCCDIR" = "default" ; then
 609   LLVMGCC="llvm-gcc${EXEEXT}"
 610   LLVMGXX="llvm-g++${EXEEXT}"
 611   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 612   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 613 else
 614   if test -z "$LLVMGCC"; then
 615     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 616   fi
 617   if test -z "$LLVMGXX"; then
 618     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 619   fi
 620   AC_SUBST(LLVMGCC,$LLVMGCC)
 621   AC_SUBST(LLVMGXX,$LLVMGXX)
 622 fi
 623
 624 AC_MSG_CHECKING([tool compatibility])
 625
 626 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 627 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 628 dnl to support those options.
 629 dnl "icc" emits gcc signatures
 630 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 631 ICC=no
 632 IXX=no
 633 case $CC in
 634   icc*|icpc*)
 635     ICC=yes
 636     IXX=yes
 637     ;;
 638    *)
 639     ;;
 640 esac
 641
 642 if test "$GCC" != "yes" && test "$ICC" != "yes"
 643 then
 644   AC_MSG_ERROR([gcc|icc required but not found])
 645 fi
 646
 647 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 648 if test "$GXX" != "yes" && test "$IXX" != "yes"
 649 then
 650   AC_MSG_ERROR([g++|icc required but not found])
 651 fi
 652
 653 dnl Verify that GCC is version 3.0 or higher
 654 if test "$GCC" = "yes"
 655 then
 656   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 657   if test "$gccmajor" -lt "3"
 658   then
 659     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 660   fi
 661 fi
 662
 663 dnl Check for GNU Make.  We use its extensions, so don't build without it
 664 if test -z "$llvm_cv_gnu_make_command"
 665 then
 666   AC_MSG_ERROR([GNU Make required but not found])
 667 fi
 668
 669 dnl Tool compatibility is okay if we make it here.
 670 AC_MSG_RESULT([ok])
 671
 672 dnl===-----------------------------------------------------------------------===
 673 dnl===
 674 dnl=== SECTION 5: Check for libraries
 675 dnl===
 676 dnl===-----------------------------------------------------------------------===
 677
 678 dnl libelf is for sparc only; we can ignore it if we don't have it
 679 AC_CHECK_LIB(elf, elf_begin)
 680 AC_CHECK_LIB(m,sin)
 681 if test "$llvm_cv_os_type" = "MingW" ; then
 682   AC_CHECK_LIB(imagehlp, main)
 683   AC_CHECK_LIB(psapi, main)
 684 fi
 685
 686 dnl lt_dlopen may be required for plugin support.
 687 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 688               [Define if lt_dlopen() is available on this platform]),
 689               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 690                            not be available]))
 691
 692 dnl dlopen() is required for plugin support.
 693 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 694                [Define if dlopen() is available on this platform.]),
 695                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 696
 697 dnl mallinfo is optional; the code can compile (minus features) without it
 698 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 699                [Define if mallinfo() is available on this platform.]))
 700
 701 dnl pthread locking functions are optional - but llvm will not be thread-safe
 702 dnl without locks.
 703 if test "$ENABLE_THREADS" -eq 1 ; then
 704   AC_CHECK_LIB(pthread,pthread_mutex_init)
 705   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 706                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 707                            [Have pthread_mutex_lock]))
 708 fi
 709
 710 dnl Allow extra x86-disassembler library
 711 AC_ARG_WITH(udis86,
 712   AS_HELP_STRING([--with-udis86=<path>],
 713     [Use udis86 external x86 disassembler library]),
 714     [
 715       AC_SUBST(USE_UDIS86, [1])
 716       case "$withval" in
 717         /usr/lib|yes) ;;
 718         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 719       esac
 720       AC_CHECK_LIB(udis86, ud_init, [], [
 721         echo "Error! You need to have libudis86 around."
 722         exit -1
 723       ])
 724     ],
 725     AC_SUBST(USE_UDIS86, [0]))
 726 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 727                    [Define if use udis86 library])
 728
 729 dnl===-----------------------------------------------------------------------===
 730 dnl===
 731 dnl=== SECTION 6: Check for header files
 732 dnl===
 733 dnl===-----------------------------------------------------------------------===
 734
 735 dnl First, use autoconf provided macros for specific headers that we need
 736 dnl We don't check for ancient stuff or things that are guaranteed to be there
 737 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 738 dnl Generally we're looking for POSIX headers.
 739 AC_HEADER_DIRENT
 740 AC_HEADER_MMAP_ANONYMOUS
 741 AC_HEADER_STAT
 742 AC_HEADER_STDC
 743 AC_HEADER_SYS_WAIT
 744 AC_HEADER_TIME
 745
 746 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 747 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 748 AC_CHECK_HEADERS([windows.h])
 749 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 750 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 751 if test "$ENABLE_THREADS" -eq 1 ; then
 752   AC_CHECK_HEADERS(pthread.h,
 753                   AC_SUBST(HAVE_PTHREAD, 1),
 754                    AC_SUBST(HAVE_PTHREAD, 0))
 755 else
 756   AC_SUBST(HAVE_PTHREAD, 0)
 757 fi
 758
 759 dnl===-----------------------------------------------------------------------===
 760 dnl===
 761 dnl=== SECTION 7: Check for types and structures
 762 dnl===
 763 dnl===-----------------------------------------------------------------------===
 764
 765 AC_HUGE_VAL_CHECK
 766 AC_TYPE_PID_T
 767 AC_TYPE_SIZE_T
 768 AC_TYPE_SIGNAL
 769 AC_STRUCT_TM
 770 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 771 AC_CHECK_TYPES([uint64_t],,
 772          AC_CHECK_TYPES([u_int64_t],,
 773          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 774
 775 dnl===-----------------------------------------------------------------------===
 776 dnl===
 777 dnl=== SECTION 8: Check for specific functions needed
 778 dnl===
 779 dnl===-----------------------------------------------------------------------===
 780
 781 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 782 AC_CHECK_FUNCS([powf fmodf strtof round ])
 783 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 784 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 785 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 786 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 787 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 788 AC_C_PRINTF_A
 789 AC_FUNC_ALLOCA
 790 AC_FUNC_RAND48
 791
 792 dnl Check for variations in the Standard C++ library and STL. These macros are
 793 dnl provided by LLVM in the autoconf/m4 directory.
 794 AC_CXX_HAVE_HASH_MAP
 795 AC_CXX_HAVE_HASH_SET
 796 AC_CXX_HAVE_STD_ITERATOR
 797 AC_CXX_HAVE_BI_ITERATOR
 798 AC_CXX_HAVE_FWD_ITERATOR
 799 AC_FUNC_ISNAN
 800 AC_FUNC_ISINF
 801
 802 dnl Check for mmap support.We also need to know if /dev/zero is required to
 803 dnl be opened for allocating RWX memory.
 804 dnl Make sure we aren't attempting to configure for an unknown system
 805 if test "$llvm_cv_platform_type" = "Unix" ; then
 806   AC_FUNC_MMAP
 807   AC_FUNC_MMAP_FILE
 808   AC_NEED_DEV_ZERO_FOR_MMAP
 809
 810   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 811   then
 812     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 813   fi
 814   if test "$ac_cv_func_mmap_file" = "no"
 815   then
 816     AC_MSG_WARN([mmap() of files required but not found])
 817   fi
 818 fi
 819
 820 dnl===-----------------------------------------------------------------------===
 821 dnl===
 822 dnl=== SECTION 9: Additional checks, variables, etc.
 823 dnl===
 824 dnl===-----------------------------------------------------------------------===
 825
 826 dnl Check, whether __dso_handle is present
 827 AC_CHECK_FUNCS([__dso_handle])
 828
 829 dnl See if the llvm-gcc executable can compile to LLVM assembly
 830 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 831 [llvm_cv_llvmgcc_sanity="no"
 832 if test -x "$LLVMGCC" ; then
 833   cp /dev/null conftest.c
 834   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 835       grep 'target datalayout =' > /dev/null 2>&1
 836   if test $? -eq 0 ; then
 837     llvm_cv_llvmgcc_sanity="yes"
 838   fi
 839   rm conftest.c
 840 fi])
 841
 842 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 843 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 844   AC_MSG_CHECKING([llvm-gcc component support])
 845   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 846   AC_SUBST(LLVMCC1,$llvmcc1path)
 847   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 848   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 849   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 850   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 851   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 852   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 853   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 854   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 855   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 856   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 857   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 858   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 859   AC_MSG_RESULT([ok])
 860 fi
 861
 862 dnl Propagate the shared library extension that the libltdl checks did to
 863 dnl the Makefiles so we can use it there too
 864 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 865
 866 # Translate the various configuration directories and other basic
 867 # information into substitutions that will end up in Makefile.config.in
 868 # that these configured values can be used by the makefiles
 869 if test "${prefix}" = "NONE" ; then
 870   prefix="/usr/local"
 871 fi
 872 eval LLVM_PREFIX="${prefix}";
 873 eval LLVM_BINDIR="${prefix}/bin";
 874 eval LLVM_LIBDIR="${prefix}/lib";
 875 eval LLVM_DATADIR="${prefix}/share/llvm";
 876 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 877 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 878 eval LLVM_INCLUDEDIR="${prefix}/include";
 879 eval LLVM_INFODIR="${prefix}/info";
 880 eval LLVM_MANDIR="${prefix}/man";
 881 LLVM_CONFIGTIME=`date`
 882 AC_SUBST(LLVM_PREFIX)
 883 AC_SUBST(LLVM_BINDIR)
 884 AC_SUBST(LLVM_LIBDIR)
 885 AC_SUBST(LLVM_DATADIR)
 886 AC_SUBST(LLVM_DOCSDIR)
 887 AC_SUBST(LLVM_ETCDIR)
 888 AC_SUBST(LLVM_INCLUDEDIR)
 889 AC_SUBST(LLVM_INFODIR)
 890 AC_SUBST(LLVM_MANDIR)
 891 AC_SUBST(LLVM_CONFIGTIME)
 892
 893 # Place the various directores into the config.h file as #defines so that we
 894 # can know about the installation paths within LLVM.
 895 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 896                    [Installation prefix directory])
 897 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 898                    [Installation directory for binary executables])
 899 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 900                    [Installation directory for libraries])
 901 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 902                    [Installation directory for data files])
 903 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 904                    [Installation directory for documentation])
 905 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 906                    [Installation directory for config files])
 907 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 908                    [Installation directory for include files])
 909 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 910                    [Installation directory for .info files])
 911 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 912                    [Installation directory for man pages])
 913 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 914                    [Time at which LLVM was configured])
 915 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 916                    [Host triple we were built on])
 917
 918 # Determine which bindings to build.
 919 if test "$BINDINGS_TO_BUILD" = auto ; then
 920   BINDINGS_TO_BUILD=""
 921   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 922     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 923   fi
 924 fi
 925 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 926
 927 # This isn't really configurey, but it avoids having to repeat the list in
 928 # other files.
 929 AC_SUBST(ALL_BINDINGS,ocaml)
 930
 931 # Do any work necessary to ensure that bindings have what they need.
 932 binding_prereqs_failed=0
 933 for a_binding in $BINDINGS_TO_BUILD ; do
 934   case "$a_binding" in
 935   ocaml)
 936     if test "x$OCAMLC" = x ; then
 937       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 938       binding_prereqs_failed=1
 939     fi
 940     if test "x$OCAMLDEP" = x ; then
 941       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 942       binding_prereqs_failed=1
 943     fi
 944     if test "x$OCAMLOPT" = x ; then
 945       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 946       dnl ocamlopt is optional!
 947     fi
 948     if test "x$with_ocaml_libdir" != xauto ; then
 949       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 950     else
 951       ocaml_stdlib="`"$OCAMLC" -where`"
 952       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 953       then
 954         # ocaml stdlib is beneath our prefix; use stdlib
 955         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 956       else
 957         # ocaml stdlib is outside our prefix; use libdir/ocaml
 958         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 959       fi
 960     fi
 961     ;;
 962   esac
 963 done
 964 if test "$binding_prereqs_failed" = 1 ; then
 965   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 966 fi
 967
 968
 969 dnl===-----------------------------------------------------------------------===
 970 dnl===
 971 dnl=== SECTION 10: Specify the output files and generate it
 972 dnl===
 973 dnl===-----------------------------------------------------------------------===
 974
 975 dnl Configure header files
 976 dnl WARNING: dnl If you add or remove any of the following config headers, then
 977 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 978 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 979 dnl files can be updated automatically when their *.in sources change.
 980 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 981 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 982 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 983 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 984 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 985
 986 dnl Configure the makefile's configuration data
 987 AC_CONFIG_FILES([Makefile.config])
 988
 989 dnl Configure the RPM spec file for LLVM
 990 AC_CONFIG_FILES([llvm.spec])
 991
 992 dnl Configure doxygen's configuration file
 993 AC_CONFIG_FILES([docs/doxygen.cfg])
 994
 995 dnl Do the first stage of configuration for llvm-config.in.
 996 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 997
 998 dnl Do special configuration of Makefiles
 999 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1000 AC_CONFIG_MAKEFILE(Makefile)
1001 AC_CONFIG_MAKEFILE(Makefile.common)
1002 AC_CONFIG_MAKEFILE(examples/Makefile)
1003 AC_CONFIG_MAKEFILE(lib/Makefile)
1004 AC_CONFIG_MAKEFILE(runtime/Makefile)
1005 AC_CONFIG_MAKEFILE(test/Makefile)
1006 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1007 AC_CONFIG_MAKEFILE(tools/Makefile)
1008 AC_CONFIG_MAKEFILE(utils/Makefile)
1009 AC_CONFIG_MAKEFILE(projects/Makefile)
1010 AC_CONFIG_MAKEFILE(bindings/Makefile)
1011 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1012
1013 dnl Finally, crank out the output
1014 AC_OUTPUT