include/llvm/IntrinsicsARM.td

   1 //===- IntrinsicsARM.td - Defines ARM intrinsics -----------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines all of the ARM-specific intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14
  15 //===----------------------------------------------------------------------===//
  16 // TLS
  17
  18 let TargetPrefix = "arm" in {  // All intrinsics start with "llvm.arm.".
  19   def int_arm_thread_pointer : GCCBuiltin<"__builtin_thread_pointer">,
  20               Intrinsic<[llvm_ptr_ty], [], [IntrNoMem]>;
  21 }
  22
  23 //===----------------------------------------------------------------------===//
  24 // Saturating Arithmentic
  25
  26 let TargetPrefix = "arm" in {  // All intrinsics start with "llvm.arm.".
  27   def int_arm_qadd : GCCBuiltin<"__builtin_arm_qadd">,
  28               Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_i32_ty],
  29                         [IntrNoMem, Commutative]>;
  30   def int_arm_qsub : GCCBuiltin<"__builtin_arm_qsub">,
  31               Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_i32_ty], [IntrNoMem]>;
  32   def int_arm_ssat : GCCBuiltin<"__builtin_arm_ssat">,
  33               Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_i32_ty], [IntrNoMem]>;
  34   def int_arm_usat : GCCBuiltin<"__builtin_arm_usat">,
  35               Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_i32_ty], [IntrNoMem]>;
  36 }
  37
  38 //===----------------------------------------------------------------------===//
  39 // VFP
  40
  41 let TargetPrefix = "arm" in {  // All intrinsics start with "llvm.arm.".
  42   def int_arm_get_fpscr : GCCBuiltin<"__builtin_arm_get_fpscr">,
  43                          Intrinsic<[llvm_i32_ty], [], [IntrNoMem]>;
  44   def int_arm_set_fpscr : GCCBuiltin<"__builtin_arm_set_fpscr">,
  45                          Intrinsic<[], [llvm_i32_ty], []>;
  46   def int_arm_vcvtr     : Intrinsic<[llvm_float_ty], [llvm_anyfloat_ty],
  47                                     [IntrNoMem]>;
  48   def int_arm_vcvtru    : Intrinsic<[llvm_float_ty], [llvm_anyfloat_ty],
  49                                     [IntrNoMem]>;
  50 }
  51
  52 //===----------------------------------------------------------------------===//
  53 // Advanced SIMD (NEON)
  54
  55 let TargetPrefix = "arm" in {  // All intrinsics start with "llvm.arm.".
  56
  57   // The following classes do not correspond directly to GCC builtins.
  58   class Neon_1Arg_Intrinsic
  59     : Intrinsic<[llvm_anyvector_ty], [LLVMMatchType<0>], [IntrNoMem]>;
  60   class Neon_1Arg_Narrow_Intrinsic
  61     : Intrinsic<[llvm_anyvector_ty],
  62                 [LLVMExtendedElementVectorType<0>], [IntrNoMem]>;
  63   class Neon_2Arg_Intrinsic
  64     : Intrinsic<[llvm_anyvector_ty], [LLVMMatchType<0>, LLVMMatchType<0>],
  65                 [IntrNoMem]>;
  66   class Neon_2Arg_Narrow_Intrinsic
  67     : Intrinsic<[llvm_anyvector_ty],
  68                 [LLVMExtendedElementVectorType<0>,
  69                  LLVMExtendedElementVectorType<0>],
  70                 [IntrNoMem]>;
  71   class Neon_2Arg_Long_Intrinsic
  72     : Intrinsic<[llvm_anyvector_ty],
  73                 [LLVMTruncatedElementVectorType<0>,
  74                  LLVMTruncatedElementVectorType<0>],
  75                 [IntrNoMem]>;
  76   class Neon_3Arg_Intrinsic
  77     : Intrinsic<[llvm_anyvector_ty],
  78                 [LLVMMatchType<0>, LLVMMatchType<0>, LLVMMatchType<0>],
  79                 [IntrNoMem]>;
  80   class Neon_3Arg_Long_Intrinsic
  81     : Intrinsic<[llvm_anyvector_ty],
  82                 [LLVMMatchType<0>,
  83                  LLVMTruncatedElementVectorType<0>,
  84                  LLVMTruncatedElementVectorType<0>],
  85                 [IntrNoMem]>;
  86   class Neon_CvtFxToFP_Intrinsic
  87     : Intrinsic<[llvm_anyfloat_ty], [llvm_anyint_ty, llvm_i32_ty], [IntrNoMem]>;
  88   class Neon_CvtFPToFx_Intrinsic
  89     : Intrinsic<[llvm_anyint_ty], [llvm_anyfloat_ty, llvm_i32_ty], [IntrNoMem]>;
  90
  91   // The table operands for VTBL and VTBX consist of 1 to 4 v8i8 vectors.
  92   // Besides the table, VTBL has one other v8i8 argument and VTBX has two.
  93   // Overall, the classes range from 2 to 6 v8i8 arguments.
  94   class Neon_Tbl2Arg_Intrinsic
  95     : Intrinsic<[llvm_v8i8_ty],
  96                 [llvm_v8i8_ty, llvm_v8i8_ty], [IntrNoMem]>;
  97   class Neon_Tbl3Arg_Intrinsic
  98     : Intrinsic<[llvm_v8i8_ty],
  99                 [llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty], [IntrNoMem]>;
 100   class Neon_Tbl4Arg_Intrinsic
 101     : Intrinsic<[llvm_v8i8_ty],
 102                 [llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty],
 103                 [IntrNoMem]>;
 104   class Neon_Tbl5Arg_Intrinsic
 105     : Intrinsic<[llvm_v8i8_ty],
 106                 [llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty,
 107                  llvm_v8i8_ty], [IntrNoMem]>;
 108   class Neon_Tbl6Arg_Intrinsic
 109     : Intrinsic<[llvm_v8i8_ty],
 110                 [llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty, llvm_v8i8_ty,
 111                  llvm_v8i8_ty, llvm_v8i8_ty], [IntrNoMem]>;
 112 }
 113
 114 // Arithmetic ops
 115
 116 let Properties = [IntrNoMem, Commutative] in {
 117
 118   // Vector Add.
 119   def int_arm_neon_vhadds : Neon_2Arg_Intrinsic;
 120   def int_arm_neon_vhaddu : Neon_2Arg_Intrinsic;
 121   def int_arm_neon_vrhadds : Neon_2Arg_Intrinsic;
 122   def int_arm_neon_vrhaddu : Neon_2Arg_Intrinsic;
 123   def int_arm_neon_vqadds : Neon_2Arg_Intrinsic;
 124   def int_arm_neon_vqaddu : Neon_2Arg_Intrinsic;
 125   def int_arm_neon_vaddhn : Neon_2Arg_Narrow_Intrinsic;
 126   def int_arm_neon_vraddhn : Neon_2Arg_Narrow_Intrinsic;
 127
 128   // Vector Multiply.
 129   def int_arm_neon_vmulp : Neon_2Arg_Intrinsic;
 130   def int_arm_neon_vqdmulh : Neon_2Arg_Intrinsic;
 131   def int_arm_neon_vqrdmulh : Neon_2Arg_Intrinsic;
 132   def int_arm_neon_vmulls : Neon_2Arg_Long_Intrinsic;
 133   def int_arm_neon_vmullu : Neon_2Arg_Long_Intrinsic;
 134   def int_arm_neon_vmullp : Neon_2Arg_Long_Intrinsic;
 135   def int_arm_neon_vqdmull : Neon_2Arg_Long_Intrinsic;
 136
 137   // Vector Multiply and Accumulate/Subtract.
 138   def int_arm_neon_vqdmlal : Neon_3Arg_Long_Intrinsic;
 139   def int_arm_neon_vqdmlsl : Neon_3Arg_Long_Intrinsic;
 140
 141   // Vector Maximum.
 142   def int_arm_neon_vmaxs : Neon_2Arg_Intrinsic;
 143   def int_arm_neon_vmaxu : Neon_2Arg_Intrinsic;
 144
 145   // Vector Minimum.
 146   def int_arm_neon_vmins : Neon_2Arg_Intrinsic;
 147   def int_arm_neon_vminu : Neon_2Arg_Intrinsic;
 148
 149   // Vector Reciprocal Step.
 150   def int_arm_neon_vrecps : Neon_2Arg_Intrinsic;
 151
 152   // Vector Reciprocal Square Root Step.
 153   def int_arm_neon_vrsqrts : Neon_2Arg_Intrinsic;
 154 }
 155
 156 // Vector Subtract.
 157 def int_arm_neon_vhsubs : Neon_2Arg_Intrinsic;
 158 def int_arm_neon_vhsubu : Neon_2Arg_Intrinsic;
 159 def int_arm_neon_vqsubs : Neon_2Arg_Intrinsic;
 160 def int_arm_neon_vqsubu : Neon_2Arg_Intrinsic;
 161 def int_arm_neon_vsubhn : Neon_2Arg_Narrow_Intrinsic;
 162 def int_arm_neon_vrsubhn : Neon_2Arg_Narrow_Intrinsic;
 163
 164 // Vector Absolute Compare.
 165 let TargetPrefix = "arm" in {
 166   def int_arm_neon_vacged : Intrinsic<[llvm_v2i32_ty],
 167                                       [llvm_v2f32_ty, llvm_v2f32_ty],
 168                                       [IntrNoMem]>;
 169   def int_arm_neon_vacgeq : Intrinsic<[llvm_v4i32_ty],
 170                                       [llvm_v4f32_ty, llvm_v4f32_ty],
 171                                       [IntrNoMem]>;
 172   def int_arm_neon_vacgtd : Intrinsic<[llvm_v2i32_ty],
 173                                       [llvm_v2f32_ty, llvm_v2f32_ty],
 174                                       [IntrNoMem]>;
 175   def int_arm_neon_vacgtq : Intrinsic<[llvm_v4i32_ty],
 176                                       [llvm_v4f32_ty, llvm_v4f32_ty],
 177                                       [IntrNoMem]>;
 178 }
 179
 180 // Vector Absolute Differences.
 181 def int_arm_neon_vabds : Neon_2Arg_Intrinsic;
 182 def int_arm_neon_vabdu : Neon_2Arg_Intrinsic;
 183
 184 // Vector Pairwise Add.
 185 def int_arm_neon_vpadd : Neon_2Arg_Intrinsic;
 186
 187 // Vector Pairwise Add Long.
 188 // Note: This is different than the other "long" NEON intrinsics because
 189 // the result vector has half as many elements as the source vector.
 190 // The source and destination vector types must be specified separately.
 191 let TargetPrefix = "arm" in {
 192   def int_arm_neon_vpaddls : Intrinsic<[llvm_anyvector_ty], [llvm_anyvector_ty],
 193                                        [IntrNoMem]>;
 194   def int_arm_neon_vpaddlu : Intrinsic<[llvm_anyvector_ty], [llvm_anyvector_ty],
 195                                        [IntrNoMem]>;
 196 }
 197
 198 // Vector Pairwise Add and Accumulate Long.
 199 // Note: This is similar to vpaddl but the destination vector also appears
 200 // as the first argument.
 201 let TargetPrefix = "arm" in {
 202   def int_arm_neon_vpadals : Intrinsic<[llvm_anyvector_ty],
 203                                        [LLVMMatchType<0>, llvm_anyvector_ty],
 204                                        [IntrNoMem]>;
 205   def int_arm_neon_vpadalu : Intrinsic<[llvm_anyvector_ty],
 206                                        [LLVMMatchType<0>, llvm_anyvector_ty],
 207                                        [IntrNoMem]>;
 208 }
 209
 210 // Vector Pairwise Maximum and Minimum.
 211 def int_arm_neon_vpmaxs : Neon_2Arg_Intrinsic;
 212 def int_arm_neon_vpmaxu : Neon_2Arg_Intrinsic;
 213 def int_arm_neon_vpmins : Neon_2Arg_Intrinsic;
 214 def int_arm_neon_vpminu : Neon_2Arg_Intrinsic;
 215
 216 // Vector Shifts:
 217 //
 218 // The various saturating and rounding vector shift operations need to be
 219 // represented by intrinsics in LLVM, and even the basic VSHL variable shift
 220 // operation cannot be safely translated to LLVM's shift operators.  VSHL can
 221 // be used for both left and right shifts, or even combinations of the two,
 222 // depending on the signs of the shift amounts.  It also has well-defined
 223 // behavior for shift amounts that LLVM leaves undefined.  Only basic shifts
 224 // by constants can be represented with LLVM's shift operators.
 225 //
 226 // The shift counts for these intrinsics are always vectors, even for constant
 227 // shifts, where the constant is replicated.  For consistency with VSHL (and
 228 // other variable shift instructions), left shifts have positive shift counts
 229 // and right shifts have negative shift counts.  This convention is also used
 230 // for constant right shift intrinsics, and to help preserve sanity, the
 231 // intrinsic names use "shift" instead of either "shl" or "shr".  Where
 232 // applicable, signed and unsigned versions of the intrinsics are
 233 // distinguished with "s" and "u" suffixes.  A few NEON shift instructions,
 234 // such as VQSHLU, take signed operands but produce unsigned results; these
 235 // use a "su" suffix.
 236
 237 // Vector Shift.
 238 def int_arm_neon_vshifts : Neon_2Arg_Intrinsic;
 239 def int_arm_neon_vshiftu : Neon_2Arg_Intrinsic;
 240 def int_arm_neon_vshiftls : Neon_2Arg_Long_Intrinsic;
 241 def int_arm_neon_vshiftlu : Neon_2Arg_Long_Intrinsic;
 242 def int_arm_neon_vshiftn : Neon_2Arg_Narrow_Intrinsic;
 243
 244 // Vector Rounding Shift.
 245 def int_arm_neon_vrshifts : Neon_2Arg_Intrinsic;
 246 def int_arm_neon_vrshiftu : Neon_2Arg_Intrinsic;
 247 def int_arm_neon_vrshiftn : Neon_2Arg_Narrow_Intrinsic;
 248
 249 // Vector Saturating Shift.
 250 def int_arm_neon_vqshifts : Neon_2Arg_Intrinsic;
 251 def int_arm_neon_vqshiftu : Neon_2Arg_Intrinsic;
 252 def int_arm_neon_vqshiftsu : Neon_2Arg_Intrinsic;
 253 def int_arm_neon_vqshiftns : Neon_2Arg_Narrow_Intrinsic;
 254 def int_arm_neon_vqshiftnu : Neon_2Arg_Narrow_Intrinsic;
 255 def int_arm_neon_vqshiftnsu : Neon_2Arg_Narrow_Intrinsic;
 256
 257 // Vector Saturating Rounding Shift.
 258 def int_arm_neon_vqrshifts : Neon_2Arg_Intrinsic;
 259 def int_arm_neon_vqrshiftu : Neon_2Arg_Intrinsic;
 260 def int_arm_neon_vqrshiftns : Neon_2Arg_Narrow_Intrinsic;
 261 def int_arm_neon_vqrshiftnu : Neon_2Arg_Narrow_Intrinsic;
 262 def int_arm_neon_vqrshiftnsu : Neon_2Arg_Narrow_Intrinsic;
 263
 264 // Vector Shift and Insert.
 265 def int_arm_neon_vshiftins : Neon_3Arg_Intrinsic;
 266
 267 // Vector Absolute Value and Saturating Absolute Value.
 268 def int_arm_neon_vabs : Neon_1Arg_Intrinsic;
 269 def int_arm_neon_vqabs : Neon_1Arg_Intrinsic;
 270
 271 // Vector Saturating Negate.
 272 def int_arm_neon_vqneg : Neon_1Arg_Intrinsic;
 273
 274 // Vector Count Leading Sign/Zero Bits.
 275 def int_arm_neon_vcls : Neon_1Arg_Intrinsic;
 276 def int_arm_neon_vclz : Neon_1Arg_Intrinsic;
 277
 278 // Vector Count One Bits.
 279 def int_arm_neon_vcnt : Neon_1Arg_Intrinsic;
 280
 281 // Vector Reciprocal Estimate.
 282 def int_arm_neon_vrecpe : Neon_1Arg_Intrinsic;
 283
 284 // Vector Reciprocal Square Root Estimate.
 285 def int_arm_neon_vrsqrte : Neon_1Arg_Intrinsic;
 286
 287 // Vector Conversions Between Floating-point and Fixed-point.
 288 def int_arm_neon_vcvtfp2fxs : Neon_CvtFPToFx_Intrinsic;
 289 def int_arm_neon_vcvtfp2fxu : Neon_CvtFPToFx_Intrinsic;
 290 def int_arm_neon_vcvtfxs2fp : Neon_CvtFxToFP_Intrinsic;
 291 def int_arm_neon_vcvtfxu2fp : Neon_CvtFxToFP_Intrinsic;
 292
 293 // Vector Conversions Between Half-Precision and Single-Precision.
 294 def int_arm_neon_vcvtfp2hf
 295     : Intrinsic<[llvm_v4i16_ty], [llvm_v4f32_ty], [IntrNoMem]>;
 296 def int_arm_neon_vcvthf2fp
 297     : Intrinsic<[llvm_v4f32_ty], [llvm_v4i16_ty], [IntrNoMem]>;
 298
 299 // Narrowing Saturating Vector Moves.
 300 def int_arm_neon_vqmovns : Neon_1Arg_Narrow_Intrinsic;
 301 def int_arm_neon_vqmovnu : Neon_1Arg_Narrow_Intrinsic;
 302 def int_arm_neon_vqmovnsu : Neon_1Arg_Narrow_Intrinsic;
 303
 304 // Vector Table Lookup.
 305 // The first 1-4 arguments are the table.
 306 def int_arm_neon_vtbl1 : Neon_Tbl2Arg_Intrinsic;
 307 def int_arm_neon_vtbl2 : Neon_Tbl3Arg_Intrinsic;
 308 def int_arm_neon_vtbl3 : Neon_Tbl4Arg_Intrinsic;
 309 def int_arm_neon_vtbl4 : Neon_Tbl5Arg_Intrinsic;
 310
 311 // Vector Table Extension.
 312 // Some elements of the destination vector may not be updated, so the original
 313 // value of that vector is passed as the first argument.  The next 1-4
 314 // arguments after that are the table.
 315 def int_arm_neon_vtbx1 : Neon_Tbl3Arg_Intrinsic;
 316 def int_arm_neon_vtbx2 : Neon_Tbl4Arg_Intrinsic;
 317 def int_arm_neon_vtbx3 : Neon_Tbl5Arg_Intrinsic;
 318 def int_arm_neon_vtbx4 : Neon_Tbl6Arg_Intrinsic;
 319
 320 let TargetPrefix = "arm" in {
 321
 322   // De-interleaving vector loads from N-element structures.
 323   // Source operands are the address and alignment.
 324   def int_arm_neon_vld1 : Intrinsic<[llvm_anyvector_ty],
 325                                     [llvm_ptr_ty, llvm_i32_ty],
 326                                     [IntrReadArgMem]>;
 327   def int_arm_neon_vld2 : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>],
 328                                     [llvm_ptr_ty, llvm_i32_ty],
 329                                     [IntrReadArgMem]>;
 330   def int_arm_neon_vld3 : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>,
 331                                      LLVMMatchType<0>],
 332                                     [llvm_ptr_ty, llvm_i32_ty],
 333                                     [IntrReadArgMem]>;
 334   def int_arm_neon_vld4 : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>,
 335                                      LLVMMatchType<0>, LLVMMatchType<0>],
 336                                     [llvm_ptr_ty, llvm_i32_ty],
 337                                     [IntrReadArgMem]>;
 338
 339   // Vector load N-element structure to one lane.
 340   // Source operands are: the address, the N input vectors (since only one
 341   // lane is assigned), the lane number, and the alignment.
 342   def int_arm_neon_vld2lane : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>],
 343                                         [llvm_ptr_ty, LLVMMatchType<0>,
 344                                          LLVMMatchType<0>, llvm_i32_ty,
 345                                          llvm_i32_ty], [IntrReadArgMem]>;
 346   def int_arm_neon_vld3lane : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>,
 347                                          LLVMMatchType<0>],
 348                                         [llvm_ptr_ty, LLVMMatchType<0>,
 349                                          LLVMMatchType<0>, LLVMMatchType<0>,
 350                                          llvm_i32_ty, llvm_i32_ty],
 351                                         [IntrReadArgMem]>;
 352   def int_arm_neon_vld4lane : Intrinsic<[llvm_anyvector_ty, LLVMMatchType<0>,
 353                                          LLVMMatchType<0>, LLVMMatchType<0>],
 354                                         [llvm_ptr_ty, LLVMMatchType<0>,
 355                                          LLVMMatchType<0>, LLVMMatchType<0>,
 356                                          LLVMMatchType<0>, llvm_i32_ty,
 357                                          llvm_i32_ty], [IntrReadArgMem]>;
 358
 359   // Interleaving vector stores from N-element structures.
 360   // Source operands are: the address, the N vectors, and the alignment.
 361   def int_arm_neon_vst1 : Intrinsic<[],
 362                                     [llvm_ptr_ty, llvm_anyvector_ty,
 363                                      llvm_i32_ty], [IntrReadWriteArgMem]>;
 364   def int_arm_neon_vst2 : Intrinsic<[],
 365                                     [llvm_ptr_ty, llvm_anyvector_ty,
 366                                      LLVMMatchType<0>, llvm_i32_ty],
 367                                     [IntrReadWriteArgMem]>;
 368   def int_arm_neon_vst3 : Intrinsic<[],
 369                                     [llvm_ptr_ty, llvm_anyvector_ty,
 370                                      LLVMMatchType<0>, LLVMMatchType<0>,
 371                                      llvm_i32_ty], [IntrReadWriteArgMem]>;
 372   def int_arm_neon_vst4 : Intrinsic<[],
 373                                     [llvm_ptr_ty, llvm_anyvector_ty,
 374                                      LLVMMatchType<0>, LLVMMatchType<0>,
 375                                      LLVMMatchType<0>, llvm_i32_ty],
 376                                     [IntrReadWriteArgMem]>;
 377
 378   // Vector store N-element structure from one lane.
 379   // Source operands are: the address, the N vectors, the lane number, and
 380   // the alignment.
 381   def int_arm_neon_vst2lane : Intrinsic<[],
 382                                         [llvm_ptr_ty, llvm_anyvector_ty,
 383                                          LLVMMatchType<0>, llvm_i32_ty,
 384                                          llvm_i32_ty], [IntrReadWriteArgMem]>;
 385   def int_arm_neon_vst3lane : Intrinsic<[],
 386                                         [llvm_ptr_ty, llvm_anyvector_ty,
 387                                          LLVMMatchType<0>, LLVMMatchType<0>,
 388                                          llvm_i32_ty, llvm_i32_ty],
 389                                         [IntrReadWriteArgMem]>;
 390   def int_arm_neon_vst4lane : Intrinsic<[],
 391                                         [llvm_ptr_ty, llvm_anyvector_ty,
 392                                          LLVMMatchType<0>, LLVMMatchType<0>,
 393                                          LLVMMatchType<0>, llvm_i32_ty,
 394                                          llvm_i32_ty], [IntrReadWriteArgMem]>;
 395 }