include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_i1_ty         : LLVMType<i1>;
  98 def llvm_i8_ty         : LLVMType<i8>;
  99 def llvm_i16_ty        : LLVMType<i16>;
 100 def llvm_i32_ty        : LLVMType<i32>;
 101 def llvm_i64_ty        : LLVMType<i64>;
 102 def llvm_float_ty      : LLVMType<f32>;
 103 def llvm_double_ty     : LLVMType<f64>;
 104 def llvm_f80_ty        : LLVMType<f80>;
 105 def llvm_f128_ty       : LLVMType<f128>;
 106 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 107 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 108 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 109 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 110 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 111 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 112
 113 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 114 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 115 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 116 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 117 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 118 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 119 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 120 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 121
 122 // MMX Vector Types
 123 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 124 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 125
 126 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 127
 128 //===----------------------------------------------------------------------===//
 129 // Intrinsic Definitions.
 130 //===----------------------------------------------------------------------===//
 131
 132 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 133 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 134 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 135 // example, llvm.bswap.i16 -> int_bswap_i16.
 136 //
 137 //  * RetTypes is a list containing the return types expected for the
 138 //    intrinsic.
 139 //  * ParamTypes is a list containing the parameter types expected for the
 140 //    intrinsic.
 141 //  * Properties can be set to describe the behavior of the intrinsic.
 142 //
 143 class Intrinsic<list<LLVMType> ret_types,
 144                 list<LLVMType> param_types = [],
 145                 list<IntrinsicProperty> properties = [],
 146                 string name = ""> {
 147   string LLVMName = name;
 148   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 149   list<LLVMType> RetTypes = ret_types;
 150   list<LLVMType> ParamTypes = param_types;
 151   list<IntrinsicProperty> Properties = properties;
 152
 153   bit isTarget = 0;
 154 }
 155
 156 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 157 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 158 /// support.
 159 class GCCBuiltin<string name> {
 160   string GCCBuiltinName = name;
 161 }
 162
 163
 164 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 165 //
 166
 167 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 168 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 169                             "llvm.va_copy">;
 170 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 171
 172 //===------------------- Garbage Collection Intrinsics --------------------===//
 173 //
 174 def int_gcroot  : Intrinsic<[llvm_void_ty],
 175                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 176 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 177                             [llvm_ptr_ty, llvm_ptrptr_ty],
 178                             [IntrReadArgMem]>;
 179 def int_gcwrite : Intrinsic<[llvm_void_ty],
 180                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 181                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 182
 183 //===--------------------- Code Generator Intrinsics ----------------------===//
 184 //
 185 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 186 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 187
 188 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 189 // model their dependencies on allocas.
 190 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 191                         GCCBuiltin<"__builtin_stack_save">;
 192 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 193                         GCCBuiltin<"__builtin_stack_restore">;
 194
 195 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 196 // however it does conveniently prevent the prefetch from being reordered
 197 // with respect to nearby accesses to the same memory.
 198 def int_prefetch      : Intrinsic<[llvm_void_ty],
 199                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 200                                   [IntrWriteArgMem, NoCapture<0>]>;
 201 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 202
 203 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 204
 205 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 206 // guard to the correct place on the stack frame.
 207 def int_stackprotector : Intrinsic<[llvm_void_ty],
 208                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 209                                    [IntrWriteMem]>;
 210
 211 //===------------------- Standard C Library Intrinsics --------------------===//
 212 //
 213
 214 def int_memcpy  : Intrinsic<[llvm_void_ty],
 215                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 216                               llvm_i32_ty],
 217                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 218 def int_memmove : Intrinsic<[llvm_void_ty],
 219                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 220                              llvm_i32_ty],
 221                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 222 def int_memset  : Intrinsic<[llvm_void_ty],
 223                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 224                              llvm_i32_ty],
 225                             [IntrWriteArgMem, NoCapture<0>]>;
 226
 227 // These functions do not actually read memory, but they are sensitive to the
 228 // rounding mode.  This needs to be modelled separately; in the meantime
 229 // declaring them as reading memory is conservatively correct.
 230 let Properties = [IntrReadMem] in {
 231   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 232   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 233   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 234   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 235   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 236                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 237   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 238   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 239   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 240   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 241   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 242 }
 243
 244 // NOTE: these are internal interfaces.
 245 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 246 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 247 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 248 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 249
 250 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 251 //
 252
 253 // None of these intrinsics accesses memory at all.
 254 let Properties = [IntrNoMem] in {
 255   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 256   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 257   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 258   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 259   def int_part_select : Intrinsic<[llvm_anyint_ty],
 260                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 261   def int_part_set : Intrinsic<[llvm_anyint_ty],
 262                                [LLVMMatchType<0>, llvm_anyint_ty,
 263                                 llvm_i32_ty, llvm_i32_ty]>;
 264 }
 265
 266 //===------------------------ Debugger Intrinsics -------------------------===//
 267 //
 268
 269 // None of these intrinsics accesses memory at all...but that doesn't mean the
 270 // optimizers can change them aggressively.  Special handling needed in a few
 271 // places.
 272 let Properties = [IntrNoMem] in {
 273   def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 274                                        [llvm_i32_ty, llvm_i32_ty,
 275                                         llvm_descriptor_ty]>;
 276   def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 277   def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 278   def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 279   def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 280                                        [llvm_descriptor_ty, llvm_descriptor_ty]>;
 281 }
 282
 283 //===------------------ Exception Handling Intrinsics----------------------===//
 284 //
 285 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 286 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 287                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 288 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 289                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 290
 291 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 292 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 293
 294 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 295 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 296
 297 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 298                         GCCBuiltin<"__builtin_unwind_init">;
 299
 300 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 301
 302 let Properties = [IntrNoMem] in {
 303 def int_builtinsetjmp  : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 304 def int_builtinlongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 305 }
 306
 307 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 308 //
 309 def int_var_annotation : Intrinsic<[llvm_void_ty],
 310                                    [llvm_ptr_ty, llvm_ptr_ty,
 311                                     llvm_ptr_ty, llvm_i32_ty],
 312                                    [], "llvm.var.annotation">;
 313 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 314                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 315                                     llvm_i32_ty],
 316                                    [], "llvm.ptr.annotation">;
 317 def int_annotation : Intrinsic<[llvm_anyint_ty],
 318                                [LLVMMatchType<0>, llvm_ptr_ty,
 319                                 llvm_ptr_ty, llvm_i32_ty],
 320                                [], "llvm.annotation">;
 321
 322 //===------------------------ Trampoline Intrinsics -----------------------===//
 323 //
 324 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 325                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 326                                     [IntrWriteArgMem]>,
 327                           GCCBuiltin<"__builtin_init_trampoline">;
 328
 329 //===------------------------ Overflow Intrinsics -------------------------===//
 330 //
 331
 332 // Expose the carry flag from add operations on two integrals.
 333 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 334                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 335 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 336                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 337
 338 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 339                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 340 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 341                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 342
 343 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 344                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 345 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 346                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 347
 348 //===------------------------- Atomic Intrinsics --------------------------===//
 349 //
 350 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 351                                    [llvm_i1_ty, llvm_i1_ty,
 352                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 353                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 354
 355 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 356                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 357                                      LLVMMatchType<0>, LLVMMatchType<0>],
 358                                     [IntrWriteArgMem, NoCapture<0>]>,
 359                            GCCBuiltin<"__sync_val_compare_and_swap">;
 360 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 361                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 362                                      LLVMMatchType<0>],
 363                                     [IntrWriteArgMem, NoCapture<0>]>,
 364                            GCCBuiltin<"__sync_fetch_and_add">;
 365 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 366                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 367                                      LLVMMatchType<0>],
 368                                     [IntrWriteArgMem, NoCapture<0>]>,
 369                            GCCBuiltin<"__sync_lock_test_and_set">;
 370 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 371                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 372                                      LLVMMatchType<0>],
 373                                     [IntrWriteArgMem, NoCapture<0>]>,
 374                            GCCBuiltin<"__sync_fetch_and_sub">;
 375 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 376                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 377                                      LLVMMatchType<0>],
 378                                     [IntrWriteArgMem, NoCapture<0>]>,
 379                            GCCBuiltin<"__sync_fetch_and_and">;
 380 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 381                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 382                                       LLVMMatchType<0>],
 383                                      [IntrWriteArgMem, NoCapture<0>]>,
 384                            GCCBuiltin<"__sync_fetch_and_or">;
 385 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 386                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 387                                      LLVMMatchType<0>],
 388                                     [IntrWriteArgMem, NoCapture<0>]>,
 389                            GCCBuiltin<"__sync_fetch_and_xor">;
 390 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 391                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 392                                       LLVMMatchType<0>],
 393                                      [IntrWriteArgMem, NoCapture<0>]>,
 394                            GCCBuiltin<"__sync_fetch_and_nand">;
 395 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 396                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 397                                       LLVMMatchType<0>],
 398                                      [IntrWriteArgMem, NoCapture<0>]>,
 399                            GCCBuiltin<"__sync_fetch_and_min">;
 400 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 401                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 402                                       LLVMMatchType<0>],
 403                                      [IntrWriteArgMem, NoCapture<0>]>,
 404                            GCCBuiltin<"__sync_fetch_and_max">;
 405 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 406                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 407                                       LLVMMatchType<0>],
 408                                      [IntrWriteArgMem, NoCapture<0>]>,
 409                            GCCBuiltin<"__sync_fetch_and_umin">;
 410 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 411                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 412                                       LLVMMatchType<0>],
 413                                      [IntrWriteArgMem, NoCapture<0>]>,
 414                            GCCBuiltin<"__sync_fetch_and_umax">;
 415
 416 //===-------------------------- Other Intrinsics --------------------------===//
 417 //
 418 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 419                      GCCBuiltin<"__builtin_flt_rounds">;
 420 def int_trap : Intrinsic<[llvm_void_ty]>,
 421                GCCBuiltin<"__builtin_trap">;
 422
 423 // These convert intrinsics are to support various conversions between
 424 // various types with rounding and saturation. NOTE: avoid using these
 425 // intrinsics as they might be removed sometime in the future and
 426 // most targets don't support them.
 427 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 428                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 429 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 430                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 431 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 432                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 433 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 434                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 435 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 436                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 437 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 438                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 439 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 440                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 441 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 442                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 443 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 444                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 445
 446 //===----------------------------------------------------------------------===//
 447 // Target-specific intrinsics
 448 //===----------------------------------------------------------------------===//
 449
 450 include "llvm/IntrinsicsPowerPC.td"
 451 include "llvm/IntrinsicsX86.td"
 452 include "llvm/IntrinsicsARM.td"
 453 include "llvm/IntrinsicsCellSPU.td"
 454 include "llvm/IntrinsicsAlpha.td"
 455 include "llvm/IntrinsicsXCore.td"