cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSymbolExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file(argz.h HAVE_ARGZ_H)
  39 check_include_file(assert.h HAVE_ASSERT_H)
  40 check_include_file(ctype.h HAVE_CTYPE_H)
  41 check_include_file(dirent.h HAVE_DIRENT_H)
  42 check_include_file(dl.h HAVE_DL_H)
  43 check_include_file(dld.h HAVE_DLD_H)
  44 check_include_file(dlfcn.h HAVE_DLFCN_H)
  45 check_include_file(errno.h HAVE_ERRNO_H)
  46 check_include_file(execinfo.h HAVE_EXECINFO_H)
  47 check_include_file(fcntl.h HAVE_FCNTL_H)
  48 check_include_file(inttypes.h HAVE_INTTYPES_H)
  49 check_include_file(limits.h HAVE_LIMITS_H)
  50 check_include_file(link.h HAVE_LINK_H)
  51 check_include_file(malloc.h HAVE_MALLOC_H)
  52 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  53 check_include_file(memory.h HAVE_MEMORY_H)
  54 check_include_file(ndir.h HAVE_NDIR_H)
  55 if( NOT PURE_WINDOWS )
  56   check_include_file(pthread.h HAVE_PTHREAD_H)
  57 endif()
  58 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  59 check_include_file(setjmp.h HAVE_SETJMP_H)
  60 check_include_file(signal.h HAVE_SIGNAL_H)
  61 check_include_file(stdint.h HAVE_STDINT_H)
  62 check_include_file(stdio.h HAVE_STDIO_H)
  63 check_include_file(stdlib.h HAVE_STDLIB_H)
  64 check_include_file(string.h HAVE_STRING_H)
  65 check_include_file(strings.h HAVE_STRINGS_H)
  66 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  67 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  68 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  69 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  70 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  71 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  72 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  73 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  74 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  75 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  76 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  77 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  78 check_include_file(termios.h HAVE_TERMIOS_H)
  79 check_include_file(unistd.h HAVE_UNISTD_H)
  80 check_include_file(utime.h HAVE_UTIME_H)
  81 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  82 check_include_file(windows.h HAVE_WINDOWS_H)
  83 check_include_file(fenv.h HAVE_FENV_H)
  84 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  85 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  86
  87 # library checks
  88 if( NOT PURE_WINDOWS )
  89   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  90   if (HAVE_LIBPTHREAD)
  91     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  92     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  93     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  94   else()
  95     # this could be Android
  96     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  97     if (PTHREAD_IN_LIBC)
  98       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  99       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 100       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 101     endif()
 102   endif()
 103   check_library_exists(dl dlopen "" HAVE_LIBDL)
 104   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 105 endif()
 106
 107 # function checks
 108 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 109 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 110 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 111 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 112 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 113 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 114 check_symbol_exists(index strings.h HAVE_INDEX)
 115 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 116 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 117 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 118 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 119 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 120 check_symbol_exists(ceilf math.h HAVE_CEILF)
 121 check_symbol_exists(floorf math.h HAVE_FLOORF)
 122 check_symbol_exists(fmodf math.h HAVE_FMODF)
 123 check_cxx_symbol_exists(log cmath HAVE_LOG)
 124 check_cxx_symbol_exists(log2 cmath HAVE_LOG2)
 125 check_cxx_symbol_exists(log10 cmath HAVE_LOG10)
 126 check_cxx_symbol_exists(exp cmath HAVE_EXP)
 127 check_cxx_symbol_exists(exp2 cmath HAVE_EXP2)
 128 check_cxx_symbol_exists(exp10 cmath HAVE_EXP10)
 129 if( HAVE_SETJMP_H )
 130   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 131   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 132   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 133   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 134 endif()
 135 if( HAVE_SYS_UIO_H )
 136   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 137 endif()
 138 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 139 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 140 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 141                     HAVE_MALLOC_ZONE_STATISTICS)
 142 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 143 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 144 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 145 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 146 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 147 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 148 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 149 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 150 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 151 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 152 check_symbol_exists(pread unistd.h HAVE_PREAD)
 153 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 154 check_symbol_exists(strchr string.h HAVE_STRCHR)
 155 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 156 check_symbol_exists(strdup string.h HAVE_STRDUP)
 157 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 158 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 159 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 160 if( HAVE_RAND48_SRAND48 )
 161   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 162   if( HAVE_RAND48_LRAND48 )
 163     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 164     if( HAVE_RAND48_DRAND48 )
 165       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 166     endif()
 167   endif()
 168 endif()
 169 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 170 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 171 check_symbol_exists(strerror string.h HAVE_STRERROR)
 172 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 173 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 174 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 175 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 176 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 177 if( PURE_WINDOWS )
 178   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 179
 180   check_function_exists(_alloca HAVE__ALLOCA)
 181   check_function_exists(__alloca HAVE___ALLOCA)
 182   check_function_exists(__chkstk HAVE___CHKSTK)
 183   check_function_exists(___chkstk HAVE____CHKSTK)
 184
 185   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 186   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 187   check_function_exists(__divdi3 HAVE___DIVDI3)
 188   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 189   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 190   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 191   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 192   check_function_exists(__moddi3 HAVE___MODDI3)
 193   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 194   check_function_exists(__umoddi3 HAVE___UMODDI3)
 195
 196   check_function_exists(__main HAVE___MAIN)
 197   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 198 endif()
 199 if( HAVE_ARGZ_H )
 200   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 201   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 202   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 203   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 204   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 205 endif()
 206 if( HAVE_DLFCN_H )
 207   if( HAVE_LIBDL )
 208     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 209   endif()
 210   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 211   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 212   if( HAVE_LIBDL )
 213     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 214   endif()
 215 endif()
 216
 217 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 218 if( LLVM_USING_GLIBC )
 219   add_llvm_definitions( -D_GNU_SOURCE )
 220 endif()
 221
 222 set(headers "")
 223 if (HAVE_SYS_TYPES_H)
 224   set(headers ${headers} "sys/types.h")
 225 endif()
 226
 227 if (HAVE_INTTYPES_H)
 228   set(headers ${headers} "inttypes.h")
 229 endif()
 230
 231 if (HAVE_STDINT_H)
 232   set(headers ${headers} "stdint.h")
 233 endif()
 234
 235 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 236 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 237 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 238 check_type_exists(error_t errno.h HAVE_ERROR_T)
 239
 240 # available programs checks
 241 function(llvm_find_program name)
 242   string(TOUPPER ${name} NAME)
 243   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 244   find_program(LLVM_PATH_${NAME} ${name})
 245   mark_as_advanced(LLVM_PATH_${NAME})
 246   if(LLVM_PATH_${NAME})
 247     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 248     mark_as_advanced(HAVE_${NAME})
 249   else(LLVM_PATH_${NAME})
 250     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 251   endif(LLVM_PATH_${NAME})
 252 endfunction()
 253
 254 llvm_find_program(gv)
 255 llvm_find_program(circo)
 256 llvm_find_program(twopi)
 257 llvm_find_program(neato)
 258 llvm_find_program(fdp)
 259 llvm_find_program(dot)
 260 llvm_find_program(dotty)
 261 llvm_find_program(xdot.py)
 262 llvm_find_program(Graphviz)
 263
 264 if( LLVM_ENABLE_FFI )
 265   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 266   if( FFI_INCLUDE_PATH )
 267     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 268     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 269   else()
 270     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 271     if( FFI_INCLUDE_PATH )
 272       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 273       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 274     endif()
 275   endif()
 276
 277   if( NOT FFI_HEADER )
 278     message(FATAL_ERROR "libffi includes are not found.")
 279   endif()
 280
 281   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 282   if( NOT FFI_LIBRARY_PATH )
 283     message(FATAL_ERROR "libffi is not found.")
 284   endif()
 285
 286   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 287   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 288   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 289   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 290   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 291 else()
 292   unset(HAVE_FFI_FFI_H CACHE)
 293   unset(HAVE_FFI_H CACHE)
 294   unset(HAVE_FFI_CALL CACHE)
 295 endif( LLVM_ENABLE_FFI )
 296
 297 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 298 include(CheckAtomic)
 299
 300 if( LLVM_ENABLE_PIC )
 301   set(ENABLE_PIC 1)
 302 else()
 303   set(ENABLE_PIC 0)
 304 endif()
 305
 306 find_package(LibXml2)
 307 if (LIBXML2_FOUND)
 308   set(CLANG_HAVE_LIBXML 1)
 309 endif ()
 310
 311 include(CheckCXXCompilerFlag)
 312
 313 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 314
 315 set(USE_NO_MAYBE_UNINITIALIZED 0)
 316 set(USE_NO_UNINITIALIZED 0)
 317
 318 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 319 # false positives.
 320 if (CMAKE_COMPILER_IS_GNUCXX)
 321   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 322   if (HAS_MAYBE_UNINITIALIZED)
 323     set(USE_NO_MAYBE_UNINITIALIZED 1)
 324   else()
 325     # Only recent versions of gcc make the distinction between -Wuninitialized
 326     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 327     # turn off all uninitialized use warnings.
 328     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 329     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 330   endif()
 331 endif()
 332
 333 include(GetHostTriple)
 334 get_host_triple(LLVM_HOST_TRIPLE)
 335
 336 # By default, we target the host, but this can be overridden at CMake
 337 # invocation time.
 338 set(LLVM_HOSTTRIPLE "${LLVM_HOST_TRIPLE}")
 339
 340 # Determine the native architecture.
 341 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 342 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 343   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 344 endif ()
 345
 346 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 347   set(LLVM_NATIVE_ARCH X86)
 348 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 349   set(LLVM_NATIVE_ARCH X86)
 350 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 351   set(LLVM_NATIVE_ARCH X86)
 352 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 353   set(LLVM_NATIVE_ARCH X86)
 354 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 355   set(LLVM_NATIVE_ARCH Sparc)
 356 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 357   set(LLVM_NATIVE_ARCH PowerPC)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 359   set(LLVM_NATIVE_ARCH ARM)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 361   set(LLVM_NATIVE_ARCH Mips)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 363   set(LLVM_NATIVE_ARCH XCore)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 365   set(LLVM_NATIVE_ARCH MSP430)
 366 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 367   set(LLVM_NATIVE_ARCH Hexagon)
 368 else ()
 369   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 370 endif ()
 371
 372 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 373 if (NATIVE_ARCH_IDX EQUAL -1)
 374   message(STATUS
 375     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 376 else ()
 377   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 378   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 379   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 380   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 381   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 382
 383   # We don't have an ASM parser for all architectures yet.
 384   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 385     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 386   endif ()
 387
 388   # We don't have an disassembler for all architectures yet.
 389   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 390     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 391   endif ()
 392 endif ()
 393
 394 if( MINGW )
 395   set(HAVE_LIBIMAGEHLP 1)
 396   set(HAVE_LIBPSAPI 1)
 397   # TODO: Check existence of libraries.
 398   #   include(CheckLibraryExists)
 399   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 400 endif( MINGW )
 401
 402 if( MSVC )
 403   set(error_t int)
 404   set(LTDL_SHLIBPATH_VAR "PATH")
 405   set(LTDL_SYSSEARCHPATH "")
 406   set(LTDL_DLOPEN_DEPLIBS 1)
 407   set(SHLIBEXT ".lib")
 408   set(LTDL_OBJDIR "_libs")
 409   set(HAVE_STRTOLL 1)
 410   set(strtoll "_strtoi64")
 411   set(strtoull "_strtoui64")
 412   set(stricmp "_stricmp")
 413   set(strdup "_strdup")
 414 else( MSVC )
 415   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 416   set(LTDL_SYSSEARCHPATH "") # TODO
 417   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 418 endif( MSVC )
 419
 420 if( PURE_WINDOWS )
 421   CHECK_CXX_SOURCE_COMPILES("
 422     #include <windows.h>
 423     #include <imagehlp.h>
 424     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 425     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 426     int main(){return 0;}"
 427     HAVE_ELMCB_PCSTR)
 428   if( HAVE_ELMCB_PCSTR )
 429     set(WIN32_ELMCB_PCSTR "PCSTR")
 430   else()
 431     set(WIN32_ELMCB_PCSTR "PSTR")
 432   endif()
 433 endif( PURE_WINDOWS )
 434
 435 # FIXME: Signal handler return type, currently hardcoded to 'void'
 436 set(RETSIGTYPE void)
 437
 438 if( LLVM_ENABLE_THREADS )
 439   # Check if threading primitives aren't supported on this platform
 440   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 441     set(LLVM_ENABLE_THREADS 0)
 442   endif()
 443 endif()
 444
 445 if( LLVM_ENABLE_THREADS )
 446   message(STATUS "Threads enabled.")
 447 else( LLVM_ENABLE_THREADS )
 448   message(STATUS "Threads disabled.")
 449 endif()
 450
 451 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})