autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.9svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl===-----------------------------------------------------------------------===
 125 dnl===
 126 dnl=== SECTION 2: Architecture, target, and host checks
 127 dnl===
 128 dnl===-----------------------------------------------------------------------===
 129
 130 dnl Check the target for which we're compiling and the host that will do the
 131 dnl compilations. This will tell us which LLVM compiler will be used for
 132 dnl compiling SSA into object code. This needs to be done early because
 133 dnl following tests depend on it.
 134 AC_CANONICAL_TARGET
 135
 136 dnl Determine the platform type and cache its value. This helps us configure
 137 dnl the System library to the correct build platform.
 138 AC_CACHE_CHECK([type of operating system we're going to host on],
 139                [llvm_cv_os_type],
 140 [case $host in
 141   *-*-aix*)
 142     llvm_cv_link_all_option="-Wl,--whole-archive"
 143     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 144     llvm_cv_os_type="AIX"
 145     llvm_cv_platform_type="Unix" ;;
 146   *-*-irix*)
 147     llvm_cv_link_all_option="-Wl,--whole-archive"
 148     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 149     llvm_cv_os_type="IRIX"
 150     llvm_cv_platform_type="Unix" ;;
 151   *-*-cygwin*)
 152     llvm_cv_link_all_option="-Wl,--whole-archive"
 153     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 154     llvm_cv_os_type="Cygwin"
 155     llvm_cv_platform_type="Unix" ;;
 156   *-*-darwin*)
 157     llvm_cv_link_all_option="-Wl,-all_load"
 158     llvm_cv_no_link_all_option="-Wl,-noall_load"
 159     llvm_cv_os_type="Darwin"
 160     llvm_cv_platform_type="Unix" ;;
 161   *-*-minix*)
 162     llvm_cv_link_all_option="-Wl,-all_load"
 163     llvm_cv_no_link_all_option="-Wl,-noall_load"
 164     llvm_cv_os_type="Minix"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-freebsd*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="FreeBSD"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-openbsd*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="OpenBSD"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-netbsd*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="NetBSD"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-dragonfly*)
 182     llvm_cv_link_all_option="-Wl,--whole-archive"
 183     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 184     llvm_cv_os_type="DragonFly"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-hpux*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="HP-UX"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-interix*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="Interix"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-linux*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="Linux"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-solaris*)
 202     llvm_cv_link_all_option="-Wl,-z,allextract"
 203     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 204     llvm_cv_os_type="SunOS"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-auroraux*)
 207     llvm_cv_link_all_option="-Wl,-z,allextract"
 208     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 209     llvm_cv_os_type="AuroraUX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-win32*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Win32"
 215     llvm_cv_platform_type="Win32" ;;
 216   *-*-mingw*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="MingW"
 220     llvm_cv_platform_type="Win32" ;;
 221   *-*-haiku*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Haiku"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_link_all_option="-Wl,--whole-archive"
 228     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 229     llvm_cv_os_type="Freestanding"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-unknown-elf*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Freestanding"
 235     llvm_cv_platform_type="Unix" ;;
 236   *)
 237     llvm_cv_link_all_option=""
 238     llvm_cv_no_link_all_option=""
 239     llvm_cv_os_type="Unknown"
 240     llvm_cv_platform_type="Unknown" ;;
 241 esac])
 242
 243 AC_CACHE_CHECK([type of operating system we're going to target],
 244                [llvm_cv_target_os_type],
 245 [case $target in
 246   *-*-aix*)
 247     llvm_cv_target_os_type="AIX" ;;
 248   *-*-irix*)
 249     llvm_cv_target_os_type="IRIX" ;;
 250   *-*-cygwin*)
 251     llvm_cv_target_os_type="Cygwin" ;;
 252   *-*-darwin*)
 253     llvm_cv_target_os_type="Darwin" ;;
 254   *-*-minix*)
 255     llvm_cv_target_os_type="Minix" ;;
 256   *-*-freebsd*)
 257     llvm_cv_target_os_type="FreeBSD" ;;
 258   *-*-openbsd*)
 259     llvm_cv_target_os_type="OpenBSD" ;;
 260   *-*-netbsd*)
 261     llvm_cv_target_os_type="NetBSD" ;;
 262   *-*-dragonfly*)
 263     llvm_cv_target_os_type="DragonFly" ;;
 264   *-*-hpux*)
 265     llvm_cv_target_os_type="HP-UX" ;;
 266   *-*-interix*)
 267     llvm_cv_target_os_type="Interix" ;;
 268   *-*-linux*)
 269     llvm_cv_target_os_type="Linux" ;;
 270   *-*-solaris*)
 271     llvm_cv_target_os_type="SunOS" ;;
 272   *-*-auroraux*)
 273     llvm_cv_target_os_type="AuroraUX" ;;
 274   *-*-win32*)
 275     llvm_cv_target_os_type="Win32" ;;
 276   *-*-mingw*)
 277     llvm_cv_target_os_type="MingW" ;;
 278   *-*-haiku*)
 279     llvm_cv_target_os_type="Haiku" ;;
 280   *-unknown-eabi*)
 281     llvm_cv_target_os_type="Freestanding" ;;
 282   *)
 283     llvm_cv_target_os_type="Unknown" ;;
 284 esac])
 285
 286 dnl Make sure we aren't attempting to configure for an unknown system
 287 if test "$llvm_cv_os_type" = "Unknown" ; then
 288   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 289 fi
 290
 291 dnl Set the "OS" Makefile variable based on the platform type so the
 292 dnl makefile can configure itself to specific build hosts
 293 AC_SUBST(OS,$llvm_cv_os_type)
 294 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 295 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 296
 297 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 298 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 299 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 300
 301 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 302 dnl This is used by lib/System to determine the basic kind of implementation
 303 dnl to use.
 304 case $llvm_cv_platform_type in
 305   Unix)
 306     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 307     AC_SUBST(LLVM_ON_UNIX,[1])
 308     AC_SUBST(LLVM_ON_WIN32,[0])
 309     ;;
 310   Win32)
 311     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 312     AC_SUBST(LLVM_ON_UNIX,[0])
 313     AC_SUBST(LLVM_ON_WIN32,[1])
 314     ;;
 315 esac
 316
 317 dnl Determine what our target architecture is and configure accordingly.
 318 dnl This will allow Makefiles to make a distinction between the hardware and
 319 dnl the OS.
 320 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 321 [case $target in
 322   i?86-*)                 llvm_cv_target_arch="x86" ;;
 323   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 324   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 325   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 326   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 327   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 328   mips-*)                 llvm_cv_target_arch="Mips" ;;
 329   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 330   xcore-*)                llvm_cv_target_arch="XCore" ;;
 331   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 332   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 333   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 334   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 335   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 336   *)                      llvm_cv_target_arch="Unknown" ;;
 337 esac])
 338
 339 if test "$llvm_cv_target_arch" = "Unknown" ; then
 340   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 341 fi
 342
 343 # Determine the LLVM native architecture for the target
 344 case "$llvm_cv_target_arch" in
 345     x86)     LLVM_NATIVE_ARCH="X86" ;;
 346     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 347     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 348 esac
 349
 350 dnl Define a substitution, ARCH, for the target architecture
 351 AC_SUBST(ARCH,$llvm_cv_target_arch)
 352
 353 dnl Check for the endianness of the target
 354 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 355
 356 dnl Check for build platform executable suffix if we're crosscompiling
 357 if test "$cross_compiling" = yes; then
 358   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 359   AC_BUILD_EXEEXT
 360   ac_build_prefix=${build_alias}-
 361   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 362   if test -z "$BUILD_CXX"; then
 363      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 364      if test -z "$BUILD_CXX"; then
 365        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 366      fi
 367   fi
 368 else
 369   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 370 fi
 371
 372 dnl Check to see if there's a .svn or .git directory indicating that this
 373 dnl build is being done from a checkout. This sets up several defaults for
 374 dnl the command line switches. When we build with a checkout directory,
 375 dnl we get a debug with assertions turned on. Without, we assume a source
 376 dnl release and we get an optimized build without assertions.
 377 dnl See --enable-optimized and --enable-assertions below
 378 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 379   cvsbuild="yes"
 380   optimize="no"
 381   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 382 else
 383   cvsbuild="no"
 384   optimize="yes"
 385 fi
 386
 387 dnl===-----------------------------------------------------------------------===
 388 dnl===
 389 dnl=== SECTION 3: Command line arguments for the configure script.
 390 dnl===
 391 dnl===-----------------------------------------------------------------------===
 392
 393 dnl --enable-optimized : check whether they want to do an optimized build:
 394 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 395  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 396 if test ${enableval} = "no" ; then
 397   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 398 else
 399   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 400 fi
 401
 402 dnl --enable-profiling : check whether they want to do a profile build:
 403 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 404  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 405 if test ${enableval} = "no" ; then
 406   AC_SUBST(ENABLE_PROFILING,[[]])
 407 else
 408   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 409 fi
 410
 411 dnl --enable-assertions : check whether they want to turn on assertions or not:
 412 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 413   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 414 if test ${enableval} = "yes" ; then
 415   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 416 else
 417   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 418 fi
 419
 420 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 421 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 422   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 423 if test ${enableval} = "yes" ; then
 424   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 425   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 426 else
 427   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 428   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 429 fi
 430
 431 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 432 AC_ARG_ENABLE(debug-runtime,
 433    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(DEBUG_RUNTIME,[[]])
 436 else
 437   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 438 fi
 439
 440 dnl --enable-debug-symbols : should even optimized compiler libraries
 441 dnl have debug symbols?
 442 AC_ARG_ENABLE(debug-symbols,
 443    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 444 if test ${enableval} = "no" ; then
 445   AC_SUBST(DEBUG_SYMBOLS,[[]])
 446 else
 447   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 448 fi
 449
 450 dnl --enable-jit: check whether they want to enable the jit
 451 AC_ARG_ENABLE(jit,
 452   AS_HELP_STRING(--enable-jit,
 453                  [Enable Just In Time Compiling (default is YES)]),,
 454   enableval=default)
 455 if test ${enableval} = "no"
 456 then
 457   AC_SUBST(JIT,[[]])
 458 else
 459   case "$llvm_cv_target_arch" in
 460     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 461     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 462     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 466     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 473     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 474     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 475   esac
 476 fi
 477
 478 dnl Allow enablement of doxygen generated documentation
 479 AC_ARG_ENABLE(doxygen,
 480               AS_HELP_STRING([--enable-doxygen],
 481                              [Build doxygen documentation (default is NO)]),,
 482                              enableval=default)
 483 case "$enableval" in
 484   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 485   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 486   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 487   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 488 esac
 489
 490 dnl Allow disablement of threads
 491 AC_ARG_ENABLE(threads,
 492               AS_HELP_STRING([--enable-threads],
 493                              [Use threads if available (default is YES)]),,
 494                              enableval=default)
 495 case "$enableval" in
 496   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 497   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 498   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 499   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 500 esac
 501 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 502
 503 dnl Allow building without position independent code
 504 AC_ARG_ENABLE(pic,
 505   AS_HELP_STRING([--enable-pic],
 506                  [Build LLVM with Position Independent Code (default is YES)]),,
 507                  enableval=default)
 508 case "$enableval" in
 509   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 510   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 511   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 512   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 513 esac
 514 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 515                    [Define if position independent code is enabled])
 516
 517 dnl Allow building a shared library and linking tools against it.
 518 AC_ARG_ENABLE(shared,
 519   AS_HELP_STRING([--enable-shared],
 520                  [Build a shared library and link tools against it (default is NO)]),,
 521                  enableval=default)
 522 case "$enableval" in
 523   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 524   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 525   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 526   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 527 esac
 528
 529 dnl Enable embedding timestamp information into build.
 530 AC_ARG_ENABLE(timestamps,
 531   AS_HELP_STRING([--enable-timestamps],
 532                  [Enable embedding timestamp information in build (default is YES)]),,
 533                  enableval=default)
 534 case "$enableval" in
 535   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 536   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 537   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 538   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 539 esac
 540 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 541                    [Define if timestamp information (e.g., __DATE___) is allowed])
 542
 543 dnl Allow specific targets to be specified for building (or not)
 544 TARGETS_TO_BUILD=""
 545 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 546     [Build specific host targets: all or target1,target2,... Valid targets are:
 547      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 548      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 549     enableval=all)
 550 if test "$enableval" = host-only ; then
 551   enableval=host
 552 fi
 553 case "$enableval" in
 554   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 555   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 556       case "$a_target" in
 557         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 558         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 559         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 560         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 561         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 562         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 563         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 564         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 565         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 566         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 567         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 568         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 569         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 570         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 571         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 572         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 573         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 574         host) case "$llvm_cv_target_arch" in
 575             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 576             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 577             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 578             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 579             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 580             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 581             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 582             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 583             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 584             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 585             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 586             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 587             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 588             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 589             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 590             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 591           esac ;;
 592         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 593       esac
 594   done
 595   ;;
 596 esac
 597 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 598
 599 # Determine whether we are building LLVM support for the native architecture.
 600 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 601 for a_target in $TARGETS_TO_BUILD; do
 602   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 603     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 604       [LLVM architecture name for the native architecture, if available])
 605     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 606     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 607     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 608     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 609       [LLVM name for the native Target init function, if available])
 610     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 611       [LLVM name for the native TargetInfo init function, if available])
 612     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 613       [LLVM name for the native AsmPrinter init function, if available])
 614   fi
 615 done
 616
 617 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 618 # target feature def files.
 619 LLVM_ENUM_TARGETS=""
 620 LLVM_ENUM_ASM_PRINTERS=""
 621 LLVM_ENUM_ASM_PARSERS=""
 622 LLVM_ENUM_DISASSEMBLERS=""
 623 for target_to_build in $TARGETS_TO_BUILD; do
 624   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 625   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 626     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 627   fi
 628   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 629     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 630   fi
 631   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 632     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 633   fi
 634 done
 635 AC_SUBST(LLVM_ENUM_TARGETS)
 636 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 637 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 638 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 639
 640 dnl Prevent the CBackend from using printf("%a") for floating point so older
 641 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 642 dnl can still compile the CBE's output
 643 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 644   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 645   enableval=default)
 646 case "$enableval" in
 647   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 648   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 649   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 650   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 651 esac
 652 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 653                    [Define if CBE is enabled for printf %a output])
 654
 655 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 656 AC_ARG_WITH(llvmgccdir,
 657   AS_HELP_STRING([--with-llvmgccdir],
 658     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 659     withval=default)
 660 case "$withval" in
 661   default) WITH_LLVMGCCDIR=default ;;
 662   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 663   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 664 esac
 665
 666 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 667 AC_ARG_WITH(llvmgcc,
 668   AS_HELP_STRING([--with-llvmgcc],
 669     [Specify location of llvm-gcc driver (default searches PATH)]),
 670     LLVMGCC=$with_llvmgcc
 671       WITH_LLVMGCCDIR="",)
 672
 673 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 674 AC_ARG_WITH(llvmgxx,
 675   AS_HELP_STRING([--with-llvmgxx],
 676     [Specify location of llvm-g++ driver (default searches PATH)]),
 677     LLVMGXX=$with_llvmgxx
 678     WITH_LLVMGCCDIR="",)
 679
 680 if test -n "$LLVMGCC"; then
 681    LLVMGCCCOMMAND="$LLVMGCC"
 682 fi
 683
 684 if test -n "$LLVMGXX"; then
 685    LLVMGXXCOMMAND="$LLVMGXX"
 686 fi
 687
 688 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 689    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 690 fi
 691
 692 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 693    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 694 fi
 695
 696 dnl Allow a specific Clang compiler to be used with this LLVM config.
 697 AC_ARG_WITH(clang,
 698   AS_HELP_STRING([--with-clang],
 699     [Specify location of clang compiler (default is --with-built-clang)]),
 700     [],[with_clang=default])
 701
 702 dnl Enable use of the built Clang.
 703 AC_ARG_WITH(built-clang,
 704   AS_HELP_STRING([--with-built-clang],
 705     [Use the compiled Clang as the LLVM compiler (default=check)]),
 706     [],[with_built_clang=check])
 707
 708 dnl Select the Clang compiler option.
 709 dnl
 710 dnl If --with-clang is given, always honor that; otherwise honor
 711 dnl --with-built-clang, or check if we have the clang sources.
 712 AC_MSG_CHECKING([clang compiler])
 713 WITH_CLANGPATH=""
 714 WITH_BUILT_CLANG=0
 715 if test "$with_clang" != "default"; then
 716    WITH_CLANGPATH="$with_clang"
 717    if ! test -x "$WITH_CLANGPATH"; then
 718      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 719    fi
 720 elif test "$with_built_clang" = "yes"; then
 721    WITH_BUILT_CLANG=1
 722 elif test "$with_built_clang" = "no"; then
 723    WITH_BUILT_CLANG=0
 724 else
 725    if test "$with_built_clang" != "check"; then
 726       AC_MSG_ERROR([invalid value for --with-built-clang.])
 727    fi
 728
 729    if test -f ${srcdir}/tools/clang/README.txt; then
 730      WITH_BUILT_CLANG=1
 731    fi
 732 fi
 733
 734 if ! test -z "$WITH_CLANGPATH"; then
 735    AC_MSG_RESULT([$WITH_CLANGPATH])
 736    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 737 elif test "$WITH_BUILT_CLANG" = "1"; then
 738    AC_MSG_RESULT([built])
 739 else
 740    AC_MSG_RESULT([none])
 741 fi
 742 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 743 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 744 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 745
 746 dnl Override the option to use for optimized builds.
 747 AC_ARG_WITH(optimize-option,
 748   AS_HELP_STRING([--with-optimize-option],
 749                  [Select the compiler options to use for optimized builds]),,
 750                  withval=default)
 751 AC_MSG_CHECKING([optimization flags])
 752 case "$withval" in
 753   default)
 754     case "$llvm_cv_os_type" in
 755     FreeBSD) optimize_option=-O2 ;;
 756     MingW) optimize_option=-O2 ;;
 757     *)     optimize_option=-O3 ;;
 758     esac ;;
 759   *) optimize_option="$withval" ;;
 760 esac
 761 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 762 AC_MSG_RESULT([$optimize_option])
 763
 764 dnl Specify extra build options
 765 AC_ARG_WITH(extra-options,
 766   AS_HELP_STRING([--with-extra-options],
 767                  [Specify additional options to compile LLVM with]),,
 768                  withval=default)
 769 case "$withval" in
 770   default) EXTRA_OPTIONS= ;;
 771   *) EXTRA_OPTIONS=$withval ;;
 772 esac
 773 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 774
 775 dnl Allow specific bindings to be specified for building (or not)
 776 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 777     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 778     enableval=default)
 779 BINDINGS_TO_BUILD=""
 780 case "$enableval" in
 781   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 782   all ) BINDINGS_TO_BUILD="ocaml" ;;
 783   none | no) BINDINGS_TO_BUILD="" ;;
 784   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 785       case "$a_binding" in
 786         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 787         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 788       esac
 789   done
 790   ;;
 791 esac
 792
 793 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 794 dnl script for bindings/ocaml/configure, except that its auto value depends on
 795 dnl OCAMLC, which is found here to support tests.
 796 AC_ARG_WITH([ocaml-libdir],
 797   [AS_HELP_STRING([--with-ocaml-libdir],
 798     [Specify install location for ocaml bindings (default is stdlib)])],
 799   [],
 800   [withval=auto])
 801 case "$withval" in
 802   auto) with_ocaml_libdir="$withval" ;;
 803   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 804   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 805 esac
 806
 807 AC_ARG_WITH(c-include-dirs,
 808   AS_HELP_STRING([--with-c-include-dirs],
 809     [Colon separated list of directories clang will search for headers]),,
 810     withval="")
 811 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 812                    [Directories clang will search for headers])
 813
 814 AC_ARG_WITH(cxx-include-root,
 815   AS_HELP_STRING([--with-cxx-include-root],
 816     [Directory with the libstdc++ headers.]),,
 817     withval="")
 818 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 819                    [Directory with the libstdc++ headers.])
 820
 821 AC_ARG_WITH(cxx-include-arch,
 822   AS_HELP_STRING([--with-cxx-include-arch],
 823     [Architecture of the libstdc++ headers.]),,
 824     withval="")
 825 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 826                    [Arch the libstdc++ headers.])
 827
 828 AC_ARG_WITH(cxx-include-32bit-dir,
 829   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 830     [32 bit multilib dir.]),,
 831     withval="")
 832 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 833                    [32 bit multilib directory.])
 834
 835 AC_ARG_WITH(cxx-include-64bit-dir,
 836   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 837     [64 bit multilib directory.]),,
 838     withval="")
 839 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 840                    [64 bit multilib directory.])
 841
 842 dnl Allow linking of LLVM with GPLv3 binutils code.
 843 AC_ARG_WITH(binutils-include,
 844   AS_HELP_STRING([--with-binutils-include],
 845     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 846   withval=default)
 847 case "$withval" in
 848   default) WITH_BINUTILS_INCDIR=default ;;
 849   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 850   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 851 esac
 852 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 853   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 854   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 855      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 856      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 857   fi
 858 fi
 859
 860 dnl --enable-libffi : check whether the user wants to turn off libffi:
 861 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 862   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 863   [case "$enableval" in
 864     yes) llvm_cv_enable_libffi="yes" ;;
 865     no)  llvm_cv_enable_libffi="no"  ;;
 866     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 867   esac],
 868   llvm_cv_enable_libffi=no)
 869
 870 dnl===-----------------------------------------------------------------------===
 871 dnl===
 872 dnl=== SECTION 4: Check for programs we need and that they are the right version
 873 dnl===
 874 dnl===-----------------------------------------------------------------------===
 875
 876 dnl Check for compilation tools
 877 AC_PROG_CPP
 878 AC_PROG_CC(gcc)
 879 AC_PROG_CXX(g++)
 880
 881 AC_PROG_NM
 882 AC_SUBST(NM)
 883
 884 dnl Check for the tools that the makefiles require
 885 AC_CHECK_GNU_MAKE
 886 AC_PROG_LN_S
 887 AC_PATH_PROG(CMP, [cmp], [cmp])
 888 AC_PATH_PROG(CP, [cp], [cp])
 889 AC_PATH_PROG(DATE, [date], [date])
 890 AC_PATH_PROG(FIND, [find], [find])
 891 AC_PATH_PROG(GREP, [grep], [grep])
 892 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 893 AC_PATH_PROG(MV,   [mv],   [mv])
 894 AC_PROG_RANLIB
 895 AC_CHECK_TOOL(AR, ar, false)
 896 AC_PATH_PROG(RM,   [rm],   [rm])
 897 AC_PATH_PROG(SED,  [sed],  [sed])
 898 AC_PATH_PROG(TAR,  [tar],  [gtar])
 899 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 900
 901 dnl Looking for misc. graph plotting software
 902 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 903 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 904   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 905   dnl If we're targeting for mingw we should emit windows paths, not msys
 906   if test "$llvm_cv_os_type" = "MingW" ; then
 907     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 908   fi
 909   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 910    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 911 fi
 912 AC_PATH_PROG(DOT, [dot], [echo dot])
 913 if test "$DOT" != "echo dot" ; then
 914   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 915   dnl If we're targeting for mingw we should emit windows paths, not msys
 916   if test "$llvm_cv_os_type" = "MingW" ; then
 917     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 918   fi
 919   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 920    [Define to path to dot program if found or 'echo dot' otherwise])
 921 fi
 922 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 923 if test "$FDP" != "echo fdp" ; then
 924   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 925   dnl If we're targeting for mingw we should emit windows paths, not msys
 926   if test "$llvm_cv_os_type" = "MingW" ; then
 927     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 928   fi
 929   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 930    [Define to path to fdp program if found or 'echo fdp' otherwise])
 931 fi
 932 AC_PATH_PROG(NEATO, [neato], [echo neato])
 933 if test "$NEATO" != "echo neato" ; then
 934   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 935   dnl If we're targeting for mingw we should emit windows paths, not msys
 936   if test "$llvm_cv_os_type" = "MingW" ; then
 937     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 938   fi
 939   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 940    [Define to path to neato program if found or 'echo neato' otherwise])
 941 fi
 942 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 943 if test "$TWOPI" != "echo twopi" ; then
 944   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 945   dnl If we're targeting for mingw we should emit windows paths, not msys
 946   if test "$llvm_cv_os_type" = "MingW" ; then
 947     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 948   fi
 949   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 950    [Define to path to twopi program if found or 'echo twopi' otherwise])
 951 fi
 952 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 953 if test "$CIRCO" != "echo circo" ; then
 954   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 955   dnl If we're targeting for mingw we should emit windows paths, not msys
 956   if test "$llvm_cv_os_type" = "MingW" ; then
 957     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 958   fi
 959   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 960    [Define to path to circo program if found or 'echo circo' otherwise])
 961 fi
 962 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 963 if test "$GV" != "echo gv" ; then
 964   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 965   dnl If we're targeting for mingw we should emit windows paths, not msys
 966   if test "$llvm_cv_os_type" = "MingW" ; then
 967     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 968   fi
 969   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 970    [Define to path to gv program if found or 'echo gv' otherwise])
 971 fi
 972 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 973 if test "$DOTTY" != "echo dotty" ; then
 974   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 975   dnl If we're targeting for mingw we should emit windows paths, not msys
 976   if test "$llvm_cv_os_type" = "MingW" ; then
 977     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 978   fi
 979   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 980    [Define to path to dotty program if found or 'echo dotty' otherwise])
 981 fi
 982 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 983 if test "$XDOT_PY" != "echo xdot.py" ; then
 984   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 985   dnl If we're targeting for mingw we should emit windows paths, not msys
 986   if test "$llvm_cv_os_type" = "MingW" ; then
 987     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 988   fi
 989   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 990    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 991 fi
 992
 993 dnl Look for a sufficiently recent version of Perl.
 994 LLVM_PROG_PERL([5.006])
 995 AC_SUBST(PERL)
 996 if test x"$PERL" = xnone; then
 997    AC_SUBST(HAVE_PERL,0)
 998    AC_MSG_ERROR([perl is required but was not found, please install it])
 999 else
