include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt> {
  56   ValueType VT = vt;
  57 }
  58
  59 class LLVMPointerType<LLVMType elty>
  60   : LLVMType<iPTR>{
  61   LLVMType ElTy = elty;
  62 }
  63
  64 class LLVMMatchType<int num>
  65   : LLVMType<OtherVT>{
  66   int Number = num;
  67 }
  68
  69 def llvm_void_ty       : LLVMType<isVoid>;
  70 def llvm_anyint_ty     : LLVMType<iAny>;
  71 def llvm_anyfloat_ty   : LLVMType<fAny>;
  72 def llvm_i1_ty         : LLVMType<i1>;
  73 def llvm_i8_ty         : LLVMType<i8>;
  74 def llvm_i16_ty        : LLVMType<i16>;
  75 def llvm_i32_ty        : LLVMType<i32>;
  76 def llvm_i64_ty        : LLVMType<i64>;
  77 def llvm_float_ty      : LLVMType<f32>;
  78 def llvm_double_ty     : LLVMType<f64>;
  79 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  80 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  81 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
  82 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  83
  84 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
  85 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
  86 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
  87 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
  88 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
  89 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
  90 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
  91 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
  92
  93 // MMX Vector Types
  94 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
  95 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
  96
  97 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
  98
  99 //===----------------------------------------------------------------------===//
 100 // Intrinsic Definitions.
 101 //===----------------------------------------------------------------------===//
 102
 103 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 104 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 105 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 106 // example, llvm.bswap.i16 -> int_bswap_i16.
 107 //
 108 //  * Types is a list containing the return type and the argument types
 109 //    expected for the intrinsic.
 110 //  * Properties can be set to describe the behavior of the intrinsic.
 111 //
 112 class Intrinsic<list<LLVMType> types,
 113                 list<IntrinsicProperty> properties = [],
 114                 string name = ""> {
 115   string LLVMName = name;
 116   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 117   list<LLVMType> Types = types;
 118   list<IntrinsicProperty> Properties = properties;
 119 }
 120
 121 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 122 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 123 /// support.
 124 class GCCBuiltin<string name> {
 125   string GCCBuiltinName = name;
 126 }
 127
 128
 129 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 130 //
 131
 132 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_start">;
 133 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty], [],
 134                             "llvm.va_copy">;
 135 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_end">;
 136
 137 //===------------------- Garbage Collection Intrinsics --------------------===//
 138 //
 139 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 140 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 141                             [IntrReadArgMem]>;
 142 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 143                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 144
 145 //===--------------------- Code Generator Intrinsics ----------------------===//
 146 //
 147 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 148 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 149 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>,
 150                         GCCBuiltin<"__builtin_stack_save">;
 151 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 152                         GCCBuiltin<"__builtin_stack_restore">;
 153 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 154                                    llvm_i32_ty, llvm_i32_ty]>;
 155 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 156
 157 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 158
 159 //===------------------- Standard C Library Intrinsics --------------------===//
 160 //
 161
 162 let Properties = [IntrWriteArgMem] in {
 163   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 164                                    llvm_i32_ty, llvm_i32_ty]>;
 165   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 166                                    llvm_i64_ty, llvm_i32_ty]>;
 167   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 168                                    llvm_i32_ty, llvm_i32_ty]>;
 169   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 170                                    llvm_i64_ty, llvm_i32_ty]>;
 171   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 172                                    llvm_i32_ty, llvm_i32_ty]>;
 173   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 174                                    llvm_i64_ty, llvm_i32_ty]>;
 175 }
 176
 177 let Properties = [IntrNoMem] in {
 178   def int_sqrt_f32 : Intrinsic<[llvm_float_ty, llvm_float_ty]>;
 179   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 180
 181   def int_powi_f32 : Intrinsic<[llvm_float_ty, llvm_float_ty, llvm_i32_ty]>;
 182   def int_powi_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty, llvm_i32_ty]>;
 183 }
 184
 185 // NOTE: these are internal interfaces.
 186 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 187 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 188 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 189 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 190
 191 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 192 //
 193
 194 // None of these intrinsics accesses memory at all.
 195 let Properties = [IntrNoMem] in {
 196   def int_bswap: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 197   def int_ctpop: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 198   def int_ctlz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 199   def int_cttz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 200   def int_part_select :
 201      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 202   def int_part_set :
 203      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_anyint_ty, llvm_i32_ty,
 204                 llvm_i32_ty]>;
 205 }
 206
 207 //===------------------------ Debugger Intrinsics -------------------------===//
 208 //
 209
 210 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 211                                       llvm_i32_ty, llvm_i32_ty,
 212                                       llvm_descriptor_ty]>;
 213 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 214 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 215 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 216 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_descriptor_ty,
 217                                                     llvm_descriptor_ty]>;
 218
 219 //===------------------ Exception Handling Intrinsics----------------------===//
 220 //
 221 def int_eh_exception     : Intrinsic<[llvm_ptr_ty]>;
 222 def int_eh_selector_i32  : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 223                                                    llvm_vararg_ty]>;
 224 def int_eh_selector_i64  : Intrinsic<[llvm_i64_ty, llvm_ptr_ty, llvm_ptr_ty,
 225                                                    llvm_vararg_ty]>;
 226
 227 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty, llvm_ptr_ty]>;
 228 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty, llvm_ptr_ty]>;
 229
 230 def int_eh_return     : Intrinsic<[llvm_void_ty, llvm_i32_ty, llvm_ptr_ty]>,
 231                         GCCBuiltin<"__builtin_eh_return">;
 232
 233 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 234                         GCCBuiltin<"__builtin_unwind_init">;
 235
 236 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty]>;
 237
 238 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 239 //
 240 def int_var_annotation : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 241                                     llvm_ptr_ty, llvm_i32_ty],
 242                                     [], "llvm.var.annotation">;
 243
 244 //===------------------------ Trampoline Intrinsics -----------------------===//
 245 //
 246 def int_init_trampoline : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty,
 247                                      llvm_ptr_ty], []>,
 248                           GCCBuiltin<"__builtin_init_trampoline">;
 249
 250 //===----------------------------------------------------------------------===//
 251 // Target-specific intrinsics
 252 //===----------------------------------------------------------------------===//
 253
 254 include "llvm/IntrinsicsPowerPC.td"
 255 include "llvm/IntrinsicsX86.td"