cmake/modules/LLVMConfig.cmake

   1 include(FindPerl)
   2
   3
   4 function(get_system_libs return_var)
   5   # Returns in `return_var' a list of system libraries used by LLVM.
   6   if( NOT MSVC )
   7     if( MINGW )
   8       set(system_libs ${system_libs} imagehlp psapi)
   9     elseif( CMAKE_HOST_UNIX )
  10       if( HAVE_LIBDL )
  11         set(system_libs ${system_libs} dl)
  12       endif()
  13       if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  14         set(system_libs ${system_libs} pthread)
  15       endif()
  16     endif( MINGW )
  17   endif( NOT MSVC )
  18   set(${return_var} ${system_libs} PARENT_SCOPE)
  19 endfunction(get_system_libs)
  20
  21
  22 macro(llvm_config executable)
  23   explicit_llvm_config(${executable} ${ARGN})
  24 endmacro(llvm_config)
  25
  26
  27 function(explicit_llvm_config executable)
  28   set( link_components ${ARGN} )
  29
  30   set(lfgs)
  31   if (MSVC)
  32     if( CMAKE_CL_64 )
  33       set(include_lflag "/INCLUDE:")
  34     else( CMAKE_CL_64 )
  35       set(include_lflag "/INCLUDE:_")
  36     endif()
  37     foreach(c ${link_components})
  38       if( c STREQUAL "jit" )
  39         set(lfgs "${lfgs} ${include_lflag}X86TargetMachineModule")
  40       endif( c STREQUAL "jit" )
  41       list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  42       if( NOT idx LESS 0 )
  43         set(lfgs "${lfgs} ${include_lflag}${c}TargetMachineModule")
  44         list(FIND LLVM_ASMPRINTERS_FORCE_LINK ${c} idx)
  45         if( NOT idx LESS 0 )
  46           set(lfgs "${lfgs} ${include_lflag}${c}AsmPrinterForceLink")
  47         endif()
  48       endif()
  49     endforeach(c)
  50   endif ()
  51
  52   explicit_map_components_to_libraries(LIBRARIES ${link_components})
  53   target_link_libraries(${executable} ${LIBRARIES})
  54
  55   if( lfgs )
  56     set_target_properties(${executable}
  57       PROPERTIES
  58       LINK_FLAGS ${lfgs})
  59   endif()
  60 endfunction(explicit_llvm_config)
  61
  62
  63 function(explicit_map_components_to_libraries out_libs)
  64   set( link_components ${ARGN} )
  65   foreach(c ${link_components})
  66     # add codegen/asmprinter
  67     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  68     if( NOT idx LESS 0 )
  69       list(FIND llvm_libs "LLVM${c}CodeGen" idx)
  70       if( NOT idx LESS 0 )
  71         list(APPEND expanded_components "LLVM${c}CodeGen")
  72       else()
  73         list(FIND llvm_libs "LLVM${c}" idx)
  74         if( NOT idx LESS 0 )
  75           list(APPEND expanded_components "LLVM${c}")
  76         else()
  77           message(FATAL_ERROR "Target ${c} is not in the set of libraries.")
  78         endif()
  79       endif()
  80       list(FIND llvm_libs "LLVM${c}AsmPrinter" asmidx)
  81       if( NOT asmidx LESS 0 )
  82         list(APPEND expanded_components "LLVM${c}AsmPrinter")
  83       endif()
  84     elseif( c STREQUAL "native" )
  85       # TODO: we assume ARCH is X86. In this case, we must use nativecodegen
  86       # component instead. Do nothing, as in llvm-config script.
  87     elseif( c STREQUAL "nativecodegen" )
  88       # TODO: we assume ARCH is X86.
  89       list(APPEND expanded_components "LLVMX86CodeGen")
  90     elseif( c STREQUAL "backend" )
  91       # same case as in `native'.
  92     elseif( c STREQUAL "engine" )
  93       # TODO: as we assume we are on X86, this is `jit'.
  94       list(APPEND expanded_components "LLVMJIT")
  95     elseif( c STREQUAL "all" )
  96       list(APPEND expanded_components ${llvm_libs})
  97     else( NOT idx LESS 0 )
  98       list(APPEND expanded_components LLVM${c})
  99     endif( NOT idx LESS 0 )
 100   endforeach(c)
 101   # We must match capitalization.
 102   string(TOUPPER "${llvm_libs}" capitalized_libs)
 103   list(REMOVE_DUPLICATES expanded_components)
 104   set(curr_idx 0)
 105   list(LENGTH expanded_components lst_size)
 106   while( ${curr_idx} LESS ${lst_size} )
 107     list(GET expanded_components ${curr_idx} c)
 108     string(TOUPPER "${c}" capitalized)
 109     list(FIND capitalized_libs ${capitalized} idx)
 110     if( idx LESS 0 )
 111       message(FATAL_ERROR "Library ${c} not found in list of llvm libraries.")
 112     endif( idx LESS 0 )
 113     list(GET llvm_libs ${idx} canonical_lib)
 114     list(APPEND result ${canonical_lib})
 115     list(APPEND result ${MSVC_LIB_DEPS_${canonical_lib}})
 116     list(APPEND expanded_components ${MSVC_LIB_DEPS_${canonical_lib}})
 117     list(REMOVE_DUPLICATES expanded_components)
 118     list(LENGTH expanded_components lst_size)
 119     math(EXPR curr_idx "${curr_idx} + 1")
 120   endwhile( ${curr_idx} LESS ${lst_size} )
 121   list(REMOVE_DUPLICATES result)
 122   set(${out_libs} ${result} PARENT_SCOPE)
 123 endfunction(explicit_map_components_to_libraries)
 124
 125 # This data is used to establish executable/library
 126 # dependencies.  Comes from the llvm-config script, which is built and
 127 # installed on the bin directory for MinGW or Linux. At the end of the
 128 # script, you'll see lines like this:
 129
 130 # LLVMARMAsmPrinter.o: LLVMARMCodeGen.o libLLVMAsmPrinter.a libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMTarget.a
 131
 132 # This is translated to:
 133
 134 # set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 135
 136 # It is necessary to remove the `lib' prefix, the `.a' and `.o'
 137 # suffixes.  Watch out for this line:
 138
 139 # LLVMExecutionEngine.o LLVMJIT.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 140
 141 # See how there are two elements before the colon. This must be
 142 # translated as if it were:
 143
 144 # LLVMExecutionEngine.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 145 # LLVMJIT.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 146
 147 # TODO: do this transformations on cmake.
 148
 149 # It is very important that the LLVM built for extracting this data
 150 # must contain all targets, not just X86.
 151
 152
 153 set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 154 set(MSVC_LIB_DEPS_LLVMARMCodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMSystem LLVMTarget)
 155 set(MSVC_LIB_DEPS_LLVMAlphaAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 156 set(MSVC_LIB_DEPS_LLVMAlphaCodeGen LLVMAlphaAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 157 set(MSVC_LIB_DEPS_LLVMCBackend LLVMAnalysis LLVMCodeGen LLVMCore LLVMScalarOpts LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)
 158 set(MSVC_LIB_DEPS_LLVMCellSPUAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 159 set(MSVC_LIB_DEPS_LLVMCellSPUCodeGen LLVMCellSPUAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 160 set(MSVC_LIB_DEPS_LLVMCppBackend LLVMCore LLVMSupport LLVMTarget)
 161 set(MSVC_LIB_DEPS_LLVMExecutionEngine LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 162 set(MSVC_LIB_DEPS_LLVMJIT LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 163 set(MSVC_LIB_DEPS_LLVMIA64 LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 164 set(MSVC_LIB_DEPS_LLVMInterpreter LLVMExecutionEngine LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 165 set(MSVC_LIB_DEPS_LLVMMSIL LLVMAnalysis LLVMCodeGen LLVMCore LLVMScalarOpts LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)
 166 set(MSVC_LIB_DEPS_LLVMMips LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 167 set(MSVC_LIB_DEPS_LLVMPIC16 LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 168 set(MSVC_LIB_DEPS_LLVMPowerPCAsmPrinter LLVMPowerPCCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 169 set(MSVC_LIB_DEPS_LLVMPowerPCCodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMSystem LLVMTarget)
 170 set(MSVC_LIB_DEPS_LLVMSparcAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 171 set(MSVC_LIB_DEPS_LLVMSparcCodeGen LLVMSparcAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 172 set(MSVC_LIB_DEPS_LLVMX86AsmPrinter LLVMX86CodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 173 set(MSVC_LIB_DEPS_LLVMX86CodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 174 set(MSVC_LIB_DEPS_LLVMXCore LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 175 set(MSVC_LIB_DEPS_LLVMAnalysis LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 176 set(MSVC_LIB_DEPS_LLVMArchive LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 177 set(MSVC_LIB_DEPS_LLVMAsmParser LLVMCore LLVMSupport)
 178 set(MSVC_LIB_DEPS_LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 179 set(MSVC_LIB_DEPS_LLVMBitReader LLVMCore LLVMSupport)
 180 set(MSVC_LIB_DEPS_LLVMBitWriter LLVMCore LLVMSupport LLVMSystem)
 181 set(MSVC_LIB_DEPS_LLVMCodeGen LLVMAnalysis LLVMCore LLVMScalarOpts LLVMSupport LLVMSystem LLVMTarget LLVMTransformUtils)
 182 set(MSVC_LIB_DEPS_LLVMCore LLVMSupport LLVMSystem)
 183 set(MSVC_LIB_DEPS_LLVMDebugger LLVMAnalysis LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 184 set(MSVC_LIB_DEPS_LLVMHello LLVMCore LLVMSupport)
 185 set(MSVC_LIB_DEPS_LLVMInstrumentation LLVMCore LLVMScalarOpts LLVMSupport LLVMTransformUtils)
 186 set(MSVC_LIB_DEPS_LLVMLinker LLVMArchive LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 187 set(MSVC_LIB_DEPS_LLVMScalarOpts LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMTransformUtils)
 188 set(MSVC_LIB_DEPS_LLVMSelectionDAG LLVMAnalysis LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 189 set(MSVC_LIB_DEPS_LLVMSupport LLVMSystem)
 190 set(MSVC_LIB_DEPS_LLVMSystem )
 191 set(MSVC_LIB_DEPS_LLVMTarget LLVMCore LLVMSupport)
 192 set(MSVC_LIB_DEPS_LLVMTransformUtils LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMipa)
 193 set(MSVC_LIB_DEPS_LLVMipa LLVMAnalysis LLVMCore LLVMSupport)
 194 set(MSVC_LIB_DEPS_LLVMipo LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)