include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // InstrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def InstrNoMem : IntrinsicProperty;
  30
  31 // InstrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def InstrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // InstrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def InstrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<string typeval> {
  56   string TypeVal = typeval;
  57 }
  58
  59 class LLVMPackedType<int numelts, LLVMType elty> : LLVMType<"Type::PackedTyID">{
  60   int NumElts = numelts;
  61   LLVMType ElTy = elty;
  62 }
  63
  64 def llvm_void_ty       : LLVMType<"Type::VoidTyID">;
  65 def llvm_bool_ty       : LLVMType<"Type::BoolTyID">;
  66 def llvm_sbyte_ty      : LLVMType<"Type::SByteTyID">;
  67 def llvm_short_ty      : LLVMType<"Type::ShortTyID">;
  68 def llvm_int_ty        : LLVMType<"Type::IntTyID">;
  69 def llvm_long_ty       : LLVMType<"Type::LongTyID">;
  70 def llvm_ubyte_ty      : LLVMType<"Type::UByteTyID">;
  71 def llvm_ushort_ty     : LLVMType<"Type::UShortTyID">;
  72 def llvm_uint_ty       : LLVMType<"Type::UIntTyID">;
  73 def llvm_ulong_ty      : LLVMType<"Type::ULongTyID">;
  74 def llvm_float_ty      : LLVMType<"Type::FloatTyID">;
  75 def llvm_double_ty     : LLVMType<"Type::DoubleTyID">;
  76 def llvm_ptr_ty        : LLVMType<"Type::PointerTyID">;     // sbyte*
  77 def llvm_ptrptr_ty     : LLVMType<"Type::PointerTyID">;     // sbyte**
  78 def llvm_descriptor_ty : LLVMType<"Type::PointerTyID">;     // global*
  79
  80 def llvm_v4i32_ty      : LLVMPackedType<4, llvm_int_ty>;    // 4 x int
  81 def llvm_v4f32_ty      : LLVMPackedType<4, llvm_float_ty>;  // 4 x float
  82 def llvm_v2f64_ty      : LLVMPackedType<2, llvm_double_ty>; // 2 x double
  83
  84 //===----------------------------------------------------------------------===//
  85 // Intrinsic Definitions.
  86 //===----------------------------------------------------------------------===//
  87
  88 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  89 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  90 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  91 // example, llvm.bswap.i16 -> int_bswap_i16.
  92 //
  93 //  * Types is a list containing the return type and the argument types
  94 //    expected for the intrinsic.
  95 //  * Properties can be set to describe the behavior of the intrinsic.
  96 //
  97 class Intrinsic<list<LLVMType> types,
  98                 list<IntrinsicProperty> properties = [],
  99                 string name = ""> {
 100   string LLVMName = name;
 101   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 102   list<LLVMType> Types = types;
 103   list<IntrinsicProperty> Properties = properties;
 104 }
 105
 106 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 107 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 108 /// support.
 109 class GCCBuiltin<string name> {
 110   string GCCBuiltinName = name;
 111 }
 112
 113
 114 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 115 //
 116
 117 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 118 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 119                             "llvm.va_copy">;
 120 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 121
 122 //===------------------- Garbage Collection Intrinsics --------------------===//
 123 //
 124 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 125 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 126                             [InstrReadArgMem]>;
 127 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 128                              llvm_ptrptr_ty], [InstrWriteArgMem]>;
 129
 130 //===--------------------- Code Generator Intrinsics ----------------------===//
 131 //
 132 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 133 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 134 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>;
 135 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>;
 136 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 137                                    llvm_uint_ty, llvm_uint_ty]>;
 138 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_uint_ty]>;
 139
 140 def int_readcyclecounter : Intrinsic<[llvm_ulong_ty]>;
 141
 142 //===------------------- Standard C Library Intrinsics --------------------===//
 143 //
 144
 145 let Properties = [InstrWriteArgMem] in {
 146   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 147                                    llvm_uint_ty, llvm_uint_ty]>;
 148   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 149                                    llvm_ulong_ty, llvm_uint_ty]>;
 150   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 151                                    llvm_uint_ty, llvm_uint_ty]>;
 152   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 153                                    llvm_ulong_ty, llvm_uint_ty]>;
 154   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 155                                    llvm_uint_ty, llvm_uint_ty]>;
 156   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 157                                    llvm_ulong_ty, llvm_uint_ty]>;
 158 }
 159
 160 let Properties = [InstrNoMem] in {
 161   def int_isunordered_f32 : Intrinsic<[llvm_bool_ty,
 162                                        llvm_float_ty,  llvm_float_ty]>;
 163   def int_isunordered_f64 : Intrinsic<[llvm_bool_ty,
 164                                        llvm_double_ty, llvm_double_ty]>;
 165   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 166   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 167 }
 168
 169 // NOTE: these are internal interfaces.
 170 def int_setjmp     : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 171 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 172 def int_sigsetjmp  : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 173 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 174
 175 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 176 //
 177
 178 // None of these intrinsics accesses memory at all.
 179 let Properties = [InstrNoMem] in {
 180   def int_bswap_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 181   def int_bswap_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 182   def int_bswap_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 183
 184   def int_ctpop_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 185   def int_ctpop_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 186   def int_ctpop_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 187   def int_ctpop_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 188
 189   def int_ctlz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 190   def int_ctlz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 191   def int_ctlz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 192   def int_ctlz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 193
 194   def int_cttz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 195   def int_cttz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 196   def int_cttz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 197   def int_cttz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 198 }
 199
 200 //===------------------------ Debugger Intrinsics -------------------------===//
 201 //
 202
 203 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 204                                       llvm_uint_ty, llvm_uint_ty,
 205                                       llvm_descriptor_ty]>;
 206 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 207 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 208 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 209 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 210                                                     llvm_descriptor_ty]>;
 211
 212 //===----------------------------------------------------------------------===//
 213 // Target-specific intrinsics
 214 //===----------------------------------------------------------------------===//
 215
 216 //===----------------------------------------------------------------------===//
 217 // PowerPC Intrinsics
 218 //
 219 let TargetPrefix = "ppc" in {  // All intrinsics start with "llvm.ppc.".
 220   def int_ppc_altivec_lvx : GCCBuiltin<"__builtin_altivec_lvx">,
 221               Intrinsic<[llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 222                         [IntrReadMem]>;
 223   def int_ppc_altivec_stvx : GCCBuiltin<"__builtin_altivec_stvx">,
 224               Intrinsic<[llvm_void_ty, llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 225                         [IntrWriteMem]>;
 226
 227   def int_ppc_altivec_vmaddfp : GCCBuiltin<"__builtin_altivec_vmaddfp">,
 228               Intrinsic<[llvm_v4f32_ty, llvm_v4f32_ty,
 229                          llvm_v4f32_ty, llvm_v4f32_ty], [InstrNoMem]>;
 230   def int_ppc_altivec_vadduwm : GCCBuiltin<"__builtin_altivec_vadduwm">,
 231               Intrinsic<[llvm_v4i32_ty, llvm_v4i32_ty, llvm_v4i32_ty],
 232                         [InstrNoMem]>;
 233
 234 }
 235
 236
 237 //===----------------------------------------------------------------------===//
 238 // X86 Intrinsics
 239 //
 240
 241 // SSE1
 242
 243 let TargetPrefix = "x86" in {  // All intrinsics start with "llvm.x86.".
 244   def int_x86_sse_movmskps : GCCBuiltin<"__builtin_ia32_movmskps">,
 245               Intrinsic<[llvm_int_ty, llvm_v4f32_ty], [InstrNoMem]>;
 246 }
 247
 248 // SSE2
 249 let TargetPrefix = "x86" in {  // All intrinsics start with "llvm.x86.".
 250   def int_x86_sse2_movmskpd : GCCBuiltin<"__builtin_ia32_movmskpd">,
 251               Intrinsic<[llvm_int_ty, llvm_v2f64_ty], [InstrNoMem]>;
 252 }