autoconf/configure.ac

   1 dnl Initialize autoconf
   2 AC_INIT([[[LLVM]]],[[[1.3]]],[llvmbugs@cs.uiuc.edu])
   3
   4 dnl Place all of the extra autoconf files into the config subdirectory
   5 AC_CONFIG_AUX_DIR([autoconf])
   6
   7 dnl Quit if the source directory has already been configured.
   8 dnl NOTE: This relies upon undocumented autoconf behavior.
   9 if test ${srcdir} != "."
  10 then
  11         if test -f ${srcdir}/include/Config/config.h
  12         then
  13                 AC_MSG_ERROR([Already configured in ${srcdir}])
  14         fi
  15 fi
  16
  17 dnl Configure all of the projects present in our source tree.
  18 for i in `ls ${srcdir}/projects`
  19 do
  20   if test ${i} != "CVS"
  21   then
  22     if test -f ${srcdir}/projects/${i}/configure
  23     then
  24       AC_CONFIG_SUBDIRS(projects/${i})
  25     fi
  26   fi
  27 done
  28
  29 dnl Configure a header file
  30 AC_CONFIG_HEADERS(include/Config/config.h)
  31 AC_CONFIG_MAKEFILE(Makefile)
  32 AC_CONFIG_MAKEFILE(Makefile.common)
  33 AC_CONFIG_MAKEFILE(lib/Makefile)
  34 AC_CONFIG_MAKEFILE(runtime/Makefile)
  35 AC_CONFIG_MAKEFILE(test/Makefile)
  36 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  37 AC_CONFIG_MAKEFILE(test/QMTest/llvm.py)
  38 AC_CONFIG_MAKEFILE(test/QMTest/llvmdb.py)
  39 AC_CONFIG_MAKEFILE(test/Programs/Makefile)
  40 AC_CONFIG_MAKEFILE(test/Programs/Makefile.programs)
  41 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.Makefile)
  42 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.report)
  43 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.report)
  44 AC_CONFIG_MAKEFILE(test/Programs/TEST.example.Makefile)
  45 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.Makefile)
  46 AC_CONFIG_MAKEFILE(test/Programs/TEST.buildrepo.Makefile)
  47 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.Makefile)
  48 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.report)
  49 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.Makefile)
  50 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.report)
  51 AC_CONFIG_MAKEFILE(test/Programs/TEST.typesafe.Makefile)
  52 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.gnuplot)
  53 AC_CONFIG_MAKEFILE(test/Programs/TEST.vtl.Makefile)
  54 AC_CONFIG_MAKEFILE(test/Programs/External/Makefile)
  55 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile)
  56 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec)
  57 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec2000)
  58 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec95)
  59 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile)
  60 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile.multisrc)
  61 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/analyzer/test.in)
  62 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/distray/Makefile)
  63 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/distray/test.in)
  64 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/fourinarow/Makefile)
  65 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/fourinarow/test.in)
  66 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/mason/Makefile)
  67 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/mason/test.in)
  68 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/neural/Makefile)
  69 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/neural/test.in)
  70 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pcompress2/Makefile)
  71 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pcompress2/test.in)
  72 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pifft/Makefile)
  73 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pifft/test.in)
  74 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile)
  75 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile.singlesrc)
  76 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/SetjmpLongjmp/Makefile)
  77 AC_CONFIG_MAKEFILE(tools/Makefile)
  78 AC_CONFIG_MAKEFILE(utils/Makefile)
  79 AC_CONFIG_MAKEFILE(projects/Makefile)
  80
  81 dnl Find the install program (needs to be done before canonical stuff)
  82 AC_PROG_INSTALL
  83
  84 dnl Check which host for which we're compiling.  This will tell us which LLVM
  85 dnl compiler will be used for compiling SSA into object code.
  86 AC_CANONICAL_TARGET
  87
  88 dnl Set the "OS" Makefile variable based on the system we are building on.
  89 dnl We will use the build machine information to set some variables.
  90 case $build in
  91         *-*-linux*)
  92              AC_SUBST(OS,[Linux])
  93                          if test -d /home/vadve/lattner/local/x86/llvm-gcc
  94                          then
  95                            AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
  96                          fi
  97                  ;;
  98
  99         *-*-solaris*)
 100              AC_SUBST(OS,[SunOS])
 101                          if test -d /home/vadve/lattner/local/sparc/llvm-gcc
 102                          then
 103                    AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 104                          fi
 105                  ;;
 106
 107         *-*-darwin*)
 108              AC_SUBST(OS,[Darwin])
 109                  ;;
 110
 111         *)       AC_SUBST(OS,[Unknown])
 112                  ;;
 113 esac
 114
 115 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 116 dnl V9, since that is all that we support at the moment, and autoconf will only
 117 dnl tell us we're a sparc.
 118 case $target in
 119         sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 120                             ;;
 121 esac
 122
 123 dnl Determine what our target architecture is and configure accordingly.
 124 dnl This will allow Makefiles to make a distinction between the hardware and
 125 dnl the OS.
 126 case $target in
 127         i*86-*)           AC_SUBST(ARCH,[x86])
 128                           ;;
 129         sparc*-*)         AC_SUBST(ARCH,[Sparc])
 130                           ;;
 131         powerpc*-*)       AC_SUBST(ARCH,[PowerPC])
 132                           ;;
 133         *)                AC_SUBST(ARCH,[Unknown])
 134                           ;;
 135 esac
 136
 137 dnl Check for compilation tools
 138 AC_PROG_CXX
 139 AC_PROG_CC(gcc)
 140 AC_PROG_CPP
 141
 142 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 143 if test "$GCC" != "yes"
 144 then
 145         AC_MSG_ERROR([gcc required but not found])
 146 fi
 147 if test "$GXX" != "yes"
 148 then
 149         AC_MSG_ERROR([g++ required but not found])
 150 fi
 151
 152 dnl Verify that GCC is version 3.0 or higher
 153 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 154 if test "$gccmajor" -lt "3"
 155 then
 156         AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 157 fi
 158
 159 dnl Check for GNU Make.  We use its extensions too, so don't build without it
 160 CHECK_GNU_MAKE
 161 if test -z "$_cv_gnu_make_command"
 162 then
 163         AC_MSG_ERROR([GNU Make required but not found])
 164 fi
 165
 166 dnl Checks for other tools
 167 AC_PROG_FLEX
 168 AC_PROG_BISON
 169 AC_PROG_LIBTOOL
 170
 171 dnl Checks for tools we can get away with not having:
 172 AC_PATH_PROG(DOT,[dot],[true dot])
 173 AC_PATH_PROG(ETAGS,[etags],[true etags])
 174 dnl Check if we know how to tell etags we are using C++:
 175 etags_version=`$ETAGS --version 2>&1`
 176 case "$etags_version" in
 177         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 178         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 179         *) ETAGSFLAGS="" ;;
 180 esac
 181 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 182 AC_PATH_PROG(PYTHON,[python],[true python])
 183 if test "$PYTHON" = "false"
 184 then
 185         AC_MSG_WARN([Python is required for the test suite, but it was not found])
 186 fi
 187 AC_PATH_PROG(QMTEST,[qmtest],[true qmtest])
 188 if test "$QMTEST" = "false"
 189 then
 190         AC_MSG_WARN([QMTest is required for the test suite, but it was not found])
 191 fi
 192
 193 dnl Verify that the version of python available is high enough for qmtest
 194 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 195 pymajor=`echo $pyversion | cut -d. -f1`
 196 pyminor=`echo $pyversion | cut -d. -f2`
 197
 198 if test "$pymajor" -ge "2"
 199 then
 200         if test "$pymajor" -eq "2"
 201         then
 202                 if test "$pyminor" -lt "2"
 203                 then
 204                         AC_MSG_WARN([QMTest requires Python 2.2 or later])
 205                 fi
 206         fi
 207 else
 208         AC_MSG_WARN([QMTest requires Python 2.2 or later])
 209 fi
 210
 211 dnl Verify that the source directory is valid
 212 AC_CONFIG_SRCDIR(["Makefile.config.in"])
 213
 214 dnl Checks for libraries:
 215 dnl libelf is for sparc only; we can ignore it if we don't have it
 216 AC_CHECK_LIB(elf, elf_begin)
 217
 218 dnl dlopen() is required for plugin support.
 219 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],[Define if dlopen() is available on this platform.]),AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 220
 221 dnl mallinfo is optional; the code can compile (minus features) without it
 222 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],[Define if mallinfo() is available on this platform.]))
 223
 224 dnl pthread locking functions are optional - but llvm will not be thread-safe
 225 dnl without locks.
 226 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,HAVE_PTHREAD_MUTEX_LOCK=1,HAVE_PTHREAD_MUTEX_LOCK=0)
 227 AC_SUBST(HAVE_PTHREAD_MUTEX_LOCK)
 228
 229 dnl Checks for header files.
 230 dnl We don't check for ancient stuff or things that are guaranteed to be there
 231 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 232 AC_HEADER_STDC
 233 AC_HEADER_SYS_WAIT
 234
 235 dnl Checks for POSIX and other various system-specific header files
 236 AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h malloc.h sys/mman.h sys/resource.h dlfcn.h link.h execinfo.h windows.h)
 237
 238 dnl Check for things that need to be included in public headers, and so
 239 dnl for which we may not have access to a HAVE_* preprocessor #define.
 240 dnl (primarily used in DataTypes.h)
 241 AC_CHECK_HEADER([sys/types.h],
 242                 [INCLUDE_SYS_TYPES_H='#include <sys/types.h>'],
 243                 [INCLUDE_SYS_TYPES_H=''])
 244 AC_SUBST(INCLUDE_SYS_TYPES_H)
 245 AC_CHECK_HEADER([inttypes.h],
 246                 [INCLUDE_INTTYPES_H='#include <inttypes.h>'],
 247                 [INCLUDE_INTTYPES_H=''])
 248 AC_SUBST(INCLUDE_INTTYPES_H)
 249
 250 dnl Check for types
 251 AC_TYPE_PID_T
 252 AC_TYPE_SIZE_T
 253 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 254 AC_CHECK_TYPES([uint64_t],,AC_MSG_ERROR([Type uint64_t required but not found]))
 255 AC_HEADER_TIME
 256 AC_STRUCT_TM
 257
 258 dnl Check for various C features
 259 AC_C_PRINTF_A
 260
 261 dnl Check for the endianness of the target
 262 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 263
 264 dnl Check for C++ extensions
 265 AC_CXX_HAVE_HASH_MAP
 266 AC_CXX_HAVE_HASH_SET
 267 AC_CXX_HAVE_STD_ITERATOR
 268 AC_CXX_HAVE_BI_ITERATOR
 269 AC_CXX_HAVE_FWD_ITERATOR
 270
 271 dnl Checks for library functions.
 272 AC_FUNC_ALLOCA
 273 AC_FUNC_MMAP
 274 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 275 then
 276         AC_MSG_WARN([mmap() required but not found])
 277 fi
 278 AC_FUNC_MMAP_FILE
 279 if test "$ac_cv_func_mmap_file" = "no"
 280 then
 281         AC_MSG_WARN([mmap() of files required but not found])
 282 fi
 283 AC_HEADER_MMAP_ANONYMOUS
 284 AC_TYPE_SIGNAL
 285 AC_CHECK_FUNCS(getcwd gettimeofday strdup strtoq strtoll backtrace isatty)
 286 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 287
 288 dnl Determine if the linker supports the -R option.
 289 AC_LINK_USE_R
 290
 291 dnl --enable/--with command-line options:
 292 dnl Check whether they want to do an optimized build:
 293 AC_ARG_ENABLE(optimized,AC_HELP_STRING([--enable-optimized],[Compile with optimizations enabled (default is NO)]),,enableval=no)
 294 if test ${enableval} = "no"
 295 then
 296         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 297 else
 298         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 299 fi
 300
 301 AC_DEFUN(EXTERNAL_BENCHMARK,
 302 [m4_define([allcapsname],translit($1,a-z,A-Z))
 303  AC_ARG_ENABLE($1,
 304  AC_HELP_STRING([--enable-$1=ARG],
 305                 [Use $1 as a benchmark (srcs in DIR)]),
 306  checkresult=$enableval,
 307  checkresult=auto)
 308 AC_MSG_CHECKING([for $1 benchmark sources])
 309 case "$checkresult" in
 310 auto|yes)
 311     defaultdir=$2
 312         if test -d "$defaultdir"
 313         then
 314                 AC_SUBST(allcapsname()[_ROOT],[$defaultdir])
 315                 AC_SUBST([USE_]allcapsname(),[USE_]allcapsname()=1)
 316         checkresult="yes, found in $defaultdir"
 317     else
 318         checkresult=no
 319     fi
 320     ;;
 321 no)
 322     AC_SUBST(allcapsname()[_ROOT],[])
 323     AC_SUBST([USE_]allcapsname(),[])
 324     checkresult=no
 325     ;;
 326 *)  if test -d "$checkresult"
 327     then
 328         AC_SUBST(allcapsname()[_ROOT],"$checkresult")
 329         AC_SUBST([USE_]allcapsname(),[USE_]allcapsname()=1)
 330         checkresult="yes, in $checkresult"
 331     else
 332         AC_SUBST(allcapsname()[_ROOT],[])
 333         AC_SUBST([USE_]allcapsname(),[])
 334         checkresult="no, not found in $checkresult"
 335     fi
 336     ;;
 337 esac
 338 AC_MSG_RESULT($checkresult)
 339 m4_undefine([allcapsname])
 340 ])
 341
 342 EXTERNAL_BENCHMARK(spec95,/home/vadve/shared/benchmarks/spec95/benchspec)
 343 EXTERNAL_BENCHMARK(spec2000,/home/vadve/shared/benchmarks/speccpu2000/benchspec)
 344 EXTERNAL_BENCHMARK(povray,/home/vadve/shared/benchmarks/povray31)
 345
 346 dnl Precompiled Bytecode Option
 347 AC_ARG_ENABLE(precompiled_bytecode,AC_HELP_STRING([--enable-precompiled_bytecode],[Use pre-compiled bytecode (default is NO)]),,enableval=no)
 348 if test ${enableval} = "no"
 349 then
 350         AC_SUBST(UPB,[[]])
 351 else
 352         AC_SUBST(UPB,[[USE_PRECOMPILED_BYTECODE=1]])
 353 fi
 354
 355 dnl LLC Diff Option
 356 AC_ARG_ENABLE(llc_diffs,AC_HELP_STRING([--enable-llc_diffs],[Enable LLC Diffs when testing (default is YES)]),,enableval=yes)
 357 if test ${enableval} = "no"
 358 then
 359         AC_SUBST(DISABLE_LLC_DIFFS,[DISABLE_LLC_DIFFS:=1])
 360 else
 361         AC_SUBST(DISABLE_LLC_DIFFS,[[]])
 362 fi
 363
 364 dnl JIT Option
 365 AC_ARG_ENABLE(jit,AC_HELP_STRING([--enable-jit],[Enable Just In Time Compiling (default is YES)]),,enableval=default)
 366 if test ${enableval} = "no"
 367 then
 368         AC_SUBST(JIT,[[]])
 369 else
 370         case $target in
 371                 *i*86*)
 372                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 373                         ;;
 374                 *sparc*)
 375                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 376                         ;;
 377                 *)
 378                         AC_SUBST(JIT,[[]])
 379                         ;;
 380         esac
 381 fi
 382
 383 dnl Find the LLVM GCC-based C/C++ front end
 384 AC_ARG_WITH(llvmgccdir,AC_HELP_STRING([--with-llvmgccdir],[Location of LLVM GCC front-end]),AC_SUBST(LLVMGCCDIR,[$withval]))
 385 AC_MSG_CHECKING([for llvm-gcc])
 386 LLVM_GCC_CHECK=no
 387 if test -d "$LLVMGCCDIR"
 388 then
 389         if test -x "$LLVMGCCDIR/bin/gcc"
 390         then
 391                 LLVM_GCC_CHECK="$LLVMGCCDIR/bin/gcc"
 392         fi
 393 fi
 394 llvmgccwarn=no
 395 AC_MSG_RESULT($LLVM_GCC_CHECK)
 396 if test "$LLVM_GCC_CHECK" = "no"
 397 then
 398     llvmgccwarn=yes
 399 fi
 400 AC_MSG_CHECKING([whether llvm-gcc is sane])
 401 LLVM_GCC_SANE=no
 402 if test -x "$LLVM_GCC_CHECK"
 403 then
 404         cp /dev/null conftest.c
 405     "$LLVM_GCC_CHECK" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 406         if test $? -eq 0
 407         then
 408                 LLVM_GCC_SANE=yes
 409         fi
 410         rm conftest.c
 411         llvmcc1path=`"$LLVM_GCC_CHECK" --print-prog-name=cc1`
 412         AC_SUBST(LLVMCC1,$llvmcc1path)
 413         llvmcc1pluspath=`"$LLVM_GCC_CHECK" --print-prog-name=cc1plus`
 414         AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 415 fi
 416 AC_MSG_RESULT($LLVM_GCC_SANE)
 417 if test "$LLVM_GCC_SANE" = "no"
 418 then
 419         llvmgccwarn=yes
 420 fi
 421
 422 dnl Location of the bytecode repository
 423 AC_ARG_WITH(bcrepos,AC_HELP_STRING([--with-bcrepos],[Location of Bytecode Repository]),AC_SUBST(BCR,[$withval]),AC_SUBST(BCR,[/home/vadve/lattner/LLVMPrograms]))
 424
 425 dnl Location of PAPI
 426 AC_ARG_WITH(papi,AC_HELP_STRING([--with-papi],[Location of PAPI]),AC_SUBST(PAPIDIR,[$withval]),AC_SUBST(PAPIDIR,[/home/vadve/shared/Sparc/papi-2.3.4.1]))
 427
 428 dnl Get libtool's idea of what the shared library suffix is.
 429 dnl (This is a hack; it relies on undocumented behavior.)
 430 AC_MSG_CHECKING([for shared library suffix])
 431 eval "SHLIBEXT=$shrext"
 432 AC_MSG_RESULT($SHLIBEXT)
 433 dnl Propagate it to the Makefiles and config.h (for gccld & bugpoint).
 434 AC_SUBST(SHLIBEXT,$SHLIBEXT)
 435 AC_DEFINE_UNQUOTED(SHLIBEXT,"$SHLIBEXT",
 436                    [Extension that shared libraries have, e.g., ".so".])
 437
 438 dnl Create the output files
 439 AC_OUTPUT(Makefile.config
 440  include/Support/DataTypes.h
 441  include/Support/ThreadSupport.h
 442  include/Support/hash_map
 443  include/Support/hash_set
 444  include/Support/iterator)
 445
 446 dnl Warn loudly if llvm-gcc was not obviously working
 447 if test $llvmgccwarn = yes
 448 then
 449         AC_MSG_WARN([***** llvm C/C++ front end was not found, or does not])
 450         AC_MSG_WARN([***** appear to be working.])
 451         AC_MSG_WARN([***** ])
 452         AC_MSG_WARN([***** Please check configure's --with-llvmgccdir option.])
 453         AC_MSG_WARN([***** Runtime libraries (in llvm/runtime) will not be built,])
 454         AC_MSG_WARN([***** but you should be able to build the llvm tools.])
 455 fi
 456