autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([support for generic build operating system],
 101                [llvm_cv_platform_type],
 102 [case $build in
 103   *-*-aix*) llvm_cv_platform_type="AIX" ;;
 104   *-*-cygwin*) llvm_cv_platform_type="Cygwin" ;;
 105   *-*-darwin*) llvm_cv_platform_type="Darwin" ;;
 106   *-*-freebsd*) llvm_cv_platform_type="FreeBSD" ;;
 107   *-*-interix*) llvm_cv_platform_type="Interix" ;;
 108   *-*-linux*) llvm_cv_platform_type="Linux" ;;
 109   *-*-solaris*) llvm_cv_platform_type="SunOS" ;;
 110   *-*-win32*) llvm_cv_platform_type="Win32" ;;
 111   *-*-mingw*) llvm_cv_platform_type="Win32" ;;
 112   *) llvm_cv_platform_type="Unknown" ;;
 113 esac])
 114
 115 dnl Make sure we aren't attempting to configure for an unknown system
 116 if test "$llvm_cv_platform_type" = "Unknown" ; then
 117   AC_MSG_ERROR([Operating system platform is unknown, configure can't continue])
 118 fi
 119
 120 dnl Set the "OS" Makefile variable based on the platform type so the
 121 dnl makefile can configure itself to specific build hosts
 122 AC_SUBST(OS,$llvm_cv_platform_type)
 123
 124 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_platform_type
 125 dnl This helps the #inclusion of the system specific include files
 126 dnl for the operating system abstraction library, lib/System.
 127 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_platform_type)
 128
 129 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 130 dnl V9, since that is all that we support at the moment, and autoconf will only
 131 dnl tell us we're a sparc.
 132 case $target in
 133   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 134   ;;
 135 esac
 136
 137 dnl Determine what our target architecture is and configure accordingly.
 138 dnl This will allow Makefiles to make a distinction between the hardware and
 139 dnl the OS.
 140 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 141 [case $target in
 142   i*86-*)      llvm_cv_target_arch="x86" ;;
 143   sparc*-*)    llvm_cv_target_arch="Sparc" ;;
 144   powerpc*-*)  llvm_cv_target_arch="PowerPC" ;;
 145   *)           llvm_cv_target_arch="Unknown" ;;
 146 esac])
 147
 148 if test "$llvm_cv_target_arch" = "Unknown" ; then
 149   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 150 fi
 151
 152 dnl Define a substitution, ARCH, for the target architecture
 153 AC_SUBST(ARCH,$llvm_cv_target_arch)
 154
 155 dnl Check for the endianness of the target
 156 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 157
 158 dnl===-----------------------------------------------------------------------===
 159 dnl===
 160 dnl=== SECTION 3: Command line arguments for the configure script.
 161 dnl===
 162 dnl===-----------------------------------------------------------------------===
 163
 164 dnl --enable-optimized : check whether they want to do an optimized build:
 165 AC_ARG_ENABLE(optimized,
 166               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 167 if test ${enableval} = "no" ; then
 168   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 169 else
 170   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 171 fi
 172
 173 dnl --enable-jit: check whether they want to enable the jit
 174 AC_ARG_ENABLE(jit,
 175   AS_HELP_STRING(--enable-jit,
 176                  [Enable Just In Time Compiling (default is YES)]),,
 177   enableval=default)
 178 if test ${enableval} = "no"
 179 then
 180   AC_SUBST(JIT,[[]])
 181 else
 182   case "$llvm_cv_target_arch" in
 183     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 184     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 185     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 186     *)       AC_SUBST(JIT,[[]]) ;;
 187   esac
 188 fi
 189
 190 dnl Allow enablement of doxygen generated documentation
 191 AC_ARG_ENABLE(doxygen,
 192               AS_HELP_STRING([--enable-doxygen],
 193                              [Build doxygen documentation (default is NO)]),,
 194                              enableval=default)
 195 case "$enableval" in
 196   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 197   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 198   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 199   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 200 esac
 201
 202 dnl Find the LLVM GCC-based C/C++ front end
 203 AC_ARG_WITH(llvmgccdir,
 204   AS_HELP_STRING(--with-llvmgccdir,[Location of LLVM GCC front-end]),
 205   AC_SUBST(LLVMGCCDIR,[$withval]))
 206
 207 dnl Provide some defaults for LLVMGCC for UIUC environments.
 208 if test "x$LLVMGCCDIR" = x ; then
 209   case "$llvm_cv_platform_type" in
 210     Linux)
 211       if test -d /home/vadve/lattner/local/x86/llvm-gcc ; then
 212         AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 213       fi
 214       ;;
 215     SunOS)
 216       if test -d /home/vadve/lattner/local/sparc/llvm-gcc ; then
 217         AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 218       fi
 219       ;;
 220   esac
 221 fi
 222
 223 dnl===-----------------------------------------------------------------------===
 224 dnl===
 225 dnl=== SECTION 4: Check for programs we need and that they are the right version
 226 dnl===
 227 dnl===-----------------------------------------------------------------------===
 228
 229 dnl Check for compilation tools
 230 AC_PROG_CPP
 231 AC_PROG_CC(gcc)
 232 AC_PROG_CXX(g++)
 233 AC_PROG_FLEX
 234 AC_PROG_BISON
 235
 236 dnl Check for the tools that the makefiles require
 237 AC_CHECK_GNU_MAKE
 238 AC_PROG_LN_S
 239 AC_PATH_PROG(DATE, [date], [date])
 240 AC_PATH_PROG(FIND, [find], [find])
 241 AC_PATH_PROG(GREP, [grep], [grep])
 242 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 243 AC_PATH_PROG(MV,   [mv],   [mv])
 244 AC_PATH_PROG(PAX,  [pax],  [pax])
 245 AC_PROG_RANLIB
 246 AC_PATH_PROG(RM,   [rm],   [rm])
 247 AC_PATH_PROG(SED,  [sed],  [sed])
 248 AC_PATH_PROG(TAR,  [tar],  [gtar])
 249
 250 dnl Find the install program
 251 AC_PROG_INSTALL
 252
 253 dnl Checks for documentation and testing tools that we can do without. If these
 254 dnl are not found then they are set to "true" which always succeeds but does
 255 dnl nothing. This just lets the build output show that we could have done
 256 dnl something if the tool was available.
 257 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 258 AC_PATH_PROG(DOT,[dot],[true dot])
 259 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 260 AC_PATH_PROG(ETAGS,[etags],[true etags])
 261 AC_PATH_PROG(GROFF,[groff],[true groff])
 262 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 263 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 264 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 265 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 266 DJ_AC_PATH_TCLSH
 267 AC_PATH_PROG(ZIP,[zip],[true zip])
 268
 269 dnl Determine if the linker supports the -R option.
 270 AC_LINK_USE_R
 271
 272 dnl Check for libtool and the library that has dlopen function (which must come
 273 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 274 dnl libtool).
 275 AC_LIBTOOL_DLOPEN
 276 AC_LIB_LTDL
 277 AC_PROG_LIBTOOL
 278
 279 dnl Check if we know how to tell etags we are using C++:
 280 etags_version=`$ETAGS --version 2>&1`
 281 case "$etags_version" in
 282         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 283         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 284         *) ETAGSFLAGS="" ;;
 285 esac
 286 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 287
 288 AC_MSG_CHECKING([tool compatibility])
 289
 290 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 291 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 292 dnl to support those options.
 293 dnl "icc" emits gcc signatures
 294 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 295 ICC=no
 296 IXX=no
 297 case $CC in
 298   icc*|icpc*)
 299     ICC=yes
 300     IXX=yes
 301     ;;
 302    *)
 303     ;;
 304 esac
 305
 306 if test "$GCC" != "yes" && test "$ICC" != "yes"
 307 then
 308   AC_MSG_ERROR([gcc|icc required but not found])
 309 fi
 310
 311 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 312 if test "$GXX" != "yes" && test "$IXX" != "yes"
 313 then
 314   AC_MSG_ERROR([g++|icc required but not found])
 315 fi
 316
 317 dnl Verify that GCC is version 3.0 or higher
 318 if test "$GCC" = "yes"
 319 then
 320   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 321   if test "$gccmajor" -lt "3"
 322   then
 323     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 324   fi
 325 fi
 326
 327 dnl Check for GNU Make.  We use its extensions, so don't build without it
 328 if test -z "$llvm_cv_gnu_make_command"
 329 then
 330   AC_MSG_ERROR([GNU Make required but not found])
 331 fi
 332
 333 dnl Tool compatibility is okay if we make it here.
 334 AC_MSG_RESULT([ok])
 335
 336 dnl===-----------------------------------------------------------------------===
 337 dnl===
 338 dnl=== SECTION 5: Check for libraries
 339 dnl===
 340 dnl===-----------------------------------------------------------------------===
 341
 342 dnl libelf is for sparc only; we can ignore it if we don't have it
 343 AC_CHECK_LIB(elf, elf_begin)
 344
 345 dnl lt_dlopen may be required for plugin support.
 346 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 347               [Define if lt_dlopen() is available on this platform]),
 348               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 349                            not be available]))
 350
 351 dnl dlopen() is required for plugin support.
 352 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 353                [Define if dlopen() is available on this platform.]),
 354                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 355
 356 dnl mallinfo is optional; the code can compile (minus features) without it
 357 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 358                [Define if mallinfo() is available on this platform.]))
 359
 360 dnl pthread locking functions are optional - but llvm will not be thread-safe
 361 dnl without locks.
 362 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 363                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 364                          [Have pthread_mutex_lock]))
 365
 366 dnl===-----------------------------------------------------------------------===
 367 dnl===
 368 dnl=== SECTION 6: Check for header files
 369 dnl===
 370 dnl===-----------------------------------------------------------------------===
 371
 372 dnl We don't check for ancient stuff or things that are guaranteed to be there
 373 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 374 AC_HEADER_STDC
 375
 376 dnl However, we do need some system specific header files. Generally we're
 377 dnl looking for POSIX headers.
 378 AC_HEADER_SYS_WAIT
 379 AC_CHECK_HEADERS([sys/time.h sys/mman.h sys/resource.h sys/time.h sys/types.h])
 380 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h limits.h link.h])
 381 AC_CHECK_HEADERS([malloc.h unistd.h windows.h])
 382 AC_HEADER_TIME
 383 AC_HEADER_MMAP_ANONYMOUS
 384
 385 dnl Check for things that need to be included in public headers, and so
 386 dnl for which we may not have access to a HAVE_* preprocessor #define.
 387 dnl (primarily used in DataTypes.h)
 388 AC_CHECK_HEADERS([inttypes.h stdint.h])
 389
 390 dnl===-----------------------------------------------------------------------===
 391 dnl===
 392 dnl=== SECTION 7: Check for types and structures
 393 dnl===
 394 dnl===-----------------------------------------------------------------------===
 395
 396 AC_TYPE_PID_T
 397 AC_TYPE_SIZE_T
 398 AC_TYPE_SIGNAL
 399 AC_STRUCT_TM
 400 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 401 AC_CHECK_TYPES([uint64_t],,
 402          AC_CHECK_TYPES([u_int64_t],,
 403          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 404
 405 dnl===-----------------------------------------------------------------------===
 406 dnl===
 407 dnl=== SECTION 8: Check for specific functions needed
 408 dnl===
 409 dnl===-----------------------------------------------------------------------===
 410
 411 AC_CHECK_FUNCS([backtrace getcwd gettimeofday isatty getrusage mkstemp])
 412 AC_CHECK_FUNCS([strdup strtoq strtoll])
 413 AC_C_PRINTF_A
 414 AC_FUNC_ALLOCA
 415 AC_FUNC_RAND48
 416
 417 dnl Check for variations in the Standard C++ library and STL. These macros are
 418 dnl provided by LLVM in the autoconf/m4 directory.
 419 AC_CXX_HAVE_HASH_MAP
 420 AC_CXX_HAVE_HASH_SET
 421 AC_CXX_HAVE_STD_ITERATOR
 422 AC_CXX_HAVE_BI_ITERATOR
 423 AC_CXX_HAVE_FWD_ITERATOR
 424 AC_FUNC_ISNAN
 425 AC_FUNC_ISINF
 426
 427 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 428 dnl bytecode loading, etc.
 429 AC_FUNC_MMAP
 430 AC_FUNC_MMAP_FILE
 431 AC_CHECK_FUNC(mprotect,,
 432               AC_MSG_ERROR([Function mprotect() required but not found]))
 433
 434 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 435 then
 436   AC_MSG_WARN([mmap() required but not found])
 437 fi
 438 if test "$ac_cv_func_mmap_file" = "no"
 439 then
 440   AC_MSG_WARN([mmap() of files required but not found])
 441 fi
 442
 443 dnl===-----------------------------------------------------------------------===
 444 dnl===
 445 dnl=== SECTION 9: Additional checks, variables, etc.
 446 dnl===
 447 dnl===-----------------------------------------------------------------------===
 448
 449 dnl Figure out if there's an executable llvm-gcc in the llvmgccdir.
 450 AC_CACHE_CHECK([for llvm-gcc],[llvm_cv_llvmgcc],
 451 [llvm_cv_llvmgcc='llvmgcc_not_found'
 452 if test -d "$LLVMGCCDIR" ; then
 453   if test -x "$LLVMGCCDIR/bin/gcc" ; then
 454     llvm_cv_llvmgcc="$LLVMGCCDIR/bin/gcc"
 455   fi
 456 fi])
 457
 458 dnl See if the llvmgcc executable can compile to LLVM assembly
 459 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 460 [llvm_cv_llvmgcc_sanity="no"
 461 if test -x "$llvm_cv_llvmgcc" ; then
 462   cp /dev/null conftest.c
 463   "$llvm_cv_llvmgcc" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 464   if test $? -eq 0 ; then
 465     llvm_cv_llvmgcc_sanity="yes"
 466   fi
 467   rm conftest.c
 468 fi])
 469
 470 dnl Since we have a sane llvmgcc, identify it and its sub-tools
 471 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 472   AC_SUBST(LLVMGCC,"$llvm_cv_llvmgcc")
 473   llvmcc1path=`"$llvm_cv_llvmgcc" --print-prog-name=cc1`
 474   AC_SUBST(LLVMCC1,$llvmcc1path)
 475   llvmcc1pluspath=`"$llvm_cv_llvmgcc" --print-prog-name=cc1plus`
 476   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 477 fi
 478
 479 dnl Propagate the shared library extension that the libltdl checks did to
 480 dnl the Makefiles so we can use it there too
 481 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 482
 483 # Translate the various configuration directories and other basic
 484 # information into substitutions that will end up in Makefile.config.in
 485 # that these configured values can be used by the makefiles
 486 eval LLVM_PREFIX="${prefix}";
 487 eval LLVM_BINDIR="${prefix}/bin";
 488 eval LLVM_LIBDIR="${prefix}/lib";
 489 eval LLVM_DATADIR="${prefix}/share/llvm";
 490 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 491 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 492 eval LLVM_INCLUDEDIR="${prefix}/include";
 493 eval LLVM_INFODIR="${prefix}/info";
 494 eval LLVM_MANDIR="${prefix}/man";
 495 LLVM_CONFIGTIME=`date`
 496 AC_SUBST(LLVM_PREFIX)
 497 AC_SUBST(LLVM_BINDIR)
 498 AC_SUBST(LLVM_LIBDIR)
 499 AC_SUBST(LLVM_DATADIR)
 500 AC_SUBST(LLVM_DOCSDIR)
 501 AC_SUBST(LLVM_ETCDIR)
 502 AC_SUBST(LLVM_INCLUDEDIR)
 503 AC_SUBST(LLVM_INFODIR)
 504 AC_SUBST(LLVM_MANDIR)
 505 AC_SUBST(LLVM_CONFIGTIME)
 506
 507 # Place the various directores into the config.h file as #defines so that we
 508 # can know about the installation paths within LLVM.
 509 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 510                    [Installation prefix directory])
 511 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 512                    [Installation directory for binary executables])
 513 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 514                    [Installation directory for libraries])
 515 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 516                    [Installation directory for data files])
 517 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 518                    [Installation directory for documentation])
 519 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 520                    [Installation directory for config files])
 521 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 522                    [Installation directory for include files])
 523 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 524                    [Installation directory for .info files])
 525 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 526                    [Installation directory for man pages])
 527 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 528                    [Time at which LLVM was configured])
 529
 530 dnl===-----------------------------------------------------------------------===
 531 dnl===
 532 dnl=== SECTION 10: Specify the output files and generate it
 533 dnl===
 534 dnl===-----------------------------------------------------------------------===
 535
 536 dnl Configure header files
 537 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 538
 539 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 540 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 541 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 542 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 543 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 544
 545 dnl Configure the makefile's configuration data
 546 AC_CONFIG_FILES([Makefile.config])
 547
 548 dnl Configure llvmc's configuration files
 549 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 550
 551 dnl Configure doxygen's configuration file
 552 AC_CONFIG_FILES([docs/doxygen.cfg])
 553
 554 dnl Do special configuration of Makefiles
 555 AC_CONFIG_MAKEFILE(Makefile)
 556 AC_CONFIG_MAKEFILE(Makefile.common)
 557 AC_CONFIG_MAKEFILE(examples/Makefile)
 558 AC_CONFIG_MAKEFILE(lib/Makefile)
 559 AC_CONFIG_MAKEFILE(runtime/Makefile)
 560 AC_CONFIG_MAKEFILE(test/Makefile)
 561 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 562 AC_CONFIG_MAKEFILE(tools/Makefile)
 563 AC_CONFIG_MAKEFILE(utils/Makefile)
 564 AC_CONFIG_MAKEFILE(projects/Makefile)
 565
 566 dnl Finally, crank out the output
 567 AC_OUTPUT
 568
 569 dnl Warn loudly if llvm-gcc was not obviously working
 570 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 571  AC_MSG_WARN([***** llvm C/C++ front end was not found, or does not])
 572  AC_MSG_WARN([***** appear to be working.])
 573  AC_MSG_WARN([***** ])
 574  AC_MSG_WARN([***** Please check configure's --with-llvmgccdir option.])
 575  AC_MSG_WARN([***** Runtime libraries (in llvm/runtime) will not be built,])
 576  AC_MSG_WARN([***** but you should be able to build the llvm tools.])
 577 fi