1000    AC_SUBST(HAVE_PERL,1)
1001 fi
1002
1003 dnl Find the install program
1004 AC_PROG_INSTALL
1005 dnl Prepend src dir to install path dir if it's a relative path
1006 dnl This is a hack for installs that take place in something other
1007 dnl than the top level.
1008 case "$INSTALL" in
1009  [[\\/$]]* | ?:[[\\/]]* ) ;;
1010  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1011 esac
1012
1013 dnl Checks for documentation and testing tools that we can do without. If these
1014 dnl are not found then they are set to "true" which always succeeds but does
1015 dnl nothing. This just lets the build output show that we could have done
1016 dnl something if the tool was available.
1017 AC_PATH_PROG(BZIP2, [bzip2])
1018 AC_PATH_PROG(CAT, [cat])
1019 AC_PATH_PROG(DOXYGEN, [doxygen])
1020 AC_PATH_PROG(GROFF, [groff])
1021 AC_PATH_PROG(GZIP, [gzip])
1022 AC_PATH_PROG(POD2HTML, [pod2html])
1023 AC_PATH_PROG(POD2MAN, [pod2man])
1024 AC_PATH_PROG(PDFROFF, [pdfroff])
1025 AC_PATH_PROG(RUNTEST, [runtest])
1026 DJ_AC_PATH_TCLSH
1027 AC_PATH_PROG(ZIP, [zip])
1028 AC_PATH_PROGS(OCAMLC, [ocamlc])
1029 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1030 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1031 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1032 AC_PATH_PROGS(GAS, [gas as])
1033
1034 dnl Get the version of the linker in use.
1035 AC_LINK_GET_VERSION
1036
1037 dnl Determine whether the linker supports the -R option.
1038 AC_LINK_USE_R
1039
1040 dnl Determine whether the linker supports the -export-dynamic option.
1041 AC_LINK_EXPORT_DYNAMIC
1042
1043 dnl Determine whether the linker supports the --version-script option.
1044 AC_LINK_VERSION_SCRIPT
1045
1046 dnl Check for libtool and the library that has dlopen function (which must come
1047 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1048 dnl libtool).
1049 AC_LIBTOOL_DLOPEN
1050 AC_LIB_LTDL
1051
1052 if test "$WITH_LLVMGCCDIR" = "default" ; then
1053   LLVMGCC="llvm-gcc${EXEEXT}"
1054   LLVMGXX="llvm-g++${EXEEXT}"
1055   LLVMGCCCOMMAND="$LLVMGCC"
1056   LLVMGXXCOMMAND="$LLVMGXX"
1057   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1058   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1059   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1060   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1061 else
1062   if test -z "$LLVMGCC"; then
1063     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1064     LLVMGCCCOMMAND="$LLVMGCC"
1065   fi
1066   if test -z "$LLVMGXX"; then
1067     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1068     LLVMGXXCOMMAND="$LLVMGXX"
1069   fi
1070
1071   AC_SUBST(LLVMGCC,$LLVMGCC)
1072   AC_SUBST(LLVMGXX,$LLVMGXX)
1073   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1074   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1075 fi
1076
1077 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1078 dnl found, otherwise clang if available.
1079 AC_ARG_WITH(llvmcc,
1080   AS_HELP_STRING([--with-llvmcc=<name>],
1081     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1082     [],[with_llvmcc=check])
1083 AC_MSG_CHECKING([LLVM capable compiler])
1084 if test "$with_llvmcc" != "check"; then
1085    if (test "$with_llvmcc" != "llvm-gcc" &&
1086        test "$with_llvmcc" != "clang" &&
1087        test "$with_llvmcc" != "none"); then
1088       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1089    fi
1090    WITH_LLVMCC="$with_llvmcc"
1091 elif test -n "$LLVMGCC"; then
1092    WITH_LLVMCC=llvm-gcc
1093 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1094    WITH_LLVMCC=clang
1095 else
1096    WITH_LLVMCC=none
1097 fi
1098 AC_MSG_RESULT([$WITH_LLVMCC])
1099 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1100
1101 AC_MSG_CHECKING([tool compatibility])
1102
1103 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1104 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1105 dnl to support those options.
1106 dnl "icc" emits gcc signatures
1107 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1108 ICC=no
1109 IXX=no
1110 case $CC in
1111   icc*|icpc*)
1112     ICC=yes
1113     IXX=yes
1114     ;;
1115    *)
1116     ;;
1117 esac
1118
1119 if test "$GCC" != "yes" && test "$ICC" != "yes"
1120 then
1121   AC_MSG_ERROR([gcc|icc required but not found])
1122 fi
1123
1124 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1125 if test "$GXX" != "yes" && test "$IXX" != "yes"
1126 then
1127   AC_MSG_ERROR([g++|icc required but not found])
1128 fi
1129
1130 dnl Verify that GCC is version 3.0 or higher
1131 if test "$GCC" = "yes"
1132 then
1133   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1134 #error Unsupported GCC version
1135 #endif
1136 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1137 fi
1138
1139 dnl Check for GNU Make.  We use its extensions, so don't build without it
1140 if test -z "$llvm_cv_gnu_make_command"
1141 then
1142   AC_MSG_ERROR([GNU Make required but not found])
1143 fi
1144
1145 dnl Tool compatibility is okay if we make it here.
1146 AC_MSG_RESULT([ok])
1147
1148 dnl Check optional compiler flags.
1149 AC_MSG_CHECKING([optional compiler flags])
1150 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1151 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1152 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1153
1154 dnl===-----------------------------------------------------------------------===
1155 dnl===
1156 dnl=== SECTION 5: Check for libraries
1157 dnl===
1158 dnl===-----------------------------------------------------------------------===
1159
1160 AC_CHECK_LIB(m,sin)
1161 if test "$llvm_cv_os_type" = "MingW" ; then
1162   AC_CHECK_LIB(imagehlp, main)
1163   AC_CHECK_LIB(psapi, main)
1164 fi
1165
1166 dnl dlopen() is required for plugin support.
1167 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1168                [Define if dlopen() is available on this platform.]),
1169                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1170
1171 dnl libffi is optional; used to call external functions from the interpreter
1172 if test "$llvm_cv_enable_libffi" = "yes" ; then
1173   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1174                  [Define if libffi is available on this platform.]),
1175                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1176 fi
1177
1178 dnl mallinfo is optional; the code can compile (minus features) without it
1179 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1180                [Define if mallinfo() is available on this platform.]))
1181
1182 dnl pthread locking functions are optional - but llvm will not be thread-safe
1183 dnl without locks.
1184 if test "$ENABLE_THREADS" -eq 1 ; then
1185   AC_CHECK_LIB(pthread, pthread_mutex_init)
1186   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1187                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1188                            [Have pthread_mutex_lock]))
1189   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1190                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1191                  [Have pthread_rwlock_init]))
1192   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1193                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1194                  [Have pthread_getspecific]))
1195 fi
1196
1197 dnl Allow extra x86-disassembler library
1198 AC_ARG_WITH(udis86,
1199   AS_HELP_STRING([--with-udis86=<path>],
1200     [Use udis86 external x86 disassembler library]),
1201     [
1202       AC_SUBST(USE_UDIS86, [1])
1203       case "$withval" in
1204         /usr/lib|yes) ;;
1205         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1206       esac
1207       AC_CHECK_LIB(udis86, ud_init, [], [
1208         echo "Error! You need to have libudis86 around."
1209         exit -1
1210       ])
1211     ],
1212     AC_SUBST(USE_UDIS86, [0]))
1213 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1214                    [Define if use udis86 library])
1215
1216 dnl Allow OProfile support for JIT output.
1217 AC_ARG_WITH(oprofile,
1218   AS_HELP_STRING([--with-oprofile=<prefix>],
1219     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1220     [
1221       AC_SUBST(USE_OPROFILE, [1])
1222       case "$withval" in
1223         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1224         no) llvm_cv_oppath=
1225             AC_SUBST(USE_OPROFILE, [0]) ;;
1226         *) llvm_cv_oppath="${withval}/lib/oprofile"
1227            CPPFLAGS="-I${withval}/include";;
1228       esac
1229       if test -n "$llvm_cv_oppath" ; then
1230         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1231         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1232         dnl libbfd is not included properly in libopagent in some Debian
1233         dnl versions.  If libbfd isn't found at all, we assume opagent works
1234         dnl anyway.
1235         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1236         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1237           echo "Error! You need to have libopagent around."
1238           exit -1
1239         ])
1240         AC_CHECK_HEADER([opagent.h], [], [
1241           echo "Error! You need to have opagent.h around."
1242           exit -1
1243           ])
1244       fi
1245     ],
1246     [
1247       AC_SUBST(USE_OPROFILE, [0])
1248     ])
1249 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1250                    [Define if we have the oprofile JIT-support library])
1251
1252 dnl===-----------------------------------------------------------------------===
1253 dnl===
1254 dnl=== SECTION 6: Check for header files
1255 dnl===
1256 dnl===-----------------------------------------------------------------------===
1257
1258 dnl First, use autoconf provided macros for specific headers that we need
1259 dnl We don't check for ancient stuff or things that are guaranteed to be there
1260 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1261 dnl Generally we're looking for POSIX headers.
1262 AC_HEADER_DIRENT
1263 AC_HEADER_MMAP_ANONYMOUS
1264 AC_HEADER_STAT
1265 AC_HEADER_STDC
1266 AC_HEADER_SYS_WAIT
1267 AC_HEADER_TIME
1268
1269 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1270 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1271 AC_CHECK_HEADERS([utime.h windows.h])
1272 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1273 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1274 AC_CHECK_HEADERS([valgrind/valgrind.h])
1275 AC_CHECK_HEADERS([fenv.h])
1276 if test "$ENABLE_THREADS" -eq 1 ; then
1277   AC_CHECK_HEADERS(pthread.h,
1278                    AC_SUBST(HAVE_PTHREAD, 1),
1279                    AC_SUBST(HAVE_PTHREAD, 0))
1280 else
1281   AC_SUBST(HAVE_PTHREAD, 0)
1282 fi
1283
1284 dnl Try to find ffi.h.
1285 if test "$llvm_cv_enable_libffi" = "yes" ; then
1286   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1287 fi
1288
1289 dnl Try to find Darwin specific crash reporting library.
1290 AC_CHECK_HEADERS([CrashReporterClient.h])
1291
1292 dnl===-----------------------------------------------------------------------===
1293 dnl===
1294 dnl=== SECTION 7: Check for types and structures
1295 dnl===
1296 dnl===-----------------------------------------------------------------------===
1297
1298 AC_HUGE_VAL_CHECK
1299 AC_TYPE_PID_T
1300 AC_TYPE_SIZE_T
1301 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1302 AC_STRUCT_TM
1303 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1304 AC_CHECK_TYPES([uint64_t],,
1305          AC_CHECK_TYPES([u_int64_t],,
1306          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1307
1308 dnl===-----------------------------------------------------------------------===
1309 dnl===
1310 dnl=== SECTION 8: Check for specific functions needed
1311 dnl===
1312 dnl===-----------------------------------------------------------------------===
1313
1314 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1315 AC_CHECK_FUNCS([powf fmodf strtof round ])
1316 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1317 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1318 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1319 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1320 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1321 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1322 AC_C_PRINTF_A
1323 AC_FUNC_RAND48
1324
1325 dnl Check for variations in the Standard C++ library and STL. These macros are
1326 dnl provided by LLVM in the autoconf/m4 directory.
1327 AC_FUNC_ISNAN
1328 AC_FUNC_ISINF
1329
1330 dnl Check for mmap support.We also need to know if /dev/zero is required to
1331 dnl be opened for allocating RWX memory.
1332 dnl Make sure we aren't attempting to configure for an unknown system
1333 if test "$llvm_cv_platform_type" = "Unix" ; then
1334   AC_FUNC_MMAP
1335   AC_FUNC_MMAP_FILE
1336   AC_NEED_DEV_ZERO_FOR_MMAP
1337
1338   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1339   then
1340     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1341   fi
1342   if test "$ac_cv_func_mmap_file" = "no"
1343   then
1344     AC_MSG_WARN([mmap() of files required but not found])
1345   fi
1346 fi
1347
1348 dnl atomic builtins are required for threading support.
1349 AC_MSG_CHECKING(for GCC atomic builtins)
1350 dnl Since we'll be using these atomic builtins in C++ files we should test
1351 dnl the C++ compiler.
1352 AC_LANG_PUSH([C++])
1353 AC_LINK_IFELSE(
1354   AC_LANG_SOURCE(
1355     [[int main() {
1356         volatile unsigned long val = 1;
1357         __sync_synchronize();
1358         __sync_val_compare_and_swap(&val, 1, 0);
1359         __sync_add_and_fetch(&val, 1);
1360         __sync_sub_and_fetch(&val, 1);
1361         return 0;
1362       }
1363     ]]),
1364   AC_LANG_POP([C++])
1365   AC_MSG_RESULT(yes)
1366   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1367   AC_MSG_RESULT(no)
1368   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1369   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1370
1371 dnl===-----------------------------------------------------------------------===
1372 dnl===
1373 dnl=== SECTION 9: Additional checks, variables, etc.
1374 dnl===
1375 dnl===-----------------------------------------------------------------------===
1376
1377 dnl Handle 32-bit linux systems running a 64-bit kernel.
1378 dnl This has to come after section 4 because it invokes the compiler.
1379 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1380   AC_IS_LINUX_MIXED
1381   if test "$llvm_cv_linux_mixed" = "yes"; then
1382     llvm_cv_target_arch="x86"
1383     ARCH="x86"
1384   fi
1385 fi
1386
1387 dnl Check, whether __dso_handle is present
1388 AC_CHECK_FUNCS([__dso_handle])
1389
1390 dnl See if the llvm-gcc executable can compile to LLVM assembly
1391 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1392 [llvm_cv_llvmgcc_sanity="no"
1393 if test -x "$LLVMGCC" ; then
1394   cp /dev/null conftest.c
1395   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1396       grep 'target datalayout =' > /dev/null 2>&1
1397   if test $? -eq 0 ; then
1398     llvm_cv_llvmgcc_sanity="yes"
1399   fi
1400   rm conftest.c
1401 fi])
1402
1403 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1404 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1405   AC_MSG_CHECKING([llvm-gcc component support])
1406   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1407   AC_SUBST(LLVMCC1,$llvmcc1path)
1408   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1409   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1410   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1411   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1412   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1413   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1414   AC_MSG_RESULT([ok])
1415 fi
1416
1417 dnl Propagate the shared library extension that the libltdl checks did to
1418 dnl the Makefiles so we can use it there too
1419 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1420
1421 dnl Propagate the run-time library path variable that the libltdl
1422 dnl checks found to the Makefiles so we can use it there too
1423 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1424
1425 # Translate the various configuration directories and other basic
1426 # information into substitutions that will end up in Makefile.config.in
1427 # that these configured values can be used by the makefiles
1428 if test "${prefix}" = "NONE" ; then
1429   prefix="/usr/local"
1430 fi
1431 eval LLVM_PREFIX="${prefix}";
1432 eval LLVM_BINDIR="${prefix}/bin";
1433 eval LLVM_LIBDIR="${prefix}/lib";
1434 eval LLVM_DATADIR="${prefix}/share/llvm";
1435 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1436 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1437 eval LLVM_INCLUDEDIR="${prefix}/include";
1438 eval LLVM_INFODIR="${prefix}/info";
1439 eval LLVM_MANDIR="${prefix}/man";
1440 LLVM_CONFIGTIME=`date`
1441 AC_SUBST(LLVM_PREFIX)
1442 AC_SUBST(LLVM_BINDIR)
1443 AC_SUBST(LLVM_LIBDIR)
1444 AC_SUBST(LLVM_DATADIR)
1445 AC_SUBST(LLVM_DOCSDIR)
1446 AC_SUBST(LLVM_ETCDIR)
1447 AC_SUBST(LLVM_INCLUDEDIR)
1448 AC_SUBST(LLVM_INFODIR)
1449 AC_SUBST(LLVM_MANDIR)
1450 AC_SUBST(LLVM_CONFIGTIME)
1451
1452 # Place the various directores into the config.h file as #defines so that we
1453 # can know about the installation paths within LLVM.
1454 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1455                    [Installation prefix directory])
1456 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1457                    [Installation directory for binary executables])
1458 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1459                    [Installation directory for libraries])
1460 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1461                    [Installation directory for data files])
1462 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1463                    [Installation directory for documentation])
1464 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1465                    [Installation directory for config files])
1466 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1467                    [Installation directory for include files])
1468 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1469                    [Installation directory for .info files])
1470 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1471                    [Installation directory for man pages])
1472 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1473                    [Time at which LLVM was configured])
1474 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1475                    [Host triple we were built on])
1476
1477 # Determine which bindings to build.
1478 if test "$BINDINGS_TO_BUILD" = auto ; then
1479   BINDINGS_TO_BUILD=""
1480   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1481     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1482   fi
1483 fi
1484 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1485
1486 # This isn't really configurey, but it avoids having to repeat the list in
1487 # other files.
1488 AC_SUBST(ALL_BINDINGS,ocaml)
1489
1490 # Do any work necessary to ensure that bindings have what they need.
1491 binding_prereqs_failed=0
1492 for a_binding in $BINDINGS_TO_BUILD ; do
1493   case "$a_binding" in
1494   ocaml)
1495     if test "x$OCAMLC" = x ; then
1496       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1497       binding_prereqs_failed=1
1498     fi
1499     if test "x$OCAMLDEP" = x ; then
1500       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1501       binding_prereqs_failed=1
1502     fi
1503     if test "x$OCAMLOPT" = x ; then
1504       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1505       dnl ocamlopt is optional!
1506     fi
1507     if test "x$with_ocaml_libdir" != xauto ; then
1508       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1509     else
1510       ocaml_stdlib="`"$OCAMLC" -where`"
1511       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1512       then
1513         # ocaml stdlib is beneath our prefix; use stdlib
1514         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1515       else
1516         # ocaml stdlib is outside our prefix; use libdir/ocaml
1517         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1518       fi
1519     fi
1520     ;;
1521   esac
1522 done
1523 if test "$binding_prereqs_failed" = 1 ; then
1524   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1525 fi
1526
1527 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1528 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1529
1530 dnl Determine linker rpath flag
1531 if test "$llvm_cv_link_use_r" = "yes" ; then
1532   RPATH="-Wl,-R"
1533 else
1534   RPATH="-Wl,-rpath"
1535 fi
1536 AC_SUBST(RPATH)
1537
1538 dnl Determine linker rdynamic flag
1539 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1540   RDYNAMIC="-Wl,-export-dynamic"
1541 else
1542   RDYNAMIC=""
1543 fi
1544 AC_SUBST(RDYNAMIC)
1545
1546 dnl===-----------------------------------------------------------------------===
1547 dnl===
1548 dnl=== SECTION 10: Specify the output files and generate it
1549 dnl===
1550 dnl===-----------------------------------------------------------------------===
1551
1552 dnl Configure header files
1553 dnl WARNING: dnl If you add or remove any of the following config headers, then
1554 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1555 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1556 dnl files can be updated automatically when their *.in sources change.
1557 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1558 AH_TOP([#ifndef CONFIG_H
1559 #define CONFIG_H])
1560 AH_BOTTOM([#endif])
1561
1562 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1563 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1564 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1565 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1566 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1567
1568 dnl Configure the makefile's configuration data
1569 AC_CONFIG_FILES([Makefile.config])
1570
1571 dnl Configure the RPM spec file for LLVM
1572 AC_CONFIG_FILES([llvm.spec])
1573
1574 dnl Configure llvmc's Base plugin
1575 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1576
1577 dnl Do the first stage of configuration for llvm-config.in.
1578 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1579
1580 dnl Do special configuration of Makefiles
1581 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1582 AC_CONFIG_MAKEFILE(Makefile)
1583 AC_CONFIG_MAKEFILE(Makefile.common)
1584 AC_CONFIG_MAKEFILE(examples/Makefile)
1585 AC_CONFIG_MAKEFILE(lib/Makefile)
1586 AC_CONFIG_MAKEFILE(runtime/Makefile)
1587 AC_CONFIG_MAKEFILE(test/Makefile)
1588 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1589 AC_CONFIG_MAKEFILE(unittests/Makefile)
1590 AC_CONFIG_MAKEFILE(tools/Makefile)
1591 AC_CONFIG_MAKEFILE(utils/Makefile)
1592 AC_CONFIG_MAKEFILE(projects/Makefile)
1593 AC_CONFIG_MAKEFILE(bindings/Makefile)
1594 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1595
1596 dnl Finally, crank out the output
1597 AC_OUTPUT