include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 //  Properties we keep track of for intrinsics.
  16 //===----------------------------------------------------------------------===//
  17
  18 class IntrinsicProperty;
  19
  20 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  21 // these properties set.  They are listed from the most aggressive (best to use
  22 // if correct) to the least aggressive.  If no property is set, the worst case
  23 // is assumed (IntrWriteMem).
  24
  25 // InstrNoMem - The intrinsic does not access memory or have any other side
  26 // effects.  It may be CSE'd deleted if dead, etc.
  27 def InstrNoMem : IntrinsicProperty;
  28
  29 // InstrReadArgMem - This intrinsic reads only from memory that one of its
  30 // arguments points to, but may read an unspecified amount.
  31 def InstrReadArgMem : IntrinsicProperty;
  32
  33 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  34 // moved across stores.  However, it can be reordered otherwise and can be
  35 // deleted if dead.
  36 def IntrReadMem : IntrinsicProperty;
  37
  38 // InstrWriteArgMem - This intrinsic reads and writes only from memory that one
  39 // of its arguments points to, but may access an unspecified amount.  It has no
  40 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  41 // the argument pointer (e.g. storing it someplace).
  42 def InstrWriteArgMem : IntrinsicProperty;
  43
  44 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  45 // other side effects.  It cannot be modified by the optimizer.  This is the
  46 // default if the intrinsic has no other Intr*Mem property.
  47 def IntrWriteMem : IntrinsicProperty;
  48
  49 //===----------------------------------------------------------------------===//
  50 // Types used by intrinsics.
  51 //===----------------------------------------------------------------------===//
  52
  53 class LLVMType<string typeval> {
  54   string TypeVal = typeval;
  55 }
  56
  57 class LLVMPackedType<int numelts, LLVMType elty> : LLVMType<"Type::PackedTyID">{
  58   int NumElts = numelts;
  59   LLVMType ElTy = elty;
  60 }
  61
  62 def llvm_void_ty       : LLVMType<"Type::VoidTyID">;
  63 def llvm_bool_ty       : LLVMType<"Type::BoolTyID">;
  64 def llvm_sbyte_ty      : LLVMType<"Type::SByteTyID">;
  65 def llvm_short_ty      : LLVMType<"Type::ShortTyID">;
  66 def llvm_int_ty        : LLVMType<"Type::IntTyID">;
  67 def llvm_long_ty       : LLVMType<"Type::LongTyID">;
  68 def llvm_ubyte_ty      : LLVMType<"Type::UByteTyID">;
  69 def llvm_ushort_ty     : LLVMType<"Type::UShortTyID">;
  70 def llvm_uint_ty       : LLVMType<"Type::UIntTyID">;
  71 def llvm_ulong_ty      : LLVMType<"Type::ULongTyID">;
  72 def llvm_float_ty      : LLVMType<"Type::FloatTyID">;
  73 def llvm_double_ty     : LLVMType<"Type::DoubleTyID">;
  74 def llvm_ptr_ty        : LLVMType<"Type::PointerTyID">;     // sbyte*
  75 def llvm_ptrptr_ty     : LLVMType<"Type::PointerTyID">;     // sbyte**
  76 def llvm_descriptor_ty : LLVMType<"Type::PointerTyID">;     // global*
  77
  78 def llvm_v4i32_ty      : LLVMPackedType<4, llvm_int_ty>;    // 4 x int
  79 def llvm_v4f32_ty      : LLVMPackedType<4, llvm_float_ty>;  // 4 x float
  80 def llvm_v2f64_ty      : LLVMPackedType<4, llvm_double_ty>; // 2 x double
  81
  82 //===----------------------------------------------------------------------===//
  83 // Intrinsic Definitions.
  84 //===----------------------------------------------------------------------===//
  85
  86 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  87 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  88 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  89 // example, llvm.bswap.i16 -> int_bswap_i16.
  90 //
  91 //  * Types is a list containing the return type and the argument types
  92 //    expected for the intrinsic.
  93 //  * Properties can be set to describe the behavior of the intrinsic.
  94 //
  95 class Intrinsic<list<LLVMType> types,
  96                 list<IntrinsicProperty> properties = [],
  97                 string name = ""> {
  98   string LLVMName = name;
  99   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 100   list<LLVMType> Types = types;
 101   list<IntrinsicProperty> Properties = properties;
 102 }
 103
 104 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 105 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 106 /// support.
 107 class GCCBuiltin<string name> {
 108   string GCCBuiltinName = name;
 109 }
 110
 111
 112 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 113 //
 114
 115 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 116 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 117                             "llvm.va_copy">;
 118 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 119
 120 //===------------------- Garbage Collection Intrinsics --------------------===//
 121 //
 122 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 123 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 124                             [InstrReadArgMem]>;
 125 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 126                              llvm_ptrptr_ty], [InstrWriteArgMem]>;
 127
 128 //===--------------------- Code Generator Intrinsics ----------------------===//
 129 //
 130 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 131 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 132 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>;
 133 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>;
 134 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 135                                    llvm_uint_ty, llvm_uint_ty]>;
 136 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_uint_ty]>;
 137
 138 def int_readcyclecounter : Intrinsic<[llvm_ulong_ty]>;
 139
 140 //===------------------- Standard C Library Intrinsics --------------------===//
 141 //
 142
 143 let Properties = [InstrWriteArgMem] in {
 144   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 145                                    llvm_uint_ty, llvm_uint_ty]>;
 146   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 147                                    llvm_ulong_ty, llvm_uint_ty]>;
 148   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 149                                    llvm_uint_ty, llvm_uint_ty]>;
 150   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 151                                    llvm_ulong_ty, llvm_uint_ty]>;
 152   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 153                                    llvm_uint_ty, llvm_uint_ty]>;
 154   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 155                                    llvm_ulong_ty, llvm_uint_ty]>;
 156 }
 157
 158 let Properties = [InstrNoMem] in {
 159   def int_isunordered_f32 : Intrinsic<[llvm_bool_ty,
 160                                        llvm_float_ty,  llvm_float_ty]>;
 161   def int_isunordered_f64 : Intrinsic<[llvm_bool_ty,
 162                                        llvm_double_ty, llvm_double_ty]>;
 163   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 164   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 165 }
 166
 167 // NOTE: these are internal interfaces.
 168 def int_setjmp     : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 169 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 170 def int_sigsetjmp  : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 171 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 172
 173 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 174 //
 175
 176 // None of these intrinsics accesses memory at all.
 177 let Properties = [InstrNoMem] in {
 178   def int_bswap_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 179   def int_bswap_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 180   def int_bswap_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 181
 182   def int_ctpop_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 183   def int_ctpop_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 184   def int_ctpop_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 185   def int_ctpop_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 186
 187   def int_ctlz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 188   def int_ctlz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 189   def int_ctlz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 190   def int_ctlz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 191
 192   def int_cttz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 193   def int_cttz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 194   def int_cttz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 195   def int_cttz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 196 }
 197
 198 //===------------------------ Debugger Intrinsics -------------------------===//
 199 //
 200
 201 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 202                                       llvm_uint_ty, llvm_uint_ty,
 203                                       llvm_descriptor_ty]>;
 204 def int_dbg_region_start : Intrinsic<[llvm_void_ty]>;
 205 def int_dbg_region_end   : Intrinsic<[llvm_void_ty]>;
 206 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 207
 208
 209 //===----------------------------------------------------------------------===//
 210 // Target-specific intrinsics
 211 //===----------------------------------------------------------------------===//
 212
 213 //===----------------------------------------------------------------------===//
 214 // PowerPC Intrinsics
 215 //
 216 let TargetPrefix = "ppc" in {  // All intrinsics start with "llvm.ppc.".
 217   def int_ppc_altivec_lvx : GCCBuiltin<"__builtin_altivec_lvx">,
 218               Intrinsic<[llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 219                         [IntrReadMem]>;
 220   def int_ppc_altivec_stvx : GCCBuiltin<"__builtin_altivec_stvx">,
 221               Intrinsic<[llvm_void_ty, llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 222                         [IntrWriteMem]>;
 223
 224   def int_ppc_altivec_vmaddfp : GCCBuiltin<"__builtin_altivec_vmaddfp">,
 225               Intrinsic<[llvm_v4f32_ty, llvm_v4f32_ty,
 226                          llvm_v4f32_ty, llvm_v4f32_ty], [InstrNoMem]>;
 227   def int_ppc_altivec_vadduwm : GCCBuiltin<"__builtin_altivec_vadduwm">,
 228               Intrinsic<[llvm_v4i32_ty, llvm_v4i32_ty, llvm_v4i32_ty],
 229                         [InstrNoMem]>;
 230
 231 }