cmake/modules/LLVMConfig.cmake

   1 include(FindPerl)
   2
   3
   4 function(get_system_libs return_var)
   5   # Returns in `return_var' a list of system libraries used by LLVM.
   6   if( NOT MSVC )
   7     if( MINGW )
   8       set(system_libs ${system_libs} imagehlp psapi)
   9     elseif( CMAKE_HOST_UNIX )
  10       if( HAVE_LIBDL )
  11         set(system_libs ${system_libs} dl)
  12       endif()
  13       if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  14         set(system_libs ${system_libs} pthread)
  15       endif()
  16     endif( MINGW )
  17   endif( NOT MSVC )
  18   set(${return_var} ${system_libs} PARENT_SCOPE)
  19 endfunction(get_system_libs)
  20
  21
  22 macro(llvm_config executable)
  23   # extra args is the list of link components.
  24   if( MSVC )
  25     msvc_llvm_config(${executable} ${ARGN})
  26   else( MSVC )
  27     nix_llvm_config(${executable} ${ARGN})
  28   endif( MSVC )
  29 endmacro(llvm_config)
  30
  31
  32 function(msvc_llvm_config executable)
  33   set( link_components ${ARGN} )
  34   if( CMAKE_CL_64 )
  35     set(include_lflag "/INCLUDE:")
  36   else( CMAKE_CL_64 )
  37     set(include_lflag "/INCLUDE:_")
  38   endif()
  39   foreach(c ${link_components})
  40     if( c STREQUAL "jit" )
  41       set(lfgs "${lfgs} ${include_lflag}X86TargetMachineModule")
  42     endif( c STREQUAL "jit" )
  43     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  44     if( NOT idx LESS 0 )
  45       set(lfgs "${lfgs} ${include_lflag}${c}TargetMachineModule")
  46       list(FIND LLVM_ASMPRINTERS_FORCE_LINK ${c} idx)
  47       if( NOT idx LESS 0 )
  48         set(lfgs "${lfgs} ${include_lflag}${c}AsmPrinterForceLink")
  49       endif()
  50     endif()
  51   endforeach(c)
  52
  53   msvc_map_components_to_libraries(LIBRARIES ${link_components})
  54   target_link_libraries(${executable} ${LIBRARIES})
  55
  56   if( lfgs )
  57     set_target_properties(${executable}
  58       PROPERTIES
  59       LINK_FLAGS ${lfgs})
  60   endif()
  61 endfunction(msvc_llvm_config)
  62
  63
  64 function(msvc_map_components_to_libraries out_libs)
  65   set( link_components ${ARGN} )
  66   foreach(c ${link_components})
  67     # add codegen/asmprinter
  68     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  69     if( NOT idx LESS 0 )
  70       list(FIND llvm_libs "LLVM${c}CodeGen" idx)
  71       if( NOT idx LESS 0 )
  72         list(APPEND expanded_components "LLVM${c}CodeGen")
  73       else()
  74         list(FIND llvm_libs "LLVM${c}" idx)
  75         if( NOT idx LESS 0 )
  76           list(APPEND expanded_components "LLVM${c}")
  77         else()
  78           message(FATAL_ERROR "Target ${c} is not in the set of libraries.")
  79         endif()
  80       endif()
  81       list(FIND llvm_libs "LLVM${c}AsmPrinter" asmidx)
  82       if( NOT asmidx LESS 0 )
  83         list(APPEND expanded_components "LLVM${c}AsmPrinter")
  84       endif()
  85     elseif( c STREQUAL "native" )
  86       # TODO: we assume ARCH is X86. In this case, we must use nativecodegen
  87       # component instead. Do nothing, as in llvm-config script.
  88     elseif( c STREQUAL "nativecodegen" )
  89       # TODO: we assume ARCH is X86.
  90       list(APPEND expanded_components "LLVMX86CodeGen")
  91     elseif( c STREQUAL "backend" )
  92       # same case as in `native'.
  93     elseif( c STREQUAL "engine" )
  94       # TODO: as we assume we are on X86, this is `jit'.
  95       list(APPEND expanded_components "LLVMJIT")
  96     elseif( c STREQUAL "all" )
  97       list(APPEND expanded_components ${llvm_libs})
  98     else( NOT idx LESS 0 )
  99       list(APPEND expanded_components LLVM${c})
 100     endif( NOT idx LESS 0 )
 101   endforeach(c)
 102   # We must match capitalization.
 103   string(TOUPPER "${llvm_libs}" capitalized_libs)
 104   list(REMOVE_DUPLICATES expanded_components)
 105   set(curr_idx 0)
 106   list(LENGTH expanded_components lst_size)
 107   while( ${curr_idx} LESS ${lst_size} )
 108     list(GET expanded_components ${curr_idx} c)
 109     string(TOUPPER "${c}" capitalized)
 110     list(FIND capitalized_libs ${capitalized} idx)
 111     if( idx LESS 0 )
 112       message(FATAL_ERROR "Library ${c} not found in list of llvm libraries.")
 113     endif( idx LESS 0 )
 114     list(GET llvm_libs ${idx} canonical_lib)
 115     list(APPEND result ${canonical_lib})
 116     list(APPEND result ${MSVC_LIB_DEPS_${canonical_lib}})
 117     list(APPEND expanded_components ${MSVC_LIB_DEPS_${canonical_lib}})
 118     list(REMOVE_DUPLICATES expanded_components)
 119     list(LENGTH expanded_components lst_size)
 120     math(EXPR curr_idx "${curr_idx} + 1")
 121   endwhile( ${curr_idx} LESS ${lst_size} )
 122   list(REMOVE_DUPLICATES result)
 123   set(${out_libs} ${result} PARENT_SCOPE)
 124 endfunction(msvc_map_components_to_libraries)
 125
 126
 127 macro(nix_llvm_config executable)
 128   set(lc "")
 129   foreach(c ${ARGN})
 130     set(lc "${lc} ${c}")
 131   endforeach(c)
 132   if( NOT HAVE_LLVM_CONFIG )
 133     target_link_libraries(${executable}
 134       "`${LLVM_TOOLS_BINARY_DIR}/llvm-config --libs ${lc}`")
 135   else( NOT HAVE_LLVM_CONFIG )
 136     # tbi: Error handling.
 137     if( NOT PERL_EXECUTABLE )
 138       message(FATAL_ERROR "Perl required but not found!")
 139     endif( NOT PERL_EXECUTABLE )
 140     execute_process(
 141       COMMAND sh -c "${PERL_EXECUTABLE} ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/llvm-config --libs ${lc}"
 142       RESULT_VARIABLE rv
 143       OUTPUT_VARIABLE libs
 144       OUTPUT_STRIP_TRAILING_WHITESPACE)
 145     if(NOT rv EQUAL 0)
 146       message(FATAL_ERROR "llvm-config failed for executable ${executable}")
 147     endif(NOT rv EQUAL 0)
 148     string(REPLACE " " ";" libs ${libs})
 149     foreach(c ${libs})
 150       if(c MATCHES ".*\\.o")
 151         get_filename_component(fn ${c} NAME)
 152         target_link_libraries(${executable}
 153           ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}/${fn})
 154       else(c MATCHES ".*\\.o")
 155         string(REPLACE "-l" "" fn ${c})
 156         target_link_libraries(${executable} ${fn})
 157       endif(c MATCHES ".*\\.o")
 158     endforeach(c)
 159   endif( NOT HAVE_LLVM_CONFIG )
 160 endmacro(nix_llvm_config)
 161
 162
 163 # This data is used on MSVC for stablishing executable/library
 164 # dependencies.  Comes from the llvm-config script, which is built and
 165 # installed on the bin directory for MinGW or Linux. At the end of the
 166 # script, you'll see lines like this:
 167
 168 # LLVMARMAsmPrinter.o: LLVMARMCodeGen.o libLLVMAsmPrinter.a libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMTarget.a
 169
 170 # This is translated to:
 171
 172 # set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 173
 174 # It is necessary to remove the `lib' prefix, the `.a' and `.o'
 175 # suffixes.  Watch out for this line:
 176
 177 # LLVMExecutionEngine.o LLVMJIT.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 178
 179 # See how there are two elements before the colon. This must be
 180 # translated as if it were:
 181
 182 # LLVMExecutionEngine.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 183 # LLVMJIT.o: libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMSystem.a libLLVMTarget.a
 184
 185 # TODO: do this transformations on cmake.
 186
 187 # It is very important that the LLVM built for extracting this data
 188 # must contain all targets, not just X86.
 189
 190
 191 set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 192 set(MSVC_LIB_DEPS_LLVMARMCodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMSystem LLVMTarget)
 193 set(MSVC_LIB_DEPS_LLVMAlphaAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 194 set(MSVC_LIB_DEPS_LLVMAlphaCodeGen LLVMAlphaAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 195 set(MSVC_LIB_DEPS_LLVMCBackend LLVMAnalysis LLVMCodeGen LLVMCore LLVMScalarOpts LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)
 196 set(MSVC_LIB_DEPS_LLVMCellSPUAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 197 set(MSVC_LIB_DEPS_LLVMCellSPUCodeGen LLVMCellSPUAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 198 set(MSVC_LIB_DEPS_LLVMCppBackend LLVMCore LLVMSupport LLVMTarget)
 199 set(MSVC_LIB_DEPS_LLVMExecutionEngine LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 200 set(MSVC_LIB_DEPS_LLVMJIT LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 201 set(MSVC_LIB_DEPS_LLVMIA64 LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 202 set(MSVC_LIB_DEPS_LLVMInterpreter LLVMExecutionEngine LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 203 set(MSVC_LIB_DEPS_LLVMMSIL LLVMAnalysis LLVMCodeGen LLVMCore LLVMScalarOpts LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)
 204 set(MSVC_LIB_DEPS_LLVMMips LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 205 set(MSVC_LIB_DEPS_LLVMPIC16 LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 206 set(MSVC_LIB_DEPS_LLVMPowerPCAsmPrinter LLVMPowerPCCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 207 set(MSVC_LIB_DEPS_LLVMPowerPCCodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMSystem LLVMTarget)
 208 set(MSVC_LIB_DEPS_LLVMSparcAsmPrinter LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 209 set(MSVC_LIB_DEPS_LLVMSparcCodeGen LLVMSparcAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 210 set(MSVC_LIB_DEPS_LLVMX86AsmPrinter LLVMX86CodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 211 set(MSVC_LIB_DEPS_LLVMX86CodeGen LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 212 set(MSVC_LIB_DEPS_LLVMXCore LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSelectionDAG LLVMSupport LLVMTarget)
 213 set(MSVC_LIB_DEPS_LLVMAnalysis LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 214 set(MSVC_LIB_DEPS_LLVMArchive LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 215 set(MSVC_LIB_DEPS_LLVMAsmParser LLVMCore LLVMSupport)
 216 set(MSVC_LIB_DEPS_LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 217 set(MSVC_LIB_DEPS_LLVMBitReader LLVMCore LLVMSupport)
 218 set(MSVC_LIB_DEPS_LLVMBitWriter LLVMCore LLVMSupport LLVMSystem)
 219 set(MSVC_LIB_DEPS_LLVMCodeGen LLVMAnalysis LLVMCore LLVMScalarOpts LLVMSupport LLVMSystem LLVMTarget LLVMTransformUtils)
 220 set(MSVC_LIB_DEPS_LLVMCore LLVMSupport LLVMSystem)
 221 set(MSVC_LIB_DEPS_LLVMDebugger LLVMAnalysis LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 222 set(MSVC_LIB_DEPS_LLVMHello LLVMCore LLVMSupport)
 223 set(MSVC_LIB_DEPS_LLVMInstrumentation LLVMCore LLVMScalarOpts LLVMSupport LLVMTransformUtils)
 224 set(MSVC_LIB_DEPS_LLVMLinker LLVMArchive LLVMBitReader LLVMCore LLVMSupport LLVMSystem)
 225 set(MSVC_LIB_DEPS_LLVMScalarOpts LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMTransformUtils)
 226 set(MSVC_LIB_DEPS_LLVMSelectionDAG LLVMAnalysis LLVMCodeGen LLVMCore LLVMSupport LLVMSystem LLVMTarget)
 227 set(MSVC_LIB_DEPS_LLVMSupport LLVMSystem)
 228 set(MSVC_LIB_DEPS_LLVMSystem )
 229 set(MSVC_LIB_DEPS_LLVMTarget LLVMCore LLVMSupport)
 230 set(MSVC_LIB_DEPS_LLVMTransformUtils LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMipa)
 231 set(MSVC_LIB_DEPS_LLVMipa LLVMAnalysis LLVMCore LLVMSupport)
 232 set(MSVC_LIB_DEPS_LLVMipo LLVMAnalysis LLVMCore LLVMSupport LLVMTarget LLVMTransformUtils LLVMipa)