cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # Helper macros and functions
  27 macro(add_cxx_include result files)
  28   set(${result} "")
  29   foreach (file_name ${files})
  30      set(${result} "${${result}}#include<${file_name}>\n")
  31   endforeach()
  32 endmacro(add_cxx_include files result)
  33
  34 function(check_type_exists type files variable)
  35   add_cxx_include(includes "${files}")
  36   CHECK_CXX_SOURCE_COMPILES("
  37     ${includes} ${type} typeVar;
  38     int main() {
  39         return 0;
  40     }
  41     " ${variable})
  42 endfunction()
  43
  44 # include checks
  45 check_include_file(dirent.h HAVE_DIRENT_H)
  46 check_include_file(dlfcn.h HAVE_DLFCN_H)
  47 check_include_file(errno.h HAVE_ERRNO_H)
  48 check_include_file(execinfo.h HAVE_EXECINFO_H)
  49 check_include_file(fcntl.h HAVE_FCNTL_H)
  50 check_include_file(inttypes.h HAVE_INTTYPES_H)
  51 check_include_file(limits.h HAVE_LIMITS_H)
  52 check_include_file(link.h HAVE_LINK_H)
  53 check_include_file(malloc.h HAVE_MALLOC_H)
  54 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  55 check_include_file(ndir.h HAVE_NDIR_H)
  56 if( NOT PURE_WINDOWS )
  57   check_include_file(pthread.h HAVE_PTHREAD_H)
  58 endif()
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  62 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  63 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  64 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  65 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  66 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  67 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  69 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  70 check_include_file(termios.h HAVE_TERMIOS_H)
  71 check_include_file(unistd.h HAVE_UNISTD_H)
  72 check_include_file(utime.h HAVE_UTIME_H)
  73 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  74 check_include_file(zlib.h HAVE_ZLIB_H)
  75 check_include_file(fenv.h HAVE_FENV_H)
  76 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  77 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  78
  79 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  80 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  81 check_include_file(histedit.h HAVE_HISTEDIT_H)
  82
  83 # size_t must be defined before including cxxabi.h on FreeBSD 10.0.
  84 check_cxx_source_compiles("
  85 #include <stddef.h>
  86 #include <cxxabi.h>
  87 int main() { return 0; }
  88 " HAVE_CXXABI_H)
  89
  90 # library checks
  91 if( NOT PURE_WINDOWS )
  92   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  93   if (HAVE_LIBPTHREAD)
  94     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  95     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  96     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  97   else()
  98     # this could be Android
  99     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 100     if (PTHREAD_IN_LIBC)
 101       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 102       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 103       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 104     endif()
 105   endif()
 106   check_library_exists(dl dlopen "" HAVE_LIBDL)
 107   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 108   if (LLVM_ENABLE_ZLIB)
 109     check_library_exists(z compress2 "" HAVE_LIBZ)
 110   else()
 111     set(HAVE_LIBZ 0)
 112   endif()
 113   if (HAVE_HISTEDIT_H)
 114     check_library_exists(edit el_init "" HAVE_LIBEDIT)
 115   endif()
 116   if(LLVM_ENABLE_TERMINFO)
 117     set(HAVE_TERMINFO 0)
 118     foreach(library tinfo terminfo curses ncurses ncursesw)
 119       string(TOUPPER ${library} library_suffix)
 120       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 121       if(HAVE_TERMINFO_${library_suffix})
 122         set(HAVE_TERMINFO 1)
 123         set(TERMINFO_LIBS "${library}")
 124         break()
 125       endif()
 126     endforeach()
 127   else()
 128     set(HAVE_TERMINFO 0)
 129   endif()
 130 endif()
 131
 132 # function checks
 133 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 134 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 135 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 136 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 137 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 138 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 139 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 140 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 141 if( HAVE_SETJMP_H )
 142   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 143   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 144   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 145   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 146 endif()
 147 if( HAVE_SYS_UIO_H )
 148   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 149 endif()
 150 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 151 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 152 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 153                     HAVE_MALLOC_ZONE_STATISTICS)
 154 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 155 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 156 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 157 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 158 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 159 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 160 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 161 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 162 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 163 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 164 check_symbol_exists(pread unistd.h HAVE_PREAD)
 165 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 166 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 167 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 168 if( HAVE_RAND48_SRAND48 )
 169   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 170   if( HAVE_RAND48_LRAND48 )
 171     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 172     if( HAVE_RAND48_DRAND48 )
 173       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 174     endif()
 175   endif()
 176 endif()
 177 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 178 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 179 check_symbol_exists(strerror string.h HAVE_STRERROR)
 180 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 181 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 182 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 183 if( PURE_WINDOWS )
 184   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 185
 186   check_function_exists(_alloca HAVE__ALLOCA)
 187   check_function_exists(__alloca HAVE___ALLOCA)
 188   check_function_exists(__chkstk HAVE___CHKSTK)
 189   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 190   check_function_exists(___chkstk HAVE____CHKSTK)
 191   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 192
 193   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 194   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 195   check_function_exists(__divdi3 HAVE___DIVDI3)
 196   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 197   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 198   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 199   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 200   check_function_exists(__moddi3 HAVE___MODDI3)
 201   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 202   check_function_exists(__umoddi3 HAVE___UMODDI3)
 203
 204   check_function_exists(__main HAVE___MAIN)
 205   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 206 endif()
 207 if( HAVE_DLFCN_H )
 208   if( HAVE_LIBDL )
 209     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 210   endif()
 211   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 212   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 213   if( HAVE_LIBDL )
 214     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 215   endif()
 216 endif()
 217
 218 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 219 if( LLVM_USING_GLIBC )
 220   add_llvm_definitions( -D_GNU_SOURCE )
 221 endif()
 222
 223 set(headers "sys/types.h")
 224
 225 if (HAVE_INTTYPES_H)
 226   set(headers ${headers} "inttypes.h")
 227 endif()
 228
 229 if (HAVE_STDINT_H)
 230   set(headers ${headers} "stdint.h")
 231 endif()
 232
 233 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 234 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 235 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 236
 237 # available programs checks
 238 function(llvm_find_program name)
 239   string(TOUPPER ${name} NAME)
 240   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 241
 242   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 243   mark_as_advanced(LLVM_PATH_${NAME})
 244   if(LLVM_PATH_${NAME})
 245     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 246     mark_as_advanced(HAVE_${NAME})
 247   else(LLVM_PATH_${NAME})
 248     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 249   endif(LLVM_PATH_${NAME})
 250 endfunction()
 251
 252 if (LLVM_ENABLE_DOXYGEN)
 253   llvm_find_program(dot)
 254 endif ()
 255
 256 if( LLVM_ENABLE_FFI )
 257   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 258   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 259     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 260     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 261   else()
 262     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 263     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 264       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 265       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 266     endif()
 267   endif()
 268
 269   if( NOT FFI_HEADER )
 270     message(FATAL_ERROR "libffi includes are not found.")
 271   endif()
 272
 273   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 274   if( NOT FFI_LIBRARY_PATH )
 275     message(FATAL_ERROR "libffi is not found.")
 276   endif()
 277
 278   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 279   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 280   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 281   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 282   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 283 else()
 284   unset(HAVE_FFI_FFI_H CACHE)
 285   unset(HAVE_FFI_H CACHE)
 286   unset(HAVE_FFI_CALL CACHE)
 287 endif( LLVM_ENABLE_FFI )
 288
 289 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 290 include(CheckAtomic)
 291
 292 if( LLVM_ENABLE_PIC )
 293   set(ENABLE_PIC 1)
 294 else()
 295   set(ENABLE_PIC 0)
 296 endif()
 297
 298 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 299
 300 set(USE_NO_MAYBE_UNINITIALIZED 0)
 301 set(USE_NO_UNINITIALIZED 0)
 302
 303 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 304 # false positives.
 305 if (CMAKE_COMPILER_IS_GNUCXX)
 306   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 307   if (HAS_MAYBE_UNINITIALIZED)
 308     set(USE_NO_MAYBE_UNINITIALIZED 1)
 309   else()
 310     # Only recent versions of gcc make the distinction between -Wuninitialized
 311     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 312     # turn off all uninitialized use warnings.
 313     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 314     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 315   endif()
 316 endif()
 317
 318 # By default, we target the host, but this can be overridden at CMake
 319 # invocation time.
 320 include(GetHostTriple)
 321 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 322
 323 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 324     "Host on which LLVM binaries will run")
 325
 326 # Determine the native architecture.
 327 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 328 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 329   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 330 endif ()
 331
 332 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 333   set(LLVM_NATIVE_ARCH X86)
 334 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 335   set(LLVM_NATIVE_ARCH X86)
 336 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 337   set(LLVM_NATIVE_ARCH X86)
 338 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 339   set(LLVM_NATIVE_ARCH X86)
 340 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 341   set(LLVM_NATIVE_ARCH Sparc)
 342 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 343   set(LLVM_NATIVE_ARCH PowerPC)
 344 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 345   set(LLVM_NATIVE_ARCH AArch64)
 346 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 347   set(LLVM_NATIVE_ARCH AArch64)
 348 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 349   set(LLVM_NATIVE_ARCH ARM)
 350 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 351   set(LLVM_NATIVE_ARCH Mips)
 352 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 353   set(LLVM_NATIVE_ARCH XCore)
 354 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 355   set(LLVM_NATIVE_ARCH MSP430)
 356 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 357   set(LLVM_NATIVE_ARCH Hexagon)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 359   set(LLVM_NATIVE_ARCH SystemZ)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 361   set(LLVM_NATIVE_ARCH WebAssembly)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 363   set(LLVM_NATIVE_ARCH WebAssembly)
 364 else ()
 365   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 366 endif ()
 367
 368 # If build targets includes "host", then replace with native architecture.
 369 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 370 if( NOT idx LESS 0 )
 371   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 372   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 373   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 374 endif()
 375
 376 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 377 if (NATIVE_ARCH_IDX EQUAL -1)
 378   message(STATUS
 379     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 380 else ()
 381   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 382   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 383   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 384   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 385   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 386
 387   # We don't have an ASM parser for all architectures yet.
 388   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 389     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 390   endif ()
 391
 392   # We don't have an disassembler for all architectures yet.
 393   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 394     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 395   endif ()
 396 endif ()
 397
 398 if( MINGW )
 399   set(HAVE_LIBPSAPI 1)
 400   set(HAVE_LIBSHELL32 1)
 401   # TODO: Check existence of libraries.
 402   #   include(CheckLibraryExists)
 403 endif( MINGW )
 404
 405 if (NOT HAVE_STRTOLL)
 406   # Use _strtoi64 if strtoll is not available.
 407   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 408   if (have_strtoi64)
 409     set(HAVE_STRTOLL 1)
 410     set(strtoll "_strtoi64")
 411     set(strtoull "_strtoui64")
 412   endif ()
 413 endif ()
 414
 415 if( MSVC )
 416   set(SHLIBEXT ".lib")
 417   set(stricmp "_stricmp")
 418   set(strdup "_strdup")
 419
 420   # See if the DIA SDK is available and usable.
 421   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 422
 423   # Due to a bug in MSVC 2013's installation software, it is possible
 424   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 425   # install directory.  If this happens, the installation is corrupt
 426   # and there's nothing we can do.  It happens with enough frequency
 427   # though that we should handle it.  We do so by simply checking that
 428   # the DIA SDK folder exists.  Should this happen you will need to
 429   # uninstall VS 2012 and then re-install VS 2013.
 430   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 431     set(HAVE_DIA_SDK 1)
 432   else()
 433     set(HAVE_DIA_SDK 0)
 434   endif()
 435 else()
 436   set(HAVE_DIA_SDK 0)
 437 endif( MSVC )
 438
 439 if( PURE_WINDOWS )
 440   CHECK_CXX_SOURCE_COMPILES("
 441     #include <windows.h>
 442     #include <imagehlp.h>
 443     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 444     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 445     int main(){return 0;}"
 446     HAVE_ELMCB_PCSTR)
 447   if( HAVE_ELMCB_PCSTR )
 448     set(WIN32_ELMCB_PCSTR "PCSTR")
 449   else()
 450     set(WIN32_ELMCB_PCSTR "PSTR")
 451   endif()
 452 endif( PURE_WINDOWS )
 453
 454 # FIXME: Signal handler return type, currently hardcoded to 'void'
 455 set(RETSIGTYPE void)
 456
 457 if( LLVM_ENABLE_THREADS )
 458   # Check if threading primitives aren't supported on this platform
 459   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 460     set(LLVM_ENABLE_THREADS 0)
 461   endif()
 462 endif()
 463
 464 if( LLVM_ENABLE_THREADS )
 465   message(STATUS "Threads enabled.")
 466 else( LLVM_ENABLE_THREADS )
 467   message(STATUS "Threads disabled.")
 468 endif()
 469
 470 if (LLVM_ENABLE_ZLIB )
 471   # Check if zlib is available in the system.
 472   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 473     set(LLVM_ENABLE_ZLIB 0)
 474   endif()
 475 endif()
 476
 477 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 478
 479 if (LLVM_ENABLE_DOXYGEN)
 480   message(STATUS "Doxygen enabled.")
 481   find_package(Doxygen REQUIRED)
 482
 483   if (DOXYGEN_FOUND)
 484     # If we find doxygen and we want to enable doxygen by default create a
 485     # global aggregate doxygen target for generating llvm and any/all
 486     # subprojects doxygen documentation.
 487     if (LLVM_BUILD_DOCS)
 488       add_custom_target(doxygen ALL)
 489     endif()
 490
 491     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 492     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 493       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 494       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 495     endif()
 496   endif()
 497 else()
 498   message(STATUS "Doxygen disabled.")
 499 endif()
 500
 501 if (LLVM_ENABLE_SPHINX)
 502   message(STATUS "Sphinx enabled.")
 503   find_package(Sphinx REQUIRED)
 504   if (LLVM_BUILD_DOCS)
 505     add_custom_target(sphinx ALL)
 506   endif()
 507 else()
 508   message(STATUS "Sphinx disabled.")
 509 endif()
 510
 511 set(LLVM_BINDINGS "")
 512 if(WIN32)
 513   message(STATUS "Go bindings disabled.")
 514 else()
 515   find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 516   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 517     message(STATUS "Go bindings disabled.")
 518   else()
 519     execute_process(COMMAND ${GO_EXECUTABLE} run ${CMAKE_SOURCE_DIR}/bindings/go/conftest.go
 520                     RESULT_VARIABLE GO_CONFTEST)
 521     if(GO_CONFTEST STREQUAL "0")
 522       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 523       message(STATUS "Go bindings enabled.")
 524     else()
 525       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 526     endif()
 527   endif()
 528 endif()
 529
 530 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 531 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 532         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 533
 534 if(APPLE)
 535   find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 536 endif()
 537
 538 include(FindOCaml)
 539 include(AddOCaml)
 540 if(WIN32)
 541   message(STATUS "OCaml bindings disabled.")
 542 else()
 543   find_package(OCaml)
 544   if( NOT OCAML_FOUND )
 545     message(STATUS "OCaml bindings disabled.")
 546   else()
 547     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 548       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 549     else()
 550       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 551       if( HAVE_OCAML_CTYPES )
 552         message(STATUS "OCaml bindings enabled.")
 553         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 554         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 555       else()
 556         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 557       endif()
 558     endif()
 559   endif()
 560 endif()
 561
 562 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")