include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 def IntrNoReturn : IntrinsicProperty;
  59
  60 //===----------------------------------------------------------------------===//
  61 // Types used by intrinsics.
  62 //===----------------------------------------------------------------------===//
  63
  64 class LLVMType<ValueType vt> {
  65   ValueType VT = vt;
  66 }
  67
  68 class LLVMQualPointerType<LLVMType elty, int addrspace>
  69   : LLVMType<iPTR>{
  70   LLVMType ElTy = elty;
  71   int AddrSpace = addrspace;
  72 }
  73
  74 class LLVMPointerType<LLVMType elty>
  75   : LLVMQualPointerType<elty, 0>;
  76
  77 class LLVMAnyPointerType<LLVMType elty>
  78   : LLVMType<iPTRAny>{
  79   LLVMType ElTy = elty;
  80 }
  81
  82 // Match the type of another intrinsic parameter.  Number is an index into the
  83 // list of overloaded types for the intrinsic, excluding all the fixed types.
  84 // The Number value must refer to a previously listed type.  For example:
  85 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  86 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  87 // refers to the first overloaded type, which is the 2nd argument.
  88 class LLVMMatchType<int num>
  89   : LLVMType<OtherVT>{
  90   int Number = num;
  91 }
  92
  93 // Match the type of another intrinsic parameter that is expected to be
  94 // an integral vector type, but change the element size to be twice as wide
  95 // or half as wide as the other type.  This is only useful when the intrinsic
  96 // is overloaded, so the matched type should be declared as iAny.
  97 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  98 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  99
 100 def llvm_void_ty       : LLVMType<isVoid>;
 101 def llvm_anyint_ty     : LLVMType<iAny>;
 102 def llvm_anyfloat_ty   : LLVMType<fAny>;
 103 def llvm_anyvector_ty  : LLVMType<vAny>;
 104 def llvm_i1_ty         : LLVMType<i1>;
 105 def llvm_i8_ty         : LLVMType<i8>;
 106 def llvm_i16_ty        : LLVMType<i16>;
 107 def llvm_i32_ty        : LLVMType<i32>;
 108 def llvm_i64_ty        : LLVMType<i64>;
 109 def llvm_float_ty      : LLVMType<f32>;
 110 def llvm_double_ty     : LLVMType<f64>;
 111 def llvm_f80_ty        : LLVMType<f80>;
 112 def llvm_f128_ty       : LLVMType<f128>;
 113 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 114 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 115 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 116 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 117 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 118 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 119 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 120
 121 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 122 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 123
 124 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 125 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 126 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 127 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 128 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 129 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 130 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 131 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 132 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 133 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 134 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 135 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 136 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 137 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 138 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 139
 140 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 141 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 142 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 143 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 144 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 145
 146 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 147
 148
 149 //===----------------------------------------------------------------------===//
 150 // Intrinsic Definitions.
 151 //===----------------------------------------------------------------------===//
 152
 153 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 154 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 155 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 156 // example, llvm.bswap.i16 -> int_bswap_i16.
 157 //
 158 //  * RetTypes is a list containing the return types expected for the
 159 //    intrinsic.
 160 //  * ParamTypes is a list containing the parameter types expected for the
 161 //    intrinsic.
 162 //  * Properties can be set to describe the behavior of the intrinsic.
 163 //
 164 class SDPatternOperator;
 165 class Intrinsic<list<LLVMType> ret_types,
 166                 list<LLVMType> param_types = [],
 167                 list<IntrinsicProperty> properties = [],
 168                 string name = ""> : SDPatternOperator {
 169   string LLVMName = name;
 170   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 171   list<LLVMType> RetTypes = ret_types;
 172   list<LLVMType> ParamTypes = param_types;
 173   list<IntrinsicProperty> Properties = properties;
 174
 175   bit isTarget = 0;
 176 }
 177
 178 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 179 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 180 /// support.
 181 class GCCBuiltin<string name> {
 182   string GCCBuiltinName = name;
 183 }
 184
 185
 186 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 187 //
 188
 189 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 190 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 191                             "llvm.va_copy">;
 192 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 193
 194 //===------------------- Garbage Collection Intrinsics --------------------===//
 195 //
 196 def int_gcroot  : Intrinsic<[],
 197                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 198 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 199                             [llvm_ptr_ty, llvm_ptrptr_ty],
 200                             [IntrReadArgMem]>;
 201 def int_gcwrite : Intrinsic<[],
 202                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 203                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 204
 205 //===--------------------- Code Generator Intrinsics ----------------------===//
 206 //
 207 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 208 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 209
 210 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 211 // model their dependencies on allocas.
 212 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 213                         GCCBuiltin<"__builtin_stack_save">;
 214 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 215                         GCCBuiltin<"__builtin_stack_restore">;
 216
 217 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 218 // however it does conveniently prevent the prefetch from being reordered
 219 // with respect to nearby accesses to the same memory.
 220 def int_prefetch      : Intrinsic<[],
 221                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 222                                    llvm_i32_ty],
 223                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 224 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 225
 226 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 227
 228 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 229 // guard to the correct place on the stack frame.
 230 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 231
 232 //===------------------- Standard C Library Intrinsics --------------------===//
 233 //
 234
 235 def int_memcpy  : Intrinsic<[],
 236                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 237                               llvm_i32_ty, llvm_i1_ty],
 238                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 239 def int_memmove : Intrinsic<[],
 240                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 241                              llvm_i32_ty, llvm_i1_ty],
 242                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 243 def int_memset  : Intrinsic<[],
 244                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 245                              llvm_i32_ty, llvm_i1_ty],
 246                             [IntrReadWriteArgMem, NoCapture<0>]>;
 247
 248 // These functions do not actually read memory, but they are sensitive to the
 249 // rounding mode.  This needs to be modelled separately; in the meantime
 250 // declaring them as reading memory is conservatively correct.
 251 let Properties = [IntrReadMem] in {
 252   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 253   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 254   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 255   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 256   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 257                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 258   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 259   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 260   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 261   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 262   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 263   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 264   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 265 }
 266
 267 let Properties = [IntrNoMem] in {
 268   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 269                          [LLVMMatchType<0>, LLVMMatchType<0>,
 270                           LLVMMatchType<0>]>;
 271
 272   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 273                               [LLVMMatchType<0>, LLVMMatchType<0>,
 274                                LLVMMatchType<0>]>;
 275 }
 276
 277 // NOTE: these are internal interfaces.
 278 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 279 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 280 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 281 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 282
 283 // Internal interface for object size checking
 284 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 285                                [IntrNoMem]>,
 286                                GCCBuiltin<"__builtin_object_size">;
 287
 288 //===------------------------- Expect Intrinsics --------------------------===//
 289 //
 290 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 291                                               LLVMMatchType<0>], [IntrNoMem]>;
 292
 293 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 294 //
 295
 296 // None of these intrinsics accesses memory at all.
 297 let Properties = [IntrNoMem] in {
 298   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 299   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 300   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 301   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 302 }
 303
 304 //===------------------------ Debugger Intrinsics -------------------------===//
 305 //
 306
 307 // None of these intrinsics accesses memory at all...but that doesn't mean the
 308 // optimizers can change them aggressively.  Special handling needed in a few
 309 // places.
 310 let Properties = [IntrNoMem] in {
 311   def int_dbg_declare      : Intrinsic<[],
 312                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 313   def int_dbg_value        : Intrinsic<[],
 314                                        [llvm_metadata_ty, llvm_i64_ty,
 315                                         llvm_metadata_ty]>;
 316 }
 317
 318 //===------------------ Exception Handling Intrinsics----------------------===//
 319 //
 320
 321 // The result of eh.typeid.for depends on the enclosing function, but inside a
 322 // given function it is 'const' and may be CSE'd etc.
 323 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 324
 325 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 326 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 327
 328 def int_eh_unwind_init: Intrinsic<[]>,
 329                         GCCBuiltin<"__builtin_unwind_init">;
 330
 331 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 332
 333 let Properties = [IntrNoMem] in {
 334   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 335   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 336 }
 337 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 338 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 339 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty]>;
 340
 341 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 342 //
 343 def int_var_annotation : Intrinsic<[],
 344                                    [llvm_ptr_ty, llvm_ptr_ty,
 345                                     llvm_ptr_ty, llvm_i32_ty],
 346                                    [], "llvm.var.annotation">;
 347 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 348                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 349                                     llvm_i32_ty],
 350                                    [], "llvm.ptr.annotation">;
 351 def int_annotation : Intrinsic<[llvm_anyint_ty],
 352                                [LLVMMatchType<0>, llvm_ptr_ty,
 353                                 llvm_ptr_ty, llvm_i32_ty],
 354                                [], "llvm.annotation">;
 355
 356 //===------------------------ Trampoline Intrinsics -----------------------===//
 357 //
 358 def int_init_trampoline : Intrinsic<[],
 359                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 360                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 361                                    GCCBuiltin<"__builtin_init_trampoline">;
 362
 363 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 364                                       [IntrReadArgMem]>,
 365                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 366
 367 //===------------------------ Overflow Intrinsics -------------------------===//
 368 //
 369
 370 // Expose the carry flag from add operations on two integrals.
 371 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 372                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 373                                        [IntrNoMem]>;
 374 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 375                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 376                                        [IntrNoMem]>;
 377
 378 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 379                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 380                                        [IntrNoMem]>;
 381 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 382                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 383                                        [IntrNoMem]>;
 384
 385 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 386                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 387                                        [IntrNoMem]>;
 388 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 389                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 390                                        [IntrNoMem]>;
 391
 392 //===------------------------- Memory Use Markers -------------------------===//
 393 //
 394 def int_lifetime_start  : Intrinsic<[],
 395                                     [llvm_i64_ty, llvm_ptr_ty],
 396                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 397 def int_lifetime_end    : Intrinsic<[],
 398                                     [llvm_i64_ty, llvm_ptr_ty],
 399                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 400 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 401                                     [llvm_i64_ty, llvm_ptr_ty],
 402                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 403 def int_invariant_end   : Intrinsic<[],
 404                                     [llvm_descriptor_ty, llvm_i64_ty,
 405                                      llvm_ptr_ty],
 406                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 407
 408 //===-------------------------- Other Intrinsics --------------------------===//
 409 //
 410 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 411                      GCCBuiltin<"__builtin_flt_rounds">;
 412 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 413                GCCBuiltin<"__builtin_trap">;
 414 def int_debugtrap : Intrinsic<[]>,
 415                     GCCBuiltin<"__builtin_debugtrap">;
 416
 417 // NOP: calls/invokes to this intrinsic are removed by codegen
 418 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 419
 420 // Intrisics to support half precision floating point format
 421 let Properties = [IntrNoMem] in {
 422 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 423                             GCCBuiltin<"__gnu_f2h_ieee">;
 424 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 425                             GCCBuiltin<"__gnu_h2f_ieee">;
 426 }
 427
 428 // These convert intrinsics are to support various conversions between
 429 // various types with rounding and saturation. NOTE: avoid using these
 430 // intrinsics as they might be removed sometime in the future and
 431 // most targets don't support them.
 432 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 433                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 434 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 435                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 436 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 437                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 438 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 439                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 440 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 441                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 442 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 443                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 444 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 445                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 446 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 447                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 448 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 449                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 450
 451 //===----------------------------------------------------------------------===//
 452 // Target-specific intrinsics
 453 //===----------------------------------------------------------------------===//
 454
 455 include "llvm/IntrinsicsPowerPC.td"
 456 include "llvm/IntrinsicsX86.td"
 457 include "llvm/IntrinsicsARM.td"
 458 include "llvm/IntrinsicsCellSPU.td"
 459 include "llvm/IntrinsicsXCore.td"
 460 include "llvm/IntrinsicsHexagon.td"
 461 include "llvm/IntrinsicsNVVM.td"
 462 include "llvm/IntrinsicsMips.td"