include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt, string typeval> {
  56   ValueType VT = vt;
  57   string TypeVal = typeval;
  58 }
  59
  60 class LLVMIntegerType<ValueType VT, int width>
  61   : LLVMType<VT, "Type::IntegerTyID"> {
  62   int Width = width;
  63 }
  64
  65 class LLVMPackedType<ValueType VT, int numelts, LLVMType elty>
  66   : LLVMType<VT, "Type::PackedTyID">{
  67   int NumElts = numelts;
  68   LLVMType ElTy = elty;
  69 }
  70
  71 def llvm_void_ty       : LLVMType<isVoid, "Type::VoidTyID">;
  72 def llvm_bool_ty       : LLVMIntegerType<i1, 1>;
  73 def llvm_i8_ty         : LLVMIntegerType<i8 , 8>;
  74 def llvm_i16_ty        : LLVMIntegerType<i16, 16>;
  75 def llvm_i32_ty        : LLVMIntegerType<i32, 32>;
  76 def llvm_i64_ty        : LLVMIntegerType<i64, 64>;
  77 def llvm_float_ty      : LLVMType<f32, "Type::FloatTyID">;
  78 def llvm_double_ty     : LLVMType<f64, "Type::DoubleTyID">;
  79 def llvm_ptr_ty        : LLVMType<iPTR, "Type::PointerTyID">;     // i8*
  80 def llvm_ptrptr_ty     : LLVMType<iPTR, "Type::PointerTyID">;     // i8**
  81 def llvm_descriptor_ty : LLVMType<iPTR, "Type::PointerTyID">;     // global*
  82
  83 def llvm_v16i8_ty      : LLVMPackedType<v16i8,16, llvm_i8_ty>;    // 16 x i8
  84 def llvm_v8i16_ty      : LLVMPackedType<v8i16, 8, llvm_i16_ty>;   //  8 x i16
  85 def llvm_v2i64_ty      : LLVMPackedType<v2i64, 2, llvm_i64_ty>;   //  2 x i64
  86 def llvm_v2i32_ty      : LLVMPackedType<v2i32, 2, llvm_i32_ty>;   //  2 x i32
  87 def llvm_v4i32_ty      : LLVMPackedType<v4i32, 4, llvm_i32_ty>;   //  4 x i32
  88 def llvm_v4f32_ty      : LLVMPackedType<v4f32, 4, llvm_float_ty>; //  4 x float
  89 def llvm_v2f64_ty      : LLVMPackedType<v2f64, 2, llvm_double_ty>;//  2 x double
  90
  91 //===----------------------------------------------------------------------===//
  92 // Intrinsic Definitions.
  93 //===----------------------------------------------------------------------===//
  94
  95 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  96 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  97 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  98 // example, llvm.bswap.i16 -> int_bswap_i16.
  99 //
 100 //  * Types is a list containing the return type and the argument types
 101 //    expected for the intrinsic.
 102 //  * Properties can be set to describe the behavior of the intrinsic.
 103 //
 104 class Intrinsic<list<LLVMType> types,
 105                 list<IntrinsicProperty> properties = [],
 106                 string name = ""> {
 107   string LLVMName = name;
 108   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 109   list<LLVMType> Types = types;
 110   list<IntrinsicProperty> Properties = properties;
 111 }
 112
 113 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 114 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 115 /// support.
 116 class GCCBuiltin<string name> {
 117   string GCCBuiltinName = name;
 118 }
 119
 120
 121 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 122 //
 123
 124 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 125 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 126                             "llvm.va_copy">;
 127 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 128
 129 //===------------------- Garbage Collection Intrinsics --------------------===//
 130 //
 131 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 132 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 133                             [IntrReadArgMem]>;
 134 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 135                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 136
 137 //===--------------------- Code Generator Intrinsics ----------------------===//
 138 //
 139 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 140 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 141 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>,
 142                         GCCBuiltin<"__builtin_stack_save">;
 143 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 144                         GCCBuiltin<"__builtin_stack_restore">;
 145 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 146                                    llvm_i32_ty, llvm_i32_ty]>;
 147 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 148
 149 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 150
 151 //===------------------- Standard C Library Intrinsics --------------------===//
 152 //
 153
 154 let Properties = [IntrWriteArgMem] in {
 155   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 156                                    llvm_i32_ty, llvm_i32_ty]>;
 157   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 158                                    llvm_i64_ty, llvm_i32_ty]>;
 159   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 160                                    llvm_i32_ty, llvm_i32_ty]>;
 161   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 162                                    llvm_i64_ty, llvm_i32_ty]>;
 163   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 164                                    llvm_i32_ty, llvm_i32_ty]>;
 165   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 166                                    llvm_i64_ty, llvm_i32_ty]>;
 167 }
 168
 169 let Properties = [IntrNoMem] in {
 170   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 171   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 172
 173   def int_powi_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty, llvm_i32_ty]>;
 174   def int_powi_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty, llvm_i32_ty]>;
 175 }
 176
 177 // NOTE: these are internal interfaces.
 178 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 179 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 180 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 181 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 182
 183 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 184 //
 185
 186 // None of these intrinsics accesses memory at all.
 187 let Properties = [IntrNoMem] in {
 188   def int_bswap_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 189   def int_bswap_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 190   def int_bswap_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 191
 192   def int_ctpop_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 193   def int_ctpop_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 194   def int_ctpop_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 195   def int_ctpop_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 196
 197   def int_ctlz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 198   def int_ctlz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 199   def int_ctlz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 200   def int_ctlz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 201
 202   def int_cttz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 203   def int_cttz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 204   def int_cttz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 205   def int_cttz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 206 }
 207
 208 //===------------------------ Debugger Intrinsics -------------------------===//
 209 //
 210
 211 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 212                                       llvm_i32_ty, llvm_i32_ty,
 213                                       llvm_descriptor_ty]>;
 214 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 215 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 216 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 217 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 218                                                     llvm_descriptor_ty]>;
 219
 220 //===----------------------------------------------------------------------===//
 221 // Target-specific intrinsics
 222 //===----------------------------------------------------------------------===//
 223
 224 include "llvm/IntrinsicsPowerPC.td"
 225 include "llvm/IntrinsicsX86.td"