cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 macro(tablegen ofn)
   6   file(GLOB local_tds "*.td")
   7   file(GLOB_RECURSE global_tds "${LLVM_MAIN_SRC_DIR}/include/llvm/*.td")
   8
   9   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  10     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  11   else()
  12     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  13       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  14   endif()
  15   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  16     # Generate tablegen output in a temporary file.
  17     COMMAND ${LLVM_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  18     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  19     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  20     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  21     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  22     # directory and local_tds may not contain it, so we must
  23     # explicitly list it here:
  24     DEPENDS tblgen ${local_tds} ${global_tds} ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  25     COMMENT "Building ${ofn}..."
  26     )
  27   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  28     # Only update the real output file if there are any differences.
  29     # This prevents recompilation of all the files depending on it if there
  30     # aren't any.
  31     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  32         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  33         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  34     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  35     COMMENT ""
  36     )
  37   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn})
  38   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  39     PROPERTIES GENERATED 1)
  40 endmacro(tablegen)