include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_i1_ty         : LLVMType<i1>;
  98 def llvm_i8_ty         : LLVMType<i8>;
  99 def llvm_i16_ty        : LLVMType<i16>;
 100 def llvm_i32_ty        : LLVMType<i32>;
 101 def llvm_i64_ty        : LLVMType<i64>;
 102 def llvm_float_ty      : LLVMType<f32>;
 103 def llvm_double_ty     : LLVMType<f64>;
 104 def llvm_f80_ty        : LLVMType<f80>;
 105 def llvm_f128_ty       : LLVMType<f128>;
 106 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 107 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 108 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 109 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 110 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 111 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 112
 113 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 114 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 115 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 116 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 117 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 118 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 119 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 120 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 121 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 122
 123 // MMX Vector Types
 124 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 125 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 126
 127 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 128
 129 //===----------------------------------------------------------------------===//
 130 // Intrinsic Definitions.
 131 //===----------------------------------------------------------------------===//
 132
 133 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 134 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 135 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 136 // example, llvm.bswap.i16 -> int_bswap_i16.
 137 //
 138 //  * RetTypes is a list containing the return types expected for the
 139 //    intrinsic.
 140 //  * ParamTypes is a list containing the parameter types expected for the
 141 //    intrinsic.
 142 //  * Properties can be set to describe the behavior of the intrinsic.
 143 //
 144 class Intrinsic<list<LLVMType> ret_types,
 145                 list<LLVMType> param_types = [],
 146                 list<IntrinsicProperty> properties = [],
 147                 string name = ""> {
 148   string LLVMName = name;
 149   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 150   list<LLVMType> RetTypes = ret_types;
 151   list<LLVMType> ParamTypes = param_types;
 152   list<IntrinsicProperty> Properties = properties;
 153
 154   bit isTarget = 0;
 155 }
 156
 157 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 158 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 159 /// support.
 160 class GCCBuiltin<string name> {
 161   string GCCBuiltinName = name;
 162 }
 163
 164
 165 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 166 //
 167
 168 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 169 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 170                             "llvm.va_copy">;
 171 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 172
 173 //===------------------- Garbage Collection Intrinsics --------------------===//
 174 //
 175 def int_gcroot  : Intrinsic<[llvm_void_ty],
 176                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 177 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 178                             [llvm_ptr_ty, llvm_ptrptr_ty],
 179                             [IntrReadArgMem]>;
 180 def int_gcwrite : Intrinsic<[llvm_void_ty],
 181                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 182                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 183
 184 //===--------------------- Code Generator Intrinsics ----------------------===//
 185 //
 186 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 187 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 188
 189 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 190 // model their dependencies on allocas.
 191 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 192                         GCCBuiltin<"__builtin_stack_save">;
 193 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 194                         GCCBuiltin<"__builtin_stack_restore">;
 195
 196 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 197 // however it does conveniently prevent the prefetch from being reordered
 198 // with respect to nearby accesses to the same memory.
 199 def int_prefetch      : Intrinsic<[llvm_void_ty],
 200                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 201                                   [IntrWriteArgMem, NoCapture<0>]>;
 202 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 203
 204 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 205
 206 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 207 // guard to the correct place on the stack frame.
 208 def int_stackprotector : Intrinsic<[llvm_void_ty],
 209                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 210                                    [IntrWriteMem]>;
 211
 212 //===------------------- Standard C Library Intrinsics --------------------===//
 213 //
 214
 215 def int_memcpy  : Intrinsic<[llvm_void_ty],
 216                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 217                               llvm_i32_ty],
 218                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 219 def int_memmove : Intrinsic<[llvm_void_ty],
 220                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 221                              llvm_i32_ty],
 222                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 223 def int_memset  : Intrinsic<[llvm_void_ty],
 224                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 225                              llvm_i32_ty],
 226                             [IntrWriteArgMem, NoCapture<0>]>;
 227
 228 // These functions do not actually read memory, but they are sensitive to the
 229 // rounding mode.  This needs to be modelled separately; in the meantime
 230 // declaring them as reading memory is conservatively correct.
 231 let Properties = [IntrReadMem] in {
 232   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 233   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 234   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 235   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 236   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 237                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 238   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 239   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 240   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 241   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 242   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 243 }
 244
 245 // NOTE: these are internal interfaces.
 246 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 247 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 248 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 249 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 250
 251 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 252 //
 253
 254 // None of these intrinsics accesses memory at all.
 255 let Properties = [IntrNoMem] in {
 256   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 257   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 258   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 259   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 260   def int_part_select : Intrinsic<[llvm_anyint_ty],
 261                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 262   def int_part_set : Intrinsic<[llvm_anyint_ty],
 263                                [LLVMMatchType<0>, llvm_anyint_ty,
 264                                 llvm_i32_ty, llvm_i32_ty]>;
 265 }
 266
 267 //===------------------------ Debugger Intrinsics -------------------------===//
 268 //
 269
 270 // None of these intrinsics accesses memory at all...but that doesn't mean the
 271 // optimizers can change them aggressively.  Special handling needed in a few
 272 // places.
 273 let Properties = [IntrNoMem] in {
 274   def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 275                                        [llvm_i32_ty, llvm_i32_ty,
 276                                         llvm_descriptor_ty]>;
 277   def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 278   def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 279   def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 280   def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 281                                        [llvm_descriptor_ty, llvm_descriptor_ty]>;
 282 }
 283
 284 //===------------------ Exception Handling Intrinsics----------------------===//
 285 //
 286 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 287 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 288                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 289 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 290                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 291
 292 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 293 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 294
 295 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 296 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 297
 298 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 299                         GCCBuiltin<"__builtin_unwind_init">;
 300
 301 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 302
 303 let Properties = [IntrNoMem] in {
 304 def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 305 def int_eh_sjlj_longjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 306 }
 307
 308 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 309 //
 310 def int_var_annotation : Intrinsic<[llvm_void_ty],
 311                                    [llvm_ptr_ty, llvm_ptr_ty,
 312                                     llvm_ptr_ty, llvm_i32_ty],
 313                                    [], "llvm.var.annotation">;
 314 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 315                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 316                                     llvm_i32_ty],
 317                                    [], "llvm.ptr.annotation">;
 318 def int_annotation : Intrinsic<[llvm_anyint_ty],
 319                                [LLVMMatchType<0>, llvm_ptr_ty,
 320                                 llvm_ptr_ty, llvm_i32_ty],
 321                                [], "llvm.annotation">;
 322
 323 //===------------------------ Trampoline Intrinsics -----------------------===//
 324 //
 325 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 326                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 327                                     [IntrWriteArgMem]>,
 328                           GCCBuiltin<"__builtin_init_trampoline">;
 329
 330 //===------------------------ Overflow Intrinsics -------------------------===//
 331 //
 332
 333 // Expose the carry flag from add operations on two integrals.
 334 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 335                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 336 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 337                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 338
 339 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 340                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 341 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 342                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 343
 344 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 345                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 346 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 347                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 348
 349 //===------------------------- Atomic Intrinsics --------------------------===//
 350 //
 351 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 352                                    [llvm_i1_ty, llvm_i1_ty,
 353                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 354                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 355
 356 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 357                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 358                                      LLVMMatchType<0>, LLVMMatchType<0>],
 359                                     [IntrWriteArgMem, NoCapture<0>]>,
 360                            GCCBuiltin<"__sync_val_compare_and_swap">;
 361 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 362                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 363                                      LLVMMatchType<0>],
 364                                     [IntrWriteArgMem, NoCapture<0>]>,
 365                            GCCBuiltin<"__sync_fetch_and_add">;
 366 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 367                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 368                                      LLVMMatchType<0>],
 369                                     [IntrWriteArgMem, NoCapture<0>]>,
 370                            GCCBuiltin<"__sync_lock_test_and_set">;
 371 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 372                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 373                                      LLVMMatchType<0>],
 374                                     [IntrWriteArgMem, NoCapture<0>]>,
 375                            GCCBuiltin<"__sync_fetch_and_sub">;
 376 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 377                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 378                                      LLVMMatchType<0>],
 379                                     [IntrWriteArgMem, NoCapture<0>]>,
 380                            GCCBuiltin<"__sync_fetch_and_and">;
 381 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 382                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 383                                       LLVMMatchType<0>],
 384                                      [IntrWriteArgMem, NoCapture<0>]>,
 385                            GCCBuiltin<"__sync_fetch_and_or">;
 386 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 387                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 388                                      LLVMMatchType<0>],
 389                                     [IntrWriteArgMem, NoCapture<0>]>,
 390                            GCCBuiltin<"__sync_fetch_and_xor">;
 391 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 392                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 393                                       LLVMMatchType<0>],
 394                                      [IntrWriteArgMem, NoCapture<0>]>,
 395                            GCCBuiltin<"__sync_fetch_and_nand">;
 396 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 397                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 398                                       LLVMMatchType<0>],
 399                                      [IntrWriteArgMem, NoCapture<0>]>,
 400                            GCCBuiltin<"__sync_fetch_and_min">;
 401 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 402                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 403                                       LLVMMatchType<0>],
 404                                      [IntrWriteArgMem, NoCapture<0>]>,
 405                            GCCBuiltin<"__sync_fetch_and_max">;
 406 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 407                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 408                                       LLVMMatchType<0>],
 409                                      [IntrWriteArgMem, NoCapture<0>]>,
 410                            GCCBuiltin<"__sync_fetch_and_umin">;
 411 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 412                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 413                                       LLVMMatchType<0>],
 414                                      [IntrWriteArgMem, NoCapture<0>]>,
 415                            GCCBuiltin<"__sync_fetch_and_umax">;
 416
 417 //===-------------------------- Other Intrinsics --------------------------===//
 418 //
 419 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 420                      GCCBuiltin<"__builtin_flt_rounds">;
 421 def int_trap : Intrinsic<[llvm_void_ty]>,
 422                GCCBuiltin<"__builtin_trap">;
 423
 424 // These convert intrinsics are to support various conversions between
 425 // various types with rounding and saturation. NOTE: avoid using these
 426 // intrinsics as they might be removed sometime in the future and
 427 // most targets don't support them.
 428 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 429                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 430 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 431                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 432 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 433                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 434 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 435                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 436 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 437                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 438 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 439                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 440 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 441                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 442 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 443                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 444 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 445                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 446
 447 //===----------------------------------------------------------------------===//
 448 // Target-specific intrinsics
 449 //===----------------------------------------------------------------------===//
 450
 451 include "llvm/IntrinsicsPowerPC.td"
 452 include "llvm/IntrinsicsX86.td"
 453 include "llvm/IntrinsicsARM.td"
 454 include "llvm/IntrinsicsCellSPU.td"
 455 include "llvm/IntrinsicsAlpha.td"
 456 include "llvm/IntrinsicsXCore.td"