autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 dnl Define a substitution, ARCH, for the target architecture
 238 AC_SUBST(ARCH,$llvm_cv_target_arch)
 239
 240 dnl Check for the endianness of the target
 241 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 242
 243 dnl Check for build platform executable suffix if we're crosscompiling
 244 if test "$cross_compiling" = yes; then
 245   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 246   AC_BUILD_EXEEXT
 247   ac_build_prefix=${build_alias}-
 248   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 249   if test -z "$BUILD_CXX"; then
 250      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 251      if test -z "$BUILD_CXX"; then
 252        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 253      fi
 254   fi
 255 else
 256   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 257 fi
 258
 259 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 260 dnl that this build is being done from a checkout. This sets up several
 261 dnl defaults for the command line switches. When we build with a CVS directory,
 262 dnl we get a debug with assertions turned on. Without, we assume a source
 263 dnl release and we get an optimized build without assertions.
 264 dnl See --enable-optimized and --enable-assertions below
 265 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 266   cvsbuild="yes"
 267   optimize="no"
 268   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 269 else
 270   cvsbuild="no"
 271   optimize="yes"
 272 fi
 273
 274 dnl===-----------------------------------------------------------------------===
 275 dnl===
 276 dnl=== SECTION 3: Command line arguments for the configure script.
 277 dnl===
 278 dnl===-----------------------------------------------------------------------===
 279
 280 dnl --enable-optimized : check whether they want to do an optimized build:
 281 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 282  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 283 if test ${enableval} = "no" ; then
 284   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 285 else
 286   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 287 fi
 288
 289 dnl --enable-profiling : check whether they want to do a profile build:
 290 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 291  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 292 if test ${enableval} = "no" ; then
 293   AC_SUBST(ENABLE_PROFILING,[[]])
 294 else
 295   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 296 fi
 297
 298 dnl --enable-assertions : check whether they want to turn on assertions or not:
 299 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 300   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 301 if test ${enableval} = "yes" ; then
 302   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 303 else
 304   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 305 fi
 306
 307 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 308 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 309   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 310 if test ${enableval} = "yes" ; then
 311   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 312   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 313 else
 314   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 315   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 316 fi
 317
 318 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 319 AC_ARG_ENABLE(debug-runtime,
 320    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 321 if test ${enableval} = "no" ; then
 322   AC_SUBST(DEBUG_RUNTIME,[[]])
 323 else
 324   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 325 fi
 326
 327 dnl --enable-jit: check whether they want to enable the jit
 328 AC_ARG_ENABLE(jit,
 329   AS_HELP_STRING(--enable-jit,
 330                  [Enable Just In Time Compiling (default is YES)]),,
 331   enableval=default)
 332 if test ${enableval} = "no"
 333 then
 334   AC_SUBST(JIT,[[]])
 335 else
 336   case "$llvm_cv_target_arch" in
 337     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 338     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 339     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 340     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 341     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 342     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 343     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 344     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 345     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 347     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 348     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 349   esac
 350 fi
 351
 352 dnl Allow enablement of doxygen generated documentation
 353 AC_ARG_ENABLE(doxygen,
 354               AS_HELP_STRING([--enable-doxygen],
 355                              [Build doxygen documentation (default is NO)]),,
 356                              enableval=default)
 357 case "$enableval" in
 358   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 359   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 360   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 361   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 362 esac
 363
 364 dnl Allow disablement of threads
 365 AC_ARG_ENABLE(threads,
 366               AS_HELP_STRING([--enable-threads],
 367                              [Use threads if available (default is YES)]),,
 368                              enableval=default)
 369 case "$enableval" in
 370   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 371   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 372   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 373   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 374 esac
 375 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 376
 377 dnl Allow building without position independent code
 378 AC_ARG_ENABLE(pic,
 379   AS_HELP_STRING([--enable-pic],
 380                  [Build LLVM with Position Independent Code (default is YES)]),,
 381                  enableval=default)
 382 case "$enableval" in
 383   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 384   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 385   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 386   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 387 esac
 388 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 389                    [Define if position independent code is enabled])
 390
 391 dnl Allow specific targets to be specified for building (or not)
 392 TARGETS_TO_BUILD=""
 393 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 394     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 395     enableval=all)
 396 case "$enableval" in
 397   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 398   host-only)
 399     case "$llvm_cv_target_arch" in
 400       x86)     TARGETS_TO_BUILD="X86" ;;
 401       x86_64)  TARGETS_TO_BUILD="X86" ;;
 402       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 403       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 404       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 405       IA64)    TARGETS_TO_BUILD="IA64" ;;
 406       ARM)     TARGETS_TO_BUILD="ARM" ;;
 407       Mips)    TARGETS_TO_BUILD="Mips" ;;
 408       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 409       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 410       XCore)   TARGETS_TO_BUILD="XCore" ;;
 411       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 412       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 413     esac
 414     ;;
 415   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 416       case "$a_target" in
 417         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 418         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 419         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 420         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 421         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 422         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 423         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 424         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 425         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 426         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 427         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 428         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 429         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 430         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 431         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 432         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 433       esac
 434   done
 435   ;;
 436 esac
 437 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 438
 439 dnl Prevent the CBackend from using printf("%a") for floating point so older
 440 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 441 dnl can still compile the CBE's output
 442 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 443   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 444   enableval=default)
 445 case "$enableval" in
 446   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 447   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 448   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 449   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 450 esac
 451 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 452                    [Define if CBE is enabled for printf %a output])
 453
 454 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 455 AC_ARG_WITH(llvmgccdir,
 456   AS_HELP_STRING([--with-llvmgccdir],
 457     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 458     withval=default)
 459 case "$withval" in
 460   default) WITH_LLVMGCCDIR=default ;;
 461   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 462   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 463 esac
 464
 465 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 466 AC_ARG_WITH(llvmgcc,
 467   AS_HELP_STRING([--with-llvmgcc],
 468     [Specify location of llvm-gcc driver (default searches PATH)]),
 469     LLVMGCC=$with_llvmgcc
 470       WITH_LLVMGCCDIR="",)
 471
 472 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 473 AC_ARG_WITH(llvmgxx,
 474   AS_HELP_STRING([--with-llvmgxx],
 475     [Specify location of llvm-g++ driver (default searches PATH)]),
 476     LLVMGXX=$with_llvmgxx
 477     WITH_LLVMGCCDIR="",)
 478
 479 if test -n "$LLVMGCC"; then
 480    LLVMGCCCOMMAND="$LLVMGCC"
 481 fi
 482
 483 if test -n "$LLVMGXX"; then
 484    LLVMGXXCOMMAND="$LLVMGXX"
 485 fi
 486
 487 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 488    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 489 fi
 490
 491 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 492    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 493 fi
 494
 495 dnl Specify extra build options
 496 AC_ARG_WITH(extra-options,
 497   AS_HELP_STRING([--with-extra-options],
 498                  [Specify additional options to compile LLVM with]),,
 499                  withval=default)
 500 case "$withval" in
 501   default) EXTRA_OPTIONS= ;;
 502   *) EXTRA_OPTIONS=$withval ;;
 503 esac
 504 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 505
 506 dnl Allow specific bindings to be specified for building (or not)
 507 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 508     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 509     enableval=default)
 510 BINDINGS_TO_BUILD=""
 511 case "$enableval" in
 512   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 513   all ) BINDINGS_TO_BUILD="ocaml" ;;
 514   none | no) BINDINGS_TO_BUILD="" ;;
 515   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 516       case "$a_binding" in
 517         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 518         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 519       esac
 520   done
 521   ;;
 522 esac
 523
 524 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 525 dnl script for bindings/ocaml/configure, except that its auto value depends on
 526 dnl OCAMLC, which is found here to support tests.
 527 AC_ARG_WITH([ocaml-libdir],
 528   [AS_HELP_STRING([--with-ocaml-libdir],
 529     [Specify install location for ocaml bindings (default is stdlib)])],
 530   [],
 531   [withval=auto])
 532 case "$withval" in
 533   auto) with_ocaml_libdir="$withval" ;;
 534   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 535   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 536 esac
 537
 538 dnl Allow linking of LLVM with GPLv3 binutils code.
 539 AC_ARG_WITH(binutils-include,
 540   AS_HELP_STRING([--with-binutils-include],
 541     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 542   withval=default)
 543 case "$withval" in
 544   default) WITH_BINUTILS_INCDIR=default ;;
 545   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 546   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 547 esac
 548 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 549   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 550   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 551      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 552      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 553   fi
 554 fi
 555
 556 dnl --enable-libffi : check whether the user wants to turn off libffi:
 557 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 558   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 559   enableval=yes)
 560 case "$enableval" in
 561   yes) llvm_cv_enable_libffi="yes" ;;
 562   no)  llvm_cv_enable_libffi="no"  ;;
 563   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 564 esac
 565
 566 dnl===-----------------------------------------------------------------------===
 567 dnl===
 568 dnl=== SECTION 4: Check for programs we need and that they are the right version
 569 dnl===
 570 dnl===-----------------------------------------------------------------------===
 571
 572 dnl Check for compilation tools
 573 AC_PROG_CPP
 574 AC_PROG_CC(gcc)
 575 AC_PROG_CXX(g++)
 576
 577 AC_PROG_NM
 578 AC_SUBST(NM)
 579
 580 dnl Check for the tools that the makefiles require
 581 AC_CHECK_GNU_MAKE
 582 AC_PROG_LN_S
 583 AC_PATH_PROG(CMP, [cmp], [cmp])
 584 AC_PATH_PROG(CP, [cp], [cp])
 585 AC_PATH_PROG(DATE, [date], [date])
 586 AC_PATH_PROG(FIND, [find], [find])
 587 AC_PATH_PROG(GREP, [grep], [grep])
 588 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 589 AC_PATH_PROG(MV,   [mv],   [mv])
 590 AC_PROG_RANLIB
 591 AC_PATH_PROG(RM,   [rm],   [rm])
 592 AC_PATH_PROG(SED,  [sed],  [sed])
 593 AC_PATH_PROG(TAR,  [tar],  [gtar])
 594 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 595
 596 dnl Looking for misc. graph plotting software
 597 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 598 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 599   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 600   dnl If we're targeting for mingw we should emit windows paths, not msys
 601   if test "$llvm_cv_os_type" = "MingW" ; then
 602     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 603   fi
 604   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 605    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 606 fi
 607 AC_PATH_PROG(DOT, [dot], [echo dot])
 608 if test "$DOT" != "echo dot" ; then
 609   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 610   dnl If we're targeting for mingw we should emit windows paths, not msys
 611   if test "$llvm_cv_os_type" = "MingW" ; then
 612     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 613   fi
 614   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 615    [Define to path to dot program if found or 'echo dot' otherwise])
 616 fi
 617 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 618 if test "$GV" != "echo gv" ; then
 619   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 620   dnl If we're targeting for mingw we should emit windows paths, not msys
 621   if test "$llvm_cv_os_type" = "MingW" ; then
 622     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 623   fi
 624   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 625    [Define to path to gv program if found or 'echo gv' otherwise])
 626 fi
 627 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 628 if test "$DOTTY" != "echo dotty" ; then
 629   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 630   dnl If we're targeting for mingw we should emit windows paths, not msys
 631   if test "$llvm_cv_os_type" = "MingW" ; then
 632     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 633   fi
 634   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 635    [Define to path to dotty program if found or 'echo dotty' otherwise])
 636 fi
 637
 638 dnl Look for a sufficiently recent version of Perl.
 639 LLVM_PROG_PERL([5.006])
 640 AC_SUBST(PERL)
 641 if test x"$PERL" = xnone; then
 642    AC_SUBST(HAVE_PERL,0)
 643    AC_MSG_ERROR([perl is required but was not found, please install it])
 644 else
 645    AC_SUBST(HAVE_PERL,1)
 646 fi
 647
 648 dnl Find the install program
 649 AC_PROG_INSTALL
 650
 651 dnl Checks for documentation and testing tools that we can do without. If these
 652 dnl are not found then they are set to "true" which always succeeds but does
 653 dnl nothing. This just lets the build output show that we could have done
 654 dnl something if the tool was available.
 655 AC_PATH_PROG(BZIP2, [bzip2])
 656 AC_PATH_PROG(DOXYGEN, [doxygen])
 657 AC_PATH_PROG(GROFF, [groff])
 658 AC_PATH_PROG(GZIP, [gzip])
 659 AC_PATH_PROG(POD2HTML, [pod2html])
 660 AC_PATH_PROG(POD2MAN, [pod2man])
 661 AC_PATH_PROG(RUNTEST, [runtest])
 662 DJ_AC_PATH_TCLSH
 663 AC_PATH_PROG(ZIP, [zip])
 664 AC_PATH_PROGS(OCAMLC, [ocamlc])
 665 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 666 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 667 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 668 AC_PATH_PROGS(GAS, [gas as])
 669
 670 dnl Determine whether the linker supports the -R option.
 671 AC_LINK_USE_R
 672
 673 dnl Determine whether the linker supports the -export-dynamic option.
 674 AC_LINK_EXPORT_DYNAMIC
 675
 676 dnl Check for libtool and the library that has dlopen function (which must come
 677 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 678 dnl libtool).
 679 AC_LIBTOOL_DLOPEN
 680 AC_LIB_LTDL
 681 AC_PROG_LIBTOOL
 682
 683 if test "$lt_cv_dlopen_self" = "yes" ; then
 684   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 685               [Define if dlopen(0) will open the symbols of the program])
 686 fi
 687
 688
 689 if test "$WITH_LLVMGCCDIR" = "default" ; then
 690   LLVMGCC="llvm-gcc${EXEEXT}"
 691   LLVMGXX="llvm-g++${EXEEXT}"
 692   LLVMGCCCOMMAND="$LLVMGCC"
 693   LLVMGXXCOMMAND="$LLVMGXX"
 694   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 695   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 696   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 697   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 698 else
 699   if test -z "$LLVMGCC"; then
 700     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 701     LLVMGCCCOMMAND="$LLVMGCC"
 702   fi
 703   if test -z "$LLVMGXX"; then
 704     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 705     LLVMGXXCOMMAND="$LLVMGXX"
 706   fi
 707
 708   AC_SUBST(LLVMGCC,$LLVMGCC)
 709   AC_SUBST(LLVMGXX,$LLVMGXX)
 710   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 711   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 712 fi
 713
 714
 715 AC_MSG_CHECKING([tool compatibility])
 716
 717 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 718 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 719 dnl to support those options.
 720 dnl "icc" emits gcc signatures
 721 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 722 ICC=no
 723 IXX=no
 724 case $CC in
 725   icc*|icpc*)
 726     ICC=yes
 727     IXX=yes
 728     ;;
 729    *)
 730     ;;
 731 esac
 732
 733 if test "$GCC" != "yes" && test "$ICC" != "yes"
 734 then
 735   AC_MSG_ERROR([gcc|icc required but not found])
 736 fi
 737
 738 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 739 if test "$GXX" != "yes" && test "$IXX" != "yes"
 740 then
 741   AC_MSG_ERROR([g++|icc required but not found])
 742 fi
 743
 744 dnl Verify that GCC is version 3.0 or higher
 745 if test "$GCC" = "yes"
 746 then
 747   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 748 #error Unsupported GCC version
 749 #endif
 750 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 751 fi
 752
 753 dnl Check for GNU Make.  We use its extensions, so don't build without it
 754 if test -z "$llvm_cv_gnu_make_command"
 755 then
 756   AC_MSG_ERROR([GNU Make required but not found])
 757 fi
 758
 759 dnl Tool compatibility is okay if we make it here.
 760 AC_MSG_RESULT([ok])
 761
 762 dnl===-----------------------------------------------------------------------===
 763 dnl===
 764 dnl=== SECTION 5: Check for libraries
 765 dnl===
 766 dnl===-----------------------------------------------------------------------===
 767
 768 dnl libelf is for sparc only; we can ignore it if we don't have it
 769 AC_CHECK_LIB(elf, elf_begin)
 770 AC_CHECK_LIB(m,sin)
 771 if test "$llvm_cv_os_type" = "MingW" ; then
 772   AC_CHECK_LIB(imagehlp, main)
 773   AC_CHECK_LIB(psapi, main)
 774 fi
 775
 776 dnl dlopen() is required for plugin support.
 777 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 778                [Define if dlopen() is available on this platform.]),
 779                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 780
 781 dnl libffi is optional; used to call external functions from the interpreter
 782 if test "$llvm_cv_enable_libffi" = "yes" ; then
 783   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 784                  [Define if libffi is available on this platform.]),
 785                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 786 fi
 787
 788 dnl mallinfo is optional; the code can compile (minus features) without it
 789 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 790                [Define if mallinfo() is available on this platform.]))
 791
 792 dnl pthread locking functions are optional - but llvm will not be thread-safe
 793 dnl without locks.
 794 if test "$ENABLE_THREADS" -eq 1 ; then
 795   AC_CHECK_LIB(pthread,pthread_mutex_init)
 796   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 797                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 798                            [Have pthread_mutex_lock]))
 799   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 800                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 801                  [Have pthread_rwlock_init]))
 802 fi
 803
 804 dnl Allow extra x86-disassembler library
 805 AC_ARG_WITH(udis86,
 806   AS_HELP_STRING([--with-udis86=<path>],
 807     [Use udis86 external x86 disassembler library]),
 808     [
 809       AC_SUBST(USE_UDIS86, [1])
 810       case "$withval" in
 811         /usr/lib|yes) ;;
 812         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 813       esac
 814       AC_CHECK_LIB(udis86, ud_init, [], [
 815         echo "Error! You need to have libudis86 around."
 816         exit -1
 817       ])
 818     ],
 819     AC_SUBST(USE_UDIS86, [0]))
 820 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 821                    [Define if use udis86 library])
 822
 823 dnl===-----------------------------------------------------------------------===
 824 dnl===
 825 dnl=== SECTION 6: Check for header files
 826 dnl===
 827 dnl===-----------------------------------------------------------------------===
 828
 829 dnl First, use autoconf provided macros for specific headers that we need
 830 dnl We don't check for ancient stuff or things that are guaranteed to be there
 831 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 832 dnl Generally we're looking for POSIX headers.
 833 AC_HEADER_DIRENT
 834 AC_HEADER_MMAP_ANONYMOUS
 835 AC_HEADER_STAT
 836 AC_HEADER_STDC
 837 AC_HEADER_SYS_WAIT
 838 AC_HEADER_TIME
 839
 840 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 841 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 842 AC_CHECK_HEADERS([utime.h windows.h])
 843 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 844 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 845 if test "$ENABLE_THREADS" -eq 1 ; then
 846   AC_CHECK_HEADERS(pthread.h,
 847                    AC_SUBST(HAVE_PTHREAD, 1),
 848                    AC_SUBST(HAVE_PTHREAD, 0))
 849 else
 850   AC_SUBST(HAVE_PTHREAD, 0)
 851 fi
 852
 853 dnl Try to find ffi.h.
 854 if test "$llvm_cv_enable_libffi" = "yes" ; then
 855   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 856 fi
 857
 858 dnl===-----------------------------------------------------------------------===
 859 dnl===
 860 dnl=== SECTION 7: Check for types and structures
 861 dnl===
 862 dnl===-----------------------------------------------------------------------===
 863
 864 AC_HUGE_VAL_CHECK
 865 AC_TYPE_PID_T
 866 AC_TYPE_SIZE_T
 867 AC_TYPE_SIGNAL
 868 AC_STRUCT_TM
 869 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 870 AC_CHECK_TYPES([uint64_t],,
 871          AC_CHECK_TYPES([u_int64_t],,
 872          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 873
 874 dnl===-----------------------------------------------------------------------===
 875 dnl===
 876 dnl=== SECTION 8: Check for specific functions needed
 877 dnl===
 878 dnl===-----------------------------------------------------------------------===
 879
 880 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 881 AC_CHECK_FUNCS([powf fmodf strtof round ])
 882 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 883 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 884 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 885 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 886 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 887 AC_C_PRINTF_A
 888 AC_FUNC_ALLOCA
 889 AC_FUNC_RAND48
 890
 891 dnl Check for variations in the Standard C++ library and STL. These macros are
 892 dnl provided by LLVM in the autoconf/m4 directory.
 893 AC_CXX_HAVE_STD_ITERATOR
 894 AC_CXX_HAVE_BI_ITERATOR
 895 AC_CXX_HAVE_FWD_ITERATOR
 896 AC_FUNC_ISNAN
 897 AC_FUNC_ISINF
 898
 899 dnl Check for mmap support.We also need to know if /dev/zero is required to
 900 dnl be opened for allocating RWX memory.
 901 dnl Make sure we aren't attempting to configure for an unknown system
 902 if test "$llvm_cv_platform_type" = "Unix" ; then
 903   AC_FUNC_MMAP
 904   AC_FUNC_MMAP_FILE
 905   AC_NEED_DEV_ZERO_FOR_MMAP
 906
 907   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 908   then
 909     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 910   fi
 911   if test "$ac_cv_func_mmap_file" = "no"
 912   then
 913     AC_MSG_WARN([mmap() of files required but not found])
 914   fi
 915 fi
 916
 917 dnl atomic builtins are required for threading support.
 918 AC_MSG_CHECKING(for GCC atomic builtins)
 919 AC_LINK_IFELSE(
 920   AC_LANG_SOURCE(
 921     [[int main() {
 922         volatile unsigned long val = 1;
 923         __sync_synchronize();
 924         __sync_val_compare_and_swap(&val, 1, 0);
 925         return 0;
 926       }
 927     ]]),
 928   AC_MSG_RESULT(yes)
 929   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
 930   AC_MSG_RESULT(no)
 931   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
 932   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
 933
 934
 935 dnl===-----------------------------------------------------------------------===
 936 dnl===
 937 dnl=== SECTION 9: Additional checks, variables, etc.
 938 dnl===
 939 dnl===-----------------------------------------------------------------------===
 940
 941 dnl Check, whether __dso_handle is present
 942 AC_CHECK_FUNCS([__dso_handle])
 943
 944 dnl See if the llvm-gcc executable can compile to LLVM assembly
 945 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 946 [llvm_cv_llvmgcc_sanity="no"
 947 if test -x "$LLVMGCC" ; then
 948   cp /dev/null conftest.c
 949   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 950       grep 'target datalayout =' > /dev/null 2>&1
 951   if test $? -eq 0 ; then
 952     llvm_cv_llvmgcc_sanity="yes"
 953   fi
 954   rm conftest.c
 955 fi])
 956
 957 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 958 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 959   AC_MSG_CHECKING([llvm-gcc component support])
 960   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 961   AC_SUBST(LLVMCC1,$llvmcc1path)
 962   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 963   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 964   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 965   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 966   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 967   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 968   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 969   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 970   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 971   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 972   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 973   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 974   AC_MSG_RESULT([ok])
 975 fi
 976
 977 dnl Propagate the shared library extension that the libltdl checks did to
 978 dnl the Makefiles so we can use it there too
 979 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 980
 981 # Translate the various configuration directories and other basic
 982 # information into substitutions that will end up in Makefile.config.in
 983 # that these configured values can be used by the makefiles
 984 if test "${prefix}" = "NONE" ; then
 985   prefix="/usr/local"
 986 fi
 987 eval LLVM_PREFIX="${prefix}";
 988 eval LLVM_BINDIR="${prefix}/bin";
 989 eval LLVM_LIBDIR="${prefix}/lib";
 990 eval LLVM_DATADIR="${prefix}/share/llvm";
 991 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 992 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 993 eval LLVM_INCLUDEDIR="${prefix}/include";
 994 eval LLVM_INFODIR="${prefix}/info";
 995 eval LLVM_MANDIR="${prefix}/man";
 996 LLVM_CONFIGTIME=`date`
 997 AC_SUBST(LLVM_PREFIX)
 998 AC_SUBST(LLVM_BINDIR)
 999 AC_SUBST(LLVM_LIBDIR)
1000 AC_SUBST(LLVM_DATADIR)
1001 AC_SUBST(LLVM_DOCSDIR)
1002 AC_SUBST(LLVM_ETCDIR)
1003 AC_SUBST(LLVM_INCLUDEDIR)
1004 AC_SUBST(LLVM_INFODIR)
1005 AC_SUBST(LLVM_MANDIR)
1006 AC_SUBST(LLVM_CONFIGTIME)
1007
1008 # Place the various directores into the config.h file as #defines so that we
1009 # can know about the installation paths within LLVM.
1010 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1011                    [Installation prefix directory])
1012 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1013                    [Installation directory for binary executables])
1014 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1015                    [Installation directory for libraries])
1016 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1017                    [Installation directory for data files])
1018 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1019                    [Installation directory for documentation])
1020 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1021                    [Installation directory for config files])
1022 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1023                    [Installation directory for include files])
1024 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1025                    [Installation directory for .info files])
1026 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1027                    [Installation directory for man pages])
1028 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1029                    [Time at which LLVM was configured])
1030 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1031                    [Host triple we were built on])
1032
1033 # Determine which bindings to build.
1034 if test "$BINDINGS_TO_BUILD" = auto ; then
1035   BINDINGS_TO_BUILD=""
1036   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1037     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1038   fi
1039 fi
1040 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1041
1042 # This isn't really configurey, but it avoids having to repeat the list in
1043 # other files.
1044 AC_SUBST(ALL_BINDINGS,ocaml)
1045
1046 # Do any work necessary to ensure that bindings have what they need.
1047 binding_prereqs_failed=0
1048 for a_binding in $BINDINGS_TO_BUILD ; do
1049   case "$a_binding" in
1050   ocaml)
1051     if test "x$OCAMLC" = x ; then
1052       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1053       binding_prereqs_failed=1
1054     fi
1055     if test "x$OCAMLDEP" = x ; then
1056       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1057       binding_prereqs_failed=1
1058     fi
1059     if test "x$OCAMLOPT" = x ; then
1060       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1061       dnl ocamlopt is optional!
1062     fi
1063     if test "x$with_ocaml_libdir" != xauto ; then
1064       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1065     else
1066       ocaml_stdlib="`"$OCAMLC" -where`"
1067       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1068       then
1069         # ocaml stdlib is beneath our prefix; use stdlib
1070         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1071       else
1072         # ocaml stdlib is outside our prefix; use libdir/ocaml
1073         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1074       fi
1075     fi
1076     ;;
1077   esac
1078 done
1079 if test "$binding_prereqs_failed" = 1 ; then
1080   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1081 fi
1082
1083 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1084 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1085
1086 dnl Determine linker rpath flag
1087 if test "$llvm_cv_link_use_r" = "yes" ; then
1088   RPATH="-Wl,-R"
1089 else
1090   RPATH="-Wl,-rpath"
1091 fi
1092 AC_SUBST(RPATH)
1093
1094 dnl Determine linker rdynamic flag
1095 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1096   RDYNAMIC="-Wl,-export-dynamic"
1097 else
1098   RDYNAMIC=""
1099 fi
1100 AC_SUBST(RDYNAMIC)
1101
1102 dnl===-----------------------------------------------------------------------===
1103 dnl===
1104 dnl=== SECTION 10: Specify the output files and generate it
1105 dnl===
1106 dnl===-----------------------------------------------------------------------===
1107
1108 dnl Configure header files
1109 dnl WARNING: dnl If you add or remove any of the following config headers, then
1110 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1111 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1112 dnl files can be updated automatically when their *.in sources change.
1113 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1114 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1115 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1116
1117 dnl Configure the makefile's configuration data
1118 AC_CONFIG_FILES([Makefile.config])
1119
1120 dnl Configure the RPM spec file for LLVM
1121 AC_CONFIG_FILES([llvm.spec])
1122
1123 dnl Configure doxygen's configuration file
1124 AC_CONFIG_FILES([docs/doxygen.cfg])
1125
1126 dnl Configure llvmc's Base plugin
1127 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1128
1129 dnl Do the first stage of configuration for llvm-config.in.
1130 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1131
1132 dnl Do special configuration of Makefiles
1133 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1134 AC_CONFIG_MAKEFILE(Makefile)
1135 AC_CONFIG_MAKEFILE(Makefile.common)
1136 AC_CONFIG_MAKEFILE(examples/Makefile)
1137 AC_CONFIG_MAKEFILE(lib/Makefile)
1138 AC_CONFIG_MAKEFILE(runtime/Makefile)
1139 AC_CONFIG_MAKEFILE(test/Makefile)
1140 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1141 AC_CONFIG_MAKEFILE(unittests/Makefile)
1142 AC_CONFIG_MAKEFILE(tools/Makefile)
1143 AC_CONFIG_MAKEFILE(utils/Makefile)
1144 AC_CONFIG_MAKEFILE(projects/Makefile)
1145 AC_CONFIG_MAKEFILE(bindings/Makefile)
1146 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1147
1148 dnl Finally, crank out the output
1149 AC_OUTPUT