1 ===========================
2 TableGen Language Reference
3 ===========================
9 This document is extremely rough. If you find something lacking, please
10 fix it, file a documentation bug, or ask about it on llvmdev.
15 This document is meant to be a normative spec about the TableGen language
16 in and of itself (i.e. how to understand a given construct in terms of how
17 it affects the final set of records represented by the TableGen file). If
18 you are unsure if this document is really what you are looking for, please
19 read the :doc:`introduction to TableGen <index>` first.
24 The lexical and syntax notation used here is intended to imitate
25 `Python's`_. In particular, for lexical definitions, the productions
26 operate at the character level and there is no implied whitespace between
27 elements. The syntax definitions operate at the token level, so there is
28 implied whitespace between tokens.
30 .. _`Python's`: http://docs.python.org/py3k/reference/introduction.html#notation
35 TableGen supports BCPL (``// ...``) and nestable C-style (``/* ... */``)
38 The following is a listing of the basic punctuation tokens::
40 - + [ ] { } ( ) < > : ; . = ? #
42 Numeric literals take one of the following forms:
44 .. TableGen actually will lex some pretty strange sequences an interpret
45 them as numbers. What is shown here is an attempt to approximate what it
49 TokInteger: `DecimalInteger` | `HexInteger` | `BinInteger`
50 DecimalInteger: ["+" | "-"] ("0"..."9")+
51 HexInteger: "0x" ("0"..."9" | "a"..."f" | "A"..."F")+
52 BinInteger: "0b" ("0" | "1")+
54 One aspect to note is that the :token:`DecimalInteger` token *includes* the
55 ``+`` or ``-``, as opposed to having ``+`` and ``-`` be unary operators as
58 TableGen has identifier-like tokens:
61 ualpha: "a"..."z" | "A"..."Z" | "_"
62 TokIdentifier: ("0"..."9")* `ualpha` (`ualpha` | "0"..."9")*
63 TokVarName: "$" `ualpha` (`ualpha` | "0"..."9")*
65 Note that unlike most languages, TableGen allows :token:`TokIdentifier` to
66 begin with a number. In case of ambiguity, a token will be interpreted as a
67 numeric literal rather than an identifier.
69 TableGen also has two string-like literals:
72 TokString: '"' <non-'"' characters and C-like escapes> '"'
73 TokCodeFragment: "[{" <shortest text not containing "}]"> "}]"
75 :token:`TokCodeFragment` is essentially a multiline string literal
76 delimited by ``[{`` and ``}]``.
79 The current implementation accepts the following C-like escapes::
83 TableGen also has the following keywords::
85 bit bits class code dag
86 def foreach defm field in
87 int let list multiclass string
89 TableGen also has "bang operators" which have a
90 wide variety of meanings:
94 :!eq !if !head !tail !con
96 :!cast !empty !subst !foreach !strconcat
101 TableGen has an ``include`` mechanism. It does not play a role in the
102 syntax per se, since it is lexically replaced with the contents of the
106 IncludeDirective: "include" `TokString`
108 TableGen's top-level production consists of "objects".
111 TableGenFile: `Object`*
112 Object: `Class` | `Def` | `Defm` | `Let` | `MultiClass` | `Foreach`
118 Class: "class" `TokIdentifier` [`TemplateArgList`] `ObjectBody`
120 A ``class`` declaration creates a record which other records can inherit
121 from. A class can be parametrized by a list of "template arguments", whose
122 values can be used in the class body.
124 A given class can only be defined once. A ``class`` declaration is
125 considered to define the class if any of the following is true:
127 .. break ObjectBody into its consituents so that they are present here?
129 #. The :token:`TemplateArgList` is present.
130 #. The :token:`Body` in the :token:`ObjectBody` is present and is not empty.
131 #. The :token:`BaseClassList` in the :token:`ObjectBody` is present.
133 You can declare an empty class by giving and empty :token:`TemplateArgList`
134 and an empty :token:`ObjectBody`. This can serve as a restricted form of
135 forward declaration: note that records deriving from the forward-declared
136 class will inherit no fields from it since the record expansion is done
137 when the record is parsed.
140 TemplateArgList: "<" `Declaration` ("," `Declaration`)* ">"
145 .. Omitting mention of arcane "field" prefix to discourage its use.
147 The declaration syntax is pretty much what you would expect as a C++
151 Declaration: `Type` `TokIdentifier` ["=" `Value`]
153 It assigns the value to the identifer.
159 Type: "string" | "code" | "bit" | "int" | "dag"
160 :| "bits" "<" `TokInteger` ">"
161 :| "list" "<" `Type` ">"
163 ClassID: `TokIdentifier`
165 Both ``string`` and ``code`` correspond to the string type; the difference
166 is purely to indicate programmer intention.
168 The :token:`ClassID` must identify a class that has been previously
175 Value: `SimpleValue` `ValueSuffix`*
176 ValueSuffix: "{" `RangeList` "}"
177 :| "[" `RangeList` "]"
178 :| "." `TokIdentifier`
179 RangeList: `RangePiece` ("," `RangePiece`)*
180 RangePiece: `TokInteger`
181 :| `TokInteger` "-" `TokInteger`
182 :| `TokInteger` `TokInteger`
184 The peculiar last form of :token:`RangePiece` is due to the fact that the
185 "``-``" is included in the :token:`TokInteger`, hence ``1-5`` gets lexed as
186 two consecutive :token:`TokInteger`'s, with values ``1`` and ``-5``,
187 instead of "1", "-", and "5".
188 The :token:`RangeList` can be thought of as specifying "list slice" in some
192 :token:`SimpleValue` has a number of forms:
196 SimpleValue: `TokIdentifier`
198 The value will be the variable referenced by the identifier. It can be one
201 .. The code for this is exceptionally abstruse. These examples are a
204 * name of a ``def``, such as the use of ``Bar`` in::
206 def Bar : SomeClass {
214 * value local to a ``def``, such as the use of ``Bar`` in::
221 * a template arg of a ``class``, such as the use of ``Bar`` in::
227 * value local to a ``multiclass``, such as the use of ``Bar`` in::
234 * a template arg to a ``multiclass``, such as the use of ``Bar`` in::
236 multiclass Foo<int Bar> {
241 SimpleValue: `TokInteger`
243 This represents the numeric value of the integer.
246 SimpleValue: `TokString`+
248 Multiple adjacent string literals are concatenated like in C/C++. The value
249 is the concatenation of the strings.
252 SimpleValue: `TokCodeFragment`
254 The value is the string value of the code fragment.
259 ``?`` represents an "unset" initializer.
262 SimpleValue: "{" `ValueList` "}"
263 ValueList: [`ValueListNE`]
264 ValueListNE: `Value` ("," `Value`)*
266 This represents a sequence of bits, as would be used to initialize a
267 ``bits<n>`` field (where ``n`` is the number of bits).
270 SimpleValue: `ClassID` "<" `ValueListNE` ">"
272 This generates a new anonymous record definition (as would be created by an
273 unnamed ``def`` inheriting from the given class with the given template
274 arguments) and the value is the value of that record definition.
277 SimpleValue: "[" `ValueList` "]" ["<" `Type` ">"]
279 A list initializer. The optional :token:`Type` can be used to indicate a
280 specific element type, otherwise the element type will be deduced from the
283 .. The initial `DagArg` of the dag must start with an identifier or
284 !cast, but this is more of an implementation detail and so for now just
288 SimpleValue: "(" `DagArg` `DagArgList` ")"
289 DagArgList: `DagArg` ("," `DagArg`)*
290 DagArg: `Value` [":" `TokVarName`] | `TokVarName`
292 The initial :token:`DagArg` is called the "operator" of the dag.
295 SimpleValue: `BangOperator` ["<" `Type` ">"] "(" `ValueListNE` ")"
301 ObjectBody: `BaseClassList` `Body`
302 BaseClassList: [":" `BaseClassListNE`]
303 BaseClassListNE: `SubClassRef` ("," `SubClassRef`)*
304 SubClassRef: (`ClassID` | `MultiClassID`) ["<" `ValueList` ">"]
305 DefmID: `TokIdentifier`
307 The version with the :token:`MultiClassID` is only valid in the
308 :token:`BaseClassList` of a ``defm``.
309 The :token:`MultiClassID` should be the name of a ``multiclass``.
311 .. put this somewhere else
313 It is after parsing the base class list that the "let stack" is applied.
316 Body: ";" | "{" BodyList "}"
318 BodyItem: `Declaration` ";"
319 :| "let" `TokIdentifier` [`RangeList`] "=" `Value` ";"
321 The ``let`` form allows overriding the value of an inherited field.
327 There can be pastes in the names here, like ``#NAME#``. Look into that
328 and document it (it boils down to ParseIDValue with IDParseMode ==
329 ParseNameMode). ParseObjectName calls into the general ParseValue, with
330 the only different from "arbitrary expression parsing" being IDParseMode
334 Def: "def" `TokIdentifier` `ObjectBody`
336 Defines a record whose name is given by the :token:`TokIdentifier`. The
337 fields of the record are inherited from the base classes and defined in the
340 Special handling occurs if this ``def`` appears inside a ``multiclass`` or
347 Defm: "defm" `TokIdentifier` ":" `BaseClassListNE` ";"
349 Note that in the :token:`BaseClassList`, all of the ``multiclass``'s must
350 precede any ``class``'s that appear.
356 Foreach: "foreach" `Declaration` "in" "{" `Object`* "}"
357 :| "foreach" `Declaration` "in" `Object`
359 The value assigned to the variable in the declaration is iterated over and
360 the object or object list is reevaluated with the variable set at each
367 Let: "let" `LetList` "in" "{" `Object`* "}"
368 :| "let" `LetList` "in" `Object`
369 LetList: `LetItem` ("," `LetItem`)*
370 LetItem: `TokIdentifier` [`RangeList`] "=" `Value`
372 This is effectively equivalent to ``let`` inside the body of a record
373 except that it applies to multiple records at a time. The bindings are
374 applied at the end of parsing the base classes of a record.
380 MultiClass: "multiclass" `TokIdentifier` [`TemplateArgList`]
381 : [":" `BaseMultiClassList`] "{" `MultiClassObject`+ "}"
382 BaseMultiClassList: `MultiClassID` ("," `MultiClassID`)*
383 MultiClassID: `TokIdentifier`
384 MultiClassObject: `Def` | `Defm` | `Let` | `Foreach`