lib/AsmParser/Lexer.l

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "llvmAsmParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 void set_scan_file(FILE * F){
  36   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  37 }
  38 void set_scan_string (const char * str) {
  39   yy_scan_string (str);
  40 }
  41
  42 #define RET_TOK(type, Enum, sym) \
  43   llvmAsmlval.type = Instruction::Enum; return sym
  44
  45 namespace llvm {
  46
  47 // TODO: All of the static identifiers are figured out by the lexer,
  48 // these should be hashed to reduce the lexer size
  49
  50
  51 // atoull - Convert an ascii string of decimal digits into the unsigned long
  52 // long representation... this does not have to do input error checking,
  53 // because we know that the input will be matched by a suitable regex...
  54 //
  55 static uint64_t atoull(const char *Buffer) {
  56   uint64_t Result = 0;
  57   for (; *Buffer; Buffer++) {
  58     uint64_t OldRes = Result;
  59     Result *= 10;
  60     Result += *Buffer-'0';
  61     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  62       ThrowException("constant bigger than 64 bits detected!");
  63   }
  64   return Result;
  65 }
  66
  67 static uint64_t HexIntToVal(const char *Buffer) {
  68   uint64_t Result = 0;
  69   for (; *Buffer; ++Buffer) {
  70     uint64_t OldRes = Result;
  71     Result *= 16;
  72     char C = *Buffer;
  73     if (C >= '0' && C <= '9')
  74       Result += C-'0';
  75     else if (C >= 'A' && C <= 'F')
  76       Result += C-'A'+10;
  77     else if (C >= 'a' && C <= 'f')
  78       Result += C-'a'+10;
  79
  80     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  81       ThrowException("constant bigger than 64 bits detected!");
  82   }
  83   return Result;
  84 }
  85
  86
  87 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  88 // point representation of it.
  89 //
  90 static double HexToFP(const char *Buffer) {
  91   // Behave nicely in the face of C TBAA rules... see:
  92   // http://www.nullstone.com/htmls/category/aliastyp.htm
  93   union {
  94     uint64_t UI;
  95     double FP;
  96   } UIntToFP;
  97   UIntToFP.UI = HexIntToVal(Buffer);
  98
  99   assert(sizeof(double) == sizeof(uint64_t) &&
 100          "Data sizes incompatible on this target!");
 101   return UIntToFP.FP;   // Cast Hex constant to double
 102 }
 103
 104
 105 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 106 // appropriate character.  If AllowNull is set to false, a \00 value will cause
 107 // an exception to be thrown.
 108 //
 109 // If AllowNull is set to true, the return value of the function points to the
 110 // last character of the string in memory.
 111 //
 112 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
 113   char *BOut = Buffer;
 114   for (char *BIn = Buffer; *BIn; ) {
 115     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 116       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
 117       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
 118       if (!AllowNull && !*BOut)
 119         ThrowException("String literal cannot accept \\00 escape!");
 120
 121       BIn[3] = Tmp;                  // Restore character
 122       BIn += 3;                      // Skip over handled chars
 123       ++BOut;
 124     } else {
 125       *BOut++ = *BIn++;
 126     }
 127   }
 128
 129   return BOut;
 130 }
 131
 132 } // End llvm namespace
 133
 134 using namespace llvm;
 135
 136 #define YY_NEVER_INTERACTIVE 1
 137 %}
 138
 139
 140
 141 /* Comments start with a ; and go till end of line */
 142 Comment    ;.*
 143
 144 /* Variable(Value) identifiers start with a % sign */
 145 VarID       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 146
 147 /* Label identifiers end with a colon */
 148 Label       [-a-zA-Z$._0-9]+:
 149 QuoteLabel \"[^\"]+\":
 150
 151 /* Quoted names can contain any character except " and \ */
 152 StringConstant \"[^\"]*\"
 153
 154
 155 /* [PN]Integer: match positive and negative literal integer values that
 156  * are preceeded by a '%' character.  These represent unnamed variable slots.
 157  */
 158 EPInteger     %[0-9]+
 159 ENInteger    %-[0-9]+
 160
 161
 162 /* E[PN]Integer: match positive and negative literal integer values */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179 %%
 180
 181 {Comment}       { /* Ignore comments for now */ }
 182
 183 begin           { return BEGINTOK; }
 184 end             { return ENDTOK; }
 185 true            { return TRUETOK;  }
 186 false           { return FALSETOK; }
 187 declare         { return DECLARE; }
 188 global          { return GLOBAL; }
 189 constant        { return CONSTANT; }
 190 internal        { return INTERNAL; }
 191 linkonce        { return LINKONCE; }
 192 weak            { return WEAK; }
 193 appending       { return APPENDING; }
 194 uninitialized   { return EXTERNAL; }    /* Deprecated, turn into external */
 195 external        { return EXTERNAL; }
 196 implementation  { return IMPLEMENTATION; }
 197 zeroinitializer { return ZEROINITIALIZER; }
 198 \.\.\.          { return DOTDOTDOT; }
 199 undef           { return UNDEF; }
 200 null            { return NULL_TOK; }
 201 to              { return TO; }
 202 except          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 203 not             { return NOT; }  /* Deprecated, turned into XOR */
 204 tail            { return TAIL; }
 205 target          { return TARGET; }
 206 triple          { return TRIPLE; }
 207 deplibs         { return DEPLIBS; }
 208 endian          { return ENDIAN; }
 209 pointersize     { return POINTERSIZE; }
 210 little          { return LITTLE; }
 211 big             { return BIG; }
 212 volatile        { return VOLATILE; }
 213 align           { return ALIGN;  }
 214 section         { return SECTION; }
 215
 216 cc              { return CC_TOK; }
 217 ccc             { return CCC_TOK; }
 218 fastcc          { return FASTCC_TOK; }
 219 coldcc          { return COLDCC_TOK; }
 220
 221 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 222 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 223 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 224 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 225 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 226 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 227 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 228 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 229 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 230 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 231 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 232 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 233 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 234 type            { return TYPE;   }
 235 opaque          { return OPAQUE; }
 236
 237 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 238 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 239 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 240 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 241 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 242 and             { RET_TOK(BinaryOpVal, And, AND); }
 243 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 244 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 245 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 246 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 247 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 248 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 249 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 250 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 251
 252 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 253 call            { RET_TOK(OtherOpVal, Call, CALL); }
 254 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 255 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 256 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 257 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 258 vanext          { return VANEXT_old; }
 259 vaarg           { return VAARG_old; }
 260 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 261 ret             { RET_TOK(TermOpVal, Ret, RET); }
 262 br              { RET_TOK(TermOpVal, Br, BR); }
 263 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 264 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 265 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 266 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 267
 268 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 269 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 270 free            { RET_TOK(MemOpVal, Free, FREE); }
 271 load            { RET_TOK(MemOpVal, Load, LOAD); }
 272 store           { RET_TOK(MemOpVal, Store, STORE); }
 273 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 274
 275
 276 {VarID}         {
 277                   UnEscapeLexed(yytext+1);
 278                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 279                   return VAR_ID;
 280                 }
 281 {Label}         {
 282                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 283                   UnEscapeLexed(yytext);
 284                   llvmAsmlval.StrVal = strdup(yytext);
 285                   return LABELSTR;
 286                 }
 287 {QuoteLabel}    {
 288                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 289                   UnEscapeLexed(yytext+1);
 290                   llvmAsmlval.StrVal = strdup(yytext+1);
 291                   return LABELSTR;
 292                 }
 293
 294 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 295                    // string constant might contain a \00 which would not be
 296                    // understood by the string stuff.  It is valid to make a
 297                    // [sbyte] c"Hello World\00" constant, for example.
 298                    //
 299                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 300                    llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 301                    return STRINGCONSTANT;
 302                  }
 303
 304
 305 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 306 {NInteger}      {
 307                   uint64_t Val = atoull(yytext+1);
 308                   // +1:  we have bigger negative range
 309                   if (Val > (uint64_t)INT64_MAX+1)
 310                     ThrowException("Constant too large for signed 64 bits!");
 311                   llvmAsmlval.SInt64Val = -Val;
 312                   return ESINT64VAL;
 313                 }
 314 {HexIntConstant} {
 315                    llvmAsmlval.UInt64Val = HexIntToVal(yytext+3);
 316                    return yytext[0] == 's' ? ESINT64VAL : EUINT64VAL;
 317                  }
 318
 319 {EPInteger}     {
 320                   uint64_t Val = atoull(yytext+1);
 321                   if ((unsigned)Val != Val)
 322                     ThrowException("Invalid value number (too large)!");
 323                   llvmAsmlval.UIntVal = unsigned(Val);
 324                   return UINTVAL;
 325                 }
 326 {ENInteger}     {
 327                   uint64_t Val = atoull(yytext+2);
 328                   // +1:  we have bigger negative range
 329                   if (Val > (uint64_t)INT32_MAX+1)
 330                     ThrowException("Constant too large for signed 32 bits!");
 331                   llvmAsmlval.SIntVal = (int)-Val;
 332                   return SINTVAL;
 333                 }
 334
 335 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 336 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 337
 338 <<EOF>>         {
 339                   /* Make sure to free the internal buffers for flex when we are
 340                    * done reading our input!
 341                    */
 342                   yy_delete_buffer(YY_CURRENT_BUFFER);
 343                   return EOF;
 344                 }
 345
 346 [ \r\t\n]       { /* Ignore whitespace */ }
 347 .               { return yytext[0]; }
 348
 349 %%