cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 function(llvm_update_compile_flags name)
   5   get_property(sources TARGET ${name} PROPERTY SOURCES)
   6   if("${sources}" MATCHES "\\.c(;|$)")
   7     set(update_src_props ON)
   8   endif()
   9
  10   # LLVM_REQUIRES_EH is an internal flag that individual
  11   # targets can use to force EH
  12   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  13     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  14       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  15       set(LLVM_REQUIRES_RTTI ON)
  16     endif()
  17   else()
  18     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  19       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  20     elseif(MSVC)
  21       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  22       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  23     endif()
  24     if (CLANG_CL)
  25       # FIXME: Remove this once clang-cl supports SEH
  26       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  33     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  34     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  35       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  36     elseif (MSVC)
  37       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  38     endif ()
  39   endif()
  40
  41   # Assume that;
  42   #   - LLVM_COMPILE_FLAGS is list.
  43   #   - PROPERTY COMPILE_FLAGS is string.
  44   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  45
  46   if(update_src_props)
  47     foreach(fn ${sources})
  48       get_filename_component(suf ${fn} EXT)
  49       if("${suf}" STREQUAL ".cpp")
  50         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  51           COMPILE_FLAGS "${target_compile_flags}")
  52       endif()
  53     endforeach()
  54   else()
  55     # Update target props, since all sources are C++.
  56     set_property(TARGET ${name} APPEND_STRING PROPERTY
  57       COMPILE_FLAGS "${target_compile_flags}")
  58   endif()
  59
  60   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  61 endfunction()
  62
  63 function(add_llvm_symbol_exports target_name export_file)
  64   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  65     set(native_export_file "${target_name}.exports")
  66     add_custom_command(OUTPUT ${native_export_file}
  67       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  68       DEPENDS ${export_file}
  69       VERBATIM
  70       COMMENT "Creating export file for ${target_name}")
  71     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  72                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  73   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  74     # Gold and BFD ld require a version script rather than a plain list.
  75     set(native_export_file "${target_name}.exports")
  76     # FIXME: Don't write the "local:" line on OpenBSD.
  77     add_custom_command(OUTPUT ${native_export_file}
  78       COMMAND echo "{" > ${native_export_file}
  79       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  80       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  81       COMMAND echo "  local: *;" >> ${native_export_file}
  82       COMMAND echo "};" >> ${native_export_file}
  83       DEPENDS ${export_file}
  84       VERBATIM
  85       COMMENT "Creating export file for ${target_name}")
  86     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88   else()
  89     set(native_export_file "${target_name}.def")
  90
  91     set(CAT "cat")
  92     set(export_file_nativeslashes ${export_file})
  93     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  94       set(CAT "type")
  95       # Convert ${export_file} to native format (backslashes) for "type"
  96       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  97       # path but a build-system specific format (see CMake bug
  98       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
  99       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 100     endif()
 101
 102     add_custom_command(OUTPUT ${native_export_file}
 103       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 104       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 105       DEPENDS ${export_file}
 106       VERBATIM
 107       COMMENT "Creating export file for ${target_name}")
 108     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 109     if(MSVC)
 110       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 111     endif()
 112     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 113                  LINK_FLAGS " ${export_file_linker_flag}")
 114   endif()
 115
 116   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 117   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 118
 119   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 120   foreach(src ${srcs})
 121     get_filename_component(extension ${src} EXT)
 122     if(extension STREQUAL ".cpp")
 123       set(first_source_file ${src})
 124       break()
 125     endif()
 126   endforeach()
 127
 128   # Force re-linking when the exports file changes. Actually, it
 129   # forces recompilation of the source file. The LINK_DEPENDS target
 130   # property only works for makefile-based generators.
 131   # FIXME: This is not safe because this will create the same target
 132   # ${native_export_file} in several different file:
 133   # - One where we emitted ${target_name}_exports
 134   # - One where we emitted the build command for the following object.
 135   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 136   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 137
 138   set_property(DIRECTORY APPEND
 139     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 140
 141   add_dependencies(${target_name} ${target_name}_exports)
 142
 143   # Add dependency to *_exports later -- CMake issue 14747
 144   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 145   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 146 endfunction(add_llvm_symbol_exports)
 147
 148 if(NOT WIN32 AND NOT APPLE)
 149   execute_process(
 150     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 151     OUTPUT_VARIABLE stdout
 152     ERROR_QUIET
 153     )
 154   if("${stdout}" MATCHES "GNU gold")
 155     set(LLVM_LINKER_IS_GOLD ON)
 156   endif()
 157 endif()
 158
 159 function(add_link_opts target_name)
 160   # Don't use linker optimizations in debug builds since it slows down the
 161   # linker in a context where the optimizations are not important.
 162   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 163
 164     # Pass -O3 to the linker. This enabled different optimizations on different
 165     # linkers.
 166     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 167       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 168                    LINK_FLAGS " -Wl,-O3")
 169     endif()
 170
 171     if(LLVM_LINKER_IS_GOLD)
 172       # With gold gc-sections is always safe.
 173       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 174                    LINK_FLAGS " -Wl,--gc-sections")
 175       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 176       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 177     endif()
 178
 179     if(NOT LLVM_NO_DEAD_STRIP)
 180       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 181         # ld64's implementation of -dead_strip breaks tools that use plugins.
 182         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 183                      LINK_FLAGS " -Wl,-dead_strip")
 184       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 185         # Object files are compiled with -ffunction-data-sections.
 186         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 187         # tools that use plugins. Always pass --gc-sections once we require
 188         # a newer linker.
 189         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 190                      LINK_FLAGS " -Wl,--gc-sections")
 191       endif()
 192     endif()
 193   endif()
 194 endfunction(add_link_opts)
 195
 196 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 197 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 198 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 199 function(set_output_directory target bindir libdir)
 200   # Do nothing if *_OUTPUT_INTDIR is empty.
 201   if("${bindir}" STREQUAL "")
 202     return()
 203   endif()
 204
 205   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 206   # It affects output of add_library(MODULE).
 207   if(WIN32 OR CYGWIN)
 208     # DLL platform
 209     set(moddir ${bindir})
 210   else()
 211     set(moddir ${libdir})
 212   endif()
 213   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 214     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 215       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 216       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 217       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 218       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 219       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 220       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 221       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 222     endforeach()
 223   else()
 224     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 225     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 226     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 227   endif()
 228 endfunction()
 229
 230 # If on Windows and building with MSVC, add the resource script containing the
 231 # VERSIONINFO data to the project.  This embeds version resource information
 232 # into the output .exe or .dll.
 233 # TODO: Enable for MinGW Windows builds too.
 234 #
 235 function(add_windows_version_resource_file OUT_VAR)
 236   set(sources ${ARGN})
 237   if (MSVC)
 238     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 239     if(EXISTS ${resource_file})
 240       set(sources ${sources} ${resource_file})
 241       source_group("Resource Files" ${resource_file})
 242       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 243     endif()
 244   endif(MSVC)
 245
 246   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 247 endfunction(add_windows_version_resource_file)
 248
 249 # set_windows_version_resource_properties(name resource_file...
 250 #   VERSION_MAJOR int
 251 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 252 #   VERSION_MINOR int
 253 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 254 #   VERSION_PATCHLEVEL int
 255 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 256 #   VERSION_STRING
 257 #     Optional version string (defaults to PACKAGE_VERSION)
 258 #   PRODUCT_NAME
 259 #     Optional product name string (defaults to "LLVM")
 260 #   )
 261 function(set_windows_version_resource_properties name resource_file)
 262   cmake_parse_arguments(ARG
 263     ""
 264     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 265     ""
 266     ${ARGN})
 267
 268   if (NOT DEFINED ARG_VERSION_MAJOR)
 269     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 270   endif()
 271
 272   if (NOT DEFINED ARG_VERSION_MINOR)
 273     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 274   endif()
 275
 276   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 277     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 278   endif()
 279
 280   if (NOT DEFINED ARG_VERSION_STRING)
 281     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 282   endif()
 283
 284   if (NOT DEFINED ARG_PRODUCT_NAME)
 285     set(ARG_PRODUCT_NAME "LLVM")
 286   endif()
 287
 288   set_property(SOURCE ${resource_file}
 289                PROPERTY COMPILE_FLAGS /nologo)
 290   set_property(SOURCE ${resource_file}
 291                PROPERTY COMPILE_DEFINITIONS
 292                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 293                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 294                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 295                "RC_VERSION_FIELD_4=0"
 296                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 297                "RC_INTERNAL_NAME=\"${name}\""
 298                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 299                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 300 endfunction(set_windows_version_resource_properties)
 301
 302 # llvm_add_library(name sources...
 303 #   SHARED;STATIC
 304 #     STATIC by default w/o BUILD_SHARED_LIBS.
 305 #     SHARED by default w/  BUILD_SHARED_LIBS.
 306 #   MODULE
 307 #     Target ${name} might not be created on unsupported platforms.
 308 #     Check with "if(TARGET ${name})".
 309 #   OUTPUT_NAME name
 310 #     Corresponds to OUTPUT_NAME in target properties.
 311 #   DEPENDS targets...
 312 #     Same semantics as add_dependencies().
 313 #   LINK_COMPONENTS components...
 314 #     Same as the variable LLVM_LINK_COMPONENTS.
 315 #   LINK_LIBS lib_targets...
 316 #     Same semantics as target_link_libraries().
 317 #   ADDITIONAL_HEADERS
 318 #     May specify header files for IDE generators.
 319 #   )
 320 function(llvm_add_library name)
 321   cmake_parse_arguments(ARG
 322     "MODULE;SHARED;STATIC"
 323     "OUTPUT_NAME"
 324     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 325     ${ARGN})
 326   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 327   if(ARG_ADDITIONAL_HEADERS)
 328     # Pass through ADDITIONAL_HEADERS.
 329     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 330   endif()
 331   if(ARG_OBJLIBS)
 332     set(ALL_FILES ${ARG_OBJLIBS})
 333   else()
 334     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 335   endif()
 336
 337   if(ARG_MODULE)
 338     if(ARG_SHARED OR ARG_STATIC)
 339       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 340     endif()
 341     if(NOT LLVM_ENABLE_PLUGINS)
 342       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 343       return()
 344     endif()
 345   else()
 346     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 347       set(ARG_SHARED TRUE)
 348     endif()
 349     if(NOT ARG_SHARED)
 350       set(ARG_STATIC TRUE)
 351     endif()
 352   endif()
 353
 354   # Generate objlib
 355   if(ARG_SHARED AND ARG_STATIC)
 356     # Generate an obj library for both targets.
 357     set(obj_name "obj.${name}")
 358     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 359       ${ALL_FILES}
 360       )
 361     llvm_update_compile_flags(${obj_name})
 362     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 363
 364     # Do add_dependencies(obj) later due to CMake issue 14747.
 365     list(APPEND objlibs ${obj_name})
 366
 367     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 368   endif()
 369
 370   if(ARG_SHARED AND ARG_STATIC)
 371     # static
 372     set(name_static "${name}_static")
 373     if(ARG_OUTPUT_NAME)
 374       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 375     endif()
 376     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 377     llvm_add_library(${name_static} STATIC
 378       ${output_name}
 379       OBJLIBS ${ALL_FILES} # objlib
 380       LINK_LIBS ${ARG_LINK_LIBS}
 381       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 382       )
 383     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 384     set(ARG_STATIC)
 385   endif()
 386
 387   if(ARG_MODULE)
 388     add_library(${name} MODULE ${ALL_FILES})
 389   elseif(ARG_SHARED)
 390     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 391     add_library(${name} SHARED ${ALL_FILES})
 392   else()
 393     add_library(${name} STATIC ${ALL_FILES})
 394   endif()
 395
 396   if(DEFINED windows_resource_file)
 397     set_windows_version_resource_properties(${name} ${windows_resource_file})
 398     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 399   endif()
 400
 401   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 402   llvm_update_compile_flags(${name})
 403   add_link_opts( ${name} )
 404   if(ARG_OUTPUT_NAME)
 405     set_target_properties(${name}
 406       PROPERTIES
 407       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 408       )
 409   endif()
 410
 411   if(ARG_MODULE)
 412     set_target_properties(${name} PROPERTIES
 413       PREFIX ""
 414       SUFFIX ${LLVM_PLUGIN_EXT}
 415       )
 416   endif()
 417
 418   if(ARG_SHARED)
 419     if(WIN32)
 420       set_target_properties(${name} PROPERTIES
 421         PREFIX ""
 422         )
 423     endif()
 424
 425     set_target_properties(${name}
 426       PROPERTIES
 427       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 428       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 429   endif()
 430
 431   if(ARG_MODULE OR ARG_SHARED)
 432     # Do not add -Dname_EXPORTS to the command-line when building files in this
 433     # target. Doing so is actively harmful for the modules build because it
 434     # creates extra module variants, and not useful because we don't use these
 435     # macros.
 436     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 437
 438     if (LLVM_EXPORTED_SYMBOL_FILE)
 439       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 440     endif()
 441   endif()
 442
 443   # Add the explicit dependency information for this library.
 444   #
 445   # It would be nice to verify that we have the dependencies for this library
 446   # name, but using get_property(... SET) doesn't suffice to determine if a
 447   # property has been set to an empty value.
 448   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 449
 450   llvm_map_components_to_libnames(llvm_libs
 451     ${ARG_LINK_COMPONENTS}
 452     ${LLVM_LINK_COMPONENTS}
 453     )
 454
 455   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 456     # Link libs w/o keywords, assuming PUBLIC.
 457     target_link_libraries(${name}
 458       ${ARG_LINK_LIBS}
 459       ${lib_deps}
 460       ${llvm_libs}
 461       )
 462   elseif(ARG_STATIC)
 463     target_link_libraries(${name} INTERFACE
 464       ${ARG_LINK_LIBS}
 465       ${lib_deps}
 466       ${llvm_libs}
 467       )
 468   else()
 469     # We can use PRIVATE since SO knows its dependent libs.
 470     target_link_libraries(${name} PRIVATE
 471       ${ARG_LINK_LIBS}
 472       ${lib_deps}
 473       ${llvm_libs}
 474       )
 475   endif()
 476
 477   if(LLVM_COMMON_DEPENDS)
 478     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 479     # Add dependencies also to objlibs.
 480     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 481     foreach(objlib ${objlibs})
 482       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 483     endforeach()
 484   endif()
 485 endfunction()
 486
 487 macro(add_llvm_library name)
 488   cmake_parse_arguments(ARG
 489     "SHARED"
 490     ""
 491     ""
 492     ${ARGN})
 493   if( BUILD_SHARED_LIBS )
 494     llvm_add_library(${name} SHARED ${ARGN})
 495   else()
 496     llvm_add_library(${name} ${ARGN})
 497   endif()
 498   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 499
 500   if( EXCLUDE_FROM_ALL )
 501     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 502   else()
 503     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 504       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 505         if(WIN32 OR CYGWIN)
 506           set(install_type RUNTIME)
 507         else()
 508           set(install_type LIBRARY)
 509         endif()
 510       else()
 511         set(install_type ARCHIVE)
 512       endif()
 513
 514       install(TARGETS ${name}
 515             EXPORT LLVMExports
 516             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 517             COMPONENT ${name})
 518
 519       if (NOT CMAKE_CONFIGURATION_TYPES)
 520         add_custom_target(install-${name}
 521                           DEPENDS ${name}
 522                           COMMAND "${CMAKE_COMMAND}"
 523                                   -DCMAKE_INSTALL_COMPONENT=${name}
 524                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 525       endif()
 526     endif()
 527     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 528   endif()
 529   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 530 endmacro(add_llvm_library name)
 531
 532 macro(add_llvm_loadable_module name)
 533   llvm_add_library(${name} MODULE ${ARGN})
 534   if(NOT TARGET ${name})
 535     # Add empty "phony" target
 536     add_custom_target(${name})
 537   else()
 538     if( EXCLUDE_FROM_ALL )
 539       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 540     else()
 541       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 542         if(WIN32 OR CYGWIN)
 543           # DLL platform
 544           set(dlldir "bin")
 545         else()
 546           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 547         endif()
 548         install(TARGETS ${name}
 549           EXPORT LLVMExports
 550           LIBRARY DESTINATION ${dlldir}
 551           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 552       endif()
 553       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 554     endif()
 555   endif()
 556
 557   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 558 endmacro(add_llvm_loadable_module name)
 559
 560
 561 macro(add_llvm_executable name)
 562   llvm_process_sources( ALL_FILES ${ARGN} )
 563   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 564
 565   if( EXCLUDE_FROM_ALL )
 566     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 567   else()
 568     add_executable(${name} ${ALL_FILES})
 569   endif()
 570
 571   if(DEFINED windows_resource_file)
 572     set_windows_version_resource_properties(${name} ${windows_resource_file})
 573   endif()
 574
 575   llvm_update_compile_flags(${name})
 576   add_link_opts( ${name} )
 577
 578   # Do not add -Dname_EXPORTS to the command-line when building files in this
 579   # target. Doing so is actively harmful for the modules build because it
 580   # creates extra module variants, and not useful because we don't use these
 581   # macros.
 582   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 583
 584   if (LLVM_EXPORTED_SYMBOL_FILE)
 585     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 586   endif(LLVM_EXPORTED_SYMBOL_FILE)
 587
 588   set(EXCLUDE_FROM_ALL OFF)
 589   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 590   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 591   if( LLVM_COMMON_DEPENDS )
 592     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 593   endif( LLVM_COMMON_DEPENDS )
 594 endmacro(add_llvm_executable name)
 595
 596 function(export_executable_symbols target)
 597   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 598     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 599   endif()
 600 endfunction()
 601
 602
 603 set (LLVM_TOOLCHAIN_TOOLS
 604   llvm-ar
 605   llvm-objdump
 606   )
 607
 608 macro(add_llvm_tool name)
 609   if( NOT LLVM_BUILD_TOOLS )
 610     set(EXCLUDE_FROM_ALL ON)
 611   endif()
 612   add_llvm_executable(${name} ${ARGN})
 613
 614   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 615   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 616     if( LLVM_BUILD_TOOLS )
 617       install(TARGETS ${name}
 618               EXPORT LLVMExports
 619               RUNTIME DESTINATION bin
 620               COMPONENT ${name})
 621
 622       if (NOT CMAKE_CONFIGURATION_TYPES)
 623         add_custom_target(install-${name}
 624                           DEPENDS ${name}
 625                           COMMAND "${CMAKE_COMMAND}"
 626                                   -DCMAKE_INSTALL_COMPONENT=${name}
 627                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 628       endif()
 629     endif()
 630   endif()
 631   if( LLVM_BUILD_TOOLS )
 632     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 633   endif()
 634   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 635 endmacro(add_llvm_tool name)
 636
 637
 638 macro(add_llvm_example name)
 639   if( NOT LLVM_BUILD_EXAMPLES )
 640     set(EXCLUDE_FROM_ALL ON)
 641   endif()
 642   add_llvm_executable(${name} ${ARGN})
 643   if( LLVM_BUILD_EXAMPLES )
 644     install(TARGETS ${name} RUNTIME DESTINATION examples)
 645   endif()
 646   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 647 endmacro(add_llvm_example name)
 648
 649
 650 macro(add_llvm_utility name)
 651   add_llvm_executable(${name} ${ARGN})
 652   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 653   if( LLVM_INSTALL_UTILS )
 654     install (TARGETS ${name}
 655       RUNTIME DESTINATION bin
 656       COMPONENT ${name})
 657     if (NOT CMAKE_CONFIGURATION_TYPES)
 658       add_custom_target(install-${name}
 659                         DEPENDS ${name}
 660                         COMMAND "${CMAKE_COMMAND}"
 661                                 -DCMAKE_INSTALL_COMPONENT=${name}
 662                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 663     endif()
 664   endif()
 665 endmacro(add_llvm_utility name)
 666
 667
 668 macro(add_llvm_target target_name)
 669   include_directories(BEFORE
 670     ${CMAKE_CURRENT_BINARY_DIR}
 671     ${CMAKE_CURRENT_SOURCE_DIR})
 672   add_llvm_library(LLVM${target_name} ${ARGN})
 673   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 674 endmacro(add_llvm_target)
 675
 676 # Add external project that may want to be built as part of llvm such as Clang,
 677 # lld, and Polly. This adds two options. One for the source directory of the
 678 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 679 # enable or disable building it with everything else.
 680 # Additional parameter can be specified as the name of directory.
 681 macro(add_llvm_external_project name)
 682   set(add_llvm_external_dir "${ARGN}")
 683   if("${add_llvm_external_dir}" STREQUAL "")
 684     set(add_llvm_external_dir ${name})
 685   endif()
 686   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 687   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 688   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 689   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 690       CACHE PATH "Path to ${name} source directory")
 691   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 692       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 693     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 694            "Whether to build ${name} as part of LLVM" ON)
 695     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 696       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 697     endif()
 698   endif()
 699 endmacro(add_llvm_external_project)
 700
 701 macro(add_llvm_tool_subdirectory name)
 702   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 703   add_subdirectory(${name})
 704 endmacro(add_llvm_tool_subdirectory)
 705
 706 macro(ignore_llvm_tool_subdirectory name)
 707   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 708 endmacro(ignore_llvm_tool_subdirectory)
 709
 710 function(add_llvm_implicit_external_projects)
 711   set(list_of_implicit_subdirs "")
 712   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 713   foreach(dir ${sub-dirs})
 714     if(IS_DIRECTORY "${dir}")
 715       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 716       if( tool_subdir_ignore EQUAL -1
 717           AND EXISTS "${dir}/CMakeLists.txt")
 718         get_filename_component(fn "${dir}" NAME)
 719         list(APPEND list_of_implicit_subdirs "${fn}")
 720       endif()
 721     endif()
 722   endforeach()
 723
 724   foreach(external_proj ${list_of_implicit_subdirs})
 725     add_llvm_external_project("${external_proj}")
 726   endforeach()
 727 endfunction(add_llvm_implicit_external_projects)
 728
 729 # Generic support for adding a unittest.
 730 function(add_unittest test_suite test_name)
 731   if( NOT LLVM_BUILD_TESTS )
 732     set(EXCLUDE_FROM_ALL ON)
 733   endif()
 734
 735   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 736   if (NOT LLVM_ENABLE_THREADS)
 737     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 738   endif ()
 739
 740   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 741     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 742   endif ()
 743
 744   set(LLVM_REQUIRES_RTTI OFF)
 745
 746   add_llvm_executable(${test_name} ${ARGN})
 747   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 748   set_output_directory(${test_name} ${outdir} ${outdir})
 749   target_link_libraries(${test_name}
 750     gtest
 751     gtest_main
 752     LLVMSupport # gtest needs it for raw_ostream.
 753     )
 754
 755   add_dependencies(${test_suite} ${test_name})
 756   get_target_property(test_suite_folder ${test_suite} FOLDER)
 757   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 758     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 759   endif ()
 760 endfunction()
 761
 762 function(llvm_add_go_executable binary pkgpath)
 763   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 764
 765   if(LLVM_BINDINGS MATCHES "go")
 766     # FIXME: This should depend only on the libraries Go needs.
 767     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 768     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 769     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 770     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 771     set(cppflags "")
 772     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 773     foreach(d ${include_dirs})
 774       set(cppflags "${cppflags} -I${d}")
 775     endforeach(d)
 776     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 777     add_custom_command(OUTPUT ${binpath}
 778       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 779               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 780       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 781               ${llvmlibs} ${ARG_DEPENDS}
 782       COMMENT "Building Go executable ${binary}"
 783       VERBATIM)
 784     if (ARG_ALL)
 785       add_custom_target(${binary} ALL DEPENDS ${binpath})
 786     else()
 787       add_custom_target(${binary} DEPENDS ${binpath})
 788     endif()
 789   endif()
 790 endfunction()
 791
 792 # This function provides an automatic way to 'configure'-like generate a file
 793 # based on a set of common and custom variables, specifically targeting the
 794 # variables needed for the 'lit.site.cfg' files. This function bundles the
 795 # common variables that any Lit instance is likely to need, and custom
 796 # variables can be passed in.
 797 function(configure_lit_site_cfg input output)
 798   foreach(c ${LLVM_TARGETS_TO_BUILD})
 799     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 800   endforeach(c)
 801   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 802
 803   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 804
 805   # Configuration-time: See Unit/lit.site.cfg.in
 806   if (CMAKE_CFG_INTDIR STREQUAL ".")
 807     set(LLVM_BUILD_MODE ".")
 808   else ()
 809     set(LLVM_BUILD_MODE "%(build_mode)s")
 810   endif ()
 811
 812   # They below might not be the build tree but provided binary tree.
 813   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 814   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 815   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 816   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 817
 818   # SHLIBDIR points the build tree.
 819   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 820
 821   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 822   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 823   # plugins. We may rename it.
 824   if(LLVM_ENABLE_PLUGINS)
 825     set(ENABLE_SHARED "1")
 826   else()
 827     set(ENABLE_SHARED "0")
 828   endif()
 829
 830   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 831     set(ENABLE_ASSERTIONS "1")
 832   else()
 833     set(ENABLE_ASSERTIONS "0")
 834   endif()
 835
 836   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 837   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 838
 839   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 840   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 841   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 842
 843   configure_file(${input} ${output} @ONLY)
 844 endfunction()
 845
 846 # A raw function to create a lit target. This is used to implement the testuite
 847 # management functions.
 848 function(add_lit_target target comment)
 849   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 850   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 851   separate_arguments(LIT_ARGS)
 852   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 853     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 854   endif ()
 855   if (LLVM_MAIN_SRC_DIR)
 856     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 857   else()
 858     find_program(LIT_COMMAND llvm-lit)
 859   endif ()
 860   list(APPEND LIT_COMMAND ${LIT_ARGS})
 861   foreach(param ${ARG_PARAMS})
 862     list(APPEND LIT_COMMAND --param ${param})
 863   endforeach()
 864   if (ARG_UNPARSED_ARGUMENTS)
 865     add_custom_target(${target}
 866       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 867       COMMENT "${comment}"
 868       ${cmake_3_2_USES_TERMINAL}
 869       )
 870   else()
 871     add_custom_target(${target}
 872       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 873     message(STATUS "${target} does nothing.")
 874   endif()
 875   if (ARG_DEPENDS)
 876     add_dependencies(${target} ${ARG_DEPENDS})
 877   endif()
 878
 879   # Tests should be excluded from "Build Solution".
 880   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 881 endfunction()
 882
 883 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 884 function(add_lit_testsuite target comment)
 885   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 886
 887   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 888   if(NOT EXCLUDE_FROM_ALL)
 889     # Register the testsuites, params and depends for the global check rule.
 890     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 891     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 892     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 893     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 894   endif()
 895
 896   # Produce a specific suffixed check rule.
 897   add_lit_target(${target} ${comment}
 898     ${ARG_UNPARSED_ARGUMENTS}
 899     PARAMS ${ARG_PARAMS}
 900     DEPENDS ${ARG_DEPENDS}
 901     ARGS ${ARG_ARGS}
 902     )
 903 endfunction()
 904
 905 function(add_lit_testsuites project directory)
 906   if (NOT CMAKE_CONFIGURATION_TYPES)
 907     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 908     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 909     set(lit_suites)
 910     foreach(f ${litCfg})
 911       get_filename_component(dir ${f} DIRECTORY)
 912       set(lit_suites ${lit_suites} ${dir})
 913     endforeach()
 914     list(REMOVE_DUPLICATES lit_suites)
 915     foreach(dir ${lit_suites})
 916       string(REPLACE ${directory} "" name_slash ${dir})
 917       if (name_slash)
 918         string(REPLACE "/" "-" name_slash ${name_slash})
 919         string(REPLACE "\\" "-" name_dashes ${name_slash})
 920         string(TOLOWER "${project}${name_dashes}" name_var)
 921         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 922           ${dir}
 923           PARAMS ${ARG_PARAMS}
 924           DEPENDS ${ARG_DEPENDS}
 925           ARGS ${ARG_ARGS}
 926         )
 927       endif()
 928     endforeach()
 929   endif()
 930 endfunction()