include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt, string typeval> {
  56   ValueType VT = vt;
  57   string TypeVal = typeval;
  58 }
  59
  60 class LLVMIntegerType<ValueType VT, int width>
  61   : LLVMType<VT, "Type::IntegerTyID"> {
  62   int Width = width;
  63 }
  64
  65 class LLVMVectorType<ValueType VT, int numelts, LLVMType elty>
  66   : LLVMType<VT, "Type::VectorTyID">{
  67   int NumElts = numelts;
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMPointerType<LLVMType elty>
  72   : LLVMType<iPTR, "Type::PointerTyID">{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 class LLVMEmptyStructType
  77   : LLVMType<OtherVT, "Type::StructTyID">{
  78 }
  79
  80 def llvm_void_ty       : LLVMType<isVoid, "Type::VoidTyID">;
  81 def llvm_bool_ty       : LLVMIntegerType<i1, 1>;
  82 def llvm_i8_ty         : LLVMIntegerType<i8 , 8>;
  83 def llvm_i16_ty        : LLVMIntegerType<i16, 16>;
  84 def llvm_i32_ty        : LLVMIntegerType<i32, 32>;
  85 def llvm_i64_ty        : LLVMIntegerType<i64, 64>;
  86 def llvm_float_ty      : LLVMType<f32, "Type::FloatTyID">;
  87 def llvm_double_ty     : LLVMType<f64, "Type::DoubleTyID">;
  88 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  89 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  90 def llvm_empty_ty      : LLVMEmptyStructType;                     // { }
  91 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  92
  93 def llvm_v16i8_ty      : LLVMVectorType<v16i8,16, llvm_i8_ty>;    // 16 x i8
  94 def llvm_v8i16_ty      : LLVMVectorType<v8i16, 8, llvm_i16_ty>;   //  8 x i16
  95 def llvm_v2i64_ty      : LLVMVectorType<v2i64, 2, llvm_i64_ty>;   //  2 x i64
  96 def llvm_v2i32_ty      : LLVMVectorType<v2i32, 2, llvm_i32_ty>;   //  2 x i32
  97 def llvm_v4i32_ty      : LLVMVectorType<v4i32, 4, llvm_i32_ty>;   //  4 x i32
  98 def llvm_v4f32_ty      : LLVMVectorType<v4f32, 4, llvm_float_ty>; //  4 x float
  99 def llvm_v2f64_ty      : LLVMVectorType<v2f64, 2, llvm_double_ty>;//  2 x double
 100
 101 // MMX Vector Types
 102 def llvm_v8i8_ty       : LLVMVectorType<v8i8,  8, llvm_i8_ty>;    //  8 x i8
 103 def llvm_v4i16_ty      : LLVMVectorType<v4i16, 4, llvm_i16_ty>;   //  4 x i16
 104
 105 def llvm_vararg_ty     : LLVMType<isVoid, "...">; // vararg
 106
 107 //===----------------------------------------------------------------------===//
 108 // Intrinsic Definitions.
 109 //===----------------------------------------------------------------------===//
 110
 111 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 112 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 113 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 114 // example, llvm.bswap.i16 -> int_bswap_i16.
 115 //
 116 //  * Types is a list containing the return type and the argument types
 117 //    expected for the intrinsic.
 118 //  * Properties can be set to describe the behavior of the intrinsic.
 119 //
 120 class Intrinsic<list<LLVMType> types,
 121                 list<IntrinsicProperty> properties = [],
 122                 string name = ""> {
 123   string LLVMName = name;
 124   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 125   list<LLVMType> Types = types;
 126   list<IntrinsicProperty> Properties = properties;
 127 }
 128
 129 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 130 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 131 /// support.
 132 class GCCBuiltin<string name> {
 133   string GCCBuiltinName = name;
 134 }
 135
 136
 137 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 138 //
 139
 140 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_start">;
 141 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty], [],
 142                             "llvm.va_copy">;
 143 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_end">;
 144
 145 //===------------------- Garbage Collection Intrinsics --------------------===//
 146 //
 147 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 148 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 149                             [IntrReadArgMem]>;
 150 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 151                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 152
 153 //===--------------------- Code Generator Intrinsics ----------------------===//
 154 //
 155 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 156 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 157 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>,
 158                         GCCBuiltin<"__builtin_stack_save">;
 159 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 160                         GCCBuiltin<"__builtin_stack_restore">;
 161 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 162                                    llvm_i32_ty, llvm_i32_ty]>;
 163 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 164
 165 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 166
 167 //===------------------- Standard C Library Intrinsics --------------------===//
 168 //
 169
 170 let Properties = [IntrWriteArgMem] in {
 171   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 172                                    llvm_i32_ty, llvm_i32_ty]>;
 173   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 174                                    llvm_i64_ty, llvm_i32_ty]>;
 175   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 176                                    llvm_i32_ty, llvm_i32_ty]>;
 177   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 178                                    llvm_i64_ty, llvm_i32_ty]>;
 179   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 180                                    llvm_i32_ty, llvm_i32_ty]>;
 181   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 182                                    llvm_i64_ty, llvm_i32_ty]>;
 183 }
 184
 185 let Properties = [IntrNoMem] in {
 186   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 187   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 188
 189   def int_powi_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty, llvm_i32_ty]>;
 190   def int_powi_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty, llvm_i32_ty]>;
 191 }
 192
 193 // NOTE: these are internal interfaces.
 194 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 195 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 196 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 197 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 198
 199 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 200 //
 201
 202 // None of these intrinsics accesses memory at all.
 203 let Properties = [IntrNoMem] in {
 204   def int_bswap_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 205   def int_bswap_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 206   def int_bswap_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 207
 208   def int_ctpop_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 209   def int_ctpop_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 210   def int_ctpop_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 211   def int_ctpop_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 212
 213   def int_ctlz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 214   def int_ctlz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 215   def int_ctlz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 216   def int_ctlz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 217
 218   def int_cttz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 219   def int_cttz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 220   def int_cttz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 221   def int_cttz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 222 }
 223
 224 //===------------------------ Debugger Intrinsics -------------------------===//
 225 //
 226
 227 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 228                                       llvm_i32_ty, llvm_i32_ty,
 229                                       llvm_descriptor_ty]>;
 230 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 231 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 232 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 233 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_descriptor_ty,
 234                                                     llvm_descriptor_ty]>;
 235
 236 //===------------------ Exception Handling Intrinsics----------------------===//
 237 //
 238 def int_eh_exception  : Intrinsic<[llvm_ptr_ty]>;
 239 def int_eh_selector   : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 240                                                 llvm_vararg_ty]>;
 241 def int_eh_filter     : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 242                                                 llvm_vararg_ty]>;
 243 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty, llvm_ptr_ty]>;
 244
 245 //===----------------------------------------------------------------------===//
 246 // Target-specific intrinsics
 247 //===----------------------------------------------------------------------===//
 248
 249 include "llvm/IntrinsicsPowerPC.td"
 250 include "llvm/IntrinsicsX86.td"