lib/AsmParser/Lexer.l

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //  This file implements the flex scanner for LLVM assembly languages files.
   4 //
   5 //===----------------------------------------------------------------------===*/
   6
   7 %option prefix="llvmAsm"
   8 %option yylineno
   9 %option nostdinit
  10 %option never-interactive
  11 %option batch
  12 %option noyywrap
  13 %option nodefault
  14 %option 8bit
  15 %option outfile="Lexer.cpp"
  16 %option ecs
  17 %option noreject
  18 %option noyymore
  19
  20 %{
  21 #include "ParserInternals.h"
  22 #include <list>
  23 #include "llvmAsmParser.h"
  24 #include <ctype.h>
  25 #include <stdlib.h>
  26
  27 #define RET_TOK(type, Enum, sym) \
  28   llvmAsmlval.type = Instruction::Enum; return sym
  29
  30
  31 // TODO: All of the static identifiers are figured out by the lexer,
  32 // these should be hashed to reduce the lexer size
  33
  34
  35 // atoull - Convert an ascii string of decimal digits into the unsigned long
  36 // long representation... this does not have to do input error checking,
  37 // because we know that the input will be matched by a suitable regex...
  38 //
  39 static uint64_t atoull(const char *Buffer) {
  40   uint64_t Result = 0;
  41   for (; *Buffer; Buffer++) {
  42     uint64_t OldRes = Result;
  43     Result *= 10;
  44     Result += *Buffer-'0';
  45     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  46       ThrowException("constant bigger than 64 bits detected!");
  47   }
  48   return Result;
  49 }
  50
  51 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  52 // point representation of it.
  53 //
  54 static double HexToFP(const char *Buffer) {
  55   uint64_t Result = 0;
  56   for (; *Buffer; ++Buffer) {
  57     uint64_t OldRes = Result;
  58     Result *= 16;
  59     char C = *Buffer;
  60     if (C >= '0' && C <= '9')
  61       Result += C-'0';
  62     else if (C >= 'A' && C <= 'F')
  63       Result += C-'A'+10;
  64     else if (C >= 'a' && C <= 'f')
  65       Result += C-'a'+10;
  66
  67     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  68       ThrowException("constant bigger than 64 bits detected!");
  69   }
  70
  71   assert(sizeof(double) == sizeof(Result) &&
  72          "Data sizes incompatible on this target!");
  73   // Behave nicely in the face of C TBAA rules... see:
  74   // http://www.nullstone.com/htmls/category/aliastyp.htm
  75   //
  76   char *ProxyPointer = (char*)&Result;
  77   return *(double*)ProxyPointer;   // Cast Hex constant to double
  78 }
  79
  80
  81 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
  82 // appropriate character.  If AllowNull is set to false, a \00 value will cause
  83 // an exception to be thrown.
  84 //
  85 // If AllowNull is set to true, the return value of the function points to the
  86 // last character of the string in memory.
  87 //
  88 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
  89   char *BOut = Buffer;
  90   for (char *BIn = Buffer; *BIn; ) {
  91     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
  92       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
  93       *BOut = strtol(BIn+1, 0, 16);  // Convert to number
  94       if (!AllowNull && !*BOut)
  95         ThrowException("String literal cannot accept \\00 escape!");
  96
  97       BIn[3] = Tmp;                  // Restore character
  98       BIn += 3;                      // Skip over handled chars
  99       ++BOut;
 100     } else {
 101       *BOut++ = *BIn++;
 102     }
 103   }
 104
 105   return BOut;
 106 }
 107
 108 #define YY_NEVER_INTERACTIVE 1
 109 %}
 110
 111
 112
 113 /* Comments start with a ; and go till end of line */
 114 Comment    ;.*
 115
 116 /* Variable(Value) identifiers start with a % sign */
 117 VarID       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 118
 119 /* Label identifiers end with a colon */
 120 Label       [-a-zA-Z$._0-9]+:
 121
 122 /* Quoted names can contain any character except " and \ */
 123 StringConstant \"[^\"]+\"
 124
 125
 126 /* [PN]Integer: match positive and negative literal integer values that
 127  * are preceeded by a '%' character.  These represent unnamed variable slots.
 128  */
 129 EPInteger     %[0-9]+
 130 ENInteger    %-[0-9]+
 131
 132
 133 /* E[PN]Integer: match positive and negative literal integer values */
 134 PInteger   [0-9]+
 135 NInteger  -[0-9]+
 136
 137 /* FPConstant - A Floating point constant.
 138  */
 139 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 140
 141 /* HexFPConstant - Floating point constant represented in IEEE format as a
 142  *  hexadecimal number for when exponential notation is not precise enough.
 143  */
 144 HexFPConstant 0x[0-9A-Fa-f]+
 145 %%
 146
 147 {Comment}       { /* Ignore comments for now */ }
 148
 149 begin           { return BEGINTOK; }
 150 end             { return ENDTOK; }
 151 true            { return TRUE;  }
 152 false           { return FALSE; }
 153 declare         { return DECLARE; }
 154 global          { return GLOBAL; }
 155 constant        { return CONSTANT; }
 156 const           { return CONST; }
 157 internal        { return INTERNAL; }
 158 uninitialized   { return UNINIT; }
 159 implementation  { return IMPLEMENTATION; }
 160 \.\.\.          { return DOTDOTDOT; }
 161 string          { return STRING; }
 162 null            { return NULL_TOK; }
 163 to              { return TO; }
 164 except          { return EXCEPT; }
 165 not             { return NOT; }  /* Deprecated, turned into XOR */
 166
 167 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 168 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 169 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 170 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 171 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 172 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 173 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 174 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 175 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 176 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 177 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 178 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 179 type            { llvmAsmlval.PrimType = Type::TypeTy  ; return TYPE;   }
 180 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 181 opaque          { return OPAQUE; }
 182
 183 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 184 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 185 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 186 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 187 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 188 and             { RET_TOK(BinaryOpVal, And, AND); }
 189 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 190 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 191 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 192 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 193 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 194 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 195 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 196 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 197
 198 phi             { RET_TOK(OtherOpVal, PHINode, PHI); }
 199 call            { RET_TOK(OtherOpVal, Call, CALL); }
 200 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 201 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 202 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 203
 204 ret             { RET_TOK(TermOpVal, Ret, RET); }
 205 br              { RET_TOK(TermOpVal, Br, BR); }
 206 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 207 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 208
 209
 210 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 211 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 212 free            { RET_TOK(MemOpVal, Free, FREE); }
 213 load            { RET_TOK(MemOpVal, Load, LOAD); }
 214 store           { RET_TOK(MemOpVal, Store, STORE); }
 215 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 216
 217
 218 {VarID}         {
 219                   UnEscapeLexed(yytext+1);
 220                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 221                   return VAR_ID;
 222                 }
 223 {Label}         {
 224                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 225                   UnEscapeLexed(yytext);
 226                   llvmAsmlval.StrVal = strdup(yytext);
 227                   return LABELSTR;
 228                 }
 229
 230 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 231                    // string constant might contain a \00 which would not be
 232                    // understood by the string stuff.  It is valid to make a
 233                    // [sbyte] c"Hello World\00" constant, for example.
 234                    //
 235                   yytext[strlen(yytext)-1] = 0;           // nuke end quote
 236                   llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 237                   return STRINGCONSTANT;
 238                  }
 239
 240
 241 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 242 {NInteger}      {
 243                   uint64_t Val = atoull(yytext+1);
 244                   // +1:  we have bigger negative range
 245                   if (Val > (uint64_t)INT64_MAX+1)
 246                     ThrowException("Constant too large for signed 64 bits!");
 247                   llvmAsmlval.SInt64Val = -Val;
 248                   return ESINT64VAL;
 249                 }
 250
 251
 252 {EPInteger}     { llvmAsmlval.UIntVal = atoull(yytext+1); return UINTVAL; }
 253 {ENInteger}     {
 254                   uint64_t Val = atoull(yytext+2);
 255                   // +1:  we have bigger negative range
 256                   if (Val > (uint64_t)INT32_MAX+1)
 257                     ThrowException("Constant too large for signed 32 bits!");
 258                   llvmAsmlval.SIntVal = -Val;
 259                   return SINTVAL;
 260                 }
 261
 262 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 263 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 264
 265 [ \t\n]         { /* Ignore whitespace */ }
 266 .               { return yytext[0]; }
 267
 268 %%