include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  51 class NoCapture<int argNo> : IntrinsicProperty {
  52   int ArgNo = argNo;
  53 }
  54
  55 //===----------------------------------------------------------------------===//
  56 // Types used by intrinsics.
  57 //===----------------------------------------------------------------------===//
  58
  59 class LLVMType<ValueType vt> {
  60   ValueType VT = vt;
  61 }
  62
  63 class LLVMPointerType<LLVMType elty>
  64   : LLVMType<iPTR>{
  65   LLVMType ElTy = elty;
  66 }
  67
  68 class LLVMAnyPointerType<LLVMType elty>
  69   : LLVMType<iPTRAny>{
  70   LLVMType ElTy = elty;
  71 }
  72
  73 // Match the type of another intrinsic parameter.  Number is an index into the
  74 // list of overloaded types for the intrinsic, excluding all the fixed types.
  75 // The Number value must refer to a previously listed type.  For example:
  76 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  77 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  78 // refers to the first overloaded type, which is the 2nd argument.
  79 class LLVMMatchType<int num>
  80   : LLVMType<OtherVT>{
  81   int Number = num;
  82 }
  83
  84 // Match the type of another intrinsic parameter that is expected to be
  85 // an integral vector type, but change the element size to be twice as wide
  86 // or half as wide as the other type.  This is only useful when the intrinsic
  87 // is overloaded, so the matched type should be declared as iAny.
  88 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  89 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  90
  91 def llvm_void_ty       : LLVMType<isVoid>;
  92 def llvm_anyint_ty     : LLVMType<iAny>;
  93 def llvm_anyfloat_ty   : LLVMType<fAny>;
  94 def llvm_anyvector_ty  : LLVMType<vAny>;
  95 def llvm_i1_ty         : LLVMType<i1>;
  96 def llvm_i8_ty         : LLVMType<i8>;
  97 def llvm_i16_ty        : LLVMType<i16>;
  98 def llvm_i32_ty        : LLVMType<i32>;
  99 def llvm_i64_ty        : LLVMType<i64>;
 100 def llvm_float_ty      : LLVMType<f32>;
 101 def llvm_double_ty     : LLVMType<f64>;
 102 def llvm_f80_ty        : LLVMType<f80>;
 103 def llvm_f128_ty       : LLVMType<f128>;
 104 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 105 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 106 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 107 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 108 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 109 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 110 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 111
 112 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 113 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 114 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 115 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 116 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 117 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  4 x i16
 118 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 119 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 120 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 121 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 122 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 123 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 124 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 125 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 126 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 127
 128 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 129 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 130 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 131 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 132 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 133
 134 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 135
 136
 137 //===----------------------------------------------------------------------===//
 138 // Intrinsic Definitions.
 139 //===----------------------------------------------------------------------===//
 140
 141 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 142 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 143 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 144 // example, llvm.bswap.i16 -> int_bswap_i16.
 145 //
 146 //  * RetTypes is a list containing the return types expected for the
 147 //    intrinsic.
 148 //  * ParamTypes is a list containing the parameter types expected for the
 149 //    intrinsic.
 150 //  * Properties can be set to describe the behavior of the intrinsic.
 151 //
 152 class Intrinsic<list<LLVMType> ret_types,
 153                 list<LLVMType> param_types = [],
 154                 list<IntrinsicProperty> properties = [],
 155                 string name = ""> {
 156   string LLVMName = name;
 157   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 158   list<LLVMType> RetTypes = ret_types;
 159   list<LLVMType> ParamTypes = param_types;
 160   list<IntrinsicProperty> Properties = properties;
 161
 162   bit isTarget = 0;
 163 }
 164
 165 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 166 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 167 /// support.
 168 class GCCBuiltin<string name> {
 169   string GCCBuiltinName = name;
 170 }
 171
 172
 173 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 174 //
 175
 176 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 177 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 178                             "llvm.va_copy">;
 179 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 180
 181 //===------------------- Garbage Collection Intrinsics --------------------===//
 182 //
 183 def int_gcroot  : Intrinsic<[],
 184                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 185 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 186                             [llvm_ptr_ty, llvm_ptrptr_ty],
 187                             [IntrReadArgMem]>;
 188 def int_gcwrite : Intrinsic<[],
 189                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 190                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 191
 192 //===--------------------- Code Generator Intrinsics ----------------------===//
 193 //
 194 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 195 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 196
 197 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 198 // model their dependencies on allocas.
 199 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 200                         GCCBuiltin<"__builtin_stack_save">;
 201 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 202                         GCCBuiltin<"__builtin_stack_restore">;
 203
 204 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 205 // however it does conveniently prevent the prefetch from being reordered
 206 // with respect to nearby accesses to the same memory.
 207 def int_prefetch      : Intrinsic<[],
 208                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 209                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 210 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 211
 212 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 213
 214 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 215 // guard to the correct place on the stack frame.
 216 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 217
 218 //===------------------- Standard C Library Intrinsics --------------------===//
 219 //
 220
 221 def int_memcpy  : Intrinsic<[],
 222                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 223                               llvm_i32_ty, llvm_i1_ty],
 224                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 225 def int_memmove : Intrinsic<[],
 226                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 227                              llvm_i32_ty, llvm_i1_ty],
 228                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 229 def int_memset  : Intrinsic<[],
 230                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 231                              llvm_i32_ty, llvm_i1_ty],
 232                             [IntrReadWriteArgMem, NoCapture<0>]>;
 233
 234 // These functions do not actually read memory, but they are sensitive to the
 235 // rounding mode.  This needs to be modelled separately; in the meantime
 236 // declaring them as reading memory is conservatively correct.
 237 let Properties = [IntrReadMem] in {
 238   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 239   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 240   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 241   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 242   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 243                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 244   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 245   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 246   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 247   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 248   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 249 }
 250
 251 // NOTE: these are internal interfaces.
 252 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 253 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 254 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 255 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 256
 257 // Internal interface for object size checking
 258 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 259                                [IntrReadArgMem]>,
 260                                GCCBuiltin<"__builtin_object_size">;
 261
 262 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 263 //
 264
 265 // None of these intrinsics accesses memory at all.
 266 let Properties = [IntrNoMem] in {
 267   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 268   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 269   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 270   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 271 }
 272
 273 //===------------------------ Debugger Intrinsics -------------------------===//
 274 //
 275
 276 // None of these intrinsics accesses memory at all...but that doesn't mean the
 277 // optimizers can change them aggressively.  Special handling needed in a few
 278 // places.
 279 let Properties = [IntrNoMem] in {
 280   def int_dbg_declare      : Intrinsic<[],
 281                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 282   def int_dbg_value        : Intrinsic<[],
 283                                        [llvm_metadata_ty, llvm_i64_ty,
 284                                         llvm_metadata_ty]>;
 285 }
 286
 287 //===------------------ Exception Handling Intrinsics----------------------===//
 288 //
 289 def int_eh_exception : Intrinsic<[llvm_ptr_ty], [], [IntrReadMem]>;
 290 def int_eh_selector  : Intrinsic<[llvm_i32_ty],
 291                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 292
 293 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 294
 295 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 296 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 297
 298 def int_eh_unwind_init: Intrinsic<[]>,
 299                         GCCBuiltin<"__builtin_unwind_init">;
 300
 301 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 302
 303 let Properties = [IntrNoMem] in {
 304   def int_eh_sjlj_lsda    : Intrinsic<[llvm_ptr_ty]>;
 305   def int_eh_sjlj_callsite: Intrinsic<[], [llvm_i32_ty]>;
 306 }
 307 def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 308 def int_eh_sjlj_longjmp : Intrinsic<[], [llvm_ptr_ty]>;
 309
 310 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 311 //
 312 def int_var_annotation : Intrinsic<[],
 313                                    [llvm_ptr_ty, llvm_ptr_ty,
 314                                     llvm_ptr_ty, llvm_i32_ty],
 315                                    [], "llvm.var.annotation">;
 316 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 317                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 318                                     llvm_i32_ty],
 319                                    [], "llvm.ptr.annotation">;
 320 def int_annotation : Intrinsic<[llvm_anyint_ty],
 321                                [LLVMMatchType<0>, llvm_ptr_ty,
 322                                 llvm_ptr_ty, llvm_i32_ty],
 323                                [], "llvm.annotation">;
 324
 325 //===------------------------ Trampoline Intrinsics -----------------------===//
 326 //
 327 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 328                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 329                                     [IntrReadWriteArgMem]>,
 330                           GCCBuiltin<"__builtin_init_trampoline">;
 331
 332 //===------------------------ Overflow Intrinsics -------------------------===//
 333 //
 334
 335 // Expose the carry flag from add operations on two integrals.
 336 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 337                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 338                                        [IntrNoMem]>;
 339 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 340                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 341                                        [IntrNoMem]>;
 342
 343 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 344                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 345                                        [IntrNoMem]>;
 346 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 347                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 348                                        [IntrNoMem]>;
 349
 350 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 351                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 352                                        [IntrNoMem]>;
 353 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 354                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 355                                        [IntrNoMem]>;
 356
 357 //===------------------------- Atomic Intrinsics --------------------------===//
 358 //
 359 def int_memory_barrier : Intrinsic<[],
 360                                    [llvm_i1_ty, llvm_i1_ty,
 361                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 362                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 363
 364 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 365                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 366                                      LLVMMatchType<0>, LLVMMatchType<0>],
 367                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 368                            GCCBuiltin<"__sync_val_compare_and_swap">;
 369 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 370                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 371                                      LLVMMatchType<0>],
 372                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 373                            GCCBuiltin<"__sync_fetch_and_add">;
 374 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 375                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 376                                      LLVMMatchType<0>],
 377                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 378                            GCCBuiltin<"__sync_lock_test_and_set">;
 379 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 380                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 381                                      LLVMMatchType<0>],
 382                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 383                            GCCBuiltin<"__sync_fetch_and_sub">;
 384 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 385                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 386                                      LLVMMatchType<0>],
 387                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 388                            GCCBuiltin<"__sync_fetch_and_and">;
 389 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 390                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 391                                       LLVMMatchType<0>],
 392                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 393                            GCCBuiltin<"__sync_fetch_and_or">;
 394 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 395                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 396                                      LLVMMatchType<0>],
 397                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 398                            GCCBuiltin<"__sync_fetch_and_xor">;
 399 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 400                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 401                                       LLVMMatchType<0>],
 402                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 403                            GCCBuiltin<"__sync_fetch_and_nand">;
 404 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 405                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 406                                       LLVMMatchType<0>],
 407                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 408                            GCCBuiltin<"__sync_fetch_and_min">;
 409 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 410                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 411                                       LLVMMatchType<0>],
 412                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 413                            GCCBuiltin<"__sync_fetch_and_max">;
 414 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 415                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 416                                       LLVMMatchType<0>],
 417                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 418                            GCCBuiltin<"__sync_fetch_and_umin">;
 419 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 420                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 421                                       LLVMMatchType<0>],
 422                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 423                            GCCBuiltin<"__sync_fetch_and_umax">;
 424
 425 //===------------------------- Memory Use Markers -------------------------===//
 426 //
 427 def int_lifetime_start  : Intrinsic<[],
 428                                     [llvm_i64_ty, llvm_ptr_ty],
 429                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 430 def int_lifetime_end    : Intrinsic<[],
 431                                     [llvm_i64_ty, llvm_ptr_ty],
 432                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 433 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 434                                     [llvm_i64_ty, llvm_ptr_ty],
 435                                     [IntrReadArgMem, NoCapture<1>]>;
 436 def int_invariant_end   : Intrinsic<[],
 437                                     [llvm_descriptor_ty, llvm_i64_ty,
 438                                      llvm_ptr_ty],
 439                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 440
 441 //===-------------------------- Other Intrinsics --------------------------===//
 442 //
 443 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 444                      GCCBuiltin<"__builtin_flt_rounds">;
 445 def int_trap : Intrinsic<[]>,
 446                GCCBuiltin<"__builtin_trap">;
 447
 448 // Intrisics to support half precision floating point format
 449 let Properties = [IntrNoMem] in {
 450 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 451                             GCCBuiltin<"__gnu_f2h_ieee">;
 452 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 453                             GCCBuiltin<"__gnu_h2f_ieee">;
 454 }
 455
 456 // These convert intrinsics are to support various conversions between
 457 // various types with rounding and saturation. NOTE: avoid using these
 458 // intrinsics as they might be removed sometime in the future and
 459 // most targets don't support them.
 460 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 461                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 462 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 463                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 464 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 465                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 466 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 467                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 468 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 469                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 470 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 471                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 472 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 473                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 474 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 475                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 476 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 477                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 478
 479 //===----------------------------------------------------------------------===//
 480 // Target-specific intrinsics
 481 //===----------------------------------------------------------------------===//
 482
 483 include "llvm/IntrinsicsPowerPC.td"
 484 include "llvm/IntrinsicsX86.td"
 485 include "llvm/IntrinsicsARM.td"
 486 include "llvm/IntrinsicsCellSPU.td"
 487 include "llvm/IntrinsicsAlpha.td"
 488 include "llvm/IntrinsicsXCore.td"