autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.1cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-netbsd*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="NetBSD"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-hpux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="HP-UX"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-interix*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Interix"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-linux*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Linux"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-solaris*)
 155     llvm_cv_link_all_option="-Wl,-z,allextract"
 156     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 157     llvm_cv_os_type="SunOS"
 158     llvm_cv_platform_type="Unix" ;;
 159   *-*-win32*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="Win32"
 163     llvm_cv_platform_type="Win32" ;;
 164   *-*-mingw*)
 165     llvm_cv_link_all_option="-Wl,--whole-archive"
 166     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 167     llvm_cv_os_type="MingW"
 168     llvm_cv_platform_type="Win32" ;;
 169   *)
 170     llvm_cv_link_all_option=""
 171     llvm_cv_no_link_all_option=""
 172     llvm_cv_os_type="Unknown"
 173     llvm_cv_platform_type="Unknown" ;;
 174 esac])
 175
 176 dnl Make sure we aren't attempting to configure for an unknown system
 177 if test "$llvm_cv_os_type" = "Unknown" ; then
 178   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 179 fi
 180
 181 dnl Set the "OS" Makefile variable based on the platform type so the
 182 dnl makefile can configure itself to specific build hosts
 183 AC_SUBST(OS,$llvm_cv_os_type)
 184
 185 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 186 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 187 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 188
 189 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 190 dnl This is used by lib/System to determine the basic kind of implementation
 191 dnl to use.
 192 case $llvm_cv_platform_type in
 193   Unix)
 194     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[1])
 196     AC_SUBST(LLVM_ON_WIN32,[0])
 197     ;;
 198   Win32)
 199     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 200     AC_SUBST(LLVM_ON_UNIX,[0])
 201     AC_SUBST(LLVM_ON_WIN32,[1])
 202     ;;
 203 esac
 204
 205 dnl Determine what our target architecture is and configure accordingly.
 206 dnl This will allow Makefiles to make a distinction between the hardware and
 207 dnl the OS.
 208 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 209 [case $target in
 210   i?86-*)                 llvm_cv_target_arch="x86" ;;
 211   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 212   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 213   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 214   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 215   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 216   arm-*)                  llvm_cv_target_arch="ARM" ;;
 217   *)                      llvm_cv_target_arch="Unknown" ;;
 218 esac])
 219
 220 if test "$llvm_cv_target_arch" = "Unknown" ; then
 221   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 222 fi
 223
 224 dnl Define a substitution, ARCH, for the target architecture
 225 AC_SUBST(ARCH,$llvm_cv_target_arch)
 226
 227 dnl Check for the endianness of the target
 228 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 229
 230 dnl Check for build platform executable suffix if we're crosscompiling
 231 if test "$cross_compiling" = yes; then
 232   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 233   AC_BUILD_EXEEXT
 234 else
 235   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 236 fi
 237
 238 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 239 dnl build is being done from a checkout. This sets up several defaults for the
 240 dnl command line switches. When we build with a CVS directory, we get a
 241 dnl debug with assertions turned on. Without, we assume a source release and we
 242 dnl get an optimized build without assertions. See --enable-optimized and
 243 dnl --enable-assertions below
 244 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 245   cvsbuild="yes"
 246   optimize="no"
 247   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 248 else
 249   cvsbuild="no"
 250   optimize="yes"
 251 fi
 252
 253 dnl===-----------------------------------------------------------------------===
 254 dnl===
 255 dnl=== SECTION 3: Command line arguments for the configure script.
 256 dnl===
 257 dnl===-----------------------------------------------------------------------===
 258
 259 dnl --enable-optimized : check whether they want to do an optimized build:
 260 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 261  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 262 if test ${enableval} = "no" ; then
 263   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 264 else
 265   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 266 fi
 267
 268 dnl --enable-assertions : check whether they want to turn on assertions or not:
 269 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 270   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 271 if test ${enableval} = "yes" ; then
 272   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 273 else
 274   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 275 fi
 276
 277 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 278 AC_ARG_ENABLE(debug-runtime,
 279    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 280 if test ${enableval} = "no" ; then
 281   AC_SUBST(DEBUG_RUNTIME,[[]])
 282 else
 283   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 284 fi
 285
 286 dnl --enable-jit: check whether they want to enable the jit
 287 AC_ARG_ENABLE(jit,
 288   AS_HELP_STRING(--enable-jit,
 289                  [Enable Just In Time Compiling (default is YES)]),,
 290   enableval=default)
 291 if test ${enableval} = "no"
 292 then
 293   AC_SUBST(JIT,[[]])
 294 else
 295   case "$llvm_cv_target_arch" in
 296     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 297     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 298     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 299     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 300     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 301     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 302     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 303     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 304   esac
 305 fi
 306
 307 dnl Allow enablement of doxygen generated documentation
 308 AC_ARG_ENABLE(doxygen,
 309               AS_HELP_STRING([--enable-doxygen],
 310                              [Build doxygen documentation (default is NO)]),,
 311                              enableval=default)
 312 case "$enableval" in
 313   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 314   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 315   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 316   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 317 esac
 318
 319 dnl Allow disablement of threads
 320 AC_ARG_ENABLE(threads,
 321               AS_HELP_STRING([--enable-threads],
 322                              [Use threads if available (default is YES)]),,
 323                              enableval=default)
 324 case "$enableval" in
 325   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 326   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 327   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 328   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 329 esac
 330 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 331
 332 dnl Allow building with position independent code
 333 AC_ARG_ENABLE(pic,
 334   AS_HELP_STRING([--enable-pic],
 335                  [Build LLVM with Position Independent Code (default is NO)]),,
 336                  enableval=default)
 337 case "$enableval" in
 338   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 339   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 340   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 341   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 342 esac
 343 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 344                    [Define if position independent code is enabled])
 345
 346 dnl Allow specific targets to be specified for building (or not)
 347 TARGETS_TO_BUILD=""
 348 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 349     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 350     enableval=all)
 351 case "$enableval" in
 352   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 353   host-only)
 354     case "$llvm_cv_target_arch" in
 355       x86)     TARGETS_TO_BUILD="X86" ;;
 356       x86_64)  TARGETS_TO_BUILD="X86" ;;
 357       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 358       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 359       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 360       IA64)    TARGETS_TO_BUILD="IA64" ;;
 361       ARM)     TARGETS_TO_BUILD="ARM" ;;
 362       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 363     esac
 364     ;;
 365   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 366       case "$a_target" in
 367         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 368         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 369         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 370         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 371         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 372         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 373         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 374         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 375       esac
 376   done
 377   ;;
 378 esac
 379 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 380 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 381
 382 dnl Prevent the CBackend from using printf("%a") for floating point so older
 383 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 384 dnl can still compile the CBE's output
 385 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 386   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 387   enableval=default)
 388 case "$enableval" in
 389   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 390   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 391   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 392   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 393 esac
 394 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 395                    [Define if CBE is enabled for printf %a output])
 396
 397 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 398 AC_ARG_WITH(llvmgccdir,
 399   AS_HELP_STRING([--with-llvmgccdir],
 400     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 401     withval=default)
 402 case "$withval" in
 403   default) WITH_LLVMGCCDIR=default ;;
 404   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 405   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 406 esac
 407
 408 dnl Specify extra build options
 409 AC_ARG_WITH(extra-options,
 410   AS_HELP_STRING([--with-extra-options],
 411                  [Specify addtional options to compile LLVM with]),,
 412                  withval=default)
 413 case "$withval" in
 414   default) EXTRA_OPTIONS= ;;
 415   *) EXTRA_OPTIONS=$withval ;;
 416 esac
 417 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 418
 419 dnl===-----------------------------------------------------------------------===
 420 dnl===
 421 dnl=== SECTION 4: Check for programs we need and that they are the right version
 422 dnl===
 423 dnl===-----------------------------------------------------------------------===
 424
 425 dnl Check for compilation tools
 426 AC_PROG_CPP
 427 AC_PROG_CC(gcc)
 428 AC_PROG_CXX(g++)
 429 AC_PROG_FLEX
 430 AC_PROG_BISON
 431
 432 AC_PROG_NM
 433 AC_SUBST(NM)
 434
 435 dnl Check for the tools that the makefiles require
 436 AC_CHECK_GNU_MAKE
 437 AC_PROG_LN_S
 438 AC_PATH_PROG(CMP, [cmp], [cmp])
 439 AC_PATH_PROG(CP, [cp], [cp])
 440 AC_PATH_PROG(DATE, [date], [date])
 441 AC_PATH_PROG(FIND, [find], [find])
 442 AC_PATH_PROG(GREP, [grep], [grep])
 443 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 444 AC_PATH_PROG(MV,   [mv],   [mv])
 445 AC_PROG_RANLIB
 446 AC_PATH_PROG(RM,   [rm],   [rm])
 447 AC_PATH_PROG(SED,  [sed],  [sed])
 448 AC_PATH_PROG(TAR,  [tar],  [gtar])
 449 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 450
 451 dnl Looking for misc. graph plotting software
 452 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 453 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 454   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 455   dnl If we're targeting for mingw we should emit windows paths, not msys
 456   if test "$llvm_cv_os_type" = "MingW" ; then
 457     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 458   fi
 459   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 460    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 461 fi
 462 AC_PATH_PROG(DOT, [dot], [echo dot])
 463 if test "$DOT" != "echo dot" ; then
 464   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 465   dnl If we're targeting for mingw we should emit windows paths, not msys
 466   if test "$llvm_cv_os_type" = "MingW" ; then
 467     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 468   fi
 469   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 470    [Define to path to dot program if found or 'echo dot' otherwise])
 471 fi
 472 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 473 if test "$GV" != "echo gv" ; then
 474   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 475   dnl If we're targeting for mingw we should emit windows paths, not msys
 476   if test "$llvm_cv_os_type" = "MingW" ; then
 477     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 478   fi
 479   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 480    [Define to path to gv program if found or 'echo gv' otherwise])
 481 fi
 482 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 483 if test "$DOTTY" != "echo dotty" ; then
 484   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 485   dnl If we're targeting for mingw we should emit windows paths, not msys
 486   if test "$llvm_cv_os_type" = "MingW" ; then
 487     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 488   fi
 489   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 490    [Define to path to dotty program if found or 'echo dotty' otherwise])
 491 fi
 492
 493 dnl Look for a sufficiently recent version of Perl.
 494 LLVM_PROG_PERL([5.006])
 495 AC_SUBST(PERL)
 496 if test x"$PERL" = xnone; then
 497    AC_SUBST(HAVE_PERL,0)
 498    AC_MSG_ERROR([perl is required but was not found, please install it])
 499 else
 500    AC_SUBST(HAVE_PERL,1)
 501 fi
 502
 503 dnl Find the install program
 504 AC_PROG_INSTALL
 505
 506 dnl Checks for documentation and testing tools that we can do without. If these
 507 dnl are not found then they are set to "true" which always succeeds but does
 508 dnl nothing. This just lets the build output show that we could have done
 509 dnl something if the tool was available.
 510 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 511 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 512 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 513 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 514 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 515 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 516 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 517 DJ_AC_PATH_TCLSH
 518 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 519
 520 dnl Determine if the linker supports the -R option.
 521 AC_LINK_USE_R
 522
 523 dnl Check for libtool and the library that has dlopen function (which must come
 524 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 525 dnl libtool).
 526 AC_LIBTOOL_DLOPEN
 527 AC_LIB_LTDL
 528 AC_PROG_LIBTOOL
 529
 530 if test "$lt_cv_dlopen_self" = "yes" ; then
 531   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 532               [Define if dlopen(0) will open the symbols of the program])
 533 fi
 534
 535 dnl Check if we know how to tell etags we are using C++:
 536 etags_version=`$ETAGS --version 2>&1`
 537 case "$etags_version" in
 538         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 539         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 540         *) ETAGSFLAGS="" ;;
 541 esac
 542 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 543
 544 if test "$WITH_LLVMGCCDIR" = "default" ; then
 545   LLVMGCC="llvm-gcc${EXEEXT}"
 546   LLVMGXX="llvm-g++${EXEEXT}"
 547   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 548   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 549 else
 550   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 551   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 552   AC_SUBST(LLVMGCC,$LLVMGCC)
 553   AC_SUBST(LLVMGXX,$LLVMGXX)
 554 fi
 555
 556 AC_MSG_CHECKING([tool compatibility])
 557
 558 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 559 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 560 dnl to support those options.
 561 dnl "icc" emits gcc signatures
 562 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 563 ICC=no
 564 IXX=no
 565 case $CC in
 566   icc*|icpc*)
 567     ICC=yes
 568     IXX=yes
 569     ;;
 570    *)
 571     ;;
 572 esac
 573
 574 if test "$GCC" != "yes" && test "$ICC" != "yes"
 575 then
 576   AC_MSG_ERROR([gcc|icc required but not found])
 577 fi
 578
 579 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 580 if test "$GXX" != "yes" && test "$IXX" != "yes"
 581 then
 582   AC_MSG_ERROR([g++|icc required but not found])
 583 fi
 584
 585 dnl Verify that GCC is version 3.0 or higher
 586 if test "$GCC" = "yes"
 587 then
 588   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 589   if test "$gccmajor" -lt "3"
 590   then
 591     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 592   fi
 593 fi
 594
 595 dnl Check for GNU Make.  We use its extensions, so don't build without it
 596 if test -z "$llvm_cv_gnu_make_command"
 597 then
 598   AC_MSG_ERROR([GNU Make required but not found])
 599 fi
 600
 601 dnl Tool compatibility is okay if we make it here.
 602 AC_MSG_RESULT([ok])
 603
 604 dnl===-----------------------------------------------------------------------===
 605 dnl===
 606 dnl=== SECTION 5: Check for libraries
 607 dnl===
 608 dnl===-----------------------------------------------------------------------===
 609
 610 dnl libelf is for sparc only; we can ignore it if we don't have it
 611 AC_CHECK_LIB(elf, elf_begin)
 612 AC_CHECK_LIB(m,sin)
 613 if test "$llvm_cv_os_type" = "MingW" ; then
 614   AC_CHECK_LIB(imagehlp, main)
 615   AC_CHECK_LIB(psapi, main)
 616 fi
 617
 618 dnl lt_dlopen may be required for plugin support.
 619 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 620               [Define if lt_dlopen() is available on this platform]),
 621               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 622                            not be available]))
 623
 624 dnl dlopen() is required for plugin support.
 625 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 626                [Define if dlopen() is available on this platform.]),
 627                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 628
 629 dnl mallinfo is optional; the code can compile (minus features) without it
 630 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 631                [Define if mallinfo() is available on this platform.]))
 632
 633 dnl pthread locking functions are optional - but llvm will not be thread-safe
 634 dnl without locks.
 635 if test "$ENABLE_THREADS" -eq 1 ; then
 636   AC_CHECK_LIB(pthread,pthread_mutex_init)
 637   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 638                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 639                            [Have pthread_mutex_lock]))
 640 fi
 641
 642 dnl Allow extra x86-disassembler library
 643 AC_ARG_WITH(udis86,
 644   AS_HELP_STRING([--with-udis86=<path>],
 645     [Use udis86 external x86 disassembler library]),
 646     [
 647       AC_SUBST(USE_UDIS86, [1])
 648       case "$withval" in
 649         /usr/lib|yes) ;;
 650         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 651       esac
 652       AC_CHECK_LIB(udis86, ud_init, [], [
 653         echo "Error! You need to have libudis86 around."
 654         exit -1
 655       ])
 656     ],
 657     AC_SUBST(USE_UDIS86, [0]))
 658 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 659                    [Define if use udis86 library])
 660
 661 dnl===-----------------------------------------------------------------------===
 662 dnl===
 663 dnl=== SECTION 6: Check for header files
 664 dnl===
 665 dnl===-----------------------------------------------------------------------===
 666
 667 dnl First, use autoconf provided macros for specific headers that we need
 668 dnl We don't check for ancient stuff or things that are guaranteed to be there
 669 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 670 dnl Generally we're looking for POSIX headers.
 671 AC_HEADER_DIRENT
 672 AC_HEADER_MMAP_ANONYMOUS
 673 AC_HEADER_STAT
 674 AC_HEADER_STDC
 675 AC_HEADER_SYS_WAIT
 676 AC_HEADER_TIME
 677
 678 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 679 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 680 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 681 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 682 if test "$ENABLE_THREADS" -eq 1 ; then
 683   AC_CHECK_HEADER(pthread.h,
 684                   AC_SUBST(HAVE_PTHREAD, 1),
 685                    AC_SUBST(HAVE_PTHREAD, 0))
 686 else
 687   AC_SUBST(HAVE_PTHREAD, 0)
 688 fi
 689
 690 dnl===-----------------------------------------------------------------------===
 691 dnl===
 692 dnl=== SECTION 7: Check for types and structures
 693 dnl===
 694 dnl===-----------------------------------------------------------------------===
 695
 696 AC_HUGE_VAL_CHECK
 697 AC_TYPE_PID_T
 698 AC_TYPE_SIZE_T
 699 AC_TYPE_SIGNAL
 700 AC_STRUCT_TM
 701 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 702 AC_CHECK_TYPES([uint64_t],,
 703          AC_CHECK_TYPES([u_int64_t],,
 704          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 705
 706 dnl===-----------------------------------------------------------------------===
 707 dnl===
 708 dnl=== SECTION 8: Check for specific functions needed
 709 dnl===
 710 dnl===-----------------------------------------------------------------------===
 711
 712 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 713 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday])
 714 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 715 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 716 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 717 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 718 AC_C_PRINTF_A
 719 AC_FUNC_ALLOCA
 720 AC_FUNC_RAND48
 721
 722 dnl Check for variations in the Standard C++ library and STL. These macros are
 723 dnl provided by LLVM in the autoconf/m4 directory.
 724 AC_CXX_HAVE_HASH_MAP
 725 AC_CXX_HAVE_HASH_SET
 726 AC_CXX_HAVE_STD_ITERATOR
 727 AC_CXX_HAVE_BI_ITERATOR
 728 AC_CXX_HAVE_FWD_ITERATOR
 729 AC_FUNC_ISNAN
 730 AC_FUNC_ISINF
 731
 732 dnl Check for mmap support.We also need to know if /dev/zero is required to
 733 dnl be opened for allocating RWX memory.
 734 dnl Make sure we aren't attempting to configure for an unknown system
 735 if test "$llvm_cv_platform_type" = "Unix" ; then
 736   AC_FUNC_MMAP
 737   AC_FUNC_MMAP_FILE
 738   AC_NEED_DEV_ZERO_FOR_MMAP
 739
 740   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 741   then
 742     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 743   fi
 744   if test "$ac_cv_func_mmap_file" = "no"
 745   then
 746     AC_MSG_WARN([mmap() of files required but not found])
 747   fi
 748 fi
 749
 750 dnl===-----------------------------------------------------------------------===
 751 dnl===
 752 dnl=== SECTION 9: Additional checks, variables, etc.
 753 dnl===
 754 dnl===-----------------------------------------------------------------------===
 755
 756 dnl See if the llvm-gcc executable can compile to LLVM assembly
 757 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 758 [llvm_cv_llvmgcc_sanity="no"
 759 if test -x "$LLVMGCC" ; then
 760   cp /dev/null conftest.c
 761   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 762       grep 'target datalayout =' > /dev/null 2>&1
 763   if test $? -eq 0 ; then
 764     llvm_cv_llvmgcc_sanity="yes"
 765   fi
 766   rm conftest.c
 767 fi])
 768
 769 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 770 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 771   AC_MSG_CHECKING([llvm-gcc component support])
 772   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 773   AC_SUBST(LLVMCC1,$llvmcc1path)
 774   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 775   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 776   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 777   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 778   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 779   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 780   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 781   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 782   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 783   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 784   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 785   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 786   AC_MSG_RESULT([ok])
 787 fi
 788
 789 dnl Propagate the shared library extension that the libltdl checks did to
 790 dnl the Makefiles so we can use it there too
 791 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 792
 793 # Translate the various configuration directories and other basic
 794 # information into substitutions that will end up in Makefile.config.in
 795 # that these configured values can be used by the makefiles
 796 if test "${prefix}" = "NONE" ; then
 797   prefix="/usr/local"
 798 fi
 799 eval LLVM_PREFIX="${prefix}";
 800 eval LLVM_BINDIR="${prefix}/bin";
 801 eval LLVM_LIBDIR="${prefix}/lib";
 802 eval LLVM_DATADIR="${prefix}/share/llvm";
 803 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 804 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 805 eval LLVM_INCLUDEDIR="${prefix}/include";
 806 eval LLVM_INFODIR="${prefix}/info";
 807 eval LLVM_MANDIR="${prefix}/man";
 808 LLVM_CONFIGTIME=`date`
 809 AC_SUBST(LLVM_PREFIX)
 810 AC_SUBST(LLVM_BINDIR)
 811 AC_SUBST(LLVM_LIBDIR)
 812 AC_SUBST(LLVM_DATADIR)
 813 AC_SUBST(LLVM_DOCSDIR)
 814 AC_SUBST(LLVM_ETCDIR)
 815 AC_SUBST(LLVM_INCLUDEDIR)
 816 AC_SUBST(LLVM_INFODIR)
 817 AC_SUBST(LLVM_MANDIR)
 818 AC_SUBST(LLVM_CONFIGTIME)
 819
 820 # Place the various directores into the config.h file as #defines so that we
 821 # can know about the installation paths within LLVM.
 822 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 823                    [Installation prefix directory])
 824 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 825                    [Installation directory for binary executables])
 826 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 827                    [Installation directory for libraries])
 828 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 829                    [Installation directory for data files])
 830 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 831                    [Installation directory for documentation])
 832 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 833                    [Installation directory for config files])
 834 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 835                    [Installation directory for include files])
 836 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 837                    [Installation directory for .info files])
 838 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 839                    [Installation directory for man pages])
 840 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 841                    [Time at which LLVM was configured])
 842
 843 dnl===-----------------------------------------------------------------------===
 844 dnl===
 845 dnl=== SECTION 10: Specify the output files and generate it
 846 dnl===
 847 dnl===-----------------------------------------------------------------------===
 848
 849 dnl Configure header files
 850 dnl WARNING: dnl If you add or remove any of the following config headers, then
 851 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 852 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 853 dnl files can be updated automatically when their *.in sources change.
 854 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 855 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 856 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 857 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 858 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 859
 860 dnl Configure the makefile's configuration data
 861 AC_CONFIG_FILES([Makefile.config])
 862
 863 dnl Configure the RPM spec file for LLVM
 864 AC_CONFIG_FILES([llvm.spec])
 865
 866 dnl Configure doxygen's configuration file
 867 AC_CONFIG_FILES([docs/doxygen.cfg])
 868
 869 dnl Do the first stage of configuration for llvm-config.in.
 870 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 871
 872 dnl Do special configuration of Makefiles
 873 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 874 AC_CONFIG_MAKEFILE(Makefile)
 875 AC_CONFIG_MAKEFILE(Makefile.common)
 876 AC_CONFIG_MAKEFILE(examples/Makefile)
 877 AC_CONFIG_MAKEFILE(lib/Makefile)
 878 AC_CONFIG_MAKEFILE(runtime/Makefile)
 879 AC_CONFIG_MAKEFILE(test/Makefile)
 880 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 881 AC_CONFIG_MAKEFILE(tools/Makefile)
 882 AC_CONFIG_MAKEFILE(utils/Makefile)
 883 AC_CONFIG_MAKEFILE(projects/Makefile)
 884
 885 dnl Finally, crank out the output
 886 AC_OUTPUT
 887