include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 def IntrNoReturn : IntrinsicProperty;
  59
  60 //===----------------------------------------------------------------------===//
  61 // Types used by intrinsics.
  62 //===----------------------------------------------------------------------===//
  63
  64 class LLVMType<ValueType vt> {
  65   ValueType VT = vt;
  66 }
  67
  68 class LLVMQualPointerType<LLVMType elty, int addrspace>
  69   : LLVMType<iPTR>{
  70   LLVMType ElTy = elty;
  71   int AddrSpace = addrspace;
  72 }
  73
  74 class LLVMPointerType<LLVMType elty>
  75   : LLVMQualPointerType<elty, 0>;
  76
  77 class LLVMAnyPointerType<LLVMType elty>
  78   : LLVMType<iPTRAny>{
  79   LLVMType ElTy = elty;
  80 }
  81
  82 // Match the type of another intrinsic parameter.  Number is an index into the
  83 // list of overloaded types for the intrinsic, excluding all the fixed types.
  84 // The Number value must refer to a previously listed type.  For example:
  85 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  86 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  87 // refers to the first overloaded type, which is the 2nd argument.
  88 class LLVMMatchType<int num>
  89   : LLVMType<OtherVT>{
  90   int Number = num;
  91 }
  92
  93 // Match the type of another intrinsic parameter that is expected to be
  94 // an integral vector type, but change the element size to be twice as wide
  95 // or half as wide as the other type.  This is only useful when the intrinsic
  96 // is overloaded, so the matched type should be declared as iAny.
  97 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  98 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  99
 100 def llvm_void_ty       : LLVMType<isVoid>;
 101 def llvm_anyint_ty     : LLVMType<iAny>;
 102 def llvm_anyfloat_ty   : LLVMType<fAny>;
 103 def llvm_anyvector_ty  : LLVMType<vAny>;
 104 def llvm_i1_ty         : LLVMType<i1>;
 105 def llvm_i8_ty         : LLVMType<i8>;
 106 def llvm_i16_ty        : LLVMType<i16>;
 107 def llvm_i32_ty        : LLVMType<i32>;
 108 def llvm_i64_ty        : LLVMType<i64>;
 109 def llvm_float_ty      : LLVMType<f32>;
 110 def llvm_double_ty     : LLVMType<f64>;
 111 def llvm_f80_ty        : LLVMType<f80>;
 112 def llvm_f128_ty       : LLVMType<f128>;
 113 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 114 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 115 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 116 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 117 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 118 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 119 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 120
 121 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 122 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 123
 124 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 125 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 126 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 127 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 128 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 129 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 130 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 131 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 132 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 133 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 134 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 135 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 136 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 137 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 138 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 139
 140 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 141 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 142 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 143 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 144 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 145
 146 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 147
 148
 149 //===----------------------------------------------------------------------===//
 150 // Intrinsic Definitions.
 151 //===----------------------------------------------------------------------===//
 152
 153 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 154 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 155 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 156 // example, llvm.bswap.i16 -> int_bswap_i16.
 157 //
 158 //  * RetTypes is a list containing the return types expected for the
 159 //    intrinsic.
 160 //  * ParamTypes is a list containing the parameter types expected for the
 161 //    intrinsic.
 162 //  * Properties can be set to describe the behavior of the intrinsic.
 163 //
 164 class Intrinsic<list<LLVMType> ret_types,
 165                 list<LLVMType> param_types = [],
 166                 list<IntrinsicProperty> properties = [],
 167                 string name = ""> {
 168   string LLVMName = name;
 169   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 170   list<LLVMType> RetTypes = ret_types;
 171   list<LLVMType> ParamTypes = param_types;
 172   list<IntrinsicProperty> Properties = properties;
 173
 174   bit isTarget = 0;
 175 }
 176
 177 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 178 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 179 /// support.
 180 class GCCBuiltin<string name> {
 181   string GCCBuiltinName = name;
 182 }
 183
 184
 185 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 186 //
 187
 188 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 189 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 190                             "llvm.va_copy">;
 191 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 192
 193 //===------------------- Garbage Collection Intrinsics --------------------===//
 194 //
 195 def int_gcroot  : Intrinsic<[],
 196                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 197 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 198                             [llvm_ptr_ty, llvm_ptrptr_ty],
 199                             [IntrReadArgMem]>;
 200 def int_gcwrite : Intrinsic<[],
 201                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 202                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 203
 204 //===--------------------- Code Generator Intrinsics ----------------------===//
 205 //
 206 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 207 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 208
 209 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 210 // model their dependencies on allocas.
 211 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 212                         GCCBuiltin<"__builtin_stack_save">;
 213 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 214                         GCCBuiltin<"__builtin_stack_restore">;
 215
 216 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 217 // however it does conveniently prevent the prefetch from being reordered
 218 // with respect to nearby accesses to the same memory.
 219 def int_prefetch      : Intrinsic<[],
 220                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 221                                    llvm_i32_ty],
 222                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 223 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 224
 225 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 226
 227 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 228 // guard to the correct place on the stack frame.
 229 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 230
 231 //===------------------- Standard C Library Intrinsics --------------------===//
 232 //
 233
 234 def int_memcpy  : Intrinsic<[],
 235                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 236                               llvm_i32_ty, llvm_i1_ty],
 237                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 238 def int_memmove : Intrinsic<[],
 239                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 240                              llvm_i32_ty, llvm_i1_ty],
 241                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 242 def int_memset  : Intrinsic<[],
 243                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 244                              llvm_i32_ty, llvm_i1_ty],
 245                             [IntrReadWriteArgMem, NoCapture<0>]>;
 246
 247 // These functions do not actually read memory, but they are sensitive to the
 248 // rounding mode.  This needs to be modelled separately; in the meantime
 249 // declaring them as reading memory is conservatively correct.
 250 let Properties = [IntrReadMem] in {
 251   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 253   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 254   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 255   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 256                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 257   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 258   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 259   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 260   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 261   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 262   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 263 }
 264
 265 let Properties = [IntrNoMem] in {
 266   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 267                          [LLVMMatchType<0>, LLVMMatchType<0>,
 268                           LLVMMatchType<0>]>;
 269
 270   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 271                               [LLVMMatchType<0>, LLVMMatchType<0>,
 272                                LLVMMatchType<0>]>;
 273 }
 274
 275 // NOTE: these are internal interfaces.
 276 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 277 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 278 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 279 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 280
 281 // Internal interface for object size checking
 282 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 283                                [IntrNoMem]>,
 284                                GCCBuiltin<"__builtin_object_size">;
 285
 286 //===------------------------- Expect Intrinsics --------------------------===//
 287 //
 288 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 289                                               LLVMMatchType<0>], [IntrNoMem]>;
 290
 291 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 292 //
 293
 294 // None of these intrinsics accesses memory at all.
 295 let Properties = [IntrNoMem] in {
 296   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 297   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 298   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 299   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 300 }
 301
 302 //===------------------------ Debugger Intrinsics -------------------------===//
 303 //
 304
 305 // None of these intrinsics accesses memory at all...but that doesn't mean the
 306 // optimizers can change them aggressively.  Special handling needed in a few
 307 // places.
 308 let Properties = [IntrNoMem] in {
 309   def int_dbg_declare      : Intrinsic<[],
 310                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 311   def int_dbg_value        : Intrinsic<[],
 312                                        [llvm_metadata_ty, llvm_i64_ty,
 313                                         llvm_metadata_ty]>;
 314 }
 315
 316 //===------------------ Exception Handling Intrinsics----------------------===//
 317 //
 318
 319 // The result of eh.typeid.for depends on the enclosing function, but inside a
 320 // given function it is 'const' and may be CSE'd etc.
 321 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 322
 323 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 324 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 325
 326 def int_eh_unwind_init: Intrinsic<[]>,
 327                         GCCBuiltin<"__builtin_unwind_init">;
 328
 329 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 330
 331 let Properties = [IntrNoMem] in {
 332   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 333   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 334 }
 335 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 336 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 337 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty]>;
 338
 339 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 340 //
 341 def int_var_annotation : Intrinsic<[],
 342                                    [llvm_ptr_ty, llvm_ptr_ty,
 343                                     llvm_ptr_ty, llvm_i32_ty],
 344                                    [], "llvm.var.annotation">;
 345 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 346                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 347                                     llvm_i32_ty],
 348                                    [], "llvm.ptr.annotation">;
 349 def int_annotation : Intrinsic<[llvm_anyint_ty],
 350                                [LLVMMatchType<0>, llvm_ptr_ty,
 351                                 llvm_ptr_ty, llvm_i32_ty],
 352                                [], "llvm.annotation">;
 353
 354 //===------------------------ Trampoline Intrinsics -----------------------===//
 355 //
 356 def int_init_trampoline : Intrinsic<[],
 357                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 358                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 359                                    GCCBuiltin<"__builtin_init_trampoline">;
 360
 361 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 362                                       [IntrReadArgMem]>,
 363                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 364
 365 //===------------------------ Overflow Intrinsics -------------------------===//
 366 //
 367
 368 // Expose the carry flag from add operations on two integrals.
 369 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 370                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 371                                        [IntrNoMem]>;
 372 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 373                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 374                                        [IntrNoMem]>;
 375
 376 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 377                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 378                                        [IntrNoMem]>;
 379 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 380                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 381                                        [IntrNoMem]>;
 382
 383 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 384                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 385                                        [IntrNoMem]>;
 386 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 387                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 388                                        [IntrNoMem]>;
 389
 390 //===------------------------- Memory Use Markers -------------------------===//
 391 //
 392 def int_lifetime_start  : Intrinsic<[],
 393                                     [llvm_i64_ty, llvm_ptr_ty],
 394                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 395 def int_lifetime_end    : Intrinsic<[],
 396                                     [llvm_i64_ty, llvm_ptr_ty],
 397                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 398 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 399                                     [llvm_i64_ty, llvm_ptr_ty],
 400                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 401 def int_invariant_end   : Intrinsic<[],
 402                                     [llvm_descriptor_ty, llvm_i64_ty,
 403                                      llvm_ptr_ty],
 404                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 405
 406 //===-------------------------- Other Intrinsics --------------------------===//
 407 //
 408 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 409                      GCCBuiltin<"__builtin_flt_rounds">;
 410 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 411                GCCBuiltin<"__builtin_trap">;
 412 def int_debugtrap : Intrinsic<[]>,
 413                     GCCBuiltin<"__builtin_debugtrap">;
 414
 415 // Intrisics to support half precision floating point format
 416 let Properties = [IntrNoMem] in {
 417 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 418                             GCCBuiltin<"__gnu_f2h_ieee">;
 419 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 420                             GCCBuiltin<"__gnu_h2f_ieee">;
 421 }
 422
 423 // These convert intrinsics are to support various conversions between
 424 // various types with rounding and saturation. NOTE: avoid using these
 425 // intrinsics as they might be removed sometime in the future and
 426 // most targets don't support them.
 427 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 428                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 429 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 430                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 431 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 432                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 433 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 434                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 435 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 436                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 437 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 438                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 439 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 440                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 441 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 442                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 443 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 444                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 445
 446 //===----------------------------------------------------------------------===//
 447 // Target-specific intrinsics
 448 //===----------------------------------------------------------------------===//
 449
 450 include "llvm/IntrinsicsPowerPC.td"
 451 include "llvm/IntrinsicsX86.td"
 452 include "llvm/IntrinsicsARM.td"
 453 include "llvm/IntrinsicsCellSPU.td"
 454 include "llvm/IntrinsicsXCore.td"
 455 include "llvm/IntrinsicsHexagon.td"
 456 include "llvm/IntrinsicsNVVM.td"
 457 include "llvm/IntrinsicsMips.td"