cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  84                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  85   else()
  86     set(native_export_file "${target_name}.def")
  87
  88     set(CAT "cat")
  89     set(export_file_nativeslashes ${export_file})
  90     if(WIN32 AND NOT CYGWIN)
  91       set(CAT "type")
  92       # Convert ${export_file} to native format (backslashes) for "type"
  93       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  94       # path but a build-system specific format (see CMake bug
  95       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
  96       string(REPLACE / \\ export_file_nativeslashes ${export_file})
  97     endif()
  98
  99     add_custom_command(OUTPUT ${native_export_file}
 100       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 101       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 102       DEPENDS ${export_file}
 103       VERBATIM
 104       COMMENT "Creating export file for ${target_name}")
 105     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 106     if(MSVC)
 107       set(export_file_linker_flag "/DEF:${export_file_linker_flag}")
 108     endif()
 109     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 110                  LINK_FLAGS " ${export_file_linker_flag}")
 111   endif()
 112
 113   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 114   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 115
 116   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 117   foreach(src ${srcs})
 118     get_filename_component(extension ${src} EXT)
 119     if(extension STREQUAL ".cpp")
 120       set(first_source_file ${src})
 121       break()
 122     endif()
 123   endforeach()
 124
 125   # Force re-linking when the exports file changes. Actually, it
 126   # forces recompilation of the source file. The LINK_DEPENDS target
 127   # property only works for makefile-based generators.
 128   # FIXME: This is not safe because this will create the same target
 129   # ${native_export_file} in several different file:
 130   # - One where we emitted ${target_name}_exports
 131   # - One where we emitted the build command for the following object.
 132   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 133   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 134
 135   set_property(DIRECTORY APPEND
 136     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 137
 138   add_dependencies(${target_name} ${target_name}_exports)
 139
 140   # Add dependency to *_exports later -- CMake issue 14747
 141   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 142   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 143 endfunction(add_llvm_symbol_exports)
 144
 145 if(NOT WIN32 AND NOT APPLE)
 146   execute_process(
 147     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 148     OUTPUT_VARIABLE stdout
 149     ERROR_QUIET
 150     )
 151   if("${stdout}" MATCHES "GNU gold")
 152     set(LLVM_LINKER_IS_GOLD ON)
 153   endif()
 154 endif()
 155
 156 function(add_link_opts target_name)
 157   # Pass -O3 to the linker. This enabled different optimizations on different
 158   # linkers.
 159   if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 160     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                  LINK_FLAGS " -Wl,-O3")
 162   endif()
 163
 164   if(LLVM_LINKER_IS_GOLD)
 165     # With gold gc-sections is always safe.
 166     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                  LINK_FLAGS " -Wl,--gc-sections")
 168     # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169     # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170   endif()
 171
 172   if(NOT LLVM_NO_DEAD_STRIP)
 173     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174       # ld64's implementation of -dead_strip breaks tools that use plugins.
 175       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                    LINK_FLAGS " -Wl,-dead_strip")
 177     elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 178       # Object files are compiled with -ffunction-data-sections.
 179       # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 180       # tools that use plugins. Always pass --gc-sections once we require
 181       # a newer linker.
 182       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 183                    LINK_FLAGS " -Wl,--gc-sections")
 184     endif()
 185   endif()
 186 endfunction(add_link_opts)
 187
 188 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 189 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 190 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 191 function(set_output_directory target bindir libdir)
 192   # Do nothing if *_OUTPUT_INTDIR is empty.
 193   if("${bindir}" STREQUAL "")
 194     return()
 195   endif()
 196
 197   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 198   # It affects output of add_library(MODULE).
 199   if(WIN32 OR CYGWIN)
 200     # DLL platform
 201     set(moddir ${bindir})
 202   else()
 203     set(moddir ${libdir})
 204   endif()
 205   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 206     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 207       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 208       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 209       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 210       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 211       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 213       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 214     endforeach()
 215   else()
 216     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 217     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 218     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 219   endif()
 220 endfunction()
 221
 222 # llvm_add_library(name sources...
 223 #   SHARED;STATIC
 224 #     STATIC by default w/o BUILD_SHARED_LIBS.
 225 #     SHARED by default w/  BUILD_SHARED_LIBS.
 226 #   MODULE
 227 #     Target ${name} might not be created on unsupported platforms.
 228 #     Check with "if(TARGET ${name})".
 229 #   OUTPUT_NAME name
 230 #     Corresponds to OUTPUT_NAME in target properties.
 231 #   DEPENDS targets...
 232 #     Same semantics as add_dependencies().
 233 #   LINK_COMPONENTS components...
 234 #     Same as the variable LLVM_LINK_COMPONENTS.
 235 #   LINK_LIBS lib_targets...
 236 #     Same semantics as target_link_libraries().
 237 #   ADDITIONAL_HEADERS
 238 #     May specify header files for IDE generators.
 239 #   )
 240 function(llvm_add_library name)
 241   cmake_parse_arguments(ARG
 242     "MODULE;SHARED;STATIC"
 243     "OUTPUT_NAME"
 244     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 245     ${ARGN})
 246   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 247   if(ARG_ADDITIONAL_HEADERS)
 248     # Pass through ADDITIONAL_HEADERS.
 249     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 250   endif()
 251   if(ARG_OBJLIBS)
 252     set(ALL_FILES ${ARG_OBJLIBS})
 253   else()
 254     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 255   endif()
 256
 257   if(ARG_MODULE)
 258     if(ARG_SHARED OR ARG_STATIC)
 259       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 260     endif()
 261     if(NOT LLVM_ENABLE_PLUGINS)
 262       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 263       return()
 264     endif()
 265   else()
 266     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 267       set(ARG_SHARED TRUE)
 268     endif()
 269     if(NOT ARG_SHARED)
 270       set(ARG_STATIC TRUE)
 271     endif()
 272   endif()
 273
 274   # Generate objlib
 275   if(ARG_SHARED AND ARG_STATIC)
 276     # Generate an obj library for both targets.
 277     set(obj_name "obj.${name}")
 278     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 279       ${ALL_FILES}
 280       )
 281     llvm_update_compile_flags(${obj_name})
 282     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 283
 284     # Do add_dependencies(obj) later due to CMake issue 14747.
 285     list(APPEND objlibs ${obj_name})
 286
 287     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 288   endif()
 289
 290   if(ARG_SHARED AND ARG_STATIC)
 291     # static
 292     set(name_static "${name}_static")
 293     if(ARG_OUTPUT_NAME)
 294       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 295     endif()
 296     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 297     llvm_add_library(${name_static} STATIC
 298       ${output_name}
 299       OBJLIBS ${ALL_FILES} # objlib
 300       LINK_LIBS ${ARG_LINK_LIBS}
 301       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 302       )
 303     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 304     set(ARG_STATIC)
 305   endif()
 306
 307   if(ARG_MODULE)
 308     add_library(${name} MODULE ${ALL_FILES})
 309   elseif(ARG_SHARED)
 310     add_library(${name} SHARED ${ALL_FILES})
 311   else()
 312     add_library(${name} STATIC ${ALL_FILES})
 313   endif()
 314   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 315   llvm_update_compile_flags(${name})
 316   add_link_opts( ${name} )
 317   if(ARG_OUTPUT_NAME)
 318     set_target_properties(${name}
 319       PROPERTIES
 320       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 321       )
 322   endif()
 323
 324   if(ARG_MODULE)
 325     set_target_properties(${name} PROPERTIES
 326       PREFIX ""
 327       SUFFIX ${LLVM_PLUGIN_EXT}
 328       )
 329   endif()
 330
 331   if(ARG_SHARED)
 332     if(WIN32)
 333       set_target_properties(${name} PROPERTIES
 334         PREFIX ""
 335         )
 336     endif()
 337
 338     set_target_properties(${name}
 339       PROPERTIES
 340       SOVERSION ${LLVM_VERSION_MAJOR}
 341       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 342   endif()
 343
 344   if(ARG_MODULE OR ARG_SHARED)
 345     # Do not add -Dname_EXPORTS to the command-line when building files in this
 346     # target. Doing so is actively harmful for the modules build because it
 347     # creates extra module variants, and not useful because we don't use these
 348     # macros.
 349     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 350
 351     if (LLVM_EXPORTED_SYMBOL_FILE)
 352       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 353     endif()
 354   endif()
 355
 356   # Add the explicit dependency information for this library.
 357   #
 358   # It would be nice to verify that we have the dependencies for this library
 359   # name, but using get_property(... SET) doesn't suffice to determine if a
 360   # property has been set to an empty value.
 361   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 362
 363   llvm_map_components_to_libnames(llvm_libs
 364     ${ARG_LINK_COMPONENTS}
 365     ${LLVM_LINK_COMPONENTS}
 366     )
 367
 368   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 369     # Link libs w/o keywords, assuming PUBLIC.
 370     target_link_libraries(${name}
 371       ${ARG_LINK_LIBS}
 372       ${lib_deps}
 373       ${llvm_libs}
 374       )
 375   elseif(ARG_STATIC)
 376     target_link_libraries(${name} INTERFACE
 377       ${ARG_LINK_LIBS}
 378       ${lib_deps}
 379       ${llvm_libs}
 380       )
 381   else()
 382     # We can use PRIVATE since SO knows its dependent libs.
 383     target_link_libraries(${name} PRIVATE
 384       ${ARG_LINK_LIBS}
 385       ${lib_deps}
 386       ${llvm_libs}
 387       )
 388   endif()
 389
 390   if(LLVM_COMMON_DEPENDS)
 391     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 392     # Add dependencies also to objlibs.
 393     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 394     foreach(objlib ${objlibs})
 395       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 396     endforeach()
 397   endif()
 398 endfunction()
 399
 400 macro(add_llvm_library name)
 401   if( BUILD_SHARED_LIBS )
 402     llvm_add_library(${name} SHARED ${ARGN})
 403   else()
 404     llvm_add_library(${name} ${ARGN})
 405   endif()
 406   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 407
 408   if( EXCLUDE_FROM_ALL )
 409     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 410   else()
 411     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 412       install(TARGETS ${name}
 413         EXPORT LLVMExports
 414         RUNTIME DESTINATION bin
 415         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 416         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 417         COMPONENT ${name})
 418
 419       if (NOT CMAKE_CONFIGURATION_TYPES)
 420         add_custom_target(install-${name}
 421                           DEPENDS ${name}
 422                           COMMAND "${CMAKE_COMMAND}"
 423                                   -DCMAKE_INSTALL_COMPONENT=${name}
 424                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 425       endif()
 426     endif()
 427     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 428   endif()
 429   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 430 endmacro(add_llvm_library name)
 431
 432 macro(add_llvm_loadable_module name)
 433   llvm_add_library(${name} MODULE ${ARGN})
 434   if(NOT TARGET ${name})
 435     # Add empty "phony" target
 436     add_custom_target(${name})
 437   else()
 438     if( EXCLUDE_FROM_ALL )
 439       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 440     else()
 441       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 442         if(WIN32 OR CYGWIN)
 443           # DLL platform
 444           set(dlldir "bin")
 445         else()
 446           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 447         endif()
 448         install(TARGETS ${name}
 449           EXPORT LLVMExports
 450           LIBRARY DESTINATION ${dlldir}
 451           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 452       endif()
 453       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 454     endif()
 455   endif()
 456
 457   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 458 endmacro(add_llvm_loadable_module name)
 459
 460
 461 macro(add_llvm_executable name)
 462   llvm_process_sources( ALL_FILES ${ARGN} )
 463   if( EXCLUDE_FROM_ALL )
 464     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 465   else()
 466     add_executable(${name} ${ALL_FILES})
 467   endif()
 468   llvm_update_compile_flags(${name})
 469   add_link_opts( ${name} )
 470
 471   # Do not add -Dname_EXPORTS to the command-line when building files in this
 472   # target. Doing so is actively harmful for the modules build because it
 473   # creates extra module variants, and not useful because we don't use these
 474   # macros.
 475   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 476
 477   if (LLVM_EXPORTED_SYMBOL_FILE)
 478     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 479   endif(LLVM_EXPORTED_SYMBOL_FILE)
 480
 481   set(EXCLUDE_FROM_ALL OFF)
 482   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 483   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 484   if( LLVM_COMMON_DEPENDS )
 485     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 486   endif( LLVM_COMMON_DEPENDS )
 487 endmacro(add_llvm_executable name)
 488
 489
 490 set (LLVM_TOOLCHAIN_TOOLS
 491   llvm-ar
 492   llvm-objdump
 493   )
 494
 495 macro(add_llvm_tool name)
 496   if( NOT LLVM_BUILD_TOOLS )
 497     set(EXCLUDE_FROM_ALL ON)
 498   endif()
 499   add_llvm_executable(${name} ${ARGN})
 500
 501   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 502   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 503     if( LLVM_BUILD_TOOLS )
 504       install(TARGETS ${name}
 505               EXPORT LLVMExports
 506               RUNTIME DESTINATION bin
 507               COMPONENT ${name})
 508
 509       if (NOT CMAKE_CONFIGURATION_TYPES)
 510         add_custom_target(install-${name}
 511                           DEPENDS ${name}
 512                           COMMAND "${CMAKE_COMMAND}"
 513                                   -DCMAKE_INSTALL_COMPONENT=${name}
 514                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 515       endif()
 516     endif()
 517   endif()
 518   if( LLVM_BUILD_TOOLS )
 519     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 520   endif()
 521   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 522 endmacro(add_llvm_tool name)
 523
 524
 525 macro(add_llvm_example name)
 526   if( NOT LLVM_BUILD_EXAMPLES )
 527     set(EXCLUDE_FROM_ALL ON)
 528   endif()
 529   add_llvm_executable(${name} ${ARGN})
 530   if( LLVM_BUILD_EXAMPLES )
 531     install(TARGETS ${name} RUNTIME DESTINATION examples)
 532   endif()
 533   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 534 endmacro(add_llvm_example name)
 535
 536
 537 macro(add_llvm_utility name)
 538   add_llvm_executable(${name} ${ARGN})
 539   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 540 endmacro(add_llvm_utility name)
 541
 542
 543 macro(add_llvm_target target_name)
 544   include_directories(BEFORE
 545     ${CMAKE_CURRENT_BINARY_DIR}
 546     ${CMAKE_CURRENT_SOURCE_DIR})
 547   add_llvm_library(LLVM${target_name} ${ARGN})
 548   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 549 endmacro(add_llvm_target)
 550
 551 # Add external project that may want to be built as part of llvm such as Clang,
 552 # lld, and Polly. This adds two options. One for the source directory of the
 553 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 554 # enable or disable building it with everything else.
 555 # Additional parameter can be specified as the name of directory.
 556 macro(add_llvm_external_project name)
 557   set(add_llvm_external_dir "${ARGN}")
 558   if("${add_llvm_external_dir}" STREQUAL "")
 559     set(add_llvm_external_dir ${name})
 560   endif()
 561   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 562   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 563   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 564   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 565       CACHE PATH "Path to ${name} source directory")
 566   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 567       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 568     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 569            "Whether to build ${name} as part of LLVM" ON)
 570     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 571       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 572     endif()
 573   endif()
 574 endmacro(add_llvm_external_project)
 575
 576 macro(add_llvm_tool_subdirectory name)
 577   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 578   add_subdirectory(${name})
 579 endmacro(add_llvm_tool_subdirectory)
 580
 581 macro(ignore_llvm_tool_subdirectory name)
 582   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 583 endmacro(ignore_llvm_tool_subdirectory)
 584
 585 function(add_llvm_implicit_external_projects)
 586   set(list_of_implicit_subdirs "")
 587   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 588   foreach(dir ${sub-dirs})
 589     if(IS_DIRECTORY "${dir}")
 590       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 591       if( tool_subdir_ignore EQUAL -1
 592           AND EXISTS "${dir}/CMakeLists.txt")
 593         get_filename_component(fn "${dir}" NAME)
 594         list(APPEND list_of_implicit_subdirs "${fn}")
 595       endif()
 596     endif()
 597   endforeach()
 598
 599   foreach(external_proj ${list_of_implicit_subdirs})
 600     add_llvm_external_project("${external_proj}")
 601   endforeach()
 602 endfunction(add_llvm_implicit_external_projects)
 603
 604 # Generic support for adding a unittest.
 605 function(add_unittest test_suite test_name)
 606   if( NOT LLVM_BUILD_TESTS )
 607     set(EXCLUDE_FROM_ALL ON)
 608   endif()
 609
 610   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 611   if (NOT LLVM_ENABLE_THREADS)
 612     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 613   endif ()
 614
 615   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 616     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 617   endif ()
 618
 619   set(LLVM_REQUIRES_RTTI OFF)
 620
 621   add_llvm_executable(${test_name} ${ARGN})
 622   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 623   set_output_directory(${test_name} ${outdir} ${outdir})
 624   target_link_libraries(${test_name}
 625     gtest
 626     gtest_main
 627     LLVMSupport # gtest needs it for raw_ostream.
 628     )
 629
 630   add_dependencies(${test_suite} ${test_name})
 631   get_target_property(test_suite_folder ${test_suite} FOLDER)
 632   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 633     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 634   endif ()
 635 endfunction()
 636
 637 function(llvm_add_go_executable binary pkgpath)
 638   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 639
 640   if(LLVM_BINDINGS MATCHES "go")
 641     # FIXME: This should depend only on the libraries Go needs.
 642     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 643     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 644     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 645     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 646     set(cppflags "")
 647     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 648     foreach(d ${include_dirs})
 649       set(cppflags "${cppflags} -I${d}")
 650     endforeach(d)
 651     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 652     add_custom_command(OUTPUT ${binpath}
 653       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 654               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 655       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 656               ${llvmlibs} ${ARG_DEPENDS}
 657       COMMENT "Building Go executable ${binary}"
 658       VERBATIM)
 659     if (ARG_ALL)
 660       add_custom_target(${binary} ALL DEPENDS ${binpath})
 661     else()
 662       add_custom_target(${binary} DEPENDS ${binpath})
 663     endif()
 664   endif()
 665 endfunction()
 666
 667 # This function provides an automatic way to 'configure'-like generate a file
 668 # based on a set of common and custom variables, specifically targeting the
 669 # variables needed for the 'lit.site.cfg' files. This function bundles the
 670 # common variables that any Lit instance is likely to need, and custom
 671 # variables can be passed in.
 672 function(configure_lit_site_cfg input output)
 673   foreach(c ${LLVM_TARGETS_TO_BUILD})
 674     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 675   endforeach(c)
 676   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 677
 678   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 679
 680   # Configuration-time: See Unit/lit.site.cfg.in
 681   if (CMAKE_CFG_INTDIR STREQUAL ".")
 682     set(LLVM_BUILD_MODE ".")
 683   else ()
 684     set(LLVM_BUILD_MODE "%(build_mode)s")
 685   endif ()
 686
 687   # They below might not be the build tree but provided binary tree.
 688   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 689   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 690   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 691   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 692
 693   # SHLIBDIR points the build tree.
 694   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 695
 696   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 697   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 698   # plugins. We may rename it.
 699   if(LLVM_ENABLE_PLUGINS)
 700     set(ENABLE_SHARED "1")
 701   else()
 702     set(ENABLE_SHARED "0")
 703   endif()
 704
 705   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 706     set(ENABLE_ASSERTIONS "1")
 707   else()
 708     set(ENABLE_ASSERTIONS "0")
 709   endif()
 710
 711   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 712   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 713
 714   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 715   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 716   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 717
 718   configure_file(${input} ${output} @ONLY)
 719 endfunction()
 720
 721 # A raw function to create a lit target. This is used to implement the testuite
 722 # management functions.
 723 function(add_lit_target target comment)
 724   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 725   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 726   separate_arguments(LIT_ARGS)
 727   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 728     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 729   endif ()
 730   if (LLVM_MAIN_SRC_DIR)
 731     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 732   else()
 733     find_program(LIT_COMMAND llvm-lit)
 734   endif ()
 735   list(APPEND LIT_COMMAND ${LIT_ARGS})
 736   foreach(param ${ARG_PARAMS})
 737     list(APPEND LIT_COMMAND --param ${param})
 738   endforeach()
 739   if( ARG_DEPENDS )
 740     add_custom_target(${target}
 741       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 742       COMMENT "${comment}"
 743       ${cmake_3_2_USES_TERMINAL}
 744       )
 745     add_dependencies(${target} ${ARG_DEPENDS})
 746   else()
 747     add_custom_target(${target}
 748       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 749     message(STATUS "${target} does nothing.")
 750   endif()
 751
 752   # Tests should be excluded from "Build Solution".
 753   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 754 endfunction()
 755
 756 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 757 function(add_lit_testsuite target comment)
 758   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 759
 760   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 761   if(NOT EXCLUDE_FROM_ALL)
 762     # Register the testsuites, params and depends for the global check rule.
 763     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 764     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 765     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 766     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 767   endif()
 768
 769   # Produce a specific suffixed check rule.
 770   add_lit_target(${target} ${comment}
 771     ${ARG_DEFAULT_ARGS}
 772     PARAMS ${ARG_PARAMS}
 773     DEPENDS ${ARG_DEPENDS}
 774     ARGS ${ARG_ARGS}
 775     )
 776 endfunction()