cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  39 check_include_file(dirent.h HAVE_DIRENT_H)
  40 check_include_file(dlfcn.h HAVE_DLFCN_H)
  41 check_include_file(errno.h HAVE_ERRNO_H)
  42 check_include_file(execinfo.h HAVE_EXECINFO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(inttypes.h HAVE_INTTYPES_H)
  45 check_include_file(limits.h HAVE_LIMITS_H)
  46 check_include_file(malloc.h HAVE_MALLOC_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT PURE_WINDOWS )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  56 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  57 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  58 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  59 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  60 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  61 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  62 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  63 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  64 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  65 check_include_file(termios.h HAVE_TERMIOS_H)
  66 check_include_file(unistd.h HAVE_UNISTD_H)
  67 check_include_file(utime.h HAVE_UTIME_H)
  68 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  69 check_include_file(zlib.h HAVE_ZLIB_H)
  70 check_include_file(fenv.h HAVE_FENV_H)
  71 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  72 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  73
  74 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  75 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  76
  77 # library checks
  78 if( NOT PURE_WINDOWS )
  79   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  80   if (HAVE_LIBPTHREAD)
  81     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  82     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  83     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  84   else()
  85     # this could be Android
  86     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  87     if (PTHREAD_IN_LIBC)
  88       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91     endif()
  92   endif()
  93   check_library_exists(dl dlopen "" HAVE_LIBDL)
  94   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  95   if (LLVM_ENABLE_ZLIB)
  96     check_library_exists(z compress2 "" HAVE_LIBZ)
  97   else()
  98     set(HAVE_LIBZ 0)
  99   endif()
 100   if(LLVM_ENABLE_TERMINFO)
 101     set(HAVE_TERMINFO 0)
 102     foreach(library tinfo terminfo curses ncurses ncursesw)
 103       string(TOUPPER ${library} library_suffix)
 104       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 105       if(HAVE_TERMINFO_${library_suffix})
 106         set(HAVE_TERMINFO 1)
 107         set(TERMINFO_LIBS "${library}")
 108         break()
 109       endif()
 110     endforeach()
 111   else()
 112     set(HAVE_TERMINFO 0)
 113   endif()
 114 endif()
 115
 116 # function checks
 117 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 118 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 119 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 120 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 121 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 122 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 123 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 124 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 125 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 126 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 127 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 128 check_symbol_exists(ceilf math.h HAVE_CEILF)
 129 check_symbol_exists(floorf math.h HAVE_FLOORF)
 130 check_symbol_exists(fmodf math.h HAVE_FMODF)
 131 check_symbol_exists(log math.h HAVE_LOG)
 132 check_symbol_exists(log2 math.h HAVE_LOG2)
 133 check_symbol_exists(log10 math.h HAVE_LOG10)
 134 check_symbol_exists(exp math.h HAVE_EXP)
 135 check_symbol_exists(exp2 math.h HAVE_EXP2)
 136 check_symbol_exists(exp10 math.h HAVE_EXP10)
 137 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 138 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 139 if( HAVE_SETJMP_H )
 140   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 141   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 142   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 143   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 144 endif()
 145 if( HAVE_SYS_UIO_H )
 146   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 147 endif()
 148 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 149 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 150 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 151                     HAVE_MALLOC_ZONE_STATISTICS)
 152 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 153 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 154 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 155 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 156 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 157 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 158 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 159 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 160 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 161 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 162 check_symbol_exists(pread unistd.h HAVE_PREAD)
 163 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 164 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 165 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 166 if( HAVE_RAND48_SRAND48 )
 167   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 168   if( HAVE_RAND48_LRAND48 )
 169     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 170     if( HAVE_RAND48_DRAND48 )
 171       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 172     endif()
 173   endif()
 174 endif()
 175 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 176 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 177 check_symbol_exists(strerror string.h HAVE_STRERROR)
 178 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 179 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 180 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 181 if( PURE_WINDOWS )
 182   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 183
 184   check_function_exists(_alloca HAVE__ALLOCA)
 185   check_function_exists(__alloca HAVE___ALLOCA)
 186   check_function_exists(__chkstk HAVE___CHKSTK)
 187   check_function_exists(___chkstk HAVE____CHKSTK)
 188
 189   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 190   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 191   check_function_exists(__divdi3 HAVE___DIVDI3)
 192   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 193   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 194   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 195   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 196   check_function_exists(__moddi3 HAVE___MODDI3)
 197   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 198   check_function_exists(__umoddi3 HAVE___UMODDI3)
 199
 200   check_function_exists(__main HAVE___MAIN)
 201   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 202 endif()
 203 if( HAVE_DLFCN_H )
 204   if( HAVE_LIBDL )
 205     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 206   endif()
 207   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 208   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 209   if( HAVE_LIBDL )
 210     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 211   endif()
 212 endif()
 213
 214 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 215 if( LLVM_USING_GLIBC )
 216   add_llvm_definitions( -D_GNU_SOURCE )
 217 endif()
 218
 219 set(headers "sys/types.h")
 220
 221 if (HAVE_INTTYPES_H)
 222   set(headers ${headers} "inttypes.h")
 223 endif()
 224
 225 if (HAVE_STDINT_H)
 226   set(headers ${headers} "stdint.h")
 227 endif()
 228
 229 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 230 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 231 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 232
 233 # available programs checks
 234 function(llvm_find_program name)
 235   string(TOUPPER ${name} NAME)
 236   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 237
 238   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 239   mark_as_advanced(LLVM_PATH_${NAME})
 240   if(LLVM_PATH_${NAME})
 241     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 242     mark_as_advanced(HAVE_${NAME})
 243   else(LLVM_PATH_${NAME})
 244     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 245   endif(LLVM_PATH_${NAME})
 246 endfunction()
 247
 248 llvm_find_program(gv)
 249 llvm_find_program(circo)
 250 llvm_find_program(twopi)
 251 llvm_find_program(neato)
 252 llvm_find_program(fdp)
 253 llvm_find_program(dot)
 254 llvm_find_program(dotty)
 255 llvm_find_program(xdot xdot.py)
 256 llvm_find_program(Graphviz)
 257
 258 if( LLVM_ENABLE_FFI )
 259   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 260   if( FFI_INCLUDE_PATH )
 261     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 262     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 263   else()
 264     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 265     if( FFI_INCLUDE_PATH )
 266       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 267       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 268     endif()
 269   endif()
 270
 271   if( NOT FFI_HEADER )
 272     message(FATAL_ERROR "libffi includes are not found.")
 273   endif()
 274
 275   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 276   if( NOT FFI_LIBRARY_PATH )
 277     message(FATAL_ERROR "libffi is not found.")
 278   endif()
 279
 280   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 281   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 282   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 283   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 284   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 285 else()
 286   unset(HAVE_FFI_FFI_H CACHE)
 287   unset(HAVE_FFI_H CACHE)
 288   unset(HAVE_FFI_CALL CACHE)
 289 endif( LLVM_ENABLE_FFI )
 290
 291 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 292 include(CheckAtomic)
 293
 294 if( LLVM_ENABLE_PIC )
 295   set(ENABLE_PIC 1)
 296 else()
 297   set(ENABLE_PIC 0)
 298 endif()
 299
 300 find_package(LibXml2)
 301 if (LIBXML2_FOUND)
 302   set(CLANG_HAVE_LIBXML 1)
 303   # When cross-compiling, liblzma is not detected as a dependency for libxml2,
 304   # which makes linking c-index-test fail. But for native builds, all libraries
 305   # are installed and checked by CMake before Makefiles are generated and everything
 306   # works according to the plan. However, if a -llzma is added to native builds,
 307   # an additional requirement on the static liblzma.a is required, but will not
 308   # be checked by CMake, breaking native compilation.
 309   # Since this is only pertinent to cross-compilations, and there's no way CMake
 310   # can check for every foreign library on every OS, we add the dep and warn the dev.
 311   if ( CMAKE_CROSSCOMPILING )
 312     if (NOT PC_LIBXML_VERSION VERSION_LESS "2.8.0")
 313       message(STATUS "Adding LZMA as a dep to XML2 for cross-compilation, make sure liblzma.a is available.")
 314       set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARIES} "-llzma")
 315     endif ()
 316   endif ()
 317 endif ()
 318
 319 include(CheckCXXCompilerFlag)
 320
 321 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 322
 323 set(USE_NO_MAYBE_UNINITIALIZED 0)
 324 set(USE_NO_UNINITIALIZED 0)
 325
 326 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 327 # false positives.
 328 if (CMAKE_COMPILER_IS_GNUCXX)
 329   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 330   if (HAS_MAYBE_UNINITIALIZED)
 331     set(USE_NO_MAYBE_UNINITIALIZED 1)
 332   else()
 333     # Only recent versions of gcc make the distinction between -Wuninitialized
 334     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 335     # turn off all uninitialized use warnings.
 336     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 337     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 338   endif()
 339 endif()
 340
 341 # By default, we target the host, but this can be overridden at CMake
 342 # invocation time.
 343 include(GetHostTriple)
 344 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 345
 346 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 347     "Host on which LLVM binaries will run")
 348
 349 # Determine the native architecture.
 350 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 351 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 352   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 353 endif ()
 354
 355 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 356   set(LLVM_NATIVE_ARCH X86)
 357 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 358   set(LLVM_NATIVE_ARCH X86)
 359 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 360   set(LLVM_NATIVE_ARCH X86)
 361 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 362   set(LLVM_NATIVE_ARCH X86)
 363 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 364   set(LLVM_NATIVE_ARCH Sparc)
 365 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 366   set(LLVM_NATIVE_ARCH PowerPC)
 367 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 368   set(LLVM_NATIVE_ARCH AArch64)
 369 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 370   set(LLVM_NATIVE_ARCH ARM)
 371 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 372   set(LLVM_NATIVE_ARCH Mips)
 373 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 374   set(LLVM_NATIVE_ARCH XCore)
 375 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 376   set(LLVM_NATIVE_ARCH MSP430)
 377 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 378   set(LLVM_NATIVE_ARCH Hexagon)
 379 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 380   set(LLVM_NATIVE_ARCH SystemZ)
 381 else ()
 382   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 383 endif ()
 384
 385 # If build targets includes "host", then replace with native architecture.
 386 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 387 if( NOT idx LESS 0 )
 388   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 389   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 390   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 391 endif()
 392
 393 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 394 if (NATIVE_ARCH_IDX EQUAL -1)
 395   message(STATUS
 396     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 397 else ()
 398   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 399   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 400   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 401   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 402   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 403
 404   # We don't have an ASM parser for all architectures yet.
 405   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 406     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 407   endif ()
 408
 409   # We don't have an disassembler for all architectures yet.
 410   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 411     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 412   endif ()
 413 endif ()
 414
 415 if( MINGW )
 416   set(HAVE_LIBIMAGEHLP 1)
 417   set(HAVE_LIBPSAPI 1)
 418   set(HAVE_LIBSHELL32 1)
 419   # TODO: Check existence of libraries.
 420   #   include(CheckLibraryExists)
 421   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 422 endif( MINGW )
 423
 424 if (NOT HAVE_STRTOLL)
 425   # Use _strtoi64 if strtoll is not available.
 426   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 427   if (have_strtoi64)
 428     set(HAVE_STRTOLL 1)
 429     set(strtoll "_strtoi64")
 430     set(strtoull "_strtoui64")
 431   endif ()
 432 endif ()
 433
 434 if( MSVC )
 435   set(SHLIBEXT ".lib")
 436   set(stricmp "_stricmp")
 437   set(strdup "_strdup")
 438 endif( MSVC )
 439
 440 if( PURE_WINDOWS )
 441   CHECK_CXX_SOURCE_COMPILES("
 442     #include <windows.h>
 443     #include <imagehlp.h>
 444     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 445     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 446     int main(){return 0;}"
 447     HAVE_ELMCB_PCSTR)
 448   if( HAVE_ELMCB_PCSTR )
 449     set(WIN32_ELMCB_PCSTR "PCSTR")
 450   else()
 451     set(WIN32_ELMCB_PCSTR "PSTR")
 452   endif()
 453 endif( PURE_WINDOWS )
 454
 455 # FIXME: Signal handler return type, currently hardcoded to 'void'
 456 set(RETSIGTYPE void)
 457
 458 if( LLVM_ENABLE_THREADS )
 459   # Check if threading primitives aren't supported on this platform
 460   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 461     set(LLVM_ENABLE_THREADS 0)
 462   endif()
 463 endif()
 464
 465 if( LLVM_ENABLE_THREADS )
 466   message(STATUS "Threads enabled.")
 467 else( LLVM_ENABLE_THREADS )
 468   message(STATUS "Threads disabled.")
 469 endif()
 470
 471 if (LLVM_ENABLE_ZLIB )
 472   # Check if zlib is available in the system.
 473   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 474     set(LLVM_ENABLE_ZLIB 0)
 475   endif()
 476 endif()
 477
 478 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 479
 480 if (LLVM_ENABLE_DOXYGEN)
 481   message(STATUS "Doxygen enabled.")
 482   find_package(Doxygen)
 483
 484   if (DOXYGEN_FOUND)
 485     # If we find doxygen and we want to enable doxygen by default create a
 486     # global aggregate doxygen target for generating llvm and any/all
 487     # subprojects doxygen documentation.
 488     if (LLVM_BUILD_DOCS)
 489       add_custom_target(doxygen ALL)
 490     endif()
 491
 492     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 493     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 494       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 495       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 496     endif()
 497   endif()
 498 else()
 499   message(STATUS "Doxygen disabled.")
 500 endif()