cmake/modules/HandleLLVMOptions.cmake

   1 include(AddLLVMDefinitions)
   2
   3 # Run-time build mode; It is used for unittests.
   4 if(MSVC_IDE)
   5   # Expect "$(Configuration)", "$(OutDir)", etc.
   6   # It is expanded by msbuild or similar.
   7   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
   8 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
   9   # Expect "Release" "Debug", etc.
  10   # Or unittests could not run.
  11   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  12 else()
  13   # It might be "."
  14   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  15 endif()
  16
  17 set(LIT_ARGS_DEFAULT "-sv")
  18 if (MSVC OR XCODE)
  19   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  20 endif()
  21 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}"
  22     CACHE STRING "Default options for lit")
  23
  24 if( LLVM_ENABLE_ASSERTIONS )
  25   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  26   if( NOT MSVC )
  27     add_definitions( -D_DEBUG )
  28   endif()
  29   # On Release builds cmake automatically defines NDEBUG, so we
  30   # explicitly undefine it:
  31   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  32     add_definitions( -UNDEBUG )
  33   endif()
  34 else()
  35   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  36     add_definitions( -DNDEBUG )
  37   endif()
  38 endif()
  39
  40 if(WIN32)
  41   if(CYGWIN)
  42     set(LLVM_ON_WIN32 0)
  43     set(LLVM_ON_UNIX 1)
  44   else(CYGWIN)
  45     set(LLVM_ON_WIN32 1)
  46     set(LLVM_ON_UNIX 0)
  47   endif(CYGWIN)
  48   set(LTDL_SHLIB_EXT ".dll")
  49   set(EXEEXT ".exe")
  50   # Maximum path length is 160 for non-unicode paths
  51   set(MAXPATHLEN 160)
  52 else(WIN32)
  53   if(UNIX)
  54     set(LLVM_ON_WIN32 0)
  55     set(LLVM_ON_UNIX 1)
  56     if(APPLE)
  57       set(LTDL_SHLIB_EXT ".dylib")
  58     else(APPLE)
  59       set(LTDL_SHLIB_EXT ".so")
  60     endif(APPLE)
  61     set(EXEEXT "")
  62     # FIXME: Maximum path length is currently set to 'safe' fixed value
  63     set(MAXPATHLEN 2024)
  64   else(UNIX)
  65     MESSAGE(SEND_ERROR "Unable to determine platform")
  66   endif(UNIX)
  67 endif(WIN32)
  68
  69 if( LLVM_ENABLE_PIC )
  70   if( XCODE )
  71     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  72     # know how to disable this, so just force ENABLE_PIC off for now.
  73     message(WARNING "-fPIC not supported with Xcode.")
  74   elseif( WIN32 )
  75     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  76   else()
  77     include(CheckCXXCompilerFlag)
  78     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  79     if( SUPPORTS_FPIC_FLAG )
  80       message(STATUS "Building with -fPIC")
  81       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  82       set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  83     else( SUPPORTS_FPIC_FLAG )
  84       message(WARNING "-fPIC not supported.")
  85     endif()
  86   endif()
  87 endif()
  88
  89 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  90   # TODO: support other platforms and toolchains.
  91   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
  92   if( LLVM_BUILD_32_BITS )
  93     message(STATUS "Building 32 bits executables and libraries.")
  94     add_llvm_definitions( -m32 )
  95     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
  96     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
  97   endif( LLVM_BUILD_32_BITS )
  98 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  99
 100 if( MSVC )
 101   include(ChooseMSVCCRT)
 102
 103   # Add definitions that make MSVC much less annoying.
 104   add_llvm_definitions(
 105     # For some reason MS wants to deprecate a bunch of standard functions...
 106     -D_CRT_SECURE_NO_DEPRECATE
 107     -D_CRT_SECURE_NO_WARNINGS
 108     -D_CRT_NONSTDC_NO_DEPRECATE
 109     -D_CRT_NONSTDC_NO_WARNINGS
 110     -D_SCL_SECURE_NO_DEPRECATE
 111     -D_SCL_SECURE_NO_WARNINGS
 112
 113     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 114     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 115     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 116     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 117     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 118     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 119     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 120     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 121     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 122     -wd4355 # Suppress ''this' : used in base member initializer list'
 123     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 124     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 125     -wd4715 # Suppress ''function' : not all control paths return a value'
 126     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 127     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 128
 129     -w14062 # Promote "enumerator in switch of enum is not handled" to level 1 warning.
 130     )
 131
 132   # Enable warnings
 133   if (LLVM_ENABLE_WARNINGS)
 134     add_llvm_definitions( /W4 /Wall )
 135     if (LLVM_ENABLE_PEDANTIC)
 136       # No MSVC equivalent available
 137     endif (LLVM_ENABLE_PEDANTIC)
 138   endif (LLVM_ENABLE_WARNINGS)
 139   if (LLVM_ENABLE_WERROR)
 140     add_llvm_definitions( /WX )
 141   endif (LLVM_ENABLE_WERROR)
 142 elseif( CMAKE_COMPILER_IS_GNUCXX )
 143   if (LLVM_ENABLE_WARNINGS)
 144     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 145     if (LLVM_ENABLE_PEDANTIC)
 146       add_llvm_definitions( -pedantic -Wno-long-long )
 147     endif (LLVM_ENABLE_PEDANTIC)
 148   endif (LLVM_ENABLE_WARNINGS)
 149   if (LLVM_ENABLE_WERROR)
 150     add_llvm_definitions( -Werror )
 151   endif (LLVM_ENABLE_WERROR)
 152 endif( MSVC )
 153
 154 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 155 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 